«Konkatenere» betyr vanligvis å knytte noe sammen i en serie eller en kjede. Denne operasjonen brukes når du trenger å slå sammen tekst fra flere Google Regneark-celler. Denne artikkelen samler de mest populære og enkle løsningene for å hjelpe deg med å løse sammenkoblingsoppgaven.

Hvor stort datasettet ditt er, kan det hende du kommer over oppgaven med å kombinere flere celler i Google Sheets sammen. Og jeg er ikke i tvil om at du ikke bare vil forhindre at alle verdier tapes, men også legge til noen kommaer, mellomrom eller andre tegn, eller til og med skille disse postene med annen tekst.

Vel, regneark tilbyr flere verktøy for denne oppgaven.

Google Sheets CONCAT-funksjon

CONCAT-funksjonen er en forenklet versjon av Google Sheets CONCATENATE:

For å slå sammen celler med denne funksjonen, må du liste opp de nødvendige verdiene:

• verdi1 – en post som verdi2 skal legges til.
• verdi2 – verdien som skal slås sammen.

For å få én streng fra 2 tekst- eller numeriske enheter, vil formelen se ut som nedenfor, med hver post i doble anførselstegn:

=CONCAT("2019:","The Lion King")

I virkeligheten er dataene dine mest sannsynlig allerede i celler. Du kan referere til disse cellene direkte i stedet for å sette ned hvert tall eller hver tekst som et argument. Så formelen for ekte data vil være slik:

=TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Tips. For å kopiere formelen til hele kolonnen, velg cellenmed formelen og dobbeltklikk på den lille firkanten nederst til høyre i cellen. Hele kolonnen fylles automatisk med formelen helt til slutten av tabellen.

Som du kan se, er funksjonen superenkel, men den har store svake punkter :

• den slår bare sammen to celler i Google Sheets om gangen.
• den kan ikke kombinere kolonner, rader eller andre store dataområder, den tar bare enkeltceller. Hvis du prøver å slå sammen flere celler, får du enten en feilmelding eller bare de to første verdiene vil bli slått sammen, slik:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT-alternativ: sammenkoblingsoperator og-tegnet (&)

Det er mange forskjellige operatorer for ulike formål i formler. Sammenkobling er ikke et unntak. Å bruke et og-tegn (&) i formler i stedet for CONCAT-funksjonen vil gi deg det samme resultatet:

=A2&B2

Men lite vet du at denne sammenkoblingsoperatøren er mer fleksibel. Her er hva den kan gjøre:

1. Slå sammen mer enn to verdier om gangen:

   =A2&B2&C2

   

2. Ikke bare slå sammen celler i Google Sheets, men separer dem også med forskjellige tegn:

   =A2&" "&B2&"; "&C2

   

Hvis du fortsatt ikke får ønsket resultat med disse alternativene , det er en funksjon til å prøve.

Hvordan bruke CONCATENATE i Google Sheets

Jeg tror at Google Sheets CONCATENATE-funksjonen er den første som brukernår det gjelder å legge til flere poster sammen.

SAMMENKNYTTE tekststrenger og tall i Google Regneark

Formelmønsteret består av følgende argumenter:

• streng1 er den første strengen du vil legge til andre verdier til. Dette argumentet er nødvendig.
• streng2, … står for alle andre strenger du kanskje vil legge til. Dette argumentet er valgfritt.

Merk. Resultatposten vil bestå av strengene i den rekkefølgen de vises i formelen.

Hvis jeg tilpasser formelen til dataene mine, får jeg dette:

=CONCATENATE(A2,B2,C2)

Eller siden funksjonen godtar områder:

=CONCATENATE(A2:D2)

Du kan umiddelbart legge merke til den første fordelen med Google Sheets CONCATENATE: den kobles enkelt sammen over to celler med både tekst og tall.

Google Sheets: sett sammen strenger med skilletegn

Å kombinere celler i Google Regneark er halve arbeidet. Men for å få resultatet til å se pent og lesbart ut, bør du legge til noen ekstra tegn.

Hvis du beholder formelen som den er, vil den bare lime alt sammen: BonnieJacksonCA , BonnieJacksonIN osv. Men Google Sheets CONCATENATE tar også tegn som argumenter.

For å legge til noen skilletegn for lesbarhet, nevne dem i doble anførselstegn i formelen:

=CONCATENATE(A2," ",B2,", ",C2)

Her vil jeg sette sammen A2 & B2 med mellomrom og skille B2 fra C2 med komma ogspace:

Du står fritt til å bruke nesten alle tegn i funksjonen som denne, men et linjeskift krever en annen tilnærming.

Tips. Hvis det er tomme celler i noen av kolonnene du slår sammen, er det en funksjon til du kan være interessert i. TEXTJOIN slår ikke bare sammen celler i Google Sheets, men ignorerer tomme felter:

=TEXTJOIN(" ",TRUE,A2:C2)

Slik fungerer det:

1. Angi ønsket skilletegn som et første argument – ​​ mellomrom (" ") for meg.
2. Sett TRUE som et andre argument for å hoppe over tomme celler eller FALSE for å inkludere dem i resultatet.
3. Skriv inn området for å slå sammen.

Sett sammen med linjeskift i Google Sheets

Selv om det er åpenbart hvordan du legger inn de fleste skilletegn for funksjonen, kan du ikke skrive et linjeskift på samme måte der. Men heldigvis lar Google deg spille mange forskjellige kort.

Det er en funksjon som hjelper deg med å få spesialtegn – den heter CHAR. Du skjønner, hvert tegn har en plass i Unicode-tabellen. Du trenger bare å mate ordinærtallet til tegnet fra den tabellen til funksjonen, og sistnevnte vil returnere tegnet selv.

Her er en formel for å få linjeskiftet:

=CHAR(10)

Legg det til formelen for å slå sammen med linjeskiftet i Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Kombiner dato og klokkeslett i Google Sheets

Hvis du prøver å kombinere dato og klokkeslett i Google Sheets ved å bruke en av metodeneovenfor, vil det ikke fungere. Regnearket ditt vil returnere tall:

For å kombinere dato og klokkeslett i Google Sheets på riktig måte, bruk TEXT-funksjonen:

• hvor nummer er et hvilket som helst tall, dato eller klokkeslett du vil ha i ønsket format
• og format er mønsteret du vil ha se som et resultat.

Tips. I mitt eksempel skal jeg referere til celler med datoer og klokkeslett, men du står fritt til å bruke dato/tidsenheter eller til og med slike funksjoner som DATO eller TID direkte i formelen.

1. Jeg bruker den første TEKST-formelen for å endre datoformatet fra 7/9/2019 til 9. juli 2019 :

   =TEXT(B2,"D MMM YYYY")

2. Den andre TEKST returnerer tiden:

   =TEXT(C2,"HH:MM:SS")

3. Ved å bruke disse i CONCATENATE lar Google Sheets meg kombinere dato og klokkeslett i ønsket format med andre tegn eller tekst:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Kombiner kolonner i Google Regneark

Med små justeringer er alle måtene jeg nevnte på, i stand til å slå sammen kolonner i Google Regneark.

Eksempel 1. Google Sheets CONCAT

For å slå sammen hele kolonner i Google Sheets med CONCAT, velg hele området som skal inneholde resultatet (C2:C11 i mitt tilfelle) og skriv inn formelen din det i ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Merk. Du kan bruke CONCATENATE-funksjonen, men den vil slå sammen alle poster i én celle siden den enkelt slår sammen flere celler og dataområder.

Eksempel 2.Sammenkoblingsoperator

Opprett matriseformler for å kombinere kolonner i Google Sheets ved å bruke og-tegnet og legg til skilletegn samtidig:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Dette ser bra ut, men jeg må påpeke noen store ulemper.

Hvis du har for mange kolonner, kan det å telle opp alle bli en smerte i nakken, spesielt hvis du ved et uhell hopper over/dupliserer/mikser opp noen tegn. .

Hvis du bestemmer deg for å legge til flere kolonner i formelen senere, må du redigere hvert eneste eksisterende område i formelen manuelt.

Det neste eksemplet løser disse problemene.

Eksempel 3. Google Sheets QUERY

Google Sheets QUERY-funksjonen er også egnet til å slå sammen flere kolonner i Google Sheets. Ta en titt:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Du tror kanskje denne merkelige formelen er utenfor din rekkevidde, men la meg legge ut alt for deg:

1. =TRANSPOSE(A2:D10) gjør radene med data til kolonner.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) slår sammen poster i hver kolonne til øverste celler.

   Tips. Når jeg legger 9^9 inn i formelen, sørger jeg for at alle rader fra alle kolonner blir trukket inn i den første raden som om de var overskrifter. Det er 9^9 siden dette uttrykket inkluderer alle mulige celler i regnearket (husker du grensen for 10M celler?) og er lett å huske. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) tar den overskriftsraden fra QUERY og gjør den om til en kolonne somen jeg har.

Her er fordelene ved å slå sammen kolonner i Google Regneark ved å bruke QUERY:

• du trenger ikke å velge hele kolonnen som du gjør for matriseformler
• trenger du ikke å nevne hver kolonne i formelen med mindre de ikke er tilstøtende. I dette tilfellet vil formelen se slik ut:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Sett sammen og legg til tekst etter posisjon

Du vet allerede at du kan legge til manglende tekst, tall , og tegn til strengene dine ved å bruke CONCATENATE-funksjonen.

Tips. Se flere formler om det i denne opplæringen.

Men hvis det er for mange poster å bli med, kan eventuelle ekstra tegn utvide formelen langt utover det du har planlagt. I tilfeller som dette er det bedre å slå sammen celler i Google Sheets som de er, eller bruke enkle skilletegn som mellomrom og legge til teksten etter det. Et spesielt verktøy fra oss vil hjelpe deg.

Legg til tekst etter posisjon setter inn tegn og strenger etter posisjonen du angir, ingen formler er nødvendig. La meg vise deg hvordan det fungerer.

I forrige eksempel slo QUERY sammen navn og telefonnumre for meg. Men jeg vil gjerne legge til landforkortelser: (USA/CA) før telefonnumre som begynner med +1 og UK før +44 :

Del celler i Google Regneark

Hvis du kombinerer celler i Google Regneark, er sjansen stor for at du må dele dem tilbake på et tidspunkt . Det er tre måter å gjøre det på:

1. Bygg en formelved å bruke Google Sheets SPLIT-funksjon.
2. Bruk standard regnearkinstrument – ​​Del tekst til kolonner.
3. Eller prøv den forbedrede versjonen av det innebygde verktøyet – Del tekst til kolonner for Google Sheets:

Den lar deg dele celler med en hvilken som helst skilletegn eller sett med skilletegn, behandle dem som én og inkludere konjunksjoner om nødvendig. Den tilbyr også muligheten til å dele celler i Google Sheets etter posisjon.

Tips. Det er et alternativ for å trekke ut data fra Google Sheets-celler i stedet for å dele innholdet.

Hvordan slå sammen celler i Google Sheets uten formler

Hvis det ikke er en del av planen din å mestre forskjellige formler, vil du dra nytte av vårt Merge Values-tillegg. Tillegget slår raskt sammen poster i rader, kolonner eller hele celleområdet. Alternativene er krystallklare, og alt du trenger å gjøre er å velge området og bestemme hvordan resultatet skal se ut.

1. Du kan velge å kombinere kolonner i Google Sheets — selv ikke-tilstøtende, skille dem med komma og mellomrom, og plasser resultatet til høyre for de opprinnelige postene:

Hvis du er interessert i verktøyet, kan du segjennom alt det gjør på denne spesielle siden eller i denne korte videoopplæringen:

Lær hvordan du bruker Kombiner dupliserte rader i denne videoen :

Jeg håper du nå har bestemt deg for hvilken av måtene som passer best for ditt tilfelle. Hvis du har noen andre metoder i tankene, vennligst del med oss ​​i kommentarfeltet nedenfor :)