O titorial mostra como usar a fórmula BUSCAR V en Excel para comparar dúas columnas para devolver valores comúns (coincidencias) ou atopar datos que faltan (diferenzas).

Cando tes datos en dous listas diferentes, moitas veces pode ter que comparalas para ver que información falta nunha das listas ou que datos hai en ambas. A comparación pódese facer de moitas formas diferentes: o método a usar depende exactamente do que queiras del.

Como comparar dúas columnas en Excel usando BUSCAR V

Cando tes dúas columnas de datos e queres saber que puntos de datos dunha lista existen na outra lista, podes usar a función BUSCAR V para comparar as listas de valores comúns.

Para construír unha fórmula de BUSCAR V forma básica, isto é o que cómpre facer:

• Para valor_busca (1º argumento), use a cela máis alta da Lista 1.
• Para table_array (2º argumento), proporcione a Lista 2 completa.
• Para col_index_num (3º argumento), use 1 xa que só hai unha columna na matriz.
• Para range_lookup (4o argumento), establece FALSE - coincidencia exacta.

Supoña que tes os nomes dos participantes na columna A (Lista 1) e os nomes daqueles que superaron as quendas de clasificación da columna B (Lista 2). Quere comparar estas 2 listas para determinar que participantes do Grupo A chegaron ao evento principal. Para iso, use o seguintefórmula.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

A fórmula vai á cela E2 e, a continuación, arrástrala cara abaixo por tantas celas como elementos hai na Lista 1.

Ten en conta que table_array está bloqueado con referencias absolutas ($C$2:$C$9) para que permaneza constante cando copies a fórmula nas celas de abaixo.

Como podes ver, os nomes dos os atletas cualificados aparecen na columna E. Para os participantes restantes, aparece un erro #N/A que indica que os seus nomes non están dispoñibles na Lista 2.

Disfraz #N/ Erros

A fórmula BUSCAR V que se comenta anteriormente cumpre perfectamente o seu obxectivo principal: devolve valores comúns e identifica puntos de datos que faltan. Non obstante, ofrece unha morea de erros #N/A, que poden confundir aos usuarios inexpertos facéndolles pensar que algo está mal coa fórmula.

Para substituír os erros por celas en branco , use BUSCAR V. en combinación coa función IFNA ou IFERROR deste xeito:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

A nosa fórmula mellorada devolve unha cadea baleira ("") en lugar de #N/ A. Tamén podes devolver o teu texto personalizado como "Non está na lista 2", "Non presente" ou "Non dispoñible". Por exemplo:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Esa é a fórmula básica de BUSCAR V para comparar dúas columnas en Excel. Dependendo da súa tarefa particular, pódese modificar como se mostra en outros exemplos.

Compare dúas columnas en diferentes follas de Excel usando BUSCARV

Na vida real, as columnas quenecesidade de comparar non sempre están na mesma folla. Nun conxunto de datos pequeno, podes tentar detectar as diferenzas manualmente vendo dúas follas unha ao lado da outra.

Para buscar noutra folla de traballo ou libro de traballo con fórmulas, tes que usar referencia externa. A mellor práctica é comezar a escribir a fórmula na súa folla principal, despois cambiar á outra folla de traballo e seleccionar a lista co rato: engadirase á fórmula automaticamente unha referencia de intervalo apropiada.

Asumindo que a Lista 1 é na columna A da Folla1 e a lista 2 está na columna A da Folla2 , podes comparar dúas columnas e atopar coincidencias usando esta fórmula:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Para obter máis información, consulte:

• BUSCAR V desde outra folla
• BUSCAR V desde un libro de traballo diferente

Compara dúas columnas e devolve os valores comúns (coincidimentos)

Nos exemplos anteriores, comentamos unha fórmula BUSCAR V na súa forma máis sinxela:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

O resultado desa fórmula é unha lista de valores que existen en ambas columnas e celas en branco en lugar dos valores que non están dispoñibles na segunda columna.

Para obter unha lista de valores comúns sen lagoas, só tes que engadir un filtro automático á columna resultante e filtra os espazos en branco.

En Excel para Microsoft 365 e Excel 2021 que é admite matrices dinámicas, podes facer uso da función FILTER para filtrar os espazos en branco de forma dinámica. Para iso, use a fórmula IFNA VLOOKUP comocriterios para FILTRO:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Por favor, preste atención a que neste caso fornecemos toda a Lista 1 (A2:A14) ao argumento lookup_value de BUSCARV. A función compara cada un dos valores de busca coa Lista 2 (C2:C9) e devolve unha matriz de coincidencias e erros #N/A que representan os valores que faltan. A función IFNA substitúe os erros por cadeas baleiras e envía os resultados á función FILTRO, que filtra os espazos en branco ("") e mostra unha matriz de coincidencias como resultado final.

Alternativamente, pode usar a función ISNA para comprobar o resultado de BUSCAR V e filtrar os elementos avaliados como FALSO, é dicir, valores distintos dos erros #N/D:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

O mesmo resultado pode conseguirse coa función XLOOKUP, que fai que a fórmula sexa aínda máis sinxela. Debido á capacidade de XLOOKUP para xestionar internamente os erros #N/A (argumento opcional if_not_found ), podemos prescindir do envoltorio IFNA ou ISNA:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Comparar dúas columnas e atopar os valores que faltan (diferenzas)

Para comparar 2 columnas en Excel para atopar diferenzas, pode proceder deste xeito:

1. Escriba a fórmula básica para buscar a primeira valor da Lista 1 (A2) na Lista 2 ($C$2:$C$9):

   BUSCAR V(A2, $C$2:$C$9, 1, FALSO)

2. Aniña o fórmula anterior na función ISNA para comprobar a saída da BUSCAR V para detectar erros #N/A. En caso de erro, ISNA dá VERDADEIRO, en caso contrario FALSO:

   ISNA(BUSCARV(A2,$C$2:$C$9, 1, FALSO))

3. Utilice a fórmula ISNA VLOOKUP para a proba lóxica da función SE. Se a proba é TRUE (erro #N/A), devolve un valor da Lista 1 na mesma fila. Se a proba é FALSA (atópase unha coincidencia na Lista 2), devolve unha cadea baleira.

A fórmula completa toma esta forma:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Para desfacerse dos espazos en branco, aplique o filtro de Excel como se demostra no exemplo anterior.

En Excel 365 e Excel 2021, pode filtrar a lista de resultados de forma dinámica. Para iso, simplemente coloque a fórmula ISNA VLOOKUP no argumento include da función FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Outra forma é use BUSCAR XL para os criterios: a función devolve cadeas baleiras ("") para os puntos de datos que faltan e filtra os valores da Lista 1 para os que BUSCAR XL devolveu cadeas baleiras (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Fórmula BUSCAR V para identificar coincidencias e diferenzas entre dúas columnas

Se quere engadir etiquetas de texto á primeira lista indicando que valores están dispoñibles na segunda lista e cales non, use a fórmula BUSCAR V xunto co Funcións IF e ISNA/ISERROR.

Por exemplo, para identificar os nomes que están nas dúas columnas A e D e os que só están na columna A, a fórmula é:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Aquí, a función ISNA detecta os erros #N/A xerados por BUSCARV e pasa ese resultado intermedio á función IF para quedevolve o texto especificado para os erros e outro texto para as buscas correctas.

Neste exemplo, usamos as etiquetas "Non cualificado"/"Calificado", que son axeitados para o noso conxunto de datos de mostra. Pode substituílos por "Non na lista 2"/"Na lista 2", "Non dispoñible"/"Dispoñible" ou calquera outra etiqueta que considere conveniente.

É mellor inserir esta fórmula nunha columna. adxacente á Lista 1 e copiado a través de tantas celas como elementos hai na súa lista.

Unha forma máis de identificar coincidencias e diferenzas en 2 columnas é usar a función COINCIDIR:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Compara 2 columnas e devolve un valor da terceira

Ao traballar con táboas que conteñan datos relacionados, ás veces pode ter que compara dúas columnas en dúas táboas diferentes e devolve un valor coincidente doutra columna. De feito, é o uso principal da función BUSCAR V, o propósito para o que foi deseñada.

Por exemplo, comparar os nomes das columnas A e D nas dúas táboas seguintes e devolver un tempo da columna E , a fórmula é:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Para ocultar os erros #N/D, use a solución comprobada: a función IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

En lugar de espazos en branco, podes devolver calquera texto que queiras para os puntos de datos que faltan; simplemente tecleo no último argumento. Por exemplo:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Ademais de BUSCAR V, a tarefa pódese realizar con algunhas outras funcións de busca.

Personalmente, confiaría nun ÍNDICE máis flexible.Fórmula COINCIDIR:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Ou use o sucesor moderno de BUSCARV: a función BUSCAR XL, dispoñible en Excel 365 e Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Para obtén os nomes dos participantes cualificados do grupo A e os seus resultados, simplemente filtra as celas en branco da columna B:

=FILTER(A3:B15, B3:B15"")

Ferramentas de comparación

Se comparas con frecuencia ficheiros ou datos en Excel, estas ferramentas intelixentes incluídas na nosa Ultimate Suite poden aforrarche moito tempo!

Comparar táboas: forma rápida de atopar duplicados (coincidencias) e valores únicos (diferenzas) en dous conxuntos de datos calquera, como columnas, listas ou táboas.

Comparar dúas follas: atopar e destacar diferenzas entre dúas follas de traballo.

Comparar varias follas: atopar e destacar diferenzas en varias follas á vez. .

Practicar o libro de traballo para descargar

VLOOKUP en Excel para comparar columnas - exemplos (ficheiro .xlsx)