El tutorial mostra com podeu aprofitar la nova funció SEQUÈNCIA per generar ràpidament una llista de dates a Excel i utilitzar la funció Emplenament automàtic per omplir una columna amb dates, dies laborables, mesos o anys.

Fins fa poc, només hi havia una manera senzilla de generar dates a Excel: la funció d'emplenament automàtic. La introducció de la nova funció SEQUENCE de matriu dinàmica també ha permès fer una sèrie de dates amb una fórmula. Aquest tutorial fa una ullada a fons als dos mètodes perquè pugueu triar el que us convingui millor.

Com omplir sèries de dates a Excel

Quan heu d'omplir una columna amb dates a Excel, la manera més ràpida és utilitzar la funció d'emplenament automàtic.

Emplenar automàticament una sèrie de dates a Excel

Omplir una columna o fila amb dates que s'incrementin en un dia és molt fàcil:

1. Escriviu la data inicial a la primera cel·la.
2. Seleccioneu la cel·la amb la data inicial i arrossegueu el mànec d'emplenament (un petit quadrat verd a la part inferior). -extrem dret) cap avall o cap a la dreta.

Excel generarà immediatament una sèrie de dates en el mateix format que la primera data que heu escrit manualment.

Ompliu una columna amb dies laborables, mesos o anys

Per crear una sèrie de dies laborables, mesos o anys, feu una de les accions següents:

• Ompliu una columna amb dates seqüencials tal com es descriu anteriorment. Després d'això, feu clic al botó Opcions d'emplenament automàtic i seleccioneul'opció desitjada, digueu Emplenar els mesos :

  

• O podeu introduir la vostra primera data, feu clic amb el botó dret al controlador d'emplenament, manteniu premut i arrossegueu tantes cel·les. segons sigui necessari. Quan deixeu anar el botó del ratolí, apareixerà un menú contextual que us permetrà seleccionar l'opció necessària, Emplenar els anys en el nostre cas:

  

Empleneu una sèrie de dates incrementant-se en N dies

Per generar automàticament una sèrie de dies, dies laborables, mesos o anys amb un pas específic , això és el que heu de fer:

1. Introduïu la data inicial a la primera cel·la.
2. Seleccioneu aquesta cel·la, feu clic amb el botó dret al controlador d'emplenament, arrossegueu-la per tantes cel·les com sigui necessari i, a continuació, deixeu anar.
3. Al menú emergent, trieu Sèrie (l'últim element).
4. Al quadre de diàleg Sèrie , seleccioneu la Unitat de data d'interès i establiu el Valor del pas .
5. Feu clic a D'acord.

Per obtenir més exemples, consulteu Com inseriu i empleneu les dates automàticament a Excel.

Com fer una seqüència de dates a Excel amb una fórmula

En un dels tutorials anteriors, vam veure com utilitzar la nova funció SEQUENCE de matriu dinàmica per generar una seqüència numèrica. Com que internament a Excel les dates s'emmagatzemen com a números de sèrie, la funció també pot produir fàcilment una sèrie de dates. Tot el que heu de fer és configurar correctament els arguments tal com s'explica als exemples següents.

Nota. Totes les fórmules comentades aquí només funcionen en elles últimes versions d'Excel 365 que admeten matrius dinàmiques. A Excel 2019, Excel 2016 i Excel 2013 predinàmics, utilitzeu la funció d'emplenament automàtic tal com es mostra a la primera part d'aquest tutorial.

Creeu una sèrie de dates a Excel

Per generar un seqüència de dates a Excel, configureu els arguments següents de la funció SEQUENCE:

• Files - el nombre de files per omplir amb dates.
• Columnes : el nombre de columnes per omplir amb dates.
• Inici : la data d'inici a la format que Excel pot entendre, com ara "8/1/2020" o "1-Aug-2020". Per evitar errors, podeu proporcionar la data utilitzant la funció DATA, com ara DATA(2020, 8, 1).
• Pas : l'increment de cada data posterior en una seqüència.

Per exemple, per fer una llista de 10 dates a partir de l'1 d'agost de 2020 i augmentant 1 dia, la fórmula és:

=SEQUENCE(10, 1, "8/1/2020", 1)

o

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

Com a alternativa, podeu introduir el nombre de dates (B1), la data d'inici (B2) i el pas (B3) a les cel·les predefinides i fer referència a aquestes cel·les a la vostra fórmula. Com que estem generant una llista, el número de columnes (1) està codificat:

=SEQUENCE(B1, 1, B2, B3)

Escriviu la fórmula següent a la cel·la superior (A6 en el nostre cas), premeu la tecla Enter i els resultats es veuran automàticament pel nombre especificat de files i columnes.

Nota. Amb el valor predeterminat General format, els resultats apareixeran com a números de sèrie. Perquè es mostrin correctament, assegureu-vos d'aplicar el format de data a totes les cel·les de l'interval de vessament.

Feu una sèrie de dies laborables a Excel

Per obtenir només una sèrie de dies laborables, embolcalleu SEQUENCE a la funció WORKDAY o WORKDAY.INTL d'aquesta manera:

Com que la funció WORKDAY afegeix el nombre de dies especificat al segon argument a la data d'inici, restem-ne 1 per tenir la data d'inici inclosa a la data d'inici. resultats.

Per exemple, per generar una seqüència de dies laborables a partir de la data de B2, la fórmula és:

=WORKDAY(B2-1, SEQUENCE(B1))

On B1 és la mida de la seqüència.

Consells i notes:

• Si la data d'inici és dissabte o diumenge, la sèrie començarà el següent dia laborable.
• La funció Excel WORKDAY assumeix que dissabte i diumenge són caps de setmana. Per configurar caps de setmana i festius personalitzats, utilitzeu la funció WORKDAY.INTL.

Genereu una seqüència mensual a Excel

Per crear una sèrie de dates incrementades en un mes, podeu utilitzar aquesta fórmula genèrica:

En aquest cas, poseu l'any objectiu al primer argument i el dia a la 3r argument. Per al segon argument, la funció SEQUENCE retorna números seqüencials de l'1 al 12. En funció dels paràmetres anteriors, la funció DATA produeix una sèrie dedates com es mostra a la part esquerra de la captura de pantalla següent:

=DATE(2020, SEQUENCE(12), 1)

Per mostrar només els noms dels mesos , configureu un dels formats de dates personalitzats següents per a l'interval de vessaments :

• mmm - forma curta com gen , feb , mar , etc.
• mmmm - complet com ara gener , febrer , març , etc.

Com a resultat, només apareixeran els noms dels mesos a les cel·les, però els valors subjacents encara seran dates completes. A les dues sèries de la captura de pantalla següent, observeu l'alineació dreta predeterminada típica per als números i les dates a Excel:

Per generar una seqüència de dates que s'incrementi en un mes i comença amb una data específica , utilitzeu la funció SEQUENCE juntament amb EDATE:

La funció EDATE retorna una data que és el nombre especificat de mesos abans o després de la data d'inici. I la funció SEQUENCE produeix una matriu de 12 números (o tants com especifiqueu) per forçar EDATE a avançar en increments d'un mes. Tingueu en compte que l'argument inici s'estableix en 0, de manera que la data d'inici s'inclou als resultats.

Amb la data d'inici a B1, la fórmula pren aquesta forma:

=EDATE(B1, SEQUENCE(12, 1, 0))

Nota. Després de completar una fórmula, recordeu aplicar un format de data adequat als resultats perquè es mostrin correctament.

Creeu una seqüència d'anys a Excel

Per feruna sèrie de dates incrementades per any, utilitzeu aquesta fórmula genèrica:

On n és el nombre de dates que voleu generar.

En aquest cas, la DATA(any, mes, dia) construeix una data d'aquesta manera:

• Any és retornat per la funció SEQUÈNCIA que està configurada per generar n files per 1 matriu de columnes de números, començant pel valor de l'any des de data_inici .
• Els valors del mes i dia s'extreuen directament des de la data d'inici.

Per exemple, si introduïu la data d'inici a B1, la fórmula següent sortirà una sèrie de 10 dates en increments d'un any:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

Després en format com a dates, els resultats es veuran de la següent manera:

Genereu una seqüència de vegades a Excel

Com que els temps s'emmagatzemen a Excel com a nombres decimals que representen un fracció del dia, la funció SEQUÈNCIA pot treballar directament amb els temps.

A Suposant que l'hora d'inici és a B1, podeu utilitzar una de les fórmules següents per produir una sèrie de 10 vegades. La diferència només està en l'argument pas . Com que hi ha 24 hores al dia, utilitzeu 1/24 per augmentar en una hora, 1/48 per augmentar en 30 minuts, i així successivament.

30 minuts de diferència:

=SEQUENCE(10, 1, B1, 1/48)

1 hora de diferència:

=SEQUENCE(10, 1, B1, 1/24)

2 hores de diferència:

=SEQUENCE(10, 1, B1, 1/12)

La captura de pantalla següent mostra elresultats:

Si no voleu molestar-vos a calcular el pas manualment, podeu definir-lo mitjançant la funció TIME:

Per a aquest exemple, introduirem totes les variables en cel·les separades com es mostra a la captura de pantalla següent . A continuació, podeu utilitzar la fórmula següent per generar una sèrie temporal amb qualsevol mida de pas d'increment que especifiqueu a les cel·les E2 (hores), E3 (minuts) i E4 (segons):

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Com crear un calendari mensual a Excel

En aquest darrer exemple, utilitzarem la funció SEQUÈNCIA juntament amb DATEVALUE i WEEKDAY per crear un calendari mensual que s'actualitzarà automàticament en funció de l'any i el mes que especifiqueu.

La fórmula a A5 és la següent:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Com funciona aquesta fórmula:

Utilitzeu la funció SEQUÈNCIA per generar una matriu de dates de 6 files (el nombre màxim possible de setmanes en un mes) per 7 columnes (el nombre de dies d'una setmana) augmentat en 1 dia. Per tant, els arguments files , columnes i pas no plantegen cap pregunta.

La part més complicada de l'argument inici . No podem començar el nostre calendari amb el primer dia del mes objectiu perquè no sabem quin dia de la setmana és. Per tant, utilitzem la fórmula següent per trobar el primer diumenge abans de l'1r dia del mes especificat iany:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

La primera funció DATEVALUE retorna un número de sèrie que, en el sistema Excel intern, representa el 1r dia del mes a B2 i l'any a B1. En el nostre cas, és 44044 corresponent a l'1 d'agost de 2020. En aquest punt, tenim:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

La funció WEEKDAY retorna el dia de la setmana corresponent al primer dia de l'objectiu. mes com a número de l'1 (diumenge) al 7 (dissabte). En el nostre cas, és el 7 perquè l'1 d'agost de 2020 és dissabte. I la nostra fórmula es redueix a:

44044 - 7 + 1

44044 - 7 és 4403, que correspon al dissabte 25 de juliol de 2020. Com que necessitem diumenge, afegim la correcció +1.

D'aquesta manera, obtenim una fórmula senzilla que genera una matriu de números de sèrie que comencen per 4404:

=SEQUENCE(6, 7, 4404, 1)

Formateu els resultats com a dates i obtindreu un calendari que es mostra a la captura de pantalla de dalt. Per exemple, podeu utilitzar un dels formats de data següents:

• d-mmm-yy per mostrar dates com 1-agost-20
• mmm d per mostrar el mes i el dia com 20 d'agost
• d per mostrar només el dia

Espereu, però volem crear un calendari mensual. Per què apareixen algunes dates del mes anterior i el següent? Per ocultar aquestes dates irrellevants, configureu una regla de format condicional amb la fórmula següent i apliqueu el color titra blanca :

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

On A5 és la cel·la més esquerra de el vostre calendari i B2 és l'objectiumes.

Per obtenir els passos detallats, vegeu Com crear una regla de format condicional basada en fórmules a Excel.

Així és com podeu generar una seqüència. de dates en Excel. Us agraeixo la lectura i espero veure-us al nostre bloc la setmana vinent!

Quader de pràctiques per descarregar

Seqüència de dates a Excel: exemples de fórmules (fitxer .xlsx)