Упатството покажува неколку брзи и лесни начини за скратување на празни места во Excel. Научете како да ги отстраните водечките, заостанатите и дополнителните празни места помеѓу зборовите, зошто функцијата Excel TRIM не работи и како да ја поправите.

Дали споредувате две колони за дупликати за кои знаете дека се таму, но вашите формули не можат да најдат еден дупликат запис? Или, дали собирате две колони со броеви, но продолжувате да добивате само нули? И зошто, побогу, вашата очигледно точна формула за Vlookup враќа само еден куп N/A грешки? Ова се само неколку примери на проблеми за кои можеби барате одговори. И сите се предизвикани од дополнителни празни места криење пред, после или помеѓу нумеричките и текстуалните вредности во вашите ќелии.

Microsoft Excel нуди неколку различни начини за отстранување празни места и исчистете ги вашите податоци. Во ова упатство, ќе ги истражиме можностите на функцијата TRIM како најбрз и најлесен начин за бришење празни места во Excel.

TRIM функција - отстранете ги дополнителните празни места во Excel

Користете ја функцијата TRIM во Excel ги отстранува дополнителните празни места од текстот. Ги брише сите водечки, задоцнети и меѓу празни места освен еден знак за празно место помеѓу зборовите.

Синтаксата на функцијата TRIM е најлесната што може да се замисли:

Каде што текст е ќелија од која сакате да ги отстраните вишокот празни места.

На пример, за да отстраните празни места во ќелијата A1, го користите оваформула:

=TRIM(A1)

И следната слика од екранот го покажува резултатот:

Да, толку е едноставно!

Ве молиме имајте предвид дека функцијата TRIM беше дизајнирана да го отстрани само знакот празно место, кој има вредност 32 во 7-битниот ASCII код систем. Ако покрај дополнителните празни места, вашите податоци содржат прекини на линии и знаци кои не се печатат, користете ја функцијата TRIM во комбинација со CLEAN за да ги избришете првите 32 знаци што не се печатат во системот ASCII.

На пример, за да отстранете ги празни места, прекини на линии и други несакани знаци од ќелијата A1, користете ја оваа формула:

=TRIM(CLEAN(A1))

За повеќе информации, погледнете Како да отстраните знаци кои не се печатат во Excel

За да се ослободите од непробивните празни места (html знак ), кој има вредност 160, користете TRIM заедно со функциите SUBSTITUTE и CHAR:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

За целосни детали, ве молиме видете Како да бришете непрекинати празни места во Excel

Како да ја користите функцијата TRIM во Excel - примери на формула

Сега кога ги знаете основите, ајде да разговараме за неколку специфични употреби на TRIM во Excel. замки со кои може да се соочите и работни решенија.

Како да скратите празни места во цела колона со податоци

Да претпоставиме дека имате колона со имиња кои имаат празно место пред и по текстот, исто така како повеќе од една празнина меѓу зборовите. Значи, како да ги отстраните сите водечки, заостанати и вишок празни места во сите ќелии истовремено? Со копирање на ExcelTRIM формула низ колоната, а потоа заменување на формулите со нивните вредности. Деталните чекори следуваат подолу.

1. Напишете TRIM формула за најгорната ќелија, A2 во нашиот пример:

   =TRIM(A2)

2. Поставете го курсорот во долниот десен агол од формулата ќелија (B2 во овој пример), и штом курсорот се претвори во знакот плус, кликнете двапати на него за да ја копирате формулата надолу во колоната, до последната ќелија со податоци. Како резултат на тоа, ќе имате 2 колони - оригинални имиња со празни места и формули исечени имиња.

• Изберете ги сите ќелии со формули Trim (B2:B8 во овој пример) и притиснете Ctrl+C за да ги копирате.
• Изберете ги сите ќелии со оригиналните податоци (A2:A8 ), и притиснете Ctrl+Alt+V, потоа V. Тоа е кратенката за вметнување вредности што го применува Посебно залепување > Вредности
• Притиснете го копчето Enter. Готово!

Како да се отстранат водечките празни места во нумеричка колона

Како што штотуку видовте, функцијата Excel TRIM ги отстрани сите дополнителни празни места од колона со текстуални податоци без накуцване. Но, што ако вашите податоци се бројки, а не текст?

На прв поглед, може да изгледа декаФункцијата TRIM ја заврши својата работа. Меѓутоа, ако погледнете подетално, ќе забележите дека исечените вредности не се однесуваат како бројки. Еве само неколку индикации за абнормалност:

• И оригиналната колона со водечки празни места и исечените броеви се лево порамнети дури и ако го примените форматот Број на ќелиите, додека нормалните броеви се порамнети десно стандардно.
• Кога се избираат две или повеќе ќелии со исечени броеви, Excel прикажува само COUNT во лентата за статус. За броеви, треба да ги прикажува и SUM и AVERAGE.
• Формулата SUM применета на исечените ќелии враќа нула.

Од сите појави, исечените вредности се текстуални низи , додека ние сакаме броеви. За да го поправите ова, можете да ги помножите исечените вредности со 1 (за да ги помножите сите вредности со еден удар, користете ја опцијата Paste Special > Multiply).

Поелегантно решение е да ја ставите функцијата TRIM во VALUE , вака:

=VALUE(TRIM(A2))

Горената формула ги отстранува сите водечки и задоцнети простори, доколку ги има, и ја претвора добиената вредност во број, како што е прикажано на сликата од екранот подолу:

Како да ги отстраните само водечките празни места во Excel (лево отсекување)

Во некои ситуации, може да напишете дупликат, па дури и тројни празни места помеѓу зборовите за да ги направите вашите податоци подобро читливи. Сепак, сакате да се ослободите од водечките простори, како ова:

Како што веќе знаете, функцијата TRIMги елиминира дополнителните празни места во средината на текстуалните низи, што не е она што го сакаме. За да ги задржиме сите простори непроменети, ќе користиме малку покомплексна формула:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

Во горната формула, комбинацијата на FIND, MID и TRIM ја пресметува позицијата на првиот текстуален знак во низа. И потоа, го снабдувате тој број на друга функција MID, така што таа ја враќа целата текстуална низа (должината на низата се пресметува со LEN) почнувајќи од позицијата на првиот текстуален знак.

Следната слика од екранот покажува дека сите водечките празни места ги нема, додека повеќе празни места меѓу зборовите сè уште има:

Како допир, заменете го оригиналниот текст со отсечените вредности, како што е прикажано во чекор 3 од примерот на формулата Trim , и вие сте подготвени!

Совет. Ако сакате да отстраните и празни места од крајот на ќелиите, користете ја алатката Trim Spaces. Не постои очигледна формула на Excel за да се отстранат водечките и заостанатите празни места со задржување на повеќе празни места меѓу зборовите непроменети.

Како да броите дополнителни празни места во ќелија

Понекогаш, пред да отстраните празни места во листот на Excel, можеби ќе сакате да знаете колку вишок празни места всушност има.

За да го добиете бројот на дополнителни празни места во ќелија, дознајте ја вкупната должина на текстот користејќи ја функцијата LEN, потоа пресметајте ја должината на низата без дополнителни празни места и одземете ја втората од првата:

=LEN(A2)-LEN(TRIM(A2))

Следнотоскриншот ја прикажува горната формула во акција:

Забелешка. Формулата го враќа бројот на дополнителни празни места во ќелијата, т.е. водечки, последователни и повеќе од едно последователно празни места помеѓу зборовите, но не брои единечни празни места во средината на текстот. Ако сакате да го добиете вкупниот број на празни места во ќелијата, користете ја оваа Замена формула.

Како да ги истакнете ќелиите со вишок празни места

Кога работите со чувствителни или важни информации, можеби се двоумите дали да избришете нешто без да видите што точно бришете. Во овој случај, можете прво да ги означите ќелиите што содржат дополнителни празни места, а потоа безбедно да ги елиминирате тие празни места.

За ова, креирајте правило за условно форматирање со следнава формула:

=LEN($A2)>LEN(TRIM($A2))

Каде што A2 е најгорната ќелија со податоци што сакате да ги истакнете.

Формулата му наложува на Excel да ги означи ќелиите во кои вкупната должина на низата е поголема од должината на исечениот текст.

За да креирате правило за условно форматирање, изберете ги сите ќелии (редови) што сакате да ги означите без заглавија на колони, одете во табулаторот Дома > Стилови и кликнете Условно форматирање > Ново правило > Користете формула за да одредите кои ќелии да се форматираат .

Ако сè уште не сте запознаени со условното форматирање на Excel , деталните чекори ќе ги најдете овде: Како да креирате правило за условно форматирање врз основа наформула.

Како што е прикажано на скриншот подолу, резултатот совршено се потврдува со дополнителните празни места што ги добивме во претходниот пример:

Како што гледате, употребата на функцијата TRIM во Excel е лесна и јасна. Сепак, ако некој сака поблиску да ги погледне формулите дискутирани во ова упатство, добредојдени сте да ја преземете работната книга Trim Excel Spaces.

Excel TRIM не работи

Функцијата TRIM само отстранува празничниот знак претставен со вредноста на кодот 32 во 7-битниот сет на знаци ASCII. Во множеството знаци на Уникод, има уште еден празен знак наречен простор што не се прекинува, кој вообичаено се користи на веб-страниците како html знак . Непрекинатото место има децимална вредност од 160, а функцијата TRIM не може сама да ја отстрани.

Значи, ако вашето множество податоци содржи едно или повеќе празни места што функцијата TRIM не ги отстранува, користете ја функцијата SUBSTITUTE да ги претворат местата што не се прекршуваат во правилни простори и потоа да ги скратат. Под претпоставка дека текстот е во А1, формулата оди на следниов начин:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Како дополнителна претпазливост, можете да ја вградите функцијата CLEAN за да ја исчистите ќелијата од какви било знаци кои не се печатат:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Следната слика од екранот ја покажува разликата:

Ако горенаведените формули не функционираат ниту за вас, големи се шансите вашите податоци да содржат одредени специфични непечатени ликовисо вредности на код различни од 32 и 160. Во овој случај, користете една од следните формули за да го дознаете кодот на знакот, каде што A1 е проблематична ќелија:

Водечки простор: =CODE(LEFT(A1,1))

Заостанува празно место: =CODE(RIGHT(A1,1))

Простор помеѓу (каде што n е позицијата на проблематичниот знак во текстуалната низа):

=CODE(MID(A1, n , 1)))

И потоа , доставете ја вратената шифра на знаци со формулата TRIM(SUBSTITUTE()) дискутирана погоре.

На пример, ако функцијата CODE врати 9, што е знакот Хоризонтално јазиче, ја користите следнава формула за да ја отстраните:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Скратете ги просторите за Excel - отстранете ги дополнителните празни места со еден клик

Дали идејата да научите неколку различни формули за справување со тривијална задача звучи смешно? Тогаш можеби ќе ви се допадне оваа техника со еден клик за да се ослободите од празни места во Excel. Дозволете ми да ве запознаам со Text Toolkit вклучен во нашиот Ultimate Suite. Помеѓу другото, како што се менување на големи букви, делење текст и бришење форматирање, тој ја нуди опцијата Trim Spaces .

Со Ultimate Suite инсталиран во вашиот Excel, отстранувањето празни места во Excel е едноставно како ова :

1. Изберете ги ќелиите каде што сакате да ги избришете празнините.
2. Кликнете на копчето Скрати празни места на лентата.
3. Изберете една или сите од следниве опции:
   • Намали водечки и заостанува празни места
   • Намали дополнителни простори помеѓу зборовите, освен еден синглпразно место
   • Скрати непрекинато празни места ( )
4. Кликнете Скрати .

Тоа е сè што има за тоа! Сите дополнителни празни места се отстрануваат веднаш.

Во овој пример, ние ги отстрануваме само водечките и задоцнетите празни места, задржувајќи ги повеќекратните празни места меѓу зборовите непроменети за подобра читливост - задачата со која формулите на Excel не можат да се справат е постигната со клик на глувчето!

Ако сте заинтересирани да пробате Скратете ги празни места во вашите листови, добредојдени сте да преземете верзија за оценување на крајот од овој пост.

Ви благодарам што прочитавте и со нетрпение очекувам да се видиме следната недела. Во нашиот следен туторијал, ќе разговараме за други начини за скратување на празни места во Excel, ве молиме останете присутни!

Достапни преземања

Скратете ги просторите на Excel - примери на формула (датотека .xlsx)

Ultimate Suite - пробна верзија (датотека .exe)