გაკვეთილი განმარტავს Excel MONTH და EOMONTH ფუნქციების თხილს და ჭანჭიკებს. თქვენ იხილავთ ფორმულის მაგალითების მასივს, რომლებიც აჩვენებენ, თუ როგორ უნდა ამოიღოთ თვე თარიღიდან Excel-ში, მიიღოთ თვის პირველი და ბოლო დღე, გადაიყვანოთ თვის სახელი რიცხვად და სხვა.

წინა სტატიაში, ჩვენ გამოვიკვლიეთ სხვადასხვა ფორმულა სამუშაო დღეების გამოსათვლელად. დღეს ჩვენ ვაპირებთ ვიმუშაოთ დროის უფრო დიდ ერთეულზე და ვისწავლოთ ფუნქციები, რომლებსაც Microsoft Excel უზრუნველყოფს თვეების განმავლობაში.

ამ გაკვეთილზე თქვენ შეისწავლით:

Excel MONTH ფუნქცია - სინტაქსი და იყენებს

Microsoft Excel გთავაზობთ სპეციალურ MONTH ფუნქციას თარიღიდან თვის ამოსაღებად, რომელიც აბრუნებს თვის რიცხვს 1-დან 12-მდე (დეკემბერი).

MONTH ფუნქცია შეიძლება გამოყენებულ იქნას Excel 2016 - 2000-ის ყველა ვერსიაში და მისი სინტაქსი ისეთივე მარტივია, როგორც ეს შეიძლება იყოს:

სადაც serial_number არის თვის ნებისმიერი მოქმედი თარიღი, რომლის პოვნასაც ცდილობთ.

Excel-ის MONTH ფორმულების სწორი მუშაობისთვის, თარიღი უნდა შეიყვანოთ DATE (წელი, თვე, დღე) ფუნქციის გამოყენებით. მაგალითად, ფორმულა =MONTH(DATE(2015,3,1)) აბრუნებს 3-ს, ვინაიდან DATE წარმოადგენს 2015 წლის მარტის 1 დღეს.

ფორმულები, როგორიცაა =MONTH("1-Mar-2015") , ასევე კარგად მუშაობს, თუმცა პრობლემები შეიძლება წარმოიშვას უფრო რთულ სცენარებში, თუ თარიღები შეყვანილია ტექსტად.

პრაქტიკაში, MONTH ფუნქციის ფარგლებში თარიღის მითითების ნაცვლად, უფრო მოსახერხებელია უჯრედის მითითება თარიღით ანMONTH და EOMONTH ფუნქციები სხვადასხვა გამოთვლების შესასრულებლად თქვენს სამუშაო ფურცლებში, შეგიძლიათ გადადგათ ნაბიჯი და გააუმჯობესოთ ვიზუალური პრეზენტაცია. ამისათვის ჩვენ ვაპირებთ გამოვიყენოთ Excel-ის პირობითი ფორმატირების შესაძლებლობები თარიღებისთვის.

აღნიშნულ სტატიაში მოყვანილი მაგალითების გარდა, ახლა მე გაჩვენებთ, თუ როგორ შეგიძლიათ სწრაფად მონიშნოთ ყველა უჯრედი ან მთელი მწკრივი. დაკავშირებულია გარკვეულ თვესთან.

მაგალითი 1. მონიშნეთ მიმდინარე თვის თარიღები

წინა მაგალითის ცხრილში, დავუშვათ, რომ გსურთ მონიშნოთ ყველა სტრიქონი მიმდინარე თვის თარიღებით.

პირველ რიგში, თქვენ ამოიღებთ თვის რიცხვებს A სვეტის თარიღებიდან უმარტივესი =MONTH($A2) ფორმულის გამოყენებით. და შემდეგ, თქვენ ადარებთ ამ რიცხვებს =MONTH(TODAY()) მიმდინარე თვესთან. შედეგად, თქვენ გაქვთ შემდეგი ფორმულა, რომელიც აბრუნებს TRUE-ს, თუ თვეების რიცხვები ემთხვევა, FALSE წინააღმდეგ შემთხვევაში:

=MONTH($A2)=MONTH(TODAY())

შექმენით Excel-ის პირობითი ფორმატირების წესი ამ ფორმულის საფუძველზე და თქვენი შედეგი შეიძლება იყოს ჰგავს ქვემოთ მოცემულ ეკრანის სურათს (სტატია დაიწერა აპრილში, ამიტომ აპრილის ყველა თარიღი მონიშნულია).

მაგალითი 2. თარიღების მონიშვნა თვისა და დღის მიხედვით

და აქ არის კიდევ ერთი გამოწვევა. დავუშვათ, რომ გსურთ გამოყოთ ძირითადი დღესასწაულები თქვენს სამუშაო ფურცელში, წლის მიუხედავად. ვთქვათ შობა-ახალი წლის დღეები. როგორ მიუდგებით ამ ამოცანას?

უბრალოდ გამოიყენეთ Excel DAY ფუნქციაამოიღეთ თვის დღე (1 - 31) და MONTH ფუნქცია, რომ მიიღოთ თვის ნომერი და შემდეგ შეამოწმეთ, DAY უდრის 25-ს ან 31-ს და თუ MONTH უდრის 12-ს:

=AND(OR(DAY($A2)=25, DAY($A2)=31), MONTH(A2)=12)

ასე მუშაობს MONTH ფუნქცია Excel-ში. როგორც ჩანს, ის ბევრად უფრო მრავალმხრივია, ვიდრე ერთი შეხედვით ჩანს, ჰა?

რამდენიმე მომდევნო პოსტში ჩვენ ვაპირებთ გამოვთვალოთ კვირები და წლები და იმედია თქვენ ისწავლით კიდევ რამდენიმე სასარგებლო ხრიკს. თუ თქვენ დაინტერესებული ხართ დროის მცირე ერთეულებით, გთხოვთ, გაეცნოთ ჩვენი Excel თარიღების სერიის წინა ნაწილებს (ქვემოთ ნახავთ ბმულებს). მადლობას გიხდით რომ კითხულობთ და იმედი მაქვს მომავალ კვირას შევხვდებით!

=MONTH(A1) - აბრუნებს თარიღის თვეს A1 უჯრედში.

=MONTH(TODAY()) - აბრუნებს მიმდინარე თვის რიცხვს.

ერთი შეხედვით, Excel MONTH ფუნქცია შეიძლება მარტივი ჩანდეს. მაგრამ გადახედეთ ქვემოთ მოცემულ მაგალითებს და გაოცდებით, თუ გაიგებთ, რამდენი სასარგებლო რამის გაკეთება შეუძლია მას რეალურად.

როგორ მივიღოთ თვის ნომერი თარიღიდან Excel-ში

არსებობს რამდენიმე გზა თვის მისაღებად თარიღიდან Excel-ში. რომელი აირჩიოს დამოკიდებულია ზუსტად იმაზე, თუ რა შედეგის მიღწევას ცდილობთ.

MONTH ფუნქცია Excel-ში - მიიღეთ თვის ნომერი თარიღიდან

ეს არის ყველაზე აშკარა და მარტივი Excel-ში თარიღის თვეში გადაყვანის გზა. მაგალითად:

• =MONTH(A2) - აბრუნებს თარიღის თვეს A2 უჯრედში.
• =MONTH(DATE(2015,4,15)) - აბრუნებს 4-ს, რომელიც შეესაბამება აპრილს.
• =MONTH("15-Apr-2015") - ცხადია, აბრუნებს ნომერს. 4 ასევე.

TEXT ფუნქცია Excel-ში - ამოიღეთ თვე ტექსტის სტრიქონად

ალტერნატიული გზა Excel-ის თარიღიდან თვის ნომრის მისაღებად არის გამოყენებით TEXT ფუნქცია:

• =TEXT(A2, "m") - აბრუნებს თვის რიცხვს წინა ნულის გარეშე, როგორც 1 - 12.
• =TEXT(A2,"mm") - აბრუნებს თვის რიცხვს წინა ნულით, როგორც 01 - 12.

გთხოვთ იყოთ ძალიან ფრთხილად TEXT ფორმულების გამოყენებისას, რადგან ისინი ყოველთვის აბრუნებენ თვის ნომრებს ტექსტის სტრიქონების სახით. ასე რომ, თუ თქვენ გეგმავთ შემდგომი გამოთვლების შესრულებას ან დაბრუნებული რიცხვების გამოყენებას სხვა ფორმულებში, უმჯობესია გამოიყენოთ Excel MONTHფუნქცია.

შემდეგი სკრინშოტი აჩვენებს ყველა ზემოთ ჩამოთვლილი ფორმულით დაბრუნებულ შედეგებს. გთხოვთ, გაითვალისწინოთ MONTH ფუნქციით დაბრუნებული რიცხვების მარჯვენა სწორება (უჯრედები C2 და C3) განსხვავებით მარცხნივ გასწორებული ტექსტის მნიშვნელობებისა, რომლებიც დაბრუნებულია TEXT ფუნქციებით (უჯრედები C4 და C5).

როგორ ამოიღოთ თვის სახელი თარიღიდან Excel-ში

თუ გსურთ მიიღოთ თვის სახელი და არა რიცხვი, კვლავ იყენებთ TEXT ფუნქციას, მაგრამ თარიღის სხვა კოდით:

• =TEXT(A2, "mmm") - აბრუნებს თვის შემოკლებულ სახელს, როგორც Jan - Dec.
• =TEXT(A2,"mmmm") - აბრუნებს თვის სრულ სახელს, როგორც იანვარი - დეკემბერი.

თუ რეალურად არ გსურთ თარიღის თვედ გადაქცევა თქვენს Excel სამუშაო ფურცელში, უბრალოდ გსურთ აჩვენოთ თვის სახელი მხოლოდ სრული თარიღის ნაცვლად, მაშინ არ გსურთ ნებისმიერი ფორმულა.

აირჩიეთ უჯრედ(ები) თარიღებით, დააჭირეთ Ctrl+1 რათა გახსნათ უჯრედების ფორმატირება დიალოგი. ნომერი ჩანართზე აირჩიეთ მორგებული და აკრიფეთ "მმმ" ან "მმმ" ველში ტიპი , რათა აჩვენოთ შემოკლებული ან სრული თვის სახელები, შესაბამისად. ამ შემთხვევაში, თქვენი ჩანაწერები დარჩება სრულად ფუნქციონალური Excel თარიღები, რომლებიც შეგიძლიათ გამოიყენოთ გამოთვლებში და სხვა ფორმულებში. თარიღის ფორმატის შეცვლის შესახებ დამატებითი ინფორმაციისთვის იხილეთ თარიღის მორგებული ფორმატის შექმნა Excel-ში.

როგორ გადაიყვანოთ თვის ნომერი თვის სახელად Excel-ში

დავუშვათ, თქვენ გაქვთ რიცხვების სია (1-დან 12-მდე)თქვენს Excel სამუშაო ფურცელში, რომლის გადაკეთება გსურთ თვეების სახელებად. ამისათვის შეგიძლიათ გამოიყენოთ რომელიმე შემდეგი ფორმულა:

თვიის შემოკლებული სახელის დასაბრუნებლად (იანვარი - დეკემბერი):

=TEXT(A2*28, "mmm")

=TEXT(DATE(2015, A2, 1), "mmm")

სრული თვის სახელის დასაბრუნებლად (იანვარი - დეკემბერი):

=TEXT(A2*28, "mmmm")

=TEXT(DATE(2015, A2, 1), "mmmm")

ყველა ზემოთ ჩამოთვლილ ფორმულაში A2 არის უჯრედი თვის ნომრით. და ერთადერთი რეალური განსხვავება ფორმულებს შორის არის თვის კოდები:

• „მმმ“ - თვის 3-ასოიანი აბრევიატურა, როგორიცაა იანვარი - დეკ
• „მმმმ“ - თვე. სრულად გაწერილია
• „მმმმმ“ - თვის პირველი ასო სახელი

როგორ მუშაობს ეს ფორმულები

გამოყენებისას თვის ფორმატის კოდებთან ერთად, როგორიცაა "მმმ" და "მმმ", Excel მიიჩნევს 1 რიცხვს, როგორც 1900 წლის იანვრის დღე 1. 1, 2, 3 და ა.შ. გამრავლებით 28-ზე, თქვენ მიიღებთ დღეებს 28, 56, 84 და ა.შ. 1900 წლის იანვარში, თებერვალში, მარტში და ა.შ. ფორმატის კოდი "მმმ" ან "მმმმ" აჩვენებს მხოლოდ თვის სახელს.

როგორ გადავიტანოთ თვის სახელი რიცხვად Excel-ში

არსებობს Excel-ის ორი ფუნქცია, რომელიც დაგეხმარებათ თვეების სახელების რიცხვებად გადაქცევაში - DATEVALUE და MONTH. Excel-ის DATEVALUE ფუნქცია გარდაქმნის ტექსტად შენახულ თარიღს სერიულ ნომერად, რომელსაც Microsoft Excel აღიარებს თარიღად. და შემდეგ, MONTH ფუნქცია ამოიღებს თვის რიცხვს ამ თარიღიდან.

სრული ფორმულა ასეთია:

=MONTH(DATEVALUE(A2 & "1"))

აქ არის A2 უჯრედში, რომელიც შეიცავს თვის სახელს.გსურთ გადააქციოთ რიცხვად (&"1" დამატებულია DATEVALUE ფუნქციისთვის, რათა გაიგოთ, რომ ეს არის თარიღი).

როგორ მივიღოთ თვის ბოლო დღე Excel (EOMONTH ფუნქცია)

EOMONTH ფუნქცია Excel-ში გამოიყენება თვის ბოლო დღის დასაბრუნებლად მითითებული დაწყების თარიღზე დაყრდნობით. მას აქვს შემდეგი არგუმენტები, რომელთაგან ორივე აუცილებელია:

• დაწყების_თარიღი - დაწყების თარიღი ან მითითება უჯრედზე დაწყების თარიღით.
• თვეები - დაწყების თარიღამდე ან მის შემდეგ თვეების რაოდენობა. გამოიყენეთ დადებითი მნიშვნელობა მომავალი თარიღებისთვის და უარყოფითი მნიშვნელობა წარსული თარიღებისთვის.

აქ არის რამდენიმე EOMONTH ფორმულის მაგალითი:

=EOMONTH(A2, 1) - აბრუნებს თვის ბოლო დღეს, ერთი თვის შემდეგ თარიღი A2 უჯრედში.

=EOMONTH(A2, -1) - აბრუნებს თვის ბოლო დღეს, A2 უჯრედის თარიღამდე ერთი თვით ადრე.

უჯრედის მითითების ნაცვლად, შეგიძლიათ თარიღის მყარი კოდირება თქვენს EOMONTH ფორმულა. მაგალითად, ქვემოთ მოცემული ორივე ფორმულა აბრუნებს აპრილის ბოლო დღეს.

=EOMONTH("15-Apr-2015", 0)

=EOMONTH(DATE(2015,4,15), 0)

დაბრუნება მიმდინარე თვის ბოლო დღეს , იყენებთ TODAY() ფუნქციას თქვენი EOMONTH ფორმულის პირველ არგუმენტში ისე, რომ დღევანდელი თარიღი მიიღება დაწყების თარიღად. months -ის არგუმენტში თქვენ ჩადეთ 0, რადგან არ გსურთ თვის შეცვლა.

=EOMONTH(TODAY(), 0)

შენიშვნა. ვინაიდან Excel EOMONTH ფუნქცია აბრუნებს თარიღის გამოსახულ სერიულ ნომერს, თქვენ გაქვთრომ გამოიყენოთ თარიღის ფორმატი უჯრედ(ებ)ზე თქვენი ფორმულებით. დეტალური ნაბიჯებისთვის იხილეთ როგორ შევცვალოთ თარიღის ფორმატი Excel-ში.

და აი, ზემოთ განხილული Excel EOMONTH ფორმულებით დაბრუნებული შედეგები:

თუ გსურთ გამოთვალოთ რამდენი დღე დარჩა მიმდინარე თვის ბოლომდე, თქვენ უბრალოდ გამოაკლებთ TODAY()-ით დაბრუნებულ თარიღს EOMONTH-ის მიერ დაბრუნებულ თარიღს და გამოიყენეთ ზოგადი ფორმატი უჯრედზე:

=EOMONTH(TODAY(), 0)-TODAY()

როგორ ვიპოვოთ თვის პირველი დღე Excel-ში

როგორც უკვე იცით, Microsoft Excel უზრუნველყოფს მხოლოდ ერთ ფუნქციას თვის ბოლო დღის დასაბრუნებლად (EOMONTH). როდესაც საქმე ეხება თვის პირველ დღეს, მისი მიღების ერთზე მეტი გზა არსებობს.

მაგალითი 1. მიიღეთ თვის 1 დღე თვის ნომრის მიხედვით

თუ გაქვთ თვის ნომერი, შემდეგ გამოიყენეთ მარტივი DATE ფორმულა, როგორიცაა:

მაგალითად, =DATE(2015, 4, 1) დაბრუნდება 1-აპრ-15.

თუ თქვენი ნომრები მდებარეობს გარკვეულ სვეტში, ვთქვათ A სვეტში, შეგიძლიათ დაამატოთ უჯრედის მითითება პირდაპირ ფორმულაში:

=DATE(2015, B2, 1)

მაგალითი 2. მიიღეთ თვის პირველი დღე თარიღიდან

თუ გსურთ გამოთვალოთ თვის პირველი დღე თარიღზე დაყრდნობით, შეგიძლიათ კვლავ გამოიყენეთ Excel DATE ფუნქცია, მაგრამ ამჯერად ასევე დაგჭირდებათ MONTH ფუნქცია თვის ნომრის ამოსაღებად:

ამისთვისმაგალითად, შემდეგი ფორმულა დააბრუნებს თვის პირველ დღეს A2 უჯრედის თარიღზე დაყრდნობით:

=DATE(2015,MONTH(A2),1)

მაგალითი 3. იპოვეთ პირველი დღე თვის მიმდინარე თარიღზე დაყრდნობით

როდესაც თქვენი გამოთვლები ეფუძნება დღევანდელ თარიღს, გამოიყენეთ Excel EOMONTH და TODAY ფუნქციების კავშირი:

=EOMONTH(TODAY(),0) +1 - აბრუნებს 1-ს მომდევნო თვის დღე.

როგორც გახსოვთ, ჩვენ უკვე გამოვიყენეთ მსგავსი EOMONTH ფორმულა მიმდინარე თვის ბოლო დღის მისაღებად. ახლა კი ამ ფორმულას უბრალოდ დაამატეთ 1, რომ მიიღოთ შემდეგი თვის პირველი დღე.

მსგავსი წესით, შეგიძლიათ მიიღოთ წინა და მიმდინარე თვის პირველი დღე:

=EOMONTH(TODAY(),-2) +1 - აბრუნებს წინა თვის პირველ დღეს.

=EOMONTH(TODAY(),-1) +1 - აბრუნებს მიმდინარე თვის პირველ დღეს.

ასევე შეგიძლიათ გამოიყენოთ Excel DATE ფუნქცია დასამუშავებლად ეს ამოცანა, თუმცა ფორმულები ცოტა გრძელი იქნება. მაგალითად, გამოიცანით რას აკეთებს შემდეგი ფორმულა?

=DATE(YEAR(TODAY()), MONTH(TODAY()), 1)

დიახ, ის აბრუნებს მიმდინარე თვის პირველ დღეს.

და როგორ აიძულებთ მას დააბრუნოს მომდევნო თვის პირველი დღე თუ წინა თვე? ქვემოთ :) უბრალოდ დაამატეთ ან გამოაკლეთ 1 მიმდინარე თვეს:

შემდეგი თვის პირველი დღის დასაბრუნებლად:

=DATE(YEAR(TODAY()), MONTH(TODAY())+1, 1)

პირველი დღის დასაბრუნებლად წინა თვის:

=DATE(YEAR(TODAY()), MONTH(TODAY())-1, 1)

როგორ გამოვთვალოთ დღეების რაოდენობა თვეში

Microsoft Excel-ში არსებობს თარიღებთან მუშაობის სხვადასხვა ფუნქცია დაჯერ. თუმცა, მას არ აქვს ფუნქცია მოცემულ თვეში დღეების რაოდენობის გამოსათვლელად. ასე რომ, ჩვენ დაგვჭირდება ამ გამოტოვების შევსება ჩვენივე ფორმულებით.

მაგალითი 1. რომ მიიღოთ დღეების რაოდენობა თვის რიცხვზე დაყრდნობით

თუ იცით თვის ნომერი, შემდეგი DAY / DATE ფორმულა დააბრუნებს დღეების რაოდენობას ამ თვეში:

ზემოთ ფორმულაში DATE ფუნქცია აბრუნებს მომდევნო თვის პირველ დღეს, რომელსაც აკლებთ 1-ს, რათა მიიღოთ თქვენთვის სასურველი თვის ბოლო დღე. და შემდეგ, DAY ფუნქცია გარდაქმნის თარიღს დღის რიცხვად.

მაგალითად, შემდეგი ფორმულა აბრუნებს დღეების რაოდენობას აპრილში (წლის მე-4 თვე).

=DAY(DATE(2015, 4 +1, 1) -1)

მაგალითი 2. თვეში დღეების რაოდენობის მისაღებად თარიღზე დაყრდნობით

თუ არ იცით თვის ნომერი, მაგრამ გაქვთ რაიმე თარიღი ამ თვეში, შეგიძლიათ გამოიყენოთ YEAR და MONTH ფუნქციები თარიღიდან წლისა და თვის ნომრის ამოსაღებად. უბრალოდ ჩადეთ ისინი ზემოთ მოცემულ მაგალითში განხილული DAY/DATE ფორმულაში და ის გეტყვით რამდენ დღეს შეიცავს მოცემული თვე:

=DAY(DATE(YEAR(A2), MONTH(A2) +1, 1) -1)

სადაც A2 არის უჯრედი თარიღით.

ალტერნატიულად, შეგიძლიათ გამოიყენოთ ბევრად უფრო მარტივი DAY / EOMONTH ფორმულა. როგორც გახსოვთ, Excel EOMONTH ფუნქცია აბრუნებს თვის ბოლო დღეს, ამიტომ დამატებითი გამოთვლები არ დაგჭირდებათ:

=DAY(EOMONTH(A1, 0))

შემდეგი სკრინშოტი აჩვენებსშედეგები დაბრუნდა ყველა ფორმულით და როგორც ხედავთ ისინი იდენტურია:

როგორ შევაჯამოთ მონაცემები თვეების მიხედვით Excel-ში

დიდ ცხრილში ბევრი მონაცემი, ხშირად შეიძლება დაგჭირდეთ მოცემული თვის მნიშვნელობების ჯამის მიღება. და ეს შეიძლება იყოს პრობლემა, თუ მონაცემები არ იყო შეყვანილი ქრონოლოგიური თანმიმდევრობით.

უმარტივესი გამოსავალი არის დამხმარე სვეტის დამატება მარტივი Excel MONTH ფორმულით, რომელიც გადააქცევს თარიღებს თვის რიცხვებად. თქვით, თუ თქვენი თარიღები არის A სვეტში, თქვენ იყენებთ =MONTH(A2).

ახლა კი, ჩაწერეთ რიცხვების სია (1-დან 12-მდე, ან მხოლოდ იმ თვეების რიცხვები, რომლებიც თქვენთვის საინტერესოა. ) ცარიელ სვეტში და ჯამის მნიშვნელობები ყოველი თვისთვის SUMIF ფორმულის მსგავსი:

=SUMIF(C2:C15, E2, B2:B15)

სადაც E2 არის თვის ნომერი.

შემდეგი ეკრანის სურათი გვიჩვენებს გამოთვლების შედეგი:

თუ არ გირჩევნიათ დამხმარე სვეტის დამატება Excel-ის ფურცელზე, პრობლემა არ არის, ამის გარეშეც შეგიძლიათ. ცოტა უფრო რთული SUMPRODUCT ფუნქცია იმუშავებს:

=SUMPRODUCT((MONTH($A$2:$A$15)=$E2) * ($B$2:$B$15))

სადაც A სვეტი შეიცავს თარიღებს, სვეტი B შეიცავს ჯამის მნიშვნელობებს და E2 არის თვის ნომერი.

Შენიშვნა. გთხოვთ გაითვალისწინოთ, რომ ორივე ზემოაღნიშნული გამოსავალი აერთიანებს ყველა მნიშვნელობას მოცემული თვისთვის, წლის მიუხედავად. ასე რომ, თუ თქვენი Excel სამუშაო ფურცელი შეიცავს რამდენიმე წლის მონაცემებს, ეს ყველაფერი შეჯამდება.

როგორ მოვახდინოთ თარიღების პირობითი ფორმატირება თვის მიხედვით

ახლა თქვენ იცით, როგორ გამოიყენოთ Excel