Tutorial menerangkan cara menjadikan Excel VLOOKUP sensitif huruf besar-besaran, menunjukkan beberapa formula lain yang membezakan huruf besar kecil dan menunjukkan kekuatan dan batasan setiap fungsi.

Saya rasa setiap Pengguna Excel mengetahui fungsi apa yang melakukan carian menegak dalam Excel. Betul, itu VLOOKUP. Walau bagaimanapun, sangat sedikit orang yang menyedari bahawa VLOOKUP Excel adalah tidak peka huruf besar-besaran, bermakna ia menganggap huruf kecil dan huruf BESAR sebagai aksara yang sama.

Berikut ialah contoh pantas yang menunjukkan ketidakupayaan VLOOKUP untuk membezakan huruf besar kecil. Katakan jika anda mempunyai "bil" dalam sel A2 dan "Bill" dalam A4. Formula di bawah akan menangkap "bil" kerana ia didahulukan dalam tatasusunan carian dan mengembalikan nilai yang sepadan daripada B2.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Lebih lanjut dalam ini artikel, saya akan menunjukkan kepada anda cara untuk menjadikan VLOOKUP sensitif huruf besar-besaran. Kami juga akan meneroka beberapa fungsi lain yang boleh melakukan padanan sensitif huruf besar-kecil dalam Excel.

Formula VLOOKUP peka huruf besar-kecil

Seperti yang dinyatakan di atas, formula VLOOKUP biasa tidak mengenali kes surat. Walau bagaimanapun, terdapat cara untuk menjadikan Excel VLOOKUP sensitif huruf besar-besaran, seperti yang ditunjukkan dalam contoh di bawah.

Andaikan anda mempunyai ID Item dalam lajur A dan ingin menarik harga dan ulasan item daripada lajur B dan C. Masalahnya ialah ID termasuk huruf kecil dan huruf besar. Sebagai contoh, nilai dalam A4 (001Tvci3u) dan A5 (001Tvci3U) berbeza hanya dalamaksara terakhir, "u" dan "U", masing-masing.

Apabila mencari "001Tvci3 U ", formula VLOOKUP standard menghasilkan $90 yang dikaitkan dengan "001Tvci3 u " kerana ia datang sebelum "001Tvci3 U " dalam tatasusunan carian. Tetapi ini bukan yang anda mahukan, bukan?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Untuk melakukan carian sensitif huruf besar-besaran dalam Excel, kami menggabungkan VLOOKUP, CHOOSE dan EXACT fungsi:

Formula generik ini berfungsi dengan sempurna dalam semua situasi. Anda juga boleh melihat ke atas dari kanan ke kiri , sesuatu yang formula VLOOKUP biasa tidak dapat lakukan. Kudos to Pouriya kerana mencadangkan penyelesaian yang ringkas dan elegan ini!

Dalam kes kami, formula sebenar adalah seperti berikut.

Untuk menarik harga dalam F3:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

Untuk mengambil ulasan F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Nota. Dalam semua versi Excel selain Excel 365, ini hanya berfungsi sebagai formula tatasusunan, jadi ingat untuk menekan Ctrl + Shift + Enter untuk melengkapkannya dengan betul. Dalam Excel 365, kerana sokongan untuk tatasusunan dinamik, ia juga berfungsi sebagai formula biasa.

Cara formula ini berfungsi:

Bahagian teras yang melakukan helah ialah formula PILIH dengan EXACT bersarang:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Di sini, fungsi EXACT membandingkan nilai dalam F2 terhadap setiap nilai dalam A2:A7 dan mengembalikan TRUE jika ia betul-betul sama termasuk huruf besar,FALSE sebaliknya:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

Untuk argumen index_num CHOOSE, kami menggunakan pemalar tatasusunan {1,2}. Hasilnya, fungsi tersebut menggabungkan nilai logik daripada tatasusunan di atas dan nilai daripada C2:C7 ke dalam tatasusunan dua dimensi seperti ini:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

Fungsi VLOOKUP mengambilnya dari sana dan mencari nilai carian (yang BENAR) dalam lajur pertama tatasusunan 2 dimensi (diwakili oleh nilai logik) dan mengembalikan padanan daripada lajur ke-2, iaitu harga yang kami cari:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Formula XLOOKUP peka huruf besar-kecil

Pelanggan Microsoft 365 boleh melakukan carian sensitif huruf besar-kecil dalam Excel dengan formula yang lebih ringkas. Seperti yang anda boleh duga, saya bercakap tentang pengganti VLOOKUP yang lebih berkuasa - fungsi XLOOKUP.

Oleh kerana XLOOKUP beroperasi pada tatasusunan carian dan pengembalian secara berasingan, kami tidak memerlukan helah tatasusunan dua dimensi daripada sebelumnya. contoh. Cuma, gunakan EXACT untuk argumen lookup_array :

Argumen terakhir ("Tidak dijumpai") adalah pilihan. Ia hanya mentakrifkan nilai yang akan dikembalikan jika tiada padanan ditemui. Jika anda meninggalkannya, maka ralat #N/A standard akan dikembalikan sekiranya formula tidak menemui apa-apa.

Untuk jadual sampel kami, ini ialah formula XLOOKUP yang sensitif huruf besar dan kecil untuk digunakan.

Untuk mendapatkan harga dalam F3:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

Untuk mengekstrakulasan F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Cara formula ini berfungsi:

Seperti dalam contoh sebelumnya, EXACT mengembalikan tatasusunan nilai TRUE dan FALSE, dengan TRUE mewakili padanan sensitif huruf besar-besaran. XLOOKUP mencari tatasusunan di atas untuk nilai TRUE dan mengembalikan padanan daripada return_array . Sila ambil perhatian, jika terdapat dua atau lebih nilai yang sama dalam lajur carian (termasuk huruf besar), formula akan mengembalikan padanan pertama yang ditemui.

Had XLOOKUP : tersedia sahaja dalam Excel 365 dan Excel 2021.

SUMPRODUCT - carian sensitif huruf besar-kecil untuk mengembalikan nombor yang sepadan

Seperti yang anda fahami daripada tajuk, SUMPRODUCT ialah satu lagi fungsi Excel yang boleh melakukan carian sensitif huruf besar-besaran , tetapi ia boleh mengembalikan nilai angka sahaja. Jika ini bukan kes anda, kemudian lompat ke contoh INDEX MATCH yang menyediakan penyelesaian untuk semua jenis data.

Seperti yang anda ketahui, SUMPRODUCT Excel mendarab komponen dalam tatasusunan yang ditentukan dan mengembalikan jumlah produk. Memandangkan kami mahukan carian sensitif huruf besar-besaran, kami menggunakan fungsi EXACT untuk mendapatkan tatasusunan pertama:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Malangnya, fungsi SUMPRODUCT tidak boleh mengembalikan padanan teks kerana nilai teks tidak boleh didarab. Dalam kes ini, anda akan mendapat #VALUE! ralat seperti dalam sel F4 dalam tangkapan skrin di bawah:

Cara formula ini berfungsi:

Seperti dalam contoh VLOOKUP, EXACT pemeriksaan fungsinilai dalam F2 terhadap semua nilai dalam A2:A7 dan mengembalikan TRUE untuk padanan sensitif huruf besar-besaran, FALSE sebaliknya:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

Dalam kebanyakan formula, Excel menilai TRUE kepada 1 dan FALSE kepada 0 . Jadi, apabila SUMPRODUCT mendarabkan elemen dua tatasusunan dalam kedudukan yang sama, semua bukan padanan (FALSE) menjadi sifar:

SUMPRODUCT({0;0;0;54;0;0})

Hasilnya, formula mengembalikan nombor daripada lajur B yang sepadan dengan padanan sensitif huruf besar-kecil yang tepat dalam lajur A.

Penghadan SUMPRODUCT : boleh mengembalikan nilai angka sahaja.

PADAN INDEKS - carian sensitif huruf besar-besaran untuk semua jenis data

Akhir sekali, kami hampir mendapat formula carian sensitif huruf besar tanpa had yang berfungsi dalam semua versi Excel dan pada semua set data.

Contoh ini datang terakhir bukan sahaja kerana yang terbaik disimpan untuk yang terakhir, tetapi juga kerana pengetahuan yang anda peroleh dalam contoh sebelumnya boleh membantu anda memahami formula MATCH INDEX sensitif huruf besar dan kecil dengan lebih baik.

Gabungan fungsi INDEX dan MATCH sering digunakan dalam Cth cel sebagai alternatif yang lebih fleksibel dan serba boleh kepada VLOOKUP. Artikel berikut berfungsi dengan baik (semoga :) menerangkan cara kedua-dua fungsi ini berfungsi bersama - Menggunakan INDEX MATCH dan bukannya VLOOKUP.

Di sini, saya hanya akan mengingatkan anda perkara utama:

• Fungsi MATCH mencari nilai carian dalam tatasusunan carian yang ditentukan dan mengembalikan kedudukan relatifnya.
• Relatifkedudukan nilai carian pergi terus ke argumen row_num bagi fungsi INDEX yang mengarahkannya untuk mengembalikan nilai daripada baris tersebut.

Untuk formula mengenali huruf besar kecil, anda hanya perlu menambah satu lagi fungsi pada gabungan INDEX MATCH klasik. Jelas sekali, anda memerlukan fungsi EXACT sekali lagi:

Formula sebenar dalam F3 ialah:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Dalam F4, kami menggunakan formula ini:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Sila ingat bahawa ia hanya berfungsi sebagai formula tatasusunan dalam semua versi selain Excel 365, jadi pastikan anda memasukkannya dengan menekan kekunci Ctrl + Shift + Enter bersama-sama. Jika dilakukan dengan betul, formula akan disertakan dalam pendakap kerinting seperti yang ditunjukkan dalam tangkapan skrin di bawah:

Cara formula ini berfungsi:

Seperti dalam semua contoh sebelumnya, EXACT mengembalikan TRUE untuk setiap nilai dalam A2:A7 yang betul-betul sepadan dengan nilai dalam F2. Memandangkan kami menggunakan TRUE untuk lookup_value MATCH, ia mengembalikan kedudukan relatif padanan sensitif huruf besar dan kecil yang tepat, iaitu apa yang INDEX perlukan untuk mengembalikan padanan daripada B2:B7.

Formula carian sensitif huruf besar lanjutan

Formula INDEX MATCH yang dinyatakan di atas kelihatan sempurna, bukan? Tetapi sebenarnya, ia tidak. Biar saya tunjukkan sebabnya.

Andaikan sel dalam lajur pulangan yang sepadan dengan nilai carian kosong. Apakah formula yang akan dikembalikan? tiada apa.Dan sekarang, mari lihat apa yang sebenarnya dipulangkan:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Op, formula mengembalikan sifar! Mungkin, ia tidak begitu penting apabila berurusan dengan nilai teks semata-mata. Walau bagaimanapun, jika lembaran kerja anda mengandungi nombor dan sebahagian daripadanya adalah sifar sebenar, ini adalah masalah.

Sebenarnya, semua formula carian lain yang dibincangkan sebelum ini berkelakuan dengan cara yang sama. Tetapi kini anda mahukan formula yang sempurna, bukan?

Untuk menjadikan formula INDEX MATCH sensitif huruf besar-besaran benar-benar sempurna, anda membungkusnya dalam fungsi IF yang menyemak sama ada sel pulangan kosong dan tidak mengembalikan apa-apa dalam kes ini:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

Dalam formula di atas:

• "C" ialah lajur pulangan.
• "1" ialah nombor yang menukarkan kedudukan relatif sel yang dikembalikan oleh fungsi MATCH menjadi alamat sel sebenar .

Sebagai contoh, tatasusunan carian dalam fungsi MATCH kami ialah A2:A7, bermakna kedudukan relatif sel A2 ialah "1", kerana ini ialah sel pertama dalam tatasusunan. Tetapi pada hakikatnya, tatasusunan carian bermula pada baris 2. Untuk mengimbangi perbezaan itu, kami menambah 1, jadi fungsi INDIRECT akan mengembalikan nilai dari sel kanan.

Tangkapan skrin di bawah menunjukkan INDEX sensitif huruf besar yang dipertingkatkan Formula MATCH dalam tindakan.

Jika sel pulangan kosong, formula tidak mengeluarkan apa-apa (rentetan kosong):

Jika sel pulangan mengandungi sifar , formula mengembalikan 0:

Jika anda mahupaparkan beberapa mesej apabila sel pulangan kosong, gantikan rentetan kosong ("") dalam hujah terakhir IF dengan beberapa teks:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Lakukan VLOOKUP sensitif huruf besar dengan cara yang mudah

Pengguna Ultimate Suite for Excel kami mempunyai alat khas yang memudahkan pencarian dalam jadual besar dan kompleks serta bebas tekanan. Perkara terbaik ialah Gabungkan Dua Jadual mempunyai pilihan sensitif huruf besar dan contoh di bawah menunjukkannya dalam tindakan.

Andaikan anda ingin menarik Kuantiti. daripada jadual Cari ke jadual Utama berdasarkan ID Item unik:

Apa yang anda lakukan ialah menjalankan Jadual Gabungan wizard dan lakukan langkah berikut:

1. Pilih jadual utama untuk menarik data baharu.
2. Pilih jadual carian untuk mencari data baharu.
3. Pilih satu atau lebih lajur utama (ID Item dalam kes kami). Dan pastikan anda menandai kotak Pemadanan sensitif huruf besar-kecil .

Seketika kemudian, anda akan mendapat hasil yang diingini :)

Begitulah cara mencari dalam Excel dengan mengambil kira kes teks. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Latihan buku kerja untuk muat turun

Contoh VLOOKUP sensitif huruf besar (fail.xlsx)