Tutorial menunjukkan beberapa cara cepat dan mudah untuk memangkas ruang Excel. Ketahui cara mengalih keluar ruang hadapan, belakang dan tambahan antara perkataan, sebab fungsi Excel TRIM tidak berfungsi dan cara membetulkannya.

Adakah anda membandingkan dua lajur untuk pendua yang anda tahu ada, tetapi formula anda tidak dapat mencari satu entri pendua? Atau, adakah anda menjumlahkan dua lajur nombor, tetapi terus mendapat sifar sahaja? Dan mengapa formula Vlookup anda yang jelas betul mengembalikan hanya sekumpulan ralat N/A? Ini hanyalah beberapa contoh masalah yang mungkin anda cari jawapannya. Dan semuanya disebabkan oleh ruang tambahan bersembunyi sebelum, selepas atau antara nilai angka dan teks dalam sel anda.

Microsoft Excel menawarkan beberapa cara berbeza untuk mengalih keluar ruang dan bersihkan data anda. Dalam tutorial ini, kami akan menyiasat keupayaan fungsi TRIM sebagai cara terpantas dan paling mudah untuk memadamkan ruang dalam Excel.

Fungsi TRIM - alih keluar ruang tambahan dalam Excel

Anda menggunakan fungsi TRIM dalam Excel mengalih keluar ruang tambahan daripada teks. Ia memadamkan semua ruang di hadapan, mengekor dan di antara kecuali untuk satu ruang aksara antara perkataan.

Sintaks fungsi TRIM adalah yang paling mudah yang boleh dibayangkan:

Di mana teks ialah sel yang anda mahu alih keluar ruang yang berlebihan.

Sebagai contoh, untuk mengalih keluar ruang dalam sel A1, anda menggunakan iniformula:

=TRIM(A1)

Dan tangkapan skrin berikut menunjukkan hasilnya:

Ya, semudah itu!

Sila ambil perhatian bahawa fungsi TRIM direka untuk mengeluarkan hanya aksara ruang, yang mempunyai nilai 32 dalam sistem kod ASCII 7-bit. Jika selain ruang tambahan, data anda mengandungi pemisah baris dan aksara bukan pencetakan, gunakan fungsi TRIM dalam kombinasi dengan CLEAN untuk memadamkan 32 aksara bukan pencetakan pertama dalam sistem ASCII.

Sebagai contoh, untuk alih keluar ruang, pemisah baris dan aksara lain yang tidak diingini daripada sel A1, gunakan formula ini:

=TRIM(CLEAN(A1))

Untuk mendapatkan maklumat lanjut, sila lihat Cara mengalih keluar aksara tidak mencetak dalam Excel

Untuk menghilangkan ruang tidak putus (aksara html ), yang mempunyai nilai 160, gunakan TRIM bersama-sama dengan fungsi SUBSTITUTE dan CHAR:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Untuk butiran penuh, sila lihat Bagaimana untuk memadam ruang tidak pecah dalam Excel

Cara menggunakan fungsi TRIM dalam Excel - contoh formula

Sekarang anda mengetahui asasnya, mari bincangkan beberapa kegunaan khusus TRIM dalam Excel, perangkap yang mungkin anda hadapi dan penyelesaian yang berkesan.

Cara memangkas ruang dalam keseluruhan lajur data

Andaikan anda mempunyai lajur nama yang mempunyai beberapa ruang putih sebelum dan selepas teks, juga sebagai lebih daripada satu ruang antara perkataan. Jadi, bagaimanakah anda mengalih keluar semua ruang hadapan, mengekor dan lebihan di antara ruang dalam semua sel pada satu masa? Dengan menyalin ExcelFormula TRIM merentas lajur, dan kemudian menggantikan formula dengan nilainya. Langkah terperinci mengikuti di bawah.

1. Tulis formula TRIM untuk sel paling atas, A2 dalam contoh kami:

   =TRIM(A2)

2. Letakkan kursor ke penjuru kanan sebelah bawah daripada sel formula (B2 dalam contoh ini), dan sebaik sahaja kursor bertukar menjadi tanda tambah, klik dua kali padanya untuk menyalin formula ke bawah lajur, sehingga ke sel terakhir dengan data. Hasilnya, anda akan mempunyai 2 lajur - nama asal dengan ruang dan nama dipangkas dipacu formula.

• Pilih semua sel dengan formula Trim (B2:B8 dalam contoh ini), dan tekan Ctrl+C untuk menyalinnya.
• Pilih semua sel dengan data asal (A2:A8 ), dan tekan Ctrl+Alt+V , kemudian V . Ia ialah pintasan nilai tampal yang menggunakan Tampal Khas > Nilai
• Tekan kekunci Enter. Selesai!

Cara mengalih keluar ruang utama dalam lajur berangka

Seperti yang baru anda lihat, fungsi Excel TRIM mengalih keluar semua ruang tambahan daripada lajur data teks tanpa satu halangan. Tetapi bagaimana jika data anda ialah nombor, bukan teks?

Pada pandangan pertama, nampaknyaFungsi TRIM telah melaksanakan tugasnya. Walau bagaimanapun, apabila melihat lebih dekat, anda akan mendapati bahawa nilai yang dipangkas tidak berkelakuan seperti nombor. Berikut hanyalah beberapa tanda keabnormalan:

• Kedua-dua lajur asal dengan ruang hadapan dan nombor dipangkas dijajar ke kiri walaupun anda menggunakan format Nombor pada sel, manakala nombor biasa dijajarkan ke kanan secara lalai.
• Apabila dua atau lebih sel dengan nombor dipangkas dipilih, Excel hanya memaparkan COUNT dalam bar status. Untuk nombor, ia juga harus memaparkan SUM dan PURATA.
• Formula SUM yang digunakan pada sel yang dipangkas mengembalikan sifar.

Daripada semua penampilan, nilai yang dipangkas ialah rentetan teks , manakala kami mahukan nombor. Untuk membetulkannya, anda boleh mendarab nilai yang dipangkas dengan 1 (untuk mendarab semua nilai dalam satu kejadian, gunakan pilihan Tampal Khas > Darab).

Penyelesaian yang lebih elegan ialah menyertakan fungsi TRIM dalam VALUE , seperti ini:

=VALUE(TRIM(A2))

Formula di atas mengalih keluar semua ruang hadapan dan belakang, jika ada, dan menukar nilai yang terhasil kepada nombor, seperti yang ditunjukkan dalam tangkapan skrin di bawah:

Cara mengalih keluar hanya ruang utama dalam Excel (Pangkas Kiri)

Dalam sesetengah situasi, anda boleh menaip ruang pendua dan juga tiga kali ganda antara perkataan untuk menjadikan data anda lebih mudah dibaca. Walau bagaimanapun, anda mahu menyingkirkan ruang utama, seperti ini:

Seperti yang anda sedia maklum, fungsi TRIMmenghapuskan ruang tambahan di tengah-tengah rentetan teks, yang bukan yang kita mahukan. Untuk memastikan semua ruang di antara tetap utuh, kami akan menggunakan formula yang sedikit lebih kompleks:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

Dalam formula di atas, gabungan FIND, MID dan TRIM mengira kedudukan aksara teks pertama dalam rentetan. Dan kemudian, anda membekalkan nombor itu kepada fungsi MID yang lain supaya ia mengembalikan keseluruhan rentetan teks (panjang rentetan dikira oleh LEN) bermula pada kedudukan aksara teks pertama.

Tangkapan skrin berikut menunjukkan bahawa semua ruang hadapan hilang, manakala berbilang ruang antara perkataan masih ada:

Sebagai sentuhan akhir, gantikan teks asal dengan nilai yang dipangkas, seperti yang ditunjukkan dalam langkah 3 contoh formula Trim , dan anda boleh pergi!

Petua. Jika anda juga ingin mengalih keluar ruang dari hujung sel, gunakan alat Trim Spaces. Tiada formula Excel yang jelas untuk mengalih keluar ruang hadapan dan belakang mengekalkan berbilang ruang antara perkataan utuh.

Cara mengira ruang tambahan dalam sel

Kadangkala, sebelum mengalih keluar ruang dalam helaian Excel anda, anda mungkin ingin mengetahui berapa banyak lebihan ruang sebenarnya ada.

Untuk mendapatkan nombor daripada ruang tambahan dalam sel, ketahui jumlah panjang teks menggunakan fungsi LEN, kemudian hitung panjang rentetan tanpa ruang tambahan, dan tolak yang terakhir daripada yang pertama:

=LEN(A2)-LEN(TRIM(A2))

Yang berikuttangkapan skrin menunjukkan formula di atas dalam tindakan:

Nota. Formula mengembalikan kiraan ruang tambahan dalam sel, iaitu mendahului, mengekori dan lebih daripada satu ruang berturut-turut antara perkataan, tetapi ia tidak mengira ruang tunggal di tengah-tengah teks. Jika anda ingin mendapatkan jumlah bilangan ruang dalam sel, gunakan formula Ganti ini.

Cara untuk menyerlahkan sel dengan lebihan ruang

Apabila bekerja dengan maklumat sensitif atau penting, anda mungkin teragak-agak untuk memadamkan apa-apa tanpa melihat apa sebenarnya yang anda padamkan. Dalam kes ini, anda boleh menyerlahkan sel yang mengandungi ruang tambahan dahulu, dan kemudian menghapuskan ruang tersebut dengan selamat.

Untuk ini, buat peraturan pemformatan bersyarat dengan formula berikut:

=LEN($A2)>LEN(TRIM($A2))

Di mana A2 ialah sel paling atas dengan data yang anda ingin serlahkan.

Formula mengarahkan Excel untuk menyerlahkan sel yang jumlah panjang rentetannya lebih besar daripada panjang teks yang dipangkas.

Untuk membuat peraturan pemformatan bersyarat, pilih semua sel (baris) yang anda ingin serlahkan tanpa pengepala lajur, pergi ke tab Laman Utama > Gaya dan klik Pemformatan bersyarat > Peraturan Baharu > Gunakan formula untuk menentukan sel mana yang hendak diformatkan .

Jika anda belum biasa dengan pemformatan bersyarat Excel lagi , anda akan menemui langkah terperinci di sini: Cara membuat peraturan pemformatan bersyarat berdasarkanformula.

Seperti yang ditunjukkan dalam tangkapan skrin di bawah, hasilnya disokong dengan sempurna dengan kiraan ruang tambahan yang kami dapat dalam contoh sebelumnya:

Seperti yang anda lihat, penggunaan fungsi TRIM dalam Excel adalah mudah dan mudah. Namun begitu, jika seseorang ingin melihat dengan lebih dekat formula yang dibincangkan dalam tutorial ini, anda dialu-alukan untuk memuat turun Buku Kerja Trim Excel Spaces.

Excel TRIM tidak berfungsi

Fungsi TRIM hanya mengalih keluar aksara ruang diwakili oleh nilai kod 32 dalam set aksara ASCII 7-bit. Dalam set aksara Unicode, terdapat satu lagi aksara ruang yang dipanggil ruang tidak putus, yang biasa digunakan pada halaman web sebagai aksara html . Ruang tanpa putus mempunyai nilai perpuluhan 160 dan fungsi TRIM tidak boleh mengalih keluarnya dengan sendirinya.

Jadi, jika set data anda mengandungi satu atau lebih ruang putih yang fungsi TRIM tidak dialih keluar, gunakan fungsi SUBSTITUTE untuk menukar ruang yang tidak pecah menjadi ruang biasa dan kemudian memangkasnya. Dengan mengandaikan teks berada dalam A1, formulanya adalah seperti berikut:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Sebagai langkah berjaga-jaga tambahan, anda boleh membenamkan fungsi CLEAN untuk membersihkan sel daripada sebarang aksara yang tidak boleh dicetak:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Tangkapan skrin berikut menunjukkan perbezaan:

Jika formula di atas juga tidak berfungsi untuk anda, kemungkinan besar data anda mengandungi beberapa bukan pencetakan khusus watakdengan nilai kod selain daripada 32 dan 160. Dalam kes ini, gunakan salah satu daripada formula berikut untuk mengetahui kod aksara, dengan A1 ialah sel bermasalah:

Ruang pendahulu: =CODE(LEFT(A1,1))

Mengikut ruang: =CODE(RIGHT(A1,1))

Ruang di antara (di mana n ialah kedudukan watak bermasalah dalam rentetan teks):

=CODE(MID(A1, n , 1)))

Dan kemudian , bekalkan kod aksara yang dikembalikan kepada formula TRIM(SUBSTITUTE()) yang dibincangkan di atas.

Sebagai contoh, jika fungsi CODE mengembalikan 9, iaitu aksara Tab Mendatar, anda menggunakan formula berikut untuk mengalih keluarnya:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Pangkas Ruang untuk Excel - alih keluar ruang tambahan dalam satu klik

Adakah idea untuk mempelajari segelintir formula berbeza untuk menangani tugas remeh kedengaran tidak masuk akal? Kemudian anda mungkin menyukai teknik satu klik ini untuk menghilangkan ruang dalam Excel. Izinkan saya memperkenalkan anda kepada Text Toolkit yang disertakan dalam Suite Ultimate kami. Antara lain seperti menukar kes, membelah teks dan mengosongkan pemformatan, ia menawarkan pilihan Trim Spaces .

Dengan Ultimate Suite dipasang dalam Excel anda, mengalih keluar ruang dalam Excel adalah semudah ini :

1. Pilih sel yang anda mahu padamkan ruang.
2. Klik butang Pangkas Ruang pada reben.
3. Pilih satu atau semua pilihan berikut:
   • Pangkas terajui dan belakang ruang
   • Pangkas tambahan ruang antara perkataan, kecuali saturuang
   • Pangkas tidak putus ruang ( )
4. Klik Pangkas .

Itu sahaja yang ada! Semua ruang tambahan dialih keluar dalam sekelip mata.

Dalam contoh ini, kami hanya mengalih keluar ruang hadapan dan belakang, mengekalkan berbilang ruang antara perkataan utuh untuk kebolehbacaan yang lebih baik - tugas yang tidak dapat ditangani oleh formula Excel diselesaikan dengan klik tetikus!

Jika anda berminat untuk mencuba Trim Spaces dalam helaian anda, anda dialu-alukan untuk memuat turun versi penilaian di penghujung siaran ini.

Saya mengucapkan terima kasih kerana membaca dan berharap untuk berjumpa anda minggu hadapan. Dalam tutorial kami yang seterusnya, kami akan membincangkan cara lain untuk memangkas ruang dalam Excel, sila tunggu!

Muat turun yang tersedia

Pangkas Ruang Excel - contoh formula (fail .xlsx)

Ultimate Suite - versi percubaan (fail .exe)