Добивате многу #N/A грешки во вашите работни листови и сте љубопитни да знаете дали постои начин да се прикаже приспособен текст наместо тоа? Формулата ИФНА е решението што ви треба.

Кога формулата на Excel не може да идентификува или пронајде нешто, ја исфрла грешката #N/A. За да ја фатите таквата грешка и да ја замените со порака погодна за корисникот, можете да ја користите функцијата IFNA. Со други зборови, #N/A е начин на Excel да каже дека вредноста што ја барате не е присутна во референтната база на податоци. IFNA е вашиот начин на заробување и справување со таа грешка.

IFNA функција во Excel

Функцијата Excel IFNA е наменета за фаќање и справување со #N/A грешки. Ако формулата се процени на #N/A, IFNA ја заробува таа грешка и ја заменува со приспособена вредност што ќе ја наведете; инаку враќа нормален резултат од формулата.

ИФНА синтакса

Синтаксата на функцијата IFNA е следна:

Каде:

Вредност (задолжително) - формулата, вредноста или референцата за проверка за грешка #N/A.

Value_if_na (задолжително) - вредноста за да се врати ако се открие грешка #N/A.

Забелешки за употреба

• Функцијата IFNA се справува само со #N/A без да се потиснат други грешки.
• Ако аргументот вредност е формула за низа , IFNA враќа низа резултати, по еден по ќелија, како што е прикажано во овој пример.

Достапност на IFNA

Функцијата IFNA беше воведена воExcel 2013 и е достапен во сите последователни верзии, вклучувајќи ги Excel 2016, Excel 2019, Excel 2021 и Microsoft 365.

Во претходните верзии, можете да фатите #N/A грешки користејќи ги заедно функциите IF и ISNA.

Како да се користи функцијата IFNA во Excel

За ефикасно користење на IFNA во Excel, следете го овој генерички пристап:

1. Во првиот аргумент ( вредност ), ставете формула под влијание на грешката #N/A.
2. Во вториот аргумент ( value_if_na ), напишете го текстот што сакате да го вратите наместо стандардната нотација за грешка. За да вратите празна ќелија кога ништо не е пронајдено, внесете празна низа ('"").

За да вратите прилагоден текст , генеричката формула е:

За да се врати празна ќелија , генеричката формула е:

Ајде да видиме како функционира на едноставен пример. Во табелата подолу, да претпоставиме дека сакате да знаете како резултатот на даден студент се рангира меѓу другите. Бидејќи податоците се подредени според колоната Оценка од највисока до најниска, рангирањето ќе одговара на релативната позиција на ученикот во табелата. И за да ја добиете позицијата, можете да ја користите функцијата MATCH во нејзината наједноставна форма:

=MATCH(E1, A2:A10, 0)

Бидејќи вредноста за пребарување (Neal) не е достапна во низата за пребарување (A2:A10), се појавува грешка #N/A.

Кога ќе се појави оваа грешка, неискусните корисници можеби мислат дека нешто не е во ред соформула, а вие како креатор на работната книга ќе добиете многу прашања. За да го избегнете ова, можете експлицитно да наведете дека формулата е точна, едноставно не може да ја најде вредноста што се бара да ја бара. Така, ја вгнездувате формулата MATCH во првиот аргумент на IFNA и, во вториот аргумент, напишете го вашиот прилагоден текст, „Не е пронајден“ во нашиот случај:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Сега, наместо стандардната нотација за грешка, вашиот сопствен текст се прикажува во ќелија, информирајќи ги корисниците дека вредноста за пребарување не е присутна во базата на податоци:

Како да се користи IFNA со VLOOKUP

Најчесто грешката #N/A се јавува во функции кои бараат нешто како што се VLOOKUP, HLOOKUP, LOOKUP и MATCH. Примерите подолу опфаќаат неколку типични случаи на употреба.

Пример 1. Основна формула IFNA VLOOKUP

За да ги заробите #N/A грешките што се појавуваат кога VLOOKUP не може да најде совпаѓање, проверете го неговиот резултат користејќи IFNA и наведете ја вредноста што треба да се прикаже наместо грешката. Вообичаената практика е да ја завиткате функцијата IFNA околу вашата постоечка формула VLOOKUP користејќи ја оваа синтакса:

Во нашата примерна табела, да претпоставиме дека сакате да добие резултат на одреден ученик (Е1). За ова, ја користите оваа класична формула VLOOKUP:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Прашањето е што Нил не го полагал испитот, затоа неговото име не е на списокот и очигледно VLOOKUP не успева да најде натпревар.

За да се скрие грешката, ниезавиткајте го VLOOKUP во IFNA вака:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Сега, резултатот не изгледа толку застрашувачки за корисникот и е многу поинформативен:

Пример 2. IFNA VLOOKUP за пребарување низ повеќе листови

Функцијата IFNA, исто така, е корисна за извршување на т.н. низ повеќе листови или различни работни книги. Идејата е да вгнездите неколку различни IFNA(VLOOKUP(…)) формули една во друга на овој начин:

Ако примарниот VLOOKUP не најде ништо, неговата IFNA функција го извршува следниот VLOOKUP додека не се најде саканата вредност. Ако сите пребарувања не успеат, формулата ќе го врати наведениот текст.

Да претпоставиме дека ги имате резултатите од различни класи наведени во различни листови (именувани Класа А , Класа Б , и Класа В ). Вашата цел е да го добиете резултатот на одреден ученик, чие име е внесено во ќелијата Б1 во вашиот тековен работен лист. За да ја исполните задачата, искористете ја оваа формула:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Формулата последователно го бара наведеното име во три различни листови по редоследот на вгнездување на VLOOKUP и го носи првото пронајдено совпаѓање:

Пример 3. IFNA со INDEX MATCH

На сличен начин, IFNA може да фати #N/A грешки генерирани од други функции за пребарување. Како пример, да го искористиме заедно со ИНДЕКС МАТЧформула:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Суштината на формулата е иста како и во сите претходни примери - INDEX MATCH врши пребарување, а IFNA го проценува резултатот и фаќа грешка #N/A ако референтната вредност не е пронајдена.

IFNA да врати повеќе резултати

Во случај внатрешната функција (т.е. формулата ставена во вредноста аргумент) враќа повеќе вредности, IFNA ќе ја тестира секоја вратена вредност поединечно и ќе даде низа резултати. На пример:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

Во динамична низа Excel (Microsoft 365 и Excel 2021), редовна формула во најгорната ќелија (E2) автоматски ги истура сите резултати во соседните ќелии (во смисла на Excel, се нарекува опсег на истурање).

Во преддинамични верзии (Excel 2019 и пониски), сличен ефект може да се постигне со користење на низа со повеќе ќелии формула, која се комплетира со кратенката Ctrl + Shift + Enter.

Која е разликата помеѓу IFNA и IFERROR?

Во зависност од основната причина за проблем, формулата на Excel може да предизвика различни грешки како што се #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM и други. Функцијата IFERROR ги фаќа сите тие грешки додека IFNA е ограничена само на #N/A. Кој е подобро да се избере? Тоа зависи од ситуацијата.

Ако сакате да спречите секаков вид на грешка , тогаш користете ја функцијата IFERROR. Тоа е особено корисно во сложени пресметки кога формулавклучува неколку функции кои можат да генерираат различни грешки.

Со функциите за пребарување , подобро е да користите IFNA бидејќи прикажува приспособен резултат само кога не е пронајдена вредност за пребарување и не ги крие основните проблеми со самата формула.

За да ја илустрираме разликата, да ја вратиме нашата основна формула IFNA VLOOKUP и „случајно“ да го напишеме погрешно името на функцијата (VLOKUP наместо VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA не ја потиснува оваа грешка, па можете јасно да видите дека нешто не е во ред со едно од имињата на функциите:

Сега, да видиме што ќе се случи ако користите IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Хм... пишува дека Оливија не го полагала испитот, што не е точно! Ова е затоа што функцијата IFERROR го заробува #NAME? грешка и наместо тоа го враќа приспособениот текст. Во оваа ситуација, не само што враќа погрешни информации туку и го замаглува проблемот со формулата.

Така се користи формулата IFNA во Excel. Ви благодарам што прочитавте и со нетрпение очекувам да се видиме на нашиот блог следната недела!

Достапни преземања

Примери на формулата на Excel IFNA (датотека .xlsx)