Daftar Isi
Tutorial ini menunjukkan cara membuat rumus Excel untuk persen kenaikan atau penurunan dan menggunakannya dengan angka positif dan negatif.
Di Microsoft Excel, ada 6 fungsi berbeda untuk menghitung varians. Namun, tidak ada satupun dari mereka yang cocok untuk menghitung perbedaan persen antara dua sel. Fungsi bawaan dirancang untuk menemukan varians dalam pengertian klasik, yaitu seberapa jauh serangkaian nilai tersebar dari rata-rata mereka. Varians persen adalah sesuatu yang berbeda. Dalam artikel ini, Anda akan menemukan yang tepatrumus untuk menghitung perubahan persen di Excel.
Apa yang dimaksud dengan persentase perubahan?
Persen perubahan, alias persentase varians atau perbedaan adalah perubahan proporsional antara dua nilai, nilai asli dan nilai baru.
Rumus perubahan persen menghitung berapa banyak sesuatu yang berubah antara dua periode secara persentase. Misalnya, Anda dapat menghitung varians antara penjualan tahun ini dan tahun lalu, antara perkiraan dan suhu yang diamati, antara biaya yang dianggarkan dan biaya riil.
Misalnya, pada bulan Januari Anda memperoleh $1.000 dan pada bulan Februari $1.200, jadi perbedaannya adalah peningkatan penghasilan sebesar $200. Tetapi berapa banyak itu dalam hal persentase? Untuk mengetahuinya, Anda menggunakan rumus perubahan persen. 
Rumus perubahan persen Excel
Ada dua rumus dasar untuk menemukan persentase perbedaan antara dua angka.
Rumus persentase varians klasik
Berikut ini adalah rumus yang umumnya digunakan untuk menghitung persen perubahan:
( new_value - old_value ) / old_valueDalam matematika, Anda biasanya melakukan 3 langkah untuk menghitung persentase varians antara dua nilai numerik:
- Kurangi nilai baru dari nilai lama.
- Bagilah selisihnya dengan angka lama.
- Kalikan hasilnya dengan 100.
Di Excel, Anda melompati langkah terakhir dengan menerapkan Persentase format.
Rumus perubahan persen Excel
Dan berikut adalah rumus yang lebih sederhana untuk perubahan persentase di Excel yang mengembalikan hasil yang sama.
new_value / old_value - 1Bagaimana cara menghitung perubahan persen di Excel
Untuk menemukan perbedaan persentase antara dua angka di Excel, Anda dapat menggunakan salah satu rumus di atas. Katakanlah Anda memiliki perkiraan penjualan di kolom B dan penjualan aktual di kolom C. Dengan asumsi angka perkiraan adalah nilai "dasar" dan aktual adalah nilai "baru", rumusnya berbentuk seperti ini:
=(C3-B3)/B3
atau
=C3/B3-1
Rumus di atas membandingkan angka-angka di baris 3. Untuk menghitung persen perubahan di seluruh kolom, inilah yang perlu Anda lakukan:
- Masukkan rumus selisih persen di sel kosong mana pun di baris 3, katakanlah di D3 atau E3.
- Dengan sel formula yang dipilih, klik tombol Persen Gaya pada pita atau tekan pintasan Ctrl + Shift + %. Ini akan mengubah angka desimal yang dikembalikan ke persentase.
- Seret rumus ke bawah di seluruh baris sebanyak yang diperlukan.
Setelah menyalin rumus tersebut, Anda akan mendapatkan kolom perubahan persen dari data Anda. 
Bagaimana rumus perubahan persen Excel bekerja
Ketika melakukan penghitungan secara manual, Anda akan mengambil nilai lama (asli) dan nilai baru, mencari selisih di antara keduanya, lalu membaginya dengan nilai asli. Untuk mendapatkan hasilnya dalam bentuk persentase, Anda akan mengalikannya dengan 100.
Contohnya, jika nilai awal adalah 120 dan nilai baru adalah 150, perbedaan persen dapat dihitung dengan cara ini:
=(150-120)/120
=30/120
=0.25
0.25*100 = 25%
Menerapkan Persentase format angka di Excel menampilkan angka desimal sebagai persentase secara otomatis, oleh karena itu bagian *100 dihilangkan.
Rumus Excel untuk persen kenaikan / penurunan
Karena persen kenaikan atau penurunan hanyalah kasus tertentu dari persentase varians, maka dihitung dengan rumus yang sama:
( new_value - initial_value ) / initial_valueAtau
new_value / initial_value - 1Contohnya, untuk menghitung persen peningkatan antara dua nilai (B2 dan C2), rumusnya adalah:
= (C2-B2) / B2
Atau
=C2/B2-1 
Formula untuk menghitung persen penurunan persis sama. 
Excel persen perubahan nilai absolut
Secara default, rumus persentase varians di Excel mengembalikan nilai positif untuk persen kenaikan dan nilai negatif untuk persen penurunan. Untuk mendapatkan persentase perubahan sebagai nilai absolut tanpa memperhatikan tandanya, bungkus rumus dalam fungsi ABS seperti ini:
ABS(( new_value - old_value ) / nilai_lama)Dalam kasus kita, rumusnya mengambil bentuk ini:
=ABS((C3-B3)/B3)
Yang ini juga akan berfungsi dengan baik:
=ABS (C3/B3-1) 
Hitung persentase diskon
Contoh ini menunjukkan satu lagi penggunaan praktis rumus perubahan persen Excel - menghitung persentase diskon. Jadi, ladies, ketika Anda pergi berbelanja, ingatlah ini:
diskon % = (harga diskon - harga reguler) / harga reguler
diskon % = harga diskon / harga reguler - 1
Persen diskon ditampilkan sebagai nilai negatif karena harga diskon baru lebih kecil dari harga awal. Untuk menampilkan hasilnya sebagai angka positif , sarangkan rumus di dalam fungsi ABS seperti yang kita lakukan pada contoh sebelumnya:
=ABS((C2-B2)/B2) 
Hitung nilai setelah perubahan persen
Untuk mendapatkan nilai setelah persentase kenaikan atau penurunan, rumus umumnya adalah:
initial_value *(1+ percent_change )Misalkan Anda memiliki nilai asli di kolom B dan perbedaan persentase di kolom C. Untuk menghitung nilai baru setelah perubahan persentase, rumus di D2 yang disalin ke bawah adalah:
=B2*(1+C2)
Pertama, Anda menemukan persentase keseluruhan yang perlu dikalikan dengan nilai aslinya. Untuk ini, cukup tambahkan persen ke 1 (1+C2). Dan kemudian, Anda mengalikan persentase keseluruhan dengan angka asli untuk mendapatkan hasil yang diinginkan.
Seperti yang bisa Anda lihat, solusi ini bekerja dengan baik untuk persentase kenaikan dan penurunan: 
Untuk menambah atau mengurangi seluruh kolom dengan persen tertentu Katakanlah, untuk menambah semua nilai di kolom B sebesar 5%, masukkan rumus di bawah ini di C2, lalu seret ke bawah ke seluruh baris yang tersisa:
=B2*(1+5%)
Di sini, Anda cukup mengalikan nilai asli dengan 105%, yang menghasilkan nilai yang 5% lebih tinggi.
Untuk memudahkan, kamu bisa memasukkan nilai persentasenya ke dalam cell yang sudah ditentukan sebelumnya (F2) dan mereferensikannya ke cell tersebut. Caranya adalah dengan mengunci referensi cellnya dengan tanda $, agar rumusnya tersalin dengan benar:
=B2*(1+$F$2)
Keuntungan dari pendekatan ini adalah bahwa untuk meningkatkan kolom dengan persentase lain, Anda hanya perlu mengubah nilai dalam satu sel. Karena semua rumus ditautkan ke sel itu, mereka akan menghitung ulang secara otomatis. 
Menghitung persen varians dengan nilai negatif
Jika beberapa nilai Anda diwakili oleh angka negatif, rumus selisih persen tradisional akan bekerja dengan tidak benar. Solusi yang umum diterima adalah membuat penyebutnya menjadi angka positif dengan bantuan fungsi ABS.
Berikut rumus Excel generik untuk perubahan persen dengan angka negatif:
( new_value - old_value ) / ABS( old_value )Dengan nilai lama di B2 dan nilai baru di C2, rumus sebenarnya adalah sebagai berikut:
=(C2-B2)/ABS(B2) 
Catatan. Meskipun penyesuaian ABS ini secara teknis benar, namun rumus ini bisa menghasilkan hasil yang menyesatkan jika nilai aslinya negatif dan nilai baru positif, dan sebaliknya.
Perubahan persen Excel dibagi dengan kesalahan nol (#DIV/0)
Jika kumpulan data Anda berisi nilai nol, Anda kemungkinan besar akan mengalami kesalahan bagi dengan nol (#DIV/0!) Saat menghitung persentase perubahan di Excel karena Anda tidak dapat membagi angka dengan nol dalam matematika. Fungsi IFERROR dapat membantu mengatasi masalah ini. Bergantung pada ekspektasi Anda untuk hasil akhir, gunakan salah satu solusi berikut.
Solusi 1: jika nilai lama adalah nol, kembalikan 0
Jika nilai lama adalah nol, persentase perubahan akan menjadi 0% terlepas dari apakah nilai baru adalah nol atau tidak.
=IFERROR((C2-B2)/B2, 0)
atau
=IFERROR(C2/B2-1, 0)
Solusi 2: jika nilai lama adalah nol, kembalikan 100%
Solusi ini mengimplementasikan pendekatan lain dengan mengasumsikan bahwa nilai baru telah tumbuh sebesar 100% mulai dari nol:
=IFERROR((C2-B2)/B2, 1)
=IFERROR(C2/B2-1, 1)
Dalam kasus ini, persen perbedaan akan menjadi 100% jika nilai lama adalah nol (baris 5) atau kedua nilai adalah nol (baris 9).
Dengan melihat catatan yang disorot di bawah ini, jelaslah bahwa tidak ada satu pun formula yang sempurna: 
Untuk mendapatkan hasil yang lebih baik, Anda bisa menggabungkan kedua rumus tersebut menjadi satu menggunakan pernyataan IF bersarang:
=IF(C20, IFERROR((C2-B2)/B2, 1), IFERROR((C2-B2)/B2, 0))
Formula yang lebih baik ini akan kembali:
- Persen perubahan sebagai 0% jika nilai lama dan baru adalah nol.
- Perubahan persen sebagai 100% jika nilai lama adalah nol dan nilai baru bukan nol.
Itulah cara menghitung persen kenaikan atau penurunan di Excel. Untuk pengalaman langsung, Anda dipersilakan untuk mengunduh buku kerja sampel kami di bawah ini. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!
Buku kerja latihan untuk diunduh
Rumus Excel untuk persen kenaikan / penurunan - contoh (.xlsx file)
