ટ્યુટોરીયલ એક્સેલ સ્પેસને ટ્રિમ કરવાની કેટલીક ઝડપી અને સરળ રીતો દર્શાવે છે. આગળની, પાછળની, અને શબ્દો વચ્ચેની વધારાની જગ્યાઓ કેવી રીતે દૂર કરવી, Excel TRIM ફંક્શન શા માટે કામ કરતું નથી અને તેને કેવી રીતે ઠીક કરવું તે જાણો.

શું તમે ડુપ્લિકેટ માટે બે કૉલમ્સની તુલના કરી રહ્યાં છો જે તમે જાણો છો કે ત્યાં છે, પરંતુ તમારા સૂત્રો એક પણ ડુપ્લિકેટ એન્ટ્રી શોધી શકતા નથી? અથવા, શું તમે સંખ્યાઓની બે કૉલમ ઉમેરી રહ્યા છો, પરંતુ માત્ર શૂન્ય મેળવવાનું ચાલુ રાખો છો? અને પૃથ્વી પર શા માટે તમારું દેખીતી રીતે યોગ્ય Vlookup ફોર્મ્યુલા N/A ભૂલોનો સમૂહ આપે છે? આ સમસ્યાઓના માત્ર થોડા ઉદાહરણો છે જેના જવાબો તમે શોધી રહ્યા છો. અને બધા તમારા કોષોમાં સંખ્યાત્મક અને ટેક્સ્ટ મૂલ્યો પહેલા, પછી અથવા વચ્ચે છુપાયેલા અતિરિક્ત જગ્યાઓ ને કારણે થાય છે.

Microsoft Excel ખાલી જગ્યાઓ દૂર કરવાની કેટલીક અલગ અલગ રીતો પ્રદાન કરે છે અને તમારો ડેટા સાફ કરો. આ ટ્યુટોરીયલમાં, અમે Excel માં ખાલી જગ્યાઓ કાઢી નાખવાની સૌથી ઝડપી અને સરળ રીત તરીકે TRIM ફંક્શનની ક્ષમતાઓની તપાસ કરીશું.

TRIM ફંક્શન - એક્સેલમાં વધારાની જગ્યાઓ દૂર કરો

તમે Excel માં TRIM ફંક્શનનો ઉપયોગ કરો છો તે ટેક્સ્ટમાંથી વધારાની જગ્યાઓ દૂર કરે છે. તે તમામ આગળની, પાછળની અને વચ્ચેની જગ્યાઓને કાઢી નાખે છે એક જ જગ્યા સિવાય શબ્દો વચ્ચેના અક્ષરો.

TRIM ફંક્શનનું સિન્ટેક્સ એ સૌથી સરળ છે જેની કલ્પના કરી શકાય છે:

TRIM( ટેક્સ્ટ)

જ્યાં ટેક્સ્ટ એ સેલ છે જેમાંથી તમે વધારાની જગ્યાઓ દૂર કરવા માંગો છો.

ઉદાહરણ તરીકે, સેલ A1 માં જગ્યાઓ દૂર કરવા માટે, તમે આનો ઉપયોગ કરો છોફોર્મ્યુલા:

=TRIM(A1)

અને નીચેનો સ્ક્રીનશોટ પરિણામ બતાવે છે:

હા, તે એટલું સરળ છે!

કૃપા કરીને નોંધ કરો કે TRIM ફંક્શન માત્ર સ્પેસ કેરેક્ટરને દૂર કરવા માટે ડિઝાઇન કરવામાં આવ્યું હતું, જેનું મૂલ્ય 7-બીટ ASCII કોડ સિસ્ટમમાં 32 છે. જો વધારાની જગ્યાઓ ઉપરાંત, તમારા ડેટામાં લાઇન બ્રેક્સ અને બિન-પ્રિન્ટિંગ અક્ષરો છે, તો ASCII સિસ્ટમમાં પ્રથમ 32 બિન-પ્રિન્ટિંગ અક્ષરોને કાઢી નાખવા માટે CLEAN સાથે સંયોજનમાં TRIM ફંક્શનનો ઉપયોગ કરો.

ઉદાહરણ તરીકે, સેલ A1 માંથી ખાલી જગ્યાઓ, લાઇન બ્રેક્સ અને અન્ય અનિચ્છનીય અક્ષરો દૂર કરો, આ સૂત્રનો ઉપયોગ કરો:

=TRIM(CLEAN(A1))

વધુ માહિતી માટે, કૃપા કરીને જુઓ કે એક્સેલમાં બિન-પ્રિન્ટિંગ અક્ષરોને કેવી રીતે દૂર કરવું

<0 160 મૂલ્ય ધરાવતી નોનબ્રેકિંગ સ્પેસ (html અક્ષર ) થી છુટકારો મેળવવા માટે, SUBSTITUTE અને CHAR ફંક્શન્સ સાથે TRIM નો ઉપયોગ કરો:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

સંપૂર્ણ વિગતો માટે, કૃપા કરીને એક્સેલમાં નોન-બ્રેકિંગ સ્પેસ કેવી રીતે ડિલીટ કરવું તે જુઓ

એક્સેલમાં TRIM ફંક્શનનો ઉપયોગ કેવી રીતે કરવો - ફોર્મ્યુલા ઉદાહરણો

હવે તમે બેઝિક્સ જાણો છો, ચાલો Excel માં TRIM ના અમુક ચોક્કસ ઉપયોગોની ચર્ચા કરીએ, તમે જે મુશ્કેલીઓનો સામનો કરી શકો છો અને કાર્યકારી ઉકેલો.

ડેટાના આખા કૉલમમાં સ્પેસ કેવી રીતે ટ્રિમ કરવી

ધારો કે તમારી પાસે નામોની કૉલમ છે જેમાં ટેક્સ્ટ પહેલાં અને પછી થોડી સફેદ જગ્યા છે, તેમજ વધુ તરીકે શબ્દો વચ્ચે એક કરતાં વધુ જગ્યાઓ. તો, તમે એક સમયે તમામ કોષોમાં તમામ અગ્રણી, પાછળની અને વધારાની જગ્યાઓ કેવી રીતે દૂર કરશો? એક્સેલની નકલ કરીનેસમગ્ર કૉલમમાં TRIM સૂત્ર, અને પછી સૂત્રોને તેમના મૂલ્યો સાથે બદલીને. વિગતવાર પગલાં નીચે અનુસરે છે.

1. અમારા ઉદાહરણમાં સૌથી ઉપરના સેલ, A2 માટે TRIM ફોર્મ્યુલા લખો:

   =TRIM(A2)

2. કર્સરને નીચેના જમણા ખૂણે સ્થાન આપો ફોર્મ્યુલા સેલનો (આ ઉદાહરણમાં B2), અને કર્સર વત્તા ચિહ્નમાં ફેરવાય કે તરત જ, ડેટા સાથે છેલ્લા કોષ સુધી, કૉલમ નીચે ફોર્મ્યુલાની નકલ કરવા માટે તેને ડબલ-ક્લિક કરો. પરિણામ સ્વરૂપે, તમારી પાસે 2 કૉલમ હશે - જગ્યાઓ સાથેના મૂળ નામો અને સૂત્ર-સંચાલિત સુવ્યવસ્થિત નામો.

આખરે, મૂળ કૉલમમાં મૂલ્યો સાથે બદલો સુવ્યવસ્થિત ડેટા. પરંતુ સાવચેત રહો! ફક્ત મૂળ કૉલમ પર સુવ્યવસ્થિત કૉલમની નકલ કરવાથી તમારા સૂત્રોનો નાશ થશે. આને થતું અટકાવવા માટે, તમારે માત્ર મૂલ્યોની નકલ કરવાની જરૂર છે, સૂત્રોની નહીં. અહીં કેવી રીતે છે:

• તમામ કોષોને ટ્રિમ ફોર્મ્યુલા સાથે પસંદ કરો (આ ઉદાહરણમાં B2:B8), અને તેમને કૉપિ કરવા માટે Ctrl+C દબાવો.
• મૂળ ડેટા (A2:A8) સાથે તમામ કોષો પસંદ કરો ), અને Ctrl+Alt+V દબાવો, પછી V દબાવો. તે પેસ્ટ વેલ્યુ શોર્ટકટ છે જે સ્પેશિયલ પેસ્ટ કરો > વેલ્યુઝ
• એન્ટર કી દબાવો. થઈ ગયું!

સંખ્યાત્મક કૉલમમાં આગળની જગ્યાઓ કેવી રીતે દૂર કરવી

તમે હમણાં જ જોયું તેમ, એક્સેલ ટ્રિમ ફંક્શને ટેક્સ્ટ ડેટાના કૉલમમાંથી બધી વધારાની જગ્યાઓ દૂર કરી એક હરકત. પરંતુ જો તમારો ડેટા નંબર હોય, ટેક્સ્ટ નહીં?

પ્રથમ દૃષ્ટિએ, એવું લાગે છે કેTRIM ફંક્શને તેનું કામ કર્યું છે. જો કે, નજીકથી જોવા પર, તમે જોશો કે સુવ્યવસ્થિત મૂલ્યો સંખ્યાઓની જેમ વર્તે નહીં. અહીં અસાધારણતાના થોડા સંકેતો છે:

• આગળની જગ્યાઓ અને ટ્રિમ કરેલ નંબરો સાથેની મૂળ કૉલમ બંને ડાબે સંરેખિત છે, ભલે તમે કોષો પર નંબર ફોર્મેટ લાગુ કરો, જ્યારે સામાન્ય સંખ્યાઓ જમણે-સંરેખિત હોય. મૂળભૂત રીતે.
• જ્યારે સુવ્યવસ્થિત નંબરો સાથે બે અથવા વધુ કોષો પસંદ કરવામાં આવે છે, ત્યારે એક્સેલ સ્ટેટસ બારમાં માત્ર COUNT દર્શાવે છે. સંખ્યાઓ માટે, તેણે SUM અને AVERAGE પણ દર્શાવવું જોઈએ.
• સુવ્યવસ્થિત કોષો પર લાગુ કરેલ SUM ફોર્મ્યુલા શૂન્ય આપે છે.

તમામ દેખાવમાંથી, ટ્રિમ કરેલ મૂલ્યો ટેક્સ્ટ સ્ટ્રીંગ્સ છે, જ્યારે અમને નંબર જોઈએ છે. આને ઠીક કરવા માટે, તમે સુવ્યવસ્થિત મૂલ્યોને 1 વડે ગુણાકાર કરી શકો છો (તમામ મૂલ્યોને એક ફોલ સ્વૂપમાં ગુણાકાર કરવા માટે, પેસ્ટ સ્પેશિયલ > ગુણાકાર વિકલ્પનો ઉપયોગ કરો).

એક વધુ ભવ્ય ઉકેલ VALUE માં TRIM ફંક્શનને બંધ કરી રહ્યું છે. , આની જેમ:

=VALUE(TRIM(A2))

ઉપરોક્ત સૂત્ર તમામ અગ્રણી અને પાછળની જગ્યાઓને દૂર કરે છે, જો કોઈ હોય તો, અને પરિણામી મૂલ્યને નંબરમાં ફેરવે છે, જેમ કે નીચેના સ્ક્રીનશોટમાં બતાવ્યા પ્રમાણે:

એક્સેલ (ડાબે ટ્રીમ) માં ફક્ત અગ્રણી જગ્યાઓ કેવી રીતે દૂર કરવી

કેટલીક પરિસ્થિતિઓમાં, તમે તમારા ડેટાને વધુ સારી રીતે વાંચી શકાય તે માટે શબ્દો વચ્ચે ડુપ્લિકેટેડ અને ટ્રિપ્લિકેટેડ સ્પેસ પણ ટાઈપ કરી શકો છો. જો કે, તમે આગળની જગ્યાઓમાંથી છૂટકારો મેળવવા માંગો છો, જેમ કે:

જેમ તમે પહેલાથી જ જાણો છો, TRIM ફંક્શનટેક્સ્ટ સ્ટ્રીંગની મધ્યમાં વધારાની જગ્યાઓ દૂર કરે છે, જે આપણને જોઈતું નથી. તમામ વચ્ચેની જગ્યાઓ અકબંધ રાખવા માટે, અમે થોડા વધુ જટિલ સૂત્રનો ઉપયોગ કરીશું:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

ઉપરના સૂત્રમાં, FIND, MID અને TRIM નું સંયોજન તેની સ્થિતિની ગણતરી કરે છે. શબ્દમાળામાં પ્રથમ ટેક્સ્ટ અક્ષર. અને પછી, તમે તે નંબરને અન્ય MID ફંક્શનમાં સપ્લાય કરો જેથી તે પ્રથમ ટેક્સ્ટ અક્ષરની સ્થિતિથી શરૂ થતાં સમગ્ર ટેક્સ્ટ સ્ટ્રિંગ (સ્ટ્રિંગ લંબાઈ LEN દ્વારા ગણવામાં આવે છે) પરત કરે.

નીચેનો સ્ક્રીનશોટ બતાવે છે કે તમામ લીડિંગ સ્પેસ જતી રહી છે, જ્યારે શબ્દો વચ્ચેની બહુવિધ જગ્યાઓ હજુ પણ છે:

ફાઇનિંગ ટચ તરીકે, મૂળ ટેક્સ્ટને ટ્રિમ કરેલા મૂલ્યો સાથે બદલો, જેમ કે ટ્રિમ ફોર્મ્યુલા ઉદાહરણના સ્ટેપ 3 માં બતાવ્યા પ્રમાણે , અને તમે જવા માટે તૈયાર છો!

ટીપ. જો તમે પણ કોષોના અંતમાંથી ખાલી જગ્યાઓ દૂર કરવા માંગતા હો, તો ટ્રિમ સ્પેસ ટૂલનો ઉપયોગ કરો. આગળ અને પાછળની જગ્યાઓ દૂર કરવા માટે કોઈ સ્પષ્ટ એક્સેલ ફોર્મ્યુલા નથી કે જે શબ્દો વચ્ચે બહુવિધ જગ્યાઓ અકબંધ રાખે છે.

કોષમાં વધારાની જગ્યાઓ કેવી રીતે ગણવી

કેટલીકવાર, તમારી એક્સેલ શીટમાંથી ખાલી જગ્યાઓ દૂર કરતા પહેલા, તમે ખરેખર કેટલી વધારાની જગ્યાઓ છે તે જાણવા માગી શકો છો.

નંબર મેળવવા માટે કોષમાં વધારાની જગ્યાઓ માટે, LEN ફંક્શનનો ઉપયોગ કરીને કુલ ટેક્સ્ટ લંબાઈ શોધો, પછી વધારાની જગ્યાઓ વિના સ્ટ્રિંગ લંબાઈની ગણતરી કરો, અને બાદમાં પહેલાનામાંથી બાદ કરો:

=LEN(A2)-LEN(TRIM(A2))

નીચેનાસ્ક્રીનશૉટ ક્રિયામાં ઉપરોક્ત સૂત્ર બતાવે છે:

નોંધ. ફોર્મ્યુલા કોષમાં વધારાની જગ્યાઓ ની ગણતરી પરત કરે છે, એટલે કે આગળ, પાછળની, અને શબ્દો વચ્ચેની એક કરતાં વધુ સળંગ જગ્યાઓ, પરંતુ તે ટેક્સ્ટની મધ્યમાં એક જગ્યાની ગણતરી કરતી નથી. જો તમે કોષમાં કુલ જગ્યાઓની સંખ્યા મેળવવા માંગતા હો, તો આ અવેજી સૂત્રનો ઉપયોગ કરો.

અધિક જગ્યાઓ સાથે કોષોને કેવી રીતે હાઇલાઇટ કરવું

સંવેદનશીલ અથવા મહત્વપૂર્ણ માહિતી સાથે કામ કરતી વખતે, તમે ખરેખર શું કાઢી રહ્યા છો તે જોયા વિના તમે કંઈપણ કાઢી નાખવામાં અચકાતા હશો. આ કિસ્સામાં, તમે પહેલા વધારાની જગ્યા ધરાવતા કોષોને હાઇલાઇટ કરી શકો છો, અને પછી તે જગ્યાઓને સુરક્ષિત રીતે દૂર કરી શકો છો.

આ માટે, નીચેના સૂત્ર સાથે શરતી ફોર્મેટિંગ નિયમ બનાવો:

=LEN($A2)>LEN(TRIM($A2))

જ્યાં A2 એ ડેટા સાથેનો સર્વોચ્ચ કોષ છે જેને તમે હાઇલાઇટ કરવા માંગો છો.

સૂત્ર એક્સેલને એવા કોષોને હાઇલાઇટ કરવા માટે સૂચના આપે છે જેમાં કુલ સ્ટ્રિંગની લંબાઈ ટ્રિમ કરેલા ટેક્સ્ટની લંબાઈ કરતાં વધુ હોય છે.

શરતી ફોર્મેટિંગ નિયમ બનાવવા માટે, તમે કૉલમ હેડર વિના હાઇલાઇટ કરવા માંગતા હો તે તમામ કોષો (પંક્તિઓ) પસંદ કરો, હોમ ટૅબ > શૈલીઓ જૂથ પર જાઓ અને <1 પર ક્લિક કરો>શરતી ફોર્મેટિંગ > નવો નિયમ > કયા કોષોને ફોર્મેટ કરવા તે નિર્ધારિત કરવા માટે ફોર્મ્યુલાનો ઉપયોગ કરો .

જો તમે હજુ સુધી Excel શરતી ફોર્મેટિંગથી પરિચિત નથી , તમને અહીં વિગતવાર પગલાંઓ મળશે: તેના આધારે શરતી ફોર્મેટિંગ નિયમ કેવી રીતે બનાવવોફોર્મ્યુલા.

નીચેના સ્ક્રીનશૉટમાં દર્શાવ્યા મુજબ, પરિણામ એ વધારાની જગ્યાઓની ગણતરી સાથે સંપૂર્ણ રીતે સમર્થન આપે છે જે અમને અગાઉના ઉદાહરણમાં મળે છે:

જેમ તમે જુઓ છો, Excel માં TRIM ફંક્શન સરળ અને સીધું છે. તેમ છતાં, જો કોઈ વ્યક્તિ આ ટ્યુટોરીયલમાં ચર્ચા કરેલ સૂત્રોને નજીકથી જોવા માંગે છે, તો તમારું ટ્રિમ એક્સેલ સ્પેસીસ વર્કબુક ડાઉનલોડ કરવા માટે સ્વાગત છે.

Excel TRIM કામ કરતું નથી

TRIM ફંક્શન ફક્ત દૂર કરે છે. 7-બીટ ASCII અક્ષર સમૂહમાં કોડ મૂલ્ય 32 દ્વારા રજૂ કરાયેલ સ્પેસ અક્ષર . યુનિકોડ કેરેક્ટર સેટમાં, વધુ એક સ્પેસ કેરેક્ટર છે જેને નોન-બ્રેકિંગ સ્પેસ, કહેવાય છે જે સામાન્ય રીતે વેબ પેજ પર html કેરેક્ટર તરીકે વપરાય છે . નોનબ્રેકિંગ સ્પેસનું દશાંશ મૂલ્ય 160 છે, અને TRIM ફંક્શન તેને જાતે જ દૂર કરી શકતું નથી.

તેથી, જો તમારા ડેટા સેટમાં એક અથવા વધુ સફેદ જગ્યાઓ હોય જેને TRIM ફંક્શન દૂર કરતું નથી, તો SUBSTITUTE ફંક્શનનો ઉપયોગ કરો નોન-બ્રેકિંગ સ્પેસને રેગ્યુલર સ્પેસમાં કન્વર્ટ કરવા અને પછી તેમને ટ્રિમ કરવા. ટેક્સ્ટ A1 માં છે એમ ધારી રહ્યા છીએ, સૂત્ર નીચે પ્રમાણે જાય છે:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

વધારાની સાવચેતી તરીકે, તમે કોઈપણ બિન-છાપવા યોગ્ય અક્ષરોના સેલને સાફ કરવા માટે CLEAN ફંક્શનને એમ્બેડ કરી શકો છો:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

નીચેનો સ્ક્રીનશૉટ તફાવત બતાવે છે:

જો ઉપરોક્ત સૂત્રો તમારા માટે પણ કામ કરતા નથી, તો સંભવ છે કે તમારા ડેટામાં અમુક ચોક્કસ નોન પ્રિન્ટિંગ હોય પાત્રો32 અને 160 સિવાયના કોડ મૂલ્યો સાથે. આ કિસ્સામાં, અક્ષર કોડ શોધવા માટે નીચેનામાંથી એક સૂત્રનો ઉપયોગ કરો, જ્યાં A1 સમસ્યારૂપ કોષ છે:

અગ્રેસર જગ્યા: =CODE(LEFT(A1,1))

પાછળ સ્પેસ: =CODE(RIGHT(A1,1))

ઇન-બીટવીન સ્પેસ (જ્યાં n ટેક્સ્ટ સ્ટ્રીંગમાં સમસ્યારૂપ અક્ષરની સ્થિતિ છે):

=CODE(MID(A1, n , 1)))

અને પછી , ઉપર ચર્ચા કરેલ TRIM(SUBSTITUTE()) ફોર્મ્યુલાને પરત કરેલ અક્ષર કોડ સપ્લાય કરો.

ઉદાહરણ તરીકે, જો CODE ફંક્શન 9 આપે છે, જે આડું ટૅબ અક્ષર છે, તો તમે તેને દૂર કરવા માટે નીચેના સૂત્રનો ઉપયોગ કરો છો:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

એક્સેલ માટે સ્પેસ ટ્રિમ કરો - એક ક્લિકમાં વધારાની જગ્યાઓ દૂર કરો

શું તુચ્છ કાર્ય સાથે વ્યવહાર કરવા માટે મુઠ્ઠીભર વિવિધ ફોર્મ્યુલા શીખવાનો વિચાર હાસ્યાસ્પદ લાગે છે? પછી એક્સેલમાં ખાલી જગ્યાઓથી છૂટકારો મેળવવા માટે તમને આ એક-ક્લિક તકનીક ગમશે. ચાલો હું તમને અમારા અલ્ટીમેટ સ્યુટમાં સમાવિષ્ટ ટેક્સ્ટ ટૂલકીટનો પરિચય કરાવું. કેસ બદલવા, ટેક્સ્ટને વિભાજીત કરવા અને ફોર્મેટિંગ સાફ કરવા જેવી અન્ય બાબતોમાં, તે ટ્રીમ સ્પેસીસ વિકલ્પ પ્રદાન કરે છે.

તમારા એક્સેલમાં સ્થાપિત અલ્ટીમેટ સ્યુટ સાથે, એક્સેલમાં ખાલી જગ્યાઓ દૂર કરવી એ આટલું જ સરળ છે. :

1. તમે જ્યાં જગ્યાઓ કાઢી નાખવા માંગો છો તે સેલ પસંદ કરો.
2. રિબન પર ટ્રીમ સ્પેસ બટન પર ક્લિક કરો.
3. નીચેનામાંથી એક અથવા બધા વિકલ્પો પસંદ કરો:
   • ટ્રીમ અગ્રેસર અને પાછળની જગ્યાઓ
   • ટ્રીમ વધારાની સ્પેસ શબ્દો વચ્ચે, એક સિવાયસ્પેસ
   • ટ્રીમ નોન-બ્રેકિંગ સ્પેસ ( )
4. ટ્રીમ કરો ક્લિક કરો.

તે બધા ત્યાં છે! બધી વધારાની જગ્યાઓ એક ઝબકમાં દૂર કરવામાં આવે છે.

આ ઉદાહરણમાં, અમે ફક્ત આગળ અને પાછળની જગ્યાઓ જ દૂર કરી રહ્યા છીએ, વધુ સારી રીતે વાંચી શકાય તે માટે શબ્દો વચ્ચે બહુવિધ જગ્યાઓ અકબંધ રાખીએ છીએ - એક્સેલ ફોર્મ્યુલા જે કાર્યનો સામનો કરી શકતું નથી તે કાર્ય એક સાથે પૂર્ણ થાય છે. માઉસ ક્લિક કરો!

જો તમે તમારી શીટ્સમાં ટ્રીમ સ્પેસ ને અજમાવવામાં રસ ધરાવો છો, તો આ પોસ્ટના અંતે મૂલ્યાંકન સંસ્કરણ ડાઉનલોડ કરવા માટે તમારું સ્વાગત છે.

વાંચવા બદલ હું તમારો આભાર માનું છું અને આવતા અઠવાડિયે તમને મળવા આતુર છું. અમારા આગામી ટ્યુટોરીયલમાં, અમે એક્સેલમાં સ્પેસને ટ્રિમ કરવાની અન્ય રીતોની ચર્ચા કરીશું, કૃપા કરીને ટ્યુન રહો!

ઉપલબ્ધ ડાઉનલોડ્સ

ટ્રીમ એક્સેલ સ્પેસ - ફોર્મ્યુલા ઉદાહરણો (.xlsx ફાઇલ)

અલ્ટિમેટ સ્યુટ - ટ્રાયલ વર્ઝન (.exe ફાઇલ)