Udžbenik pokazuje nekoliko brzih i jednostavnih načina skraćivanja Excel prostora. Naučite kako ukloniti početne, završne i dodatne razmake između riječi, zašto funkcija Excel TRIM ne radi i kako to popraviti.

Usređujete li dva stupca za duplikate za koje znate da postoje, ali vaše formule ne mogu pronaći niti jedan duplikat? Ili zbrajate dva stupca brojeva, ali dobivate samo nule? I zašto, zaboga, vaša očito ispravna Vlookup formula vraća samo hrpu N/A pogrešaka? Ovo je samo nekoliko primjera problema na koje možda tražite odgovore. A sve su uzrokovane dodatnim razmacima koji se skrivaju prije, iza ili između numeričkih i tekstualnih vrijednosti u vašim ćelijama.

Microsoft Excel nudi nekoliko različitih načina za uklanjanje razmaka i očistite svoje podatke. U ovom ćemo vodiču istražiti mogućnosti funkcije TRIM kao najbržeg i najlakšeg načina za brisanje razmaka u Excelu.

Funkcija TRIM - uklonite višak razmaka u Excelu

Koristite funkciju TRIM u programu Excel koja uklanja dodatne razmake iz teksta. Briše sve razmake na početku, na kraju i razmake između osim jednog znaka razmaka između riječi.

Sintaksa funkcije TRIM je najlakša koju možete zamisliti:

TRIM( tekst)

Gdje je tekst ćelija iz koje želite ukloniti višak razmaka.

Na primjer, da biste uklonili razmake u ćeliji A1, koristite ovoformula:

=TRIM(A1)

I sljedeća snimka zaslona prikazuje rezultat:

Da, tako je jednostavno!

Imajte na umu da funkcija TRIM dizajnirana je za uklanjanje samo znaka za razmak, koji ima vrijednost 32 u 7-bitnom ASCII kodnom sustavu. Ako uz dodatne razmake vaši podaci sadrže prijelome retka i neispisne znakove, upotrijebite funkciju TRIM u kombinaciji s CLEAN za brisanje prva 32 neispisiva znaka u ASCII sustavu.

Na primjer, za uklonite razmake, prijelome redaka i druge neželjene znakove iz ćelije A1, upotrijebite ovu formulu:

=TRIM(CLEAN(A1))

Za više informacija pogledajte Kako ukloniti znakove koji se ne ispisuju u programu Excel

Da biste se riješili neprekinutih razmaka (html znak ), koji ima vrijednost 160, koristite TRIM zajedno s funkcijama SUBSTITUTE i CHAR:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Za sve detalje, molimo pogledajte Kako izbrisati neprekinute razmake u Excelu

Kako koristiti funkciju TRIM u Excelu - primjeri formula

Sada kada znate osnove, razgovarajmo o nekoliko specifičnih upotreba TRIM-a u Excelu, zamke s kojima se možete suočiti i radna rješenja.

Kako smanjiti razmake u cijelom stupcu podataka

Pretpostavimo da imate stupac imena koji također imaju razmake prije i iza teksta što više od jednog razmaka između riječi. Dakle, kako ukloniti sve početne, zadnje i višak razmaka između u svim ćelijama odjednom? Kopiranjem ExcelaTRIM formulu preko stupca, a zatim zamjenjujući formule njihovim vrijednostima. Detaljni koraci slijede u nastavku.

1. Napišite formulu TRIM za najvišu ćeliju, A2 u našem primjeru:

   =TRIM(A2)

2. Postavite kursor u donji desni kut ćelije formule (B2 u ovom primjeru), a čim se kursor pretvori u znak plusa, dvaput kliknite na njega da kopirate formulu niz stupac, do zadnje ćelije s podacima. Kao rezultat, imat ćete 2 stupca - izvorna imena s razmacima i skraćena imena vođena formulama.

Na kraju, zamijenite vrijednosti u izvornom stupcu s skraćeni podaci. Ali budi pažljiv! Jednostavno kopiranje skraćenog stupca preko izvornog stupca uništilo bi vaše formule. Da se to ne dogodi, morate kopirati samo vrijednosti, a ne formule. Evo kako:

• Odaberite sve ćelije s Trim formulama (B2:B8 u ovom primjeru) i pritisnite Ctrl+C da ih kopirate.
• Odaberite sve ćelije s izvornim podacima (A2:A8 ), i pritisnite Ctrl+Alt+V , zatim V . Prečac za lijepljenje vrijednosti primjenjuje Posebno lijepljenje > Vrijednosti
• Pritisnite tipku Enter. Gotovo!

Kako ukloniti vodeće razmake u numeričkom stupcu

Kao što ste upravo vidjeli, funkcija Excel TRIM uklonila je sve dodatne razmake iz stupca tekstualnih podataka bez zastoj. Ali što ako su vaši podaci brojevi, a ne tekst?

Na prvi pogled može se činiti daTRIM funkcija je obavila svoj posao. Međutim, ako bolje pogledate, primijetit ćete da se skraćene vrijednosti ne ponašaju kao brojevi. Evo samo nekoliko pokazatelja abnormalnosti:

• I izvorni stupac s vodećim razmacima i skraćeni brojevi poravnati su lijevo čak i ako na ćelije primijenite format broja, dok su normalni brojevi desno poravnati prema zadanim postavkama.
• Kada su odabrane dvije ili više ćelija s skraćenim brojevima, Excel na statusnoj traci prikazuje samo COUNT. Za brojeve bi također trebao prikazivati ​​SUM i AVERAGE.
• Formula SUM primijenjena na skraćene ćelije vraća nulu.

Po svemu sudeći, skraćene vrijednosti su tekstualni nizovi , dok mi želimo brojeve. Da biste to popravili, možete pomnožiti skraćene vrijednosti s 1 (za množenje svih vrijednosti jednim potezom, upotrijebite opciju Posebno lijepljenje > Množenje).

Elegantnije rješenje je uključivanje funkcije TRIM u VRIJEDNOST , ovako:

=VALUE(TRIM(A2))

Gornja formula uklanja sve razmake na početku i na kraju, ako ih ima, i pretvara dobivenu vrijednost u broj, kao što je prikazano na snimci zaslona u nastavku:

Kako ukloniti samo početne razmake u Excelu (lijevo skraćivanje)

U nekim situacijama možete upisivati ​​duplicirane ili čak utrostručene razmake između riječi kako bi vaši podaci bili čitljiviji. Međutim, želite se riješiti vodećih razmaka, ovako:

Kao što već znate, funkcija TRIMeliminira dodatne razmake u sredini tekstualnih nizova, što nije ono što želimo. Kako bi svi razmaci između ostali netaknuti, koristit ćemo malo složeniju formulu:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

U gornjoj formuli, kombinacija FIND, MID i TRIM izračunava položaj prvi tekstualni znak u nizu. Zatim dostavite taj broj drugoj MID funkciji tako da vrati cijeli tekstualni niz (dužinu niza izračunava LEN) počevši od položaja prvog tekstualnog znaka.

Sljedeća snimka zaslona pokazuje da su svi vodeći razmaci su nestali, dok višestruki razmaci između riječi još uvijek postoje:

Kao završni detalj, zamijenite izvorni tekst skraćenim vrijednostima, kao što je prikazano u koraku 3 primjera formule Trim , i spremni ste!

Savjet. Ako također želite ukloniti razmake s kraja ćelija, upotrijebite alat Trim Spaces. Ne postoji očita Excel formula za uklanjanje razmaka na početku i na kraju, a da višestruki razmaci između riječi ostanu netaknuti.

Kako prebrojati dodatne razmake u ćeliji

Ponekad, prije nego što uklonite razmake u svom Excel listu, možda ćete htjeti znati koliko viška mjesta zapravo ima.

Da biste dobili broj dodatnih razmaka u ćeliji, saznajte ukupnu duljinu teksta pomoću funkcije LEN, zatim izračunajte duljinu niza bez dodatnih razmaka i oduzmite potonju od prve:

=LEN(A2)-LEN(TRIM(A2))

Sljedećesnimka zaslona prikazuje gornju formulu na djelu:

Napomena. Formula vraća broj dodatnih razmaka u ćeliji, tj. početnih, završnih i više od jednog uzastopnog razmaka između riječi, ali ne broji pojedinačne razmake u sredini teksta. Ako želite dobiti ukupan broj razmaka u ćeliji, upotrijebite ovu formulu zamjene.

Kako istaknuti ćelije s viškom razmaka

Kada radite s osjetljivim ili važnim informacijama, možda ćete oklijevati izbrisati bilo što, a da ne vidite što točno brišete. U ovom slučaju, prvo možete označiti ćelije koje sadrže dodatne razmake, a zatim sigurno ukloniti te razmake.

Za to izradite pravilo uvjetnog oblikovanja sa sljedećom formulom:

=LEN($A2)>LEN(TRIM($A2))

Gdje je A2 najviša ćelija s podacima koje želite istaknuti.

Formula upućuje Excel da označi ćelije u kojima je ukupna duljina niza veća od duljine skraćenog teksta.

Da biste stvorili pravilo uvjetnog oblikovanja, odaberite sve ćelije (retke) koje želite istaknuti bez zaglavlja stupaca, idite na karticu Početna > Stilovi grupu i kliknite Uvjetno oblikovanje > Novo pravilo > Upotrijebite formulu da odredite koje ćelije oblikovati .

Ako još niste upoznati s uvjetnim oblikovanjem programa Excel , ovdje ćete pronaći detaljne korake: Kako stvoriti pravilo uvjetnog oblikovanja na temeljuformula.

Kao što je prikazano na snimci zaslona u nastavku, rezultat savršeno potvrđuje dodatni broj razmaka koji smo dobili u prethodnom primjeru:

Kao što vidite, upotreba funkcije TRIM u Excelu je jednostavan i jasan. Unatoč tome, ako netko želi pobliže pogledati formule o kojima se govori u ovom vodiču, slobodno možete preuzeti radnu knjigu Trim Excel Spaces.

Excel TRIM ne radi

Funkcija TRIM samo uklanja razmak predstavljen vrijednošću koda 32 u 7-bitnom ASCII skupu znakova. U Unicode skupu znakova postoji još jedan razmak koji se zove neprekidni razmak, koji se obično koristi na web stranicama kao html znak . Neraskidivi razmak ima decimalnu vrijednost 160, a funkcija TRIM ga ne može sama ukloniti.

Dakle, ako vaš skup podataka sadrži jedan ili više razmaka koje funkcija TRIM ne uklanja, upotrijebite funkciju SUBSTITUTE za pretvaranje neprekinutih razmaka u pravilne razmake i zatim ih skraćivanje. Pod pretpostavkom da je tekst u A1, formula je sljedeća:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Kao dodatnu mjeru opreza, možete ugraditi funkciju CLEAN za čišćenje ćelije od svih znakova koji se ne mogu ispisati:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Sljedeća snimka zaslona pokazuje razliku:

Ako ni gornje formule ne rade za vas, velike su šanse da vaši podaci sadrže neke specifične neispisne podatke likovis vrijednostima koda koje nisu 32 i 160. U ovom slučaju upotrijebite jednu od sljedećih formula da biste saznali kod znaka, gdje je A1 problematična ćelija:

Razmak na početku: =CODE(LEFT(A1,1))

Završni razmak: =CODE(RIGHT(A1,1))

Razmak između (gdje je n položaj problematičnog znaka u tekstualnom nizu):

=CODE(MID(A1, n , 1)))

I onda , dostavite vraćeni kod znaka u formulu TRIM(SUBSTITUTE()) koja je gore razmotrena.

Na primjer, ako funkcija CODE vrati 9, što je vodoravni tabulator, upotrijebite sljedeću formulu da biste ga uklonili:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Skratite razmake za Excel - uklonite višak razmaka jednim klikom

Zvuči li smiješna ideja o učenju nekoliko različitih formula za rješavanje trivijalnog zadatka? Onda bi vam se mogla svidjeti ova tehnika jednim klikom za uklanjanje razmaka u Excelu. Dopustite mi da vam predstavim Text Toolkit uključen u naš Ultimate Suite. Između ostalog, kao što je promjena velikih i malih slova, dijeljenje teksta i brisanje oblikovanja, nudi opciju Skraćivanje razmaka .

S Ultimate Suiteom instaliranim u vašem Excelu, uklanjanje razmaka u Excelu jednostavno je kao ovo :

1. Odaberite ćeliju(e) u kojoj želite izbrisati razmake.
2. Kliknite gumb Skrati razmake na vrpci.
3. Odaberite jednu ili sve od sljedećih opcija:
   • Skrati početne i zadnje razmake
   • Skrati dodatne razmake između riječi, osim jednerazmak
   • Skrati neprekidne razmake ( )
4. Klikni Skrati .

To je sve! Svi dodatni razmaci uklanjaju se u tren oka.

U ovom primjeru uklanjamo samo razmake na početku i na kraju, zadržavajući više razmaka između riječi netaknutima radi bolje čitljivosti - zadatak s kojim se Excel formule ne mogu nositi postiže se s kliknite mišem!

Ako ste zainteresirani isprobati Trim Spaces u svojim listovima, slobodno možete preuzeti probnu verziju na kraju ovog posta.

Zahvaljujem vam na čitanju i veselim se što ćemo se vidjeti sljedeći tjedan. U našem sljedećem vodiču raspravljat ćemo o drugim načinima skraćivanja prostora u Excelu, ostanite s nama!

Dostupna preuzimanja

Skraćivanje Excel prostora - primjeri formula (.xlsx datoteka)

Ultimate Suite - probna verzija (.exe datoteka)