Ang tutorial ay nagpapakita ng ilang mabilis at madaling paraan upang i-trim ang mga puwang ng Excel. Matutunan kung paano mag-alis ng nangunguna, sumusunod, at mga karagdagang puwang sa pagitan ng mga salita, kung bakit hindi gumagana ang Excel TRIM function at kung paano ito ayusin.

Naghahambing ka ba ng dalawang column para sa mga duplicate na alam mong naroroon, ngunit hindi mahanap ng iyong mga formula ang isang solong duplicate na entry? O, nagdaragdag ka ba ng dalawang column ng mga numero, ngunit patuloy na nakakakuha lamang ng mga zero? At bakit sa mundo ang iyong malinaw na tamang Vlookup formula ay nagbabalik lamang ng isang grupo ng mga N/A error? Ito ay ilan lamang sa mga halimbawa ng mga problema na maaaring hinahanapan mo ng mga kasagutan. At ang lahat ay sanhi ng mga karagdagang espasyo na nagtatago bago, pagkatapos o sa pagitan ng mga numeric at text value sa iyong mga cell.

Nag-aalok ang Microsoft Excel ng ilang iba't ibang paraan upang alisin ang mga puwang at linisin ang iyong data. Sa tutorial na ito, sisiyasatin namin ang mga kakayahan ng TRIM function bilang ang pinakamabilis at pinakamadaling paraan upang magtanggal ng mga puwang sa Excel.

TRIM function - alisin ang mga dagdag na espasyo sa Excel

Gamitin mo ang TRIM function sa Excel na nag-aalis ng mga dagdag na espasyo mula sa text. Tinatanggal nito ang lahat ng nangunguna, sumusunod at nasa pagitan ng mga puwang maliban sa iisang espasyo na character sa pagitan ng mga salita.

Ang syntax ng TRIM function ay ang pinakamadaling maisip ng isa:

Kung saan ang text ay isang cell kung saan mo gustong alisin ang mga sobrang espasyo.

Halimbawa, para mag-alis ng mga puwang sa cell A1, gagamitin mo itoformula:

=TRIM(A1)

At ipinapakita ng sumusunod na screenshot ang resulta:

Oo, ganoon kasimple!

Pakitandaan na ang TRIM function ay idinisenyo upang alisin lamang ang space character, na may halagang 32 sa 7-bit ASCII code system. Kung bilang karagdagan sa mga dagdag na espasyo, ang iyong data ay naglalaman ng mga line break at hindi nagpi-print na mga character, gamitin ang TRIM function na kasama ng CLEAN upang tanggalin ang unang 32 hindi nagpi-print na mga character sa ASCII system.

Halimbawa, upang alisin ang mga puwang, line break at iba pang hindi gustong mga character mula sa cell A1, gamitin ang formula na ito:

=TRIM(CLEAN(A1))

Para sa higit pang impormasyon, pakitingnan ang Paano mag-alis ng mga hindi naka-print na character sa Excel

Upang maalis ang mga hindi nasisira na espasyo (html character ), na may value na 160, gamitin ang TRIM kasama ng SUBSTITUTE at CHAR function:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Para sa buong detalye, mangyaring tingnan ang Paano magtanggal ng mga hindi nakakasira na puwang sa Excel

Paano gamitin ang TRIM function sa Excel - mga halimbawa ng formula

Ngayong alam mo na ang mga pangunahing kaalaman, talakayin natin ang ilang partikular na paggamit ng TRIM sa Excel, mga pitfalls na maaari mong harapin at gumaganang solusyon.

Paano mag-trim ng mga puwang sa isang buong column ng data

Ipagpalagay na mayroon kang column ng mga pangalan na may ilang whitespace bago at pagkatapos ng text, pati na rin bilang higit pa kaysa sa isang puwang sa pagitan ng mga salita. Kaya, paano mo aalisin ang lahat ng nangunguna, sumusunod at labis na mga puwang sa lahat ng mga cell nang sabay-sabay? Sa pamamagitan ng pagkopya ng ExcelTRIM formula sa buong column, at pagkatapos ay palitan ang mga formula ng kanilang mga value. Ang mga detalyadong hakbang ay sumusunod sa ibaba.

1. Sumulat ng TRIM formula para sa pinakamataas na cell, A2 sa aming halimbawa:

   =TRIM(A2)

   Tingnan din: Excel Advanced Filter – kung paano gumawa at gumamit
2. Iposisyon ang cursor sa kanang sulok sa ibaba ng formula cell (B2 sa halimbawang ito), at sa sandaling maging plus sign ang cursor, i-double click ito upang kopyahin ang formula pababa sa column, hanggang sa huling cell na may data. Bilang resulta, magkakaroon ka ng 2 column - mga orihinal na pangalan na may mga puwang at trimmed na pangalan na batay sa formula.

• Piliin ang lahat ng cell na may mga Trim formula (B2:B8 sa halimbawang ito), at pindutin ang Ctrl+C para kopyahin ang mga ito.
• Piliin ang lahat ng cell na may orihinal na data (A2:A8 ), at pindutin ang Ctrl+Alt+V , pagkatapos ay V . Ito ang shortcut ng mga paste na value na naglalapat ng Paste Special > Values ​​
• Pindutin ang Enter key. Tapos na!

Paano mag-alis ng mga nangungunang puwang sa isang numeric na column

Tulad ng nakita mo lang, inalis ng Excel TRIM function ang lahat ng karagdagang puwang mula sa isang column ng text data nang walang isang sagabal. Ngunit paano kung ang iyong data ay mga numero, hindi text?

Sa unang tingin, maaaring mukhang angGinawa na ng TRIM function ang trabaho nito. Sa isang mas malapit na pagtingin, gayunpaman, mapapansin mo na ang mga na-trim na halaga ay hindi kumikilos tulad ng mga numero. Narito ang ilang indikasyon lamang ng abnormalidad:

• Parehong naka-left-align ang orihinal na column na may mga leading space at trimmed na numero kahit na inilapat mo ang Number format sa mga cell, habang ang mga normal na numero ay naka-align sa kanan. bilang default.
• Kapag pinili ang dalawa o higit pang mga cell na may mga naka-trim na numero, COUNT lang ang ipinapakita ng Excel sa status bar. Para sa mga numero, dapat din itong magpakita ng SUM at AVERAGE.
• Ang formula ng SUM na inilapat sa mga na-trim na cell ay nagbabalik ng zero.

Mula sa lahat ng hitsura, ang mga na-trim na halaga ay mga string ng teksto , habang gusto namin ng mga numero. Upang ayusin ito, maaari mong i-multiply ang mga na-trim na value sa pamamagitan ng 1 (upang i-multiply ang lahat ng value sa isang pagkakataon, gamitin ang opsyong I-paste Special > Multiply).

Ang isang mas eleganteng solusyon ay kasama ang TRIM function sa VALUE , tulad nito:

=VALUE(TRIM(A2))

Aalisin ng formula sa itaas ang lahat ng nangunguna at sumusunod na mga puwang, kung mayroon, at ginagawang numero ang resultang halaga, tulad ng ipinapakita sa screenshot sa ibaba:

Paano mag-alis lamang ng mga nangungunang puwang sa Excel (Left Trim)

Sa ilang sitwasyon, maaari kang mag-type ng mga duplicate at kahit na triplicated na mga puwang sa pagitan ng mga salita upang gawing mas madaling mabasa ang iyong data. Gayunpaman, gusto mong alisin ang mga nangungunang puwang, tulad nito:

Tulad ng alam mo na, ang TRIM functionnag-aalis ng mga karagdagang puwang sa gitna ng mga string ng teksto, na hindi natin gusto. Upang panatilihing buo ang lahat sa pagitan ng mga puwang, gagamit kami ng medyo mas kumplikadong formula:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

Sa formula sa itaas, kinakalkula ng kumbinasyon ng FIND, MID at TRIM ang posisyon ng ang unang text character sa isang string. At pagkatapos, ibibigay mo ang numerong iyon sa isa pang MID function upang maibalik nito ang buong string ng teksto (ang haba ng string ay kinakalkula ng LEN) simula sa posisyon ng unang character ng teksto.

Ipinapakita ng sumusunod na screenshot na lahat nawala ang mga nangungunang puwang, habang nandoon pa rin ang maraming puwang sa pagitan ng mga salita:

Bilang pagtatapos, palitan ang orihinal na text ng mga na-trim na halaga, tulad ng ipinapakita sa hakbang 3 ng halimbawa ng Trim formula , at handa ka nang umalis!

Tip. Kung gusto mo ring mag-alis ng mga puwang sa dulo ng mga cell, gamitin ang tool na Trim Spaces. Walang malinaw na formula ng Excel upang alisin ang mga nangunguna at sumusunod na mga puwang na pinananatiling buo ang maraming puwang sa pagitan ng mga salita.

Paano magbilang ng mga dagdag na espasyo sa isang cell

Minsan, bago mag-alis ng mga puwang sa iyong Excel sheet, maaaring gusto mong malaman kung gaano karaming mga sobrang espasyo ang aktwal na naroroon.

Upang makuha ang numero ng mga dagdag na puwang sa isang cell, alamin ang kabuuang haba ng teksto gamit ang function na LEN, pagkatapos ay kalkulahin ang haba ng string nang walang dagdag na mga puwang, at ibawas ang huli sa nauna:

=LEN(A2)-LEN(TRIM(A2))

Ang sumusunodipinapakita ng screenshot ang formula sa itaas na kumikilos:

Tandaan. Ibinabalik ng formula ang bilang ng mga karagdagang espasyo sa isang cell, ibig sabihin, nangunguna, nakasunod, at higit sa isang magkakasunod na puwang sa pagitan ng mga salita, ngunit hindi ito nagbibilang ng mga solong espasyo sa gitna ng teksto. Kung gusto mong makuha ang kabuuang bilang ng mga puwang sa isang cell, gamitin itong Substitute formula.

Paano i-highlight ang mga cell na may labis na espasyo

Kapag nagtatrabaho gamit ang sensitibo o mahalagang impormasyon, maaaring mag-alinlangan kang magtanggal ng anuman nang hindi nakikita kung ano ang eksaktong tinatanggal mo. Sa kasong ito, maaari mong i-highlight muna ang mga cell na naglalaman ng mga karagdagang puwang, at pagkatapos ay ligtas na alisin ang mga puwang na iyon.

Para dito, lumikha ng tuntunin sa pag-format ng kondisyon na may sumusunod na formula:

=LEN($A2)>LEN(TRIM($A2))

Kung saan ang A2 ang pinakamataas na cell na may data na gusto mong i-highlight.

Inutusan ng formula ang Excel na i-highlight ang mga cell kung saan ang kabuuang haba ng string ay mas malaki kaysa sa haba ng trimmed text.

Upang gumawa ng kondisyonal na tuntunin sa pag-format, piliin ang lahat ng mga cell (mga hilera) na gusto mong i-highlight nang walang mga header ng column, pumunta sa tab na Home > Mga Estilo , at i-click ang Conditional formatting > Bagong Panuntunan > Gumamit ng formula upang matukoy kung aling mga cell ang ipo-format .

Kung hindi ka pa pamilyar sa Excel conditional formatting , makikita mo ang mga detalyadong hakbang dito: Paano gumawa ng kondisyonal na tuntunin sa pag-format batay saformula.

Tulad ng ipinakita sa screenshot sa ibaba, ang resulta ay perpektong nagpapatunay sa bilang ng mga karagdagang espasyo na nakuha namin sa nakaraang halimbawa:

Tulad ng nakikita mo, ang paggamit ng TRIM function sa Excel ay madali at prangka. Gayunpaman, kung may gustong tingnang mabuti ang mga formula na tinalakay sa tutorial na ito, maaari kang mag-download ng Trim Excel Spaces Workbook.

Hindi gumagana ang Excel TRIM

Aalisin lang ng TRIM function ang space character na kinakatawan ng code value 32 sa 7-bit ASCII character set. Sa Unicode character set, may isa pang space character na tinatawag na non-breaking space, na karaniwang ginagamit sa mga web page bilang html character na . Ang nonbreaking space ay may decimal na value na 160, at hindi ito maalis ng TRIM function nang mag-isa.

Kaya, kung ang iyong data set ay naglalaman ng isa o higit pang white space na hindi inaalis ng TRIM function, gamitin ang SUBSTITUTE function upang i-convert ang mga hindi nasisira na espasyo sa mga regular na espasyo at pagkatapos ay putulin ang mga ito. Ipagpalagay na ang text ay nasa A1, ang formula ay sumusunod:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Bilang karagdagang pag-iingat, maaari mong i-embed ang CLEAN function upang linisin ang cell ng anumang hindi napi-print na mga character:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Ang sumusunod na screenshot ay nagpapakita ng pagkakaiba:

Kung ang mga formula sa itaas ay hindi rin gagana para sa iyo, malamang na ang iyong data ay naglalaman ng ilang partikular na hindi pag-print mga karakterna may mga value ng code maliban sa 32 at 160. Sa kasong ito, gamitin ang isa sa mga sumusunod na formula upang malaman ang code ng character, kung saan ang A1 ay isang may problemang cell:

Nangungunang espasyo: =CODE(LEFT(A1,1))

Trailing space: =CODE(RIGHT(A1,1))

In-between space (kung saan ang n ay ang posisyon ng may problemang character sa text string):

=CODE(MID(A1, n , 1)))

At pagkatapos , ibigay ang ibinalik na code ng character sa TRIM(SUBSTITUTE()) na formula na tinalakay sa itaas.

Halimbawa, kung ang CODE function ay nagbabalik ng 9, na siyang Horizontal Tab character, gagamitin mo ang sumusunod na formula para alisin ito:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Trim Spaces para sa Excel - mag-alis ng mga dagdag na espasyo sa isang pag-click

Nakakatawa ba ang ideya ng pag-aaral ng ilang iba't ibang formula upang harapin ang isang maliit na gawain? Pagkatapos ay maaaring gusto mo ang isang-click na pamamaraan na ito upang maalis ang mga puwang sa Excel. Hayaan akong ipakilala sa iyo ang Text Toolkit na kasama sa aming Ultimate Suite. Sa iba pang mga bagay gaya ng pagpapalit ng case, paghahati ng text at pag-clear ng formatting, nag-aalok ito ng opsyon na Trim Spaces .

Sa Ultimate Suite na naka-install sa iyong Excel, ang pag-alis ng mga puwang sa Excel ay kasing simple nito. :

1. Piliin ang (mga) cell kung saan mo gustong magtanggal ng mga puwang.
2. I-click ang button na Trim Spaces sa ribbon.
3. Pumili ng isa o lahat ng sumusunod na opsyon:
   • Trim nangunguna at trailing na mga puwang
   • Trim dagdag mga puwang sa pagitan ng mga salita, maliban sa isang solong salitaspace
   • Puwang hindi nasisira ( )
4. I-click ang Trim .

Iyon lang ang mayroon! Ang lahat ng dagdag na espasyo ay inalis sa isang iglap.

Sa halimbawang ito, inaalis lang namin ang mga nangunguna at sumusunod na mga puwang, na pinananatiling buo ang maraming puwang sa pagitan ng mga salita para sa mas madaling mabasa - ang gawain na hindi kayang harapin ng mga formula ng Excel ay nagagawa sa pamamagitan ng isang pag-click ng mouse!

Kung interesado kang subukan ang Trim Spaces sa iyong mga sheet, maaari kang mag-download ng bersyon ng pagsusuri sa dulo ng post na ito.

Nagpapasalamat ako sa iyong pagbabasa at umaasa akong makita ka sa susunod na linggo. Sa aming susunod na tutorial, tatalakayin namin ang iba pang mga paraan upang mag-trim ng mga puwang sa Excel, mangyaring manatiling nakatutok!

Mga available na download

Trim Excel Spaces - mga halimbawa ng formula (.xlsx file)

Ultimate Suite - trial na bersyon (.exe file)