Vodič demonstrira nekoliko brzih i lakih načina za skraćivanje Excel razmaka. Naučite kako ukloniti početne, zadnje i dodatne razmake između riječi, zašto Excel funkcija TRIM ne radi i kako to popraviti.

Upoređujete li dvije kolone za duplikate za koje znate da postoje, ali vaše formule ne mogu pronaći niti jedan duplikat unosa? Ili, zbrajate li dva stupca brojeva, ali stalno dobivate samo nule? I zašto, zaboga, vaša očito ispravna Vlookup formula vraća samo gomilu N/A grešaka? Ovo je samo nekoliko primjera problema na koje možda tražite odgovore. A sve je uzrokovano dodatnim razmacima koji se skrivaju prije, poslije ili između numeričkih i tekstualnih vrijednosti u vašim ćelijama.

Microsoft Excel nudi nekoliko različitih načina za uklanjanje razmaka i očistite svoje podatke. U ovom vodiču ćemo istražiti mogućnosti funkcije TRIM kao najbržeg i najlakšeg načina za brisanje razmaka u Excelu.

funkcija TRIM - uklonite dodatne razmake u Excelu

Koristite funkciju TRIM u Excelu, uklanja dodatne razmake iz teksta. Briše sve početne, zadnje i između razmaka osim jednog znaka razmak između riječi.

Sintaksa funkcije TRIM je najlakša koju možete zamisliti:

TRIM( tekst)

Gdje je text ćelija iz koje želite ukloniti višak razmaka.

Na primjer, da biste uklonili razmake u ćeliji A1, koristite ovoformula:

=TRIM(A1)

I sljedeća snimka ekrana prikazuje rezultat:

Da, tako je jednostavno!

Imajte na umu da TRIM funkcija je dizajnirana da ukloni samo razmak, koji ima vrijednost 32 u 7-bitnom ASCII kodnom sistemu. Ako osim dodatnih razmaka, vaši podaci sadrže prijelome reda i znakove koji se ne ispisuju, koristite funkciju TRIM u kombinaciji s CLEAN da izbrišete prva 32 znaka koji se ne ispisuju u ASCII sistemu.

Na primjer, da uklonite razmake, prijelome reda i druge neželjene znakove iz ćelije A1, koristite ovu formulu:

=TRIM(CLEAN(A1))

Za više informacija pogledajte Kako ukloniti znakove koji se ne ispisuju u Excelu

Da biste se riješili neprekidnih razmaka (html karakter ), koji ima vrijednost 160, koristite TRIM zajedno sa funkcijama SUBSTITUTE i CHAR:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Za sve detalje, molimo pogledajte Kako izbrisati razmake bez prekida u Excelu

Kako koristiti funkciju TRIM u Excelu - primjeri formule

Sada kada znate osnove, razgovarajmo o nekoliko specifičnih upotreba TRIM-a u Excelu, zamke sa kojima se možete suočiti i radna rješenja.

Kako smanjiti razmake u cijeloj koloni podataka

Pretpostavimo da imate kolonu imena koja ima razmake prije i poslije teksta, također kao više nego jedan razmak između riječi. Dakle, kako ukloniti sve vodeće, zadnje i višak međuprostora u svim ćelijama odjednom? Kopiranjem Excel-aTRIM formulu preko kolone, a zatim zamijenite formule njihovim vrijednostima. Detaljni koraci slijede u nastavku.

1. Napišite formulu TRIM za najgornju ćeliju, A2 u našem primjeru:

   =TRIM(A2)

2. Postavite kursor u donji desni kut ćelije formule (B2 u ovom primjeru), i čim se kursor pretvori u znak plus, dvaput kliknite na njega da kopirate formulu niz kolonu, do posljednje ćelije s podacima. Kao rezultat, imat ćete 2 stupca - originalna imena s razmacima i skraćena imena na osnovu formule.

Konačno, zamijenite vrijednosti u originalnoj koloni sa skraćeni podaci. Ali budite oprezni! Jednostavno kopiranje skraćene kolone preko originalne kolone uništilo bi vaše formule. Da biste spriječili da se to dogodi, morate kopirati samo vrijednosti, a ne formule. Evo kako:

• Izaberite sve ćelije sa formulama za obrezivanje (B2:B8 u ovom primjeru) i pritisnite Ctrl+C da ih kopirate.
• Izaberite sve ćelije s originalnim podacima (A2:A8 ), i pritisnite Ctrl+Alt+V, a zatim V. To je prečica za lijepljenje vrijednosti koja primjenjuje Specijalno lijepljenje > Vrijednosti
• Pritisnite tipku Enter. Gotovo!

Kako ukloniti vodeće razmake u numeričkom stupcu

Kao što ste upravo vidjeli, Excel TRIM funkcija je uklonila sve dodatne razmake iz stupca tekstualnih podataka bez zastoj. Ali šta ako su vaši podaci brojevi, a ne tekst?

Na prvi pogled može izgledati daTRIM funkcija je odradila svoj posao. Međutim, ako bolje pogledate, primijetit ćete da se izrezane vrijednosti ne ponašaju kao brojevi. Evo samo nekoliko naznaka abnormalnosti:

• I originalni stupac s vodećim razmacima i skraćeni brojevi su poravnati lijevo čak i ako primijenite format broja na ćelije, dok su normalni brojevi poravnati desno po defaultu.
• Kada su odabrane dvije ili više ćelija sa skraćenim brojevima, Excel prikazuje samo COUNT na statusnoj traci. Za brojeve, također bi trebao prikazati SUM i AVERAGE.
• Formula SUM primijenjena na odrezane ćelije vraća nulu.

Po svemu sudeći, skraćene vrijednosti su tekstualni nizovi , dok želimo brojeve. Da biste to popravili, možete pomnožiti izrezane vrijednosti sa 1 (da pomnožite sve vrijednosti jednim potezom, koristite opciju Paste Special > Multiply).

Elegantnije rješenje je zatvaranje funkcije TRIM u VALUE , ovako:

=VALUE(TRIM(A2))

Gorenja formula uklanja sve početne i zadnje razmake, ako ih ima, i pretvara rezultirajuću vrijednost u broj, kao što je prikazano na slici ispod:

Kako ukloniti samo početne razmake u Excelu (lijevo obrezivanje)

U nekim situacijama možete upisivati ​​duplicirane, pa čak i trostruke razmake između riječi da bi vaši podaci bili čitljiviji. Međutim, želite se riješiti vodećih razmaka, poput ovoga:

Kao što već znate, funkcija TRIMeliminiše dodatne razmake u sredini tekstualnih nizova, što nije ono što želimo. Da bi svi međuprostori ostali netaknuti, koristit ćemo malo složeniju formulu:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

U gornjoj formuli, kombinacija FIND, MID i TRIM izračunava poziciju prvi karakter teksta u nizu. A zatim taj broj dostavite drugoj MID funkciji tako da ona vraća cijeli tekstualni niz (dužina niza se izračunava pomoću LEN-a) počevši od pozicije prvog znakova teksta.

Sljedeći snimak ekrana pokazuje da su svi vodeći razmaci su nestali, dok je više razmaka između riječi još uvijek tu:

Kao završni dodir, zamijenite originalni tekst skraćenim vrijednostima, kao što je prikazano u 3. koraku primjera formule za izrezivanje , i spremni ste!

Savjet. Ako također želite ukloniti razmake s kraja ćelija, koristite alat Trim Spaces. Ne postoji očigledna Excel formula za uklanjanje vodećih i završnih razmaka zadržavajući više razmaka između riječi netaknutim.

Kako prebrojati dodatne razmake u ćeliji

Ponekad, prije uklanjanja razmaka u Excel listu, možda ćete htjeti znati koliko viška prostora zapravo ima.

Da biste dobili broj dodatnih razmaka u ćeliji, saznajte ukupnu dužinu teksta koristeći LEN funkciju, zatim izračunajte dužinu niza bez dodatnih razmaka i oduzmite ovo drugo od prvog:

=LEN(A2)-LEN(TRIM(A2))

Sljedećesnimka ekrana prikazuje gornju formulu u akciji:

Napomena. Formula vraća broj dodatnih razmaka u ćeliji, tj. na početku, na kraju i više od jednog uzastopnog razmaka između riječi, ali ne broji pojedinačne razmake u sredini teksta. Ako želite da dobijete ukupan broj razmaka u ćeliji, koristite ovu formulu zamene.

Kako istaknuti ćelije s viškom razmaka

Kada radite s osjetljivim ili važnim informacijama, možda ćete oklijevati da izbrišete bilo šta, a da ne vidite šta tačno brišete. U ovom slučaju, prvo možete istaknuti ćelije koje sadrže dodatne razmake, a zatim ih sigurno eliminirati.

Za to kreirajte pravilo uvjetnog oblikovanja sa sljedećom formulom:

=LEN($A2)>LEN(TRIM($A2))

Gdje je A2 najviša ćelija s podacima koje želite istaknuti.

Formula nalaže Excelu da istakne ćelije u kojima je ukupna dužina niza veća od dužine skraćenog teksta.

Da kreirate pravilo uslovnog oblikovanja, izaberite sve ćelije (redove) koje želite da istaknete bez zaglavlja kolona, ​​idite na karticu Početna > Stilovi grupu i kliknite na Uslovno formatiranje > Novo pravilo > Koristite formulu da odredite koje ćelije da formatirate .

Ako još niste upoznati sa Excel uslovnim oblikovanjem , ovde ćete pronaći detaljne korake: Kako kreirati pravilo uslovnog oblikovanja na osnovuformula.

Kao što je prikazano na snimku ekrana ispod, rezultat savršeno potvrđuje broj dodatnih razmaka koji smo dobili u prethodnom primjeru:

Kao što vidite, upotreba funkcije TRIM u Excelu je lako i jednostavno. Ipak, ako neko želi bliže pogledati formule o kojima se govori u ovom vodiču, možete preuzeti radnu knjigu Trim Excel Spaces.

Excel TRIM ne radi

Funkcija TRIM samo uklanja znak razmak predstavljen vrijednošću koda 32 u 7-bitnom ASCII skupu znakova. U Unicode skupu znakova postoji još jedan znak za razmak koji se zove razmak bez prekida, koji se obično koristi na web stranicama kao html karakter . Neprekidani razmak ima decimalnu vrijednost od 160, a funkcija TRIM ga ne može ukloniti sama.

Dakle, ako vaš skup podataka sadrži jedan ili više bijelih razmaka koje funkcija TRIM ne uklanja, koristite funkciju SUBSTITUTE za pretvaranje neprekidnih razmaka u pravilne razmake, a zatim ih skratiti. Pod pretpostavkom da je tekst u A1, formula ide kako slijedi:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Kao dodatnu mjeru opreza, možete ugraditi funkciju CLEAN da očistite ćeliju od znakova koji se ne mogu ispisati:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Sljedeći snimak ekrana pokazuje razliku:

Ako ni gore navedene formule ne rade za vas, velike su šanse da vaši podaci sadrže neke specifične neispisne karakterasa vrijednostima koda različitim od 32 i 160. U ovom slučaju, koristite jednu od sljedećih formula da saznate kod znakova, gdje je A1 problematična ćelija:

Predvodni razmak: =CODE(LEFT(A1,1))

Završni razmak: =CODE(RIGHT(A1,1))

Između razmaka (gdje je n pozicija problematičnog karaktera u tekstualnom nizu):

=CODE(MID(A1, n , 1)))

I tada , dostavite vraćeni kod znakova u formulu TRIM(SUBSTITUTE()) o kojoj se raspravljalo gore.

Na primjer, ako funkcija CODE vrati 9, što je Horizontal Tab karakter, koristite sljedeću formulu da ga uklonite:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Skratite razmake za Excel - uklonite dodatne razmake jednim klikom

Da li ideja o učenju pregršt različitih formula za rješavanje trivijalnog zadatka zvuči smiješno? Tada će vam se možda svidjeti ova tehnika jednim klikom kako biste se riješili razmaka u Excelu. Dozvolite mi da vam predstavim Text Toolkit uključen u naš Ultimate Suite. Između ostalih stvari kao što su promjena velikih i malih slova, dijeljenje teksta i brisanje formatiranja, nudi opciju Trim Spaces .

Sa Ultimate Suite instaliranim u vašem Excelu, uklanjanje razmaka u Excelu je jednostavno kao što je ovo :

1. Odaberite ćeliju(e) u kojoj želite da izbrišete razmake.
2. Kliknite na dugme Skrati razmake na traci.
3. Odaberite jednu ili sve od sljedećih opcija:
   • Obrezivanje vodeće i zadnje razmake
   • Obrezivanje dodatnih razmaka između riječi, osim jednerazmak
   • Obrezivanje neprekidljivo razmaka ( )
4. Kliknite Obriši .

To je sve! Svi dodatni razmaci se uklanjaju za tren.

U ovom primjeru uklanjamo samo početne i zadnje razmake, zadržavajući više razmaka između riječi netaknutim radi bolje čitljivosti - zadatak s kojim se Excel formule ne mogu nositi se postiže pomoću klik mišem!

Ako ste zainteresirani da isprobate Trim Spaces u svojim listovima, dobrodošli ste da preuzmete procjenu verziju na kraju ovog posta.

Zahvaljujem vam na čitanju i radujem se što ću vas vidjeti sljedeće sedmice. U našem sljedećem tutorijalu ćemo razgovarati o drugim načinima za skraćivanje razmaka u Excelu, budite u toku!

Dostupna preuzimanja

Skratite Excel razmake - primjeri formule (.xlsx datoteka)

Ultimate Suite - probna verzija (.exe fajl)