Þegar þú vinnur að skýrslu, fjárfestingaráætlun eða einhverju öðru gagnasafni með dagsetningum gætirðu oft þurft að leggja saman tölur innan ákveðins tímabils. Þessi kennsla mun kenna þér fljótlega og auðvelda lausn - SUMIFS formúla með tímabil sem viðmið.

Á blogginu okkar og öðrum Excel spjallborðum spyr fólk oft hvernig eigi að nota SUMIF fyrir tímabil. Málið er að til að leggja saman á milli tveggja dagsetninga þarftu að skilgreina báðar dagsetningar á meðan Excel SUMIF aðgerðin leyfir aðeins eitt skilyrði. Sem betur fer höfum við líka SUMIFS aðgerðina sem styður mörg viðmið.

Hvernig á að leggja saman ef á milli tveggja dagsetninga í Excel

Til að leggja saman gildi innan ákveðins tímabils, notaðu SUMIFS formúla með upphafs- og lokadagsetningu sem viðmið. Setningafræði SUMIFS fallsins krefst þess að þú tilgreinir fyrst gildin sem á að leggja saman (summa_svið) og gefur síðan upp svið/viðmiðapör. Í okkar tilviki mun bilið (listi yfir dagsetningar) vera það sama fyrir bæði skilyrðin.

Miðað við ofangreint eru almennu formúlurnar til að leggja saman gildi á milli tveggja dagsetninga á þessu formi:

Þar með talið þröskuldsdagsetningar:

Að undanskildum þröskuldsdagsetningum:

Eins og þú sérð er munurinn aðeins í rökrænum rekstraraðilum. Í fyrstu formúlunni notum við stærraen eða jafnt og (>=) og minna en eða jafnt og (<=) til að innihalda þröskuldsdagsetningar í niðurstöðunni. Önnur formúlan athugar hvort dagsetning er stærri en (>) eða lægri en (<), og sleppir upphafs- og lokadagsetningum.

Í töflunni hér að neðan, segjum að þú viljir leggja saman verkefni sem eru á gjalddaga á tilteknu tímabili, að meðtöldum. Til að gera það, notaðu þessa formúlu:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Ef þú vilt ekki harðkóða dagsetningarbil í formúlunni, þá geturðu slegið inn upphafsdagsetningu í F1, lokadagsetningu í G1, tengdu saman rökrænu rekstraraðila og frumutilvísanir og settu öll viðmiðin innan gæsalappa eins og þetta:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Til að forðast hugsanleg mistök geturðu gefið dagsetningar með hjálp DATE fallsins:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&DATE(2020,9,20))

Summa innan kviks bils miðað við dagsetningu dagsins í dag

Í aðstæðum þegar þú þarft að leggja saman gögn innan kviks dagsetningarbils (X dagar aftur í tímann frá í dag eða Y dagar áfram), smíðaðu viðmiðin með því að nota TODAY aðgerðina, sem fær núverandi dagsetningu og uppfærir hana sjálfkrafa.

Til dæmis til að leggja saman fjárhagsáætlanir sem eru á gjalddaga á síðasta ári. 7 dagar að meðtöldum dagsetningu í dag , formúlan er:

=SUMIFS(B2:B10, C2:C10, ""&TODAY()-7)

Ef þú vilt ekki hafa núverandi dagsetningu með í lokaniðurstöðunni skaltu nota minni en rekstraraðili (<) fyrir fyrstu viðmiðin til að útiloka dagsetningu dagsins og stærri en eða jöfn og (>=) fyrir seinni viðmiðunina tilinnihalda dagsetninguna sem er 7 dögum fyrir daginn í dag:

=SUMIFS(B2:B10, C2:C10, "="&TODAY()-7)

Á svipaðan hátt er hægt að leggja saman gildi ef dagsetning er ákveðinn fjöldi daga áfram.

Til dæmis, til að fá heildarfjárveitingar sem eru á gjalddaga á næstu 3 dögum, notaðu eina af eftirfarandi formúlum:

Dagsetningin í dag er innifalin í niðurstöðunni:

=SUMIFS(B2:B10, C2:C10, ">="&TODAY(), C2:C10, "<"&TODAY()+3)

Dagsetningin í dag er ekki innifalin í niðurstöðunni:

=SUMIFS(B2:B10, C2:C10, ">"&TODAY(), C2:C10, "<="&TODAY()+3)

Summa ef á milli tveggja dagsetninga og annarra viðmiða

Til að leggja saman gildi innan tímabils sem uppfylla önnur skilyrði í öðrum dálki skaltu einfaldlega bæta einu svið/viðmiðapöri við SUMIFS formúluna þína.

Til dæmis til að leggja saman fjárhagsáætlanir innan ákveðins tímabil fyrir öll verkefnin sem innihalda "ábending" í nöfnum þeirra, framlengdu formúluna með algildisviðmiðum:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1, A2:A10, "tip*")

Þar sem A2:A10 eru verknöfnin, B2:B10 eru tölur til að summa, C2:C10 eru dagsetningarnar sem á að athuga, F1 er upphafsdagsetning og G1 er lokadagsetning.

Auðvitað kemur ekkert í veg fyrir að þú slærð inn þriðja viðmiðið í sepa hlutfallsreit líka, og vísar til þess reits eins og sýnt er á skjámyndinni:

SUMIFS setningafræði dagsetningarviðmiða

Þegar kemur að því að nota dagsetningar sem viðmið fyrir Excel SUMIF og SUMIFS aðgerðir, þá værir þú ekki fyrsti manneskjan til að ruglast :)

Þegar þú skoðar það betur, þá snýst öll margvísleg notkunartilvik um nokkrar einfaldar reglur:

Ef þú setur dagsetningar beint í viðmiðinrök , sláðu síðan inn rökrænan rekstraraðila (>, <, =, ) rétt fyrir dagsetninguna og settu öll skilyrðin innan gæsalappa. Til dæmis:

=SUMIFS(B2:B10, C2:C10, ">=9/10/2020", C2:C10, "<=9/20/2020")

Þegar dagsetning er sett inn í fyrirfram skilgreindan hólf , gefðu upp viðmið í formi textastrengs: settu rökrænan rekstraraðila innan gæsalappa við byrjaðu streng og notaðu ampermerki (&) til að sameina og klára strenginn. Til dæmis:

=SUMIFS(B2:B10, C2:C10, ">="&F1, C2:C10, "<="&G1)

Þegar dagsetning er knúin áfram af annarri aðgerð eins og DATE eða TODAY() skaltu tengja saman samanburðaraðgerð og fall. Til dæmis:

=SUMIFS(B2:B10, C2:C10, ">="&DATE(2020,9,10), C2:C10, "<="&TODAY())

Excel SUMIFS á milli dagsetninga virkar ekki

Ef formúlan þín virkar ekki eða gefur rangar niðurstöður gætu eftirfarandi ráðleggingar um bilanaleit varpað ljósi á hvers vegna það mistakast og hjálpa þér að laga vandamálið.

Athugaðu snið dagsetninga og talna

Ef að því er virðist rétt SUMIFS formúla skilar engu nema núlli, þá er það fyrsta sem þarf að athuga hvort dagsetningar þínar séu í raun dagsetningar , og ekki textastrengir sem líta aðeins út eins og dagsetningar. Næst skaltu ganga úr skugga um að þú sért að leggja saman tölur, en ekki tölur sem eru geymdar sem texti. Eftirfarandi kennsluefni munu hjálpa þér að koma auga á og laga þessi vandamál.

• Hvernig á að breyta "textadagsetningum" í raunverulegar dagsetningar
• Hvernig á að breyta texta í númer

Notaðu rétta setningafræði fyrir viðmið

Þegar dagsetningar eru skoðaðar með SUMIFS ætti að setja dagsetningu innan gæsalappanna eins og ">=9/10/2020"; frumuvísanir ogföll ættu að vera fyrir utan gæsalappirnar eins og "<="&G1 eða "<="&TODAY(). Fyrir allar upplýsingar, vinsamlegast sjá setningafræði dagsetningarskilyrða.

Staðfestu rökfræði formúlunnar

Lítil innsláttarvilla í fjárhagsáætlun gæti kostað milljónir. Smá mistök í formúlu gætu kostað klukkutíma af villuleitartíma. Svo, þegar lagt er saman á milli 2 dagsetninga, athugaðu hvort upphafsdagsetningin sé á undan stærri en (>) eða stærri en eða jöfn (>=) og endinn dagsetning er forskeyti minna en (<) eða minna en eða jafnt og (<=).

Gakktu úr skugga um að öll svið séu jafnstór

Til að SUMIFS aðgerðin virki rétt, ættu summusvið og viðmiðunarsvið að vera jafnstór, annars er #VALUE! villa kemur upp. Til að laga það skaltu ganga úr skugga um að allar viðmiðunarsvið frumbreytur hafi sama fjölda lína og dálka og summasvið .

Svona á að nota Excel SUMIFS fallið til að leggja saman gögn í dagsetningarbil. Ef þú hefur einhverjar aðrar áhugaverðar lausnir í huga, þá mun ég vera mjög þakklátur ef þú deilir í athugasemdum. Þakka þér fyrir að lesa og vonumst til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til niðurhals

SUMIFS tímabilsdæmi (.xlsx skrá)