O titorial explica como contar palabras en Excel usando a función LEN en combinación con outras funcións de Excel e ofrece fórmulas que distinguen maiúsculas e minúsculas para contar palabras/texto total ou específico nunha cela ou rango .

Microsoft Excel ten un puñado de funcións útiles que poden contar case todo: a función COUNT para contar celas con números, COUNTA para contar as celas non en branco, COUNTIF e COUNTIFS para contar celas condicionalmente e LEN para calcular a lonxitude dunha cadea de texto.

Desafortunadamente, Excel non ofrece ningunha ferramenta integrada para contar o número de palabras. Afortunadamente, combinando funcións serval podes facer fórmulas máis complexas para realizar case calquera tarefa. E usaremos este enfoque para contar palabras en Excel.

Como contar o número total de palabras nunha cela

Para contar palabras nunha cela, use a seguinte combinación de funcións LEN, SUBSTITUTE e TRIM:

Onde celda é o enderezo da cela onde quere contar as palabras.

Por exemplo, para contar palabras na cela A2, use esta fórmula:

=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1

E logo, pode copiar a fórmula para contar palabras noutras celas da columna A:

Como funciona esta fórmula de conta de palabras

Primeiro, usa a función SUBSTITUTE para eliminar todos os espazos da cela substituíndoos por un texto baleirocadea ("") para que a función LEN devolva a lonxitude da cadea sen espazos:

LEN(SUBSTITUTE(A2," ",""))

Despois diso, resta a lonxitude da cadea sen espazos da lonxitude total da cadea, e engade 1 ao reconto de palabras final, xa que o número de palabras nunha cela é igual ao número de espazos máis 1.

Ademais, utiliza a función TRIM para eliminar espazos adicionais na cela, se hai. Ás veces, unha folla de traballo pode conter moitos espazos invisibles, por exemplo dous ou máis espazos entre palabras, ou espazos escritos accidentalmente ao principio ou ao final do texto (é dicir, espazos ao principio e ao final). E todos eses espazos adicionais poden perder a túa conta de palabras. Para evitar isto, antes de calcular a lonxitude total da cadea, usamos a función TRIM para eliminar todos os espazos en exceso excepto os espazos individuais entre as palabras.

Fórmula mellorada que xestiona correctamente as celas baleiras

A fórmula anterior para contar palabras en Excel podería chamarse perfecta se non fose por un inconveniente: devolve 1 para as celas baleiras. Para solucionar isto, podes engadir unha instrución IF para comprobar as celas en branco:

=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)

Como podes ver na captura de pantalla anterior, a fórmula devolve cero para as celas en branco e o reconto de palabras correcto para as celas non baleiras.

Como contar palabras específicas nunha cela

Para contar cantas veces aparece unha determinada palabra, texto ou subcadea. nunha cela, utiliza o seguintefórmula:

=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )

Por exemplo, calculemos o número de ocorrencias de " lúa " na cela A2:

=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")

En lugar de introducir a palabra que se vai contar directamente na fórmula, pode tecleala nalgunha cela e facer referencia a esa cela na súa fórmula. Como resultado, obterá unha fórmula máis versátil para contar palabras en Excel.

Consello. Se pensas copiar a túa fórmula en varias celas, asegúrate de corrixir a referencia á cela que contén a palabra a contar co signo $. Por exemplo:

=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)

Como conta esta fórmula as aparicións dun texto específico nunha cela

1. A función SUBSTITUTE elimina o especificado palabra do texto orixinal.

Neste exemplo, eliminamos a palabra introducida na cela B1 do texto orixinal situado en A2:

SUBSTITUTE(A2, $B$1,"")

Neste exemplo, LEN(SUBSTITUTE(A2, $B$1,"")) devolve a lonxitude do texto na cela A2 despois de eliminar todos os caracteres contidos en todas as ocorrencias da palabra " lua ".

(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))

O resultado deste operación é o número de caracteres contidos en todas as ocorrencias da palabra de destino, que é 12 neste exemplo (3 ocorrencias da palabra " lúa ", 4 caracteres cada unha).

Ademais de contar o número de determinadas palabras nunha cela, podes usar esta fórmula para contar as ocurrencias de calquera texto (subcadea). Por exemplo, pode contar cantas veces aparece o texto " escolle " na cela A2:

Fórmula que distingue entre maiúsculas e minúsculas para contar palabras específicas nun cell

Como probablemente sabes, Excel SUBSTITUTE é unha función que distingue entre maiúsculas e minúsculas e, polo tanto, a fórmula de reconto de palabras baseada en SUBSTITUTE distingue entre maiúsculas e minúsculas por defecto:

Fórmula que non distingue entre maiúsculas e minúsculas para contar palabras específicas nunha cela

Se precisa contar tanto as aparicións en maiúsculas como en minúsculas dunha determinada palabra, use a función UPPER ou LOWER dentro de SUBSTITUTE para converter o texto orixinal e o texto que quere contar para o mesmo caso.

Ou

Por exemplo, para contar o número de aparicións da palabra en B1 dentro da cela A2 ignorando maiúsculas e minúsculas, use esta fórmula:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)

Como se demostra a continuacióncaptura de pantalla, a fórmula devolve o mesmo número de palabras independentemente de que a palabra se escriba en MAIÚSCULAS (cela B1), en minúsculas (cela D1) ou en minúsculas (cela C1):

Conta o número total de palabras nun intervalo

Para saber cantas palabras contén un determinado intervalo, tome a fórmula que conta o total de palabras nunha cela e inscríbea na función SUMAPRODUTO ou SUMA:

Ou

SUMPRODUCT é unha das poucas funcións de Excel que poden manexar matrices, e completa a fórmula do xeito habitual premendo a tecla Intro.

Para que a función SUMA calcule matrices, debe usarse nunha fórmula matricial, que se completa premendo Ctrl+Maiús+Intro en lugar de o trazo de Intro habitual.

Por exemplo, para contar todas as palabras do intervalo A2:A4, use unha das seguintes fórmulas:

=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

Contar palabras específicas nunha ra nge

Se queres contar cantas veces aparece unha palabra ou texto en particular dentro dun rango de celas, utiliza un enfoque similar: toma a fórmula para contar palabras específicas nunha cela e combínaa coa SUMA ou Función SUMPRODUCT:

Ou

Lembre de premer Ctrl+Maiús+Intro para completar correctamente a fórmula da SUMA da matriz.

Por exemplo, para contar todas as ocorrencias da palabra introducida na cela C1 dentro do intervalo A2:A4, use esta fórmula:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))

Como vostede lembre, SUBSTITUTE é unha función distingue entre maiúsculas e minúsculas e, polo tanto, a fórmula anterior distingue entre texto en maiúscula e minúscula:

Para facer a fórmula insensible entre maiúsculas e minúsculas , use a función SUPERIOR ou INFERIOR:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))

Ou

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))

Así contas as palabras en Excel. Para comprender mellor e, probablemente, realizar enxeñaría inversa das fórmulas, podes descargar o libro de traballo de exemplo de Excel Count Words.

Se ningunha das fórmulas que se comentan neste titorial resolveu a túa tarefa, consulta a seguinte lista de recursos que demostran outras solucións para contar celas, texto e caracteres individuais en Excel.