Die tutoriaal demonstreer 'n paar vinnige en maklike maniere om Excel-spasies te snoei. Leer hoe om voor-, agter- en ekstra spasies tussen woorde te verwyder, hoekom Excel TRIM-funksie nie werk nie en hoe om dit reg te stel.

Vergelyk jy twee kolomme vir duplikate wat jy weet daar is, maar kan u formules nie 'n enkele duplikaatinskrywing vind nie? Of tel jy twee kolomme getalle bymekaar, maar kry steeds net nulle? En hoekom op aarde gee jou klaarblyklik korrekte Vlookup-formule net 'n klomp N/A-foute terug? Hierdie is slegs 'n paar voorbeelde van probleme waarop jy dalk antwoorde soek. En almal word veroorsaak deur ekstra spasies wat voor, na of tussen numeriese en tekswaardes in jou selle wegsteek.

Microsoft Excel bied 'n paar verskillende maniere om spasies te verwyder en maak jou data skoon. In hierdie tutoriaal sal ons die vermoëns van die TRIM-funksie ondersoek as die vinnigste en maklikste manier om spasies in Excel uit te vee.

TRIM-funksie - verwyder ekstra spasies in Excel

Jy gebruik die TRIM-funksie in Excel, verwyder ekstra spasies uit teks. Dit vee alle voor-, agter- en tussen-spasies behalwe vir 'n enkele spasie -karakter tussen woorde uit.

Die sintaksis van die TRIM-funksie is die maklikste wat jy jou kan voorstel:

Waar teks 'n sel is waaruit jy oortollige spasies wil verwyder.

Om byvoorbeeld spasies in sel A1 te verwyder, gebruik jy hierdieformule:

=TRIM(A1)

En die volgende skermkiekie wys die resultaat:

Jip, dit is so eenvoudig!

Neem asseblief kennis dat die TRIM-funksie is ontwerp om slegs die spasiekarakter te verwyder, wat waarde 32 in die 7-bis ASCII-kodestelsel het. As jou data benewens ekstra spasies reëlbreuke en nie-drukkarakters bevat, gebruik die TRIM-funksie in kombinasie met CLEAN om die eerste 32 nie-drukkarakters in die ASCII-stelsel uit te vee.

Byvoorbeeld, om verwyder spasies, lynbreuke en ander ongewenste karakters uit sel A1, gebruik hierdie formule:

=TRIM(CLEAN(A1))

Vir meer inligting, sien asseblief Hoe om nie-druk karakters in Excel te verwyder

Om ontslae te raak van onbreekbare spasies (html karakter ), wat waarde 160 het, gebruik TRIM saam met SUBSTITUTE en CHAR funksies:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Vir volledige besonderhede, asseblief sien Hoe om nie-breek spasies in Excel uit te vee

Hoe om TRIM-funksie in Excel te gebruik - formulevoorbeelde

Nou dat jy die basiese beginsels ken, kom ons bespreek 'n paar spesifieke gebruike van TRIM in Excel, slaggate wat jy in die gesig staar en werkende oplossings.

Hoe om spasies in 'n hele kolom van data te snoei

Gestel jy het 'n kolom met name wat ook 'n wit spasie voor en na die teks het, soos meer as een spasies tussen die woorde. So, hoe verwyder jy alle voorste, agterste en oortollige tussenruimtes in alle selle op 'n slag? Deur 'n Excel te kopieerTRIM formule oor die kolom, en vervang dan formules met hul waardes. Die gedetailleerde stappe volg hieronder.

1. Skryf 'n TRIM-formule vir die boonste sel, A2 in ons voorbeeld:

   =TRIM(A2)

2. Posisioneer die wyser na die onderste regterhoek van die formulesel (B2 in hierdie voorbeeld), en sodra die wyser in die plusteken verander, dubbelklik daarop om die formule in die kolom af te kopieer, tot by die laaste sel met data. As gevolg hiervan sal jy 2 kolomme hê - oorspronklike name met spasies en formule-gedrewe afgesnyde name.

• Kies alle selle met Sny-formules (B2:B8 in hierdie voorbeeld), en druk Ctrl+C om hulle te kopieer.
• Kies alle selle met die oorspronklike data (A2:A8) ), en druk Ctrl+Alt+V en dan V . Dit is die plakwaarde-kortpad wat die Plak Spesiaal > Waardes
• Druk die Enter-sleutel. Klaar!

Hoe om voorste spasies in 'n numeriese kolom te verwyder

Soos jy sopas gesien het, het die Excel TRIM-funksie alle ekstra spasies uit 'n kolom teksdata verwyder sonder 'n haakplek. Maar wat as jou data getalle is, nie teks nie?

Op die oog af lyk dit dalk asof dieTRIM-funksie het sy werk gedoen. As u egter van nader kyk, sal u sien dat die afgewerkte waardes nie soos syfers optree nie. Hier is net 'n paar aanduidings van abnormaliteit:

• Beide die oorspronklike kolom met voorste spasies en afgesnyde getalle is linksbelyn, selfs al pas jy die Getalformaat op die selle toe, terwyl normale getalle regsbelyn is. by verstek.
• Wanneer twee of meer selle met gesnyde getalle gekies word, vertoon Excel slegs COUNT in die statusbalk. Vir getalle moet dit ook SOM en GEMIDDELDE vertoon.
• 'n SOM-formule wat op die gesnoeide selle toegepas word, gee nul terug.

Van alle verskynings, die gesnoeide waardes is teksstringe , terwyl ons getalle wil hê. Om dit reg te stel, kan jy die afgewerkte waardes met 1 vermenigvuldig (om al die waardes in een klap te vermenigvuldig, gebruik die Plak Spesiale > Vermenigvuldig-opsie).

'n Meer elegante oplossing is om die TRIM-funksie in VALUE in te sluit. , soos volg:

=VALUE(TRIM(A2))

Die formule hierbo verwyder alle voorste en agterste spasies, indien enige, en verander die resulterende waarde in 'n getal, soos in die skermkiekie hieronder getoon:

Hoe om slegs voorste spasies in Excel te verwyder (linksknip)

In sommige situasies kan jy gedupliseerde en selfs verdriedubbelde spasies tussen woorde tik om jou data beter leesbaar te maak. Jy wil egter ontslae raak van voorste spasies, soos hierdie:

Soos jy reeds weet, die TRIM-funksieskakel ekstra spasies in die middel van teksstringe uit, wat nie is wat ons wil hê nie. Om alle tussen-ruimtes ongeskonde te hou, sal ons 'n bietjie meer komplekse formule gebruik:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

In die formule hierbo bereken die kombinasie van FIND, MID en TRIM die posisie van die eerste tekskarakter in 'n string. En dan verskaf jy daardie getal aan 'n ander MID-funksie sodat dit die hele teksstring terugstuur (die stringlengte word deur LEN bereken) begin by die posisie van die eerste tekskarakter.

Die volgende skermkiekie wys dat alle voorste spasies is weg, terwyl veelvuldige spasies tussen woorde nog daar is:

As 'n afronding, vervang die oorspronklike teks met die gesnyde waardes, soos getoon in stap 3 van die Trim formule-voorbeeld , en jy is goed om te gaan!

Wenk. As jy ook spasies van die einde van selle wil verwyder, maak gebruik van die Trim Spaces-nutsding. Daar is geen voor die hand liggende Excel-formule om voorste en agterste spasies te verwyder, terwyl verskeie spasies tussen woorde ongeskonde bly nie.

Hoe om ekstra spasies in 'n sel te tel

Soms, voordat jy spasies in jou Excel-blad verwyder, wil jy dalk weet hoeveel oortollige spasies daar is.

Om die getal te kry van ekstra spasies in 'n sel, vind uit die totale tekslengte deur die LEN-funksie te gebruik, bereken dan die stringlengte sonder ekstra spasies, en trek laasgenoemde van eersgenoemde af:

=LEN(A2)-LEN(TRIM(A2))

Die volgendeskermkiekie wys die formule hierbo in aksie:

Let wel. Die formule gee die telling van ekstra spasies in 'n sel terug, d.w.s. voorste, agtervolgende en meer as een opeenvolgende spasies tussen woorde, maar dit tel nie enkele spasies in die middel van die teks nie. As jy die totale aantal spasies in 'n sel wil kry, gebruik hierdie Vervang-formule.

Hoe om selle met oortollige spasies uit te lig

Wanneer jy met sensitiewe of belangrike inligting werk, kan jy huiwerig wees om enigiets uit te vee sonder om te sien wat jy presies uitvee. In hierdie geval kan jy eers selle wat ekstra spasies bevat uitlig, en dan daardie spasies veilig uitskakel.

Skep hiervoor 'n voorwaardelike formateringreël met die volgende formule:

=LEN($A2)>LEN(TRIM($A2))

Waar A2 die boonste sel is met data wat jy wil uitlig.

Die formule gee Excel opdrag om selle uit te lig waarin die totale stringlengte groter is as die lengte van die geknipte teks.

Om 'n voorwaardelike formateringreël te skep, kies al die selle (rye) wat jy sonder kolomopskrifte wil uitlig, gaan na die Tuis -oortjie > Style -groep, en klik Voorwaardelike formatering > Nuwe reël > Gebruik 'n formule om te bepaal watter selle om te formateer .

As jy nog nie met Excel-voorwaardelike formatering vertroud is nie , sal jy die gedetailleerde stappe hier vind: Hoe om 'n voorwaardelike formatering reël te skep gebaseer opformule.

Soos gedemonstreer in die skermkiekie hieronder, stem die resultaat perfek saam met die ekstra spasiestelling wat ons in die vorige voorbeeld gekry het:

Soos jy sien, die gebruik van die TRIM-funksie in Excel is maklik en reguit. Nietemin, as iemand die formules wat in hierdie tutoriaal bespreek is van nader wil kyk, is jy welkom om die Trim Excel Spaces-werkboek af te laai.

Excel TRIM werk nie

Die TRIM-funksie verwyder net die spasiekarakter verteenwoordig deur kodewaarde 32 in die 7-bis ASCII karakterstel. In die Unicode-karakterstel is daar nog een spasiekarakter genaamd die nie-brekende spasie, wat algemeen op webblaaie as die html-karakter gebruik word. Die onbreekbare spasie het 'n desimale waarde van 160, en die TRIM-funksie kan dit nie op sigself verwyder nie.

Dus, as jou datastel een of meer wit spasies bevat wat die TRIM-funksie nie verwyder nie, gebruik die SUBSTITUTE-funksie om nie-breek spasies in gewone spasies te omskep en dit dan te snoei. Gestel die teks is in A1, gaan die formule soos volg:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

As 'n ekstra voorsorgmaatreël kan jy die SKOON funksie inbed om die sel skoon te maak van enige nie-drukbare karakters:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Die volgende skermkiekie wys die verskil:

As bogenoemde formules ook nie vir jou werk nie, is die kans goed dat jou data 'n spesifieke nie-druk bevat karaktersmet kodewaardes anders as 32 en 160. Gebruik in hierdie geval een van die volgende formules om die karakterkode uit te vind, waar A1 'n problematiese sel is:

Leading space: =CODE(LEFT(A1,1))

Trailing spasie: =CODE(RIGHT(A1,1))

Tussen-in spasie (waar n die posisie van die problematiese karakter in die teksstring is):

=CODE(MID(A1, n , 1)))

En dan , verskaf die teruggestuurde karakterkode aan die TRIM(SUBSTITUTE()) formule wat hierbo bespreek is.

Byvoorbeeld, as die CODE-funksie 9 terugstuur, wat die Horizontal Tab-karakter is, gebruik jy die volgende formule om dit te verwyder:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Sny spasies vir Excel - verwyder ekstra spasies in 'n klik

Klink die idee om 'n handvol verskillende formules te leer om 'n onbenullige taak te hanteer, belaglik? Dan hou jy dalk van hierdie een-klik-tegniek om van spasies in Excel ontslae te raak. Laat ek jou voorstel aan Text Toolkit wat in ons Ultimate Suite ingesluit is. Dit bied onder meer die opsie Sny spasies , soos om hoofletters te verander, teks te verdeel en formatering skoon te maak.

Met Ultimate Suite geïnstalleer in jou Excel, is die verwydering van spasies in Excel so eenvoudig soos hierdie :

1. Kies die sel(s) waar jy spasies wil uitvee.
2. Klik op die Sny spasies -knoppie op die lint.
3. Kies een of al die volgende opsies:
   • Sny voorste en volgende spasies
   • Sny ekstra spasies tussen woorde, behalwe vir 'n enkelespasie
   • Sny nie-breek spasies ( )
4. Klik Snoei .

Dit is al wat daar is! Alle ekstra spasies word in 'n oogwink verwyder.

In hierdie voorbeeld verwyder ons slegs voor- en agterspasies, en hou veelvuldige spasies tussen woorde ongeskonde vir beter leesbaarheid - die taak waarmee Excel-formules nie kan klaarkom nie, word uitgevoer met 'n muisklik!

As jy belangstel om Trim Spaces in jou blaaie te probeer, is jy welkom om 'n evalueringsweergawe aan die einde van hierdie pos af te laai.

Ek bedank jou vir die lees en sien uit daarna om jou volgende week te sien. In ons volgende tutoriaal sal ons ander maniere bespreek om spasies in Excel te snoei, bly asseblief ingeskakel!

Beskikbare aflaaie

Sny Excel-spasies - formulevoorbeelde (.xlsx-lêer)

Ultimate Suite - proefweergawe (.exe-lêer)