INHOUDSOPGAWE
In hierdie tutoriaal sal ons kyk hoe om die ISERROR met VLOOKUP in Excel te gebruik om alle soorte foute produktief te hanteer.
VLOOKUP is een van die mees verwarrende Excel-funksies wat geteister word met baie kwessies. In watter tabel jy ook al kyk, #N/A-foute is 'n algemene gesig, met #NAAM en #WAARDE wat ook nou en dan verskyn. Die gebruik van VLOOKUP met ISERROR kan jou help om alle moontlike foute op te spoor en dit te hanteer op 'n manier wat die mees geskikte is vir jou situasie.
Hoekom gee VLOOKUP 'n fout?
Die meeste algemene fout in VLOOKUP-formules is #N/A wat voorkom wanneer 'n opsoekwaarde nie gevind word nie. Dit kan weens verskillende redes gebeur:
- Die opsoekwaarde bestaan nie in die opsoekskikking nie.
- Die opsoekwaarde is verkeerd gespel.
- Daar is voor- of agterste spasies in die opsoekwaarde of opsoekkolom.
- Die opsoekkolom is nie die linkerkolom van die tabelskikking nie.
Boonop kan jy 'n #VALUE raakloop ! fout, bv. wanneer die opsoekwaarde meer as 255 karakters bevat. Indien daar 'n spelfout in die funksie se naam is, sal 'n #NAAM? fout verskyn.
Vir volledige verwysing, sien asseblief ons vroeëre plasing oor Hoekom Excel VLOOKUP nie werk nie.
INDIEN IERROR VLOOKUP-formule om foute met gepasmaakte teks te vervang
Om alle moontlike foute wat deur VLOOKUP geaktiveer kan word te verdoesel, kan jy dit binne-in die IF IERROR-formule plaassoos hierdie:
IF(ISERROR(VLOOKUP(…)), " text_if_error", VLOOKUP(...))Kom ons trek as voorbeeld die name van die vakke waarin die studente van groep A het toetse gedruip:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Gevolglik kry jy 'n klomp #N/A-foute, wat 'n indruk kan skep dat die formule korrup is.
In werklikheid dui hierdie foute net aan dat sommige van die opsoekwaardes (A3:A14) nie in die opsoeklys (D3:D9) gevind word nie. Om daardie idee duidelik oor te dra, nes jou VLOOKUP-formule in die IF ISERROR-konstruksie:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Dit sal foute opvang en jou persoonlike teksboodskap terugstuur:
Wenke en notas:
- Die grootste voordeel van hierdie formule is dat dit goed werk in alle weergawes van Excel 2000 deur Excel 365. In moderne weergawes, eenvoudiger en meer kompakte alternatiewe is beskikbaar.
- Die ISERROR-funksie vang absoluut alle foute op , soos #N/A, #NAAM, #WAARDE, ens. Indien jy 'n pasgemaakte wil vertoon boodskap slegs wanneer 'n opsoekwaarde nie gevind word nie (#N/A fout), gebruik die IF ISNA VLOOKUP (in alle weergawes) of IFNA VLOOKUP (in Excel 2013 en later).
ISERROR VLOOKUP na gee leë sel terug as fout
Om 'n leë sel te hê wanneer 'n fout voorkom, kry jou formule om 'n leë string ("") terug te gee in plaas van 'n pasgemaakte teks:
IF(ISERROR(VLOOKUP(...) ), "", VLOOKUP(…))In ons geval neem die formule hierdie vorm aan:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Dieresultaat is presies soos verwag - 'n leë sel as die student se naam nie in die opsoektabel gevind word nie.
Wenk. Op 'n soortgelyke manier kan jy VLOOKUP-foute vervang met nulle, strepies of enige ander karakter wat jy wil. Gebruik net die verlangde karakter in die plek van 'n leë string.
INDIEN FOUT VLOOKUP Ja/Nee formule
In sommige situasies soek jy dalk na iets, maar in plaas daarvan om die vuurhoutjies te trek, wil jy net terugstuur Ja (of 'n ander teks as die opsoekwaarde gevind word) en Nee (as die opsoekwaarde nie gevind word nie). Om dit te laat doen, kan jy hierdie generiese formule gebruik:
IF(ISERROR(VLOOKUP(…)), " text_if_not_found ", " text_if_found ")In ons voorbeelddatastel, veronderstel jy wil weet watter studente 'n toets gedruip het en watter nie. Om dit te bereik, dien die reeds bekende ISERROR VLOOKUP-formule aan die logiese toets van IF en vertel dit om "Nee" uit te voer as die waarde nie gevind word nie (ISERROR VLOOKUP gee WAAR terug), "Ja" indien gevind (FOUT VLOOKUP gee ONWAAR terug):
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Yes")
ISERROR VLOOKUP-alternatiewe
Die IF ISERROR-kombinasie is die oudste bewese tegniek vir Vlookup sonder foute in Excel. Met verloop van tyd het nuwe funksies ontwikkel, wat makliker maniere verskaf het om dieselfde taak uit te voer. Hieronder sal ons ander moontlike oplossings bespreek en wanneer elkeen die beste is om toegepas te word.
IFERROR VLOOKUP
Beskikbaar in Excel 2007 enhoër
Begin met weergawe 2007, het Excel 'n spesiale funksie, genaamd IFERROR, om 'n formule vir foute na te gaan en jou eie teks terug te stuur (of 'n alternatiewe formule uit te voer) indien enige fout opgespoor word.
IFERROR(VLOOKUP(…), " text_if_error ")Die werklike formule is soos volg:
=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
Met die eerste oogopslag lyk dit soos 'n korter analoog van die IF ISERROR VLOOKUP-formule. Daar is egter 'n wesenlike verskil:
- IFERROR VLOOKUP neem aan dat jy altyd die resultaat van VLOOKUP wil hê as dit nie 'n fout is nie.
- INDIEN FOUT VLOOKUP laat jou spesifiseer wat om te gee terug as 'n fout en wat as geen fout nie.
Vir meer besonderhede, sien asseblief Gebruik van IFERROR met VLOOKUP in Excel.
IF ISNA VLOOKUP
Werk in Excel 2000 en later
In situasies wanneer jy net #N/A wil vang sonder om enige ander foute op te vang, kom die ISNA-funksie handig te pas. Die sintaksis is dieselfde as dié van IF ISERROR VLOOKUP:
IF(ISNA(VLOOKUP(…)), " text_if_error ", VLOOKUP(...))Maar onder sekere omstandighede is dit oënskynlik identiese formule kan verskillende resultate lewer:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
In die prent hieronder bevat sel A13 baie agterste spasies, waardeur die totale lengte van die opsoekwaarde 255 karakters oorskry. As gevolg hiervan, aktiveer die formule 'n #WAARDE! fout, om jou aandag op daardie sel te vestig en aan te moedig om die redes te ondersoek. FOUTVLOOKUP sal in hierdie geval "Nee" terugstuur, wat net die kwessie sal verbloem en 'n absoluut verkeerde resultaat sal lewer.
Wanneer om te gebruik:
Hierdie formule werk pragtig in 'n situasie wanneer jy net 'n teks wil vertoon wanneer 'n opsoekwaarde nie gevind word nie en nie onderliggende probleme met die VLOOKUP-formule self wil masker nie, bv. wanneer die funksie se naam verkeerd getik is (#NAME?) of die volledige pad na die opsoekwerkboek nie gespesifiseer is nie (#VALUE!).
Vir meer inligting, sien asseblief ISNA-funksie in Excel met formulevoorbeelde.
IFNA VLOOKUP
Beskikbaar in Excel 2013 en hoër
Dit is 'n moderne vervanging van die IF ISNA-kombinasie waarmee jy #N/A-foute in 'n makliker manier.
IFNA(VLOOKUP(…), " text_if_error ")Hier is 'n snelskrif-ekwivalent van ons IF ISNA VLOOKUP-formule:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
Wanneer om te gebruik:
Dit is 'n ideale oplossing om #N/A-foute in moderne weergawes van Excel (2013 - 365) vas te vang en te hanteer.
Vir volledige besonderhede, sien Excel IFNA-funksie.
XLOOKUP
Ondersteun in Excel 2021 en Excel 365
As gevolg van sy ingeboude "as fout"-funksionaliteit , is die XLOOKUP-funksie die maklikste manier om op te soek sonder #N/A-foute in Excel. Tik eenvoudig jou gebruikersvriendelike teks in die opsionele 4de argument genaamd as_nie_gevind nie .
Byvoorbeeld:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")
Beperking: Dit vang net #N/A foute op, ignoreerander tipes.
Vir meer inligting, kyk na XLOOKUP-funksie in Excel.
Soos jy sien, bied Excel heelwat verskillende opsies om op VLOOKUP-foute te rig. Hopelik het hierdie tutoriaal 'n bietjie lig gewerp oor hoe om dit effektief te gebruik. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien!
Beskikbare aflaaie
ISERROR with VLOOKUP-voorbeelde (.xlsx-lêer)
