Vodič pokazuje kako koristiti formulu VLOOKUP u Excelu za upoređivanje dva stupca da biste vratili uobičajene vrijednosti (podudaranja) ili pronašli podatke koji nedostaju (razlike).

Kada imate podatke u dva različite liste, možda ćete morati da ih uporedite da biste videli koje informacije nedostaju na jednoj od lista ili koji podaci su prisutni u obe. Poređenje se može obaviti na mnogo različitih načina - koja metoda će se koristiti ovisi o tome šta tačno želite od nje.

Kako uporediti dvije kolone u Excelu koristeći VLOOKUP

Kada imate dva stupca podataka i želite saznati koje točke podataka s jedne liste postoje na drugoj listi, možete koristiti funkciju VLOOKUP da uporedite liste za uobičajene vrijednosti.

Da biste napravili VLOOKUP formulu u njenom osnovni oblik, ovo je ono što trebate učiniti:

• Za lookup_value (1. argument), koristite najgornju ćeliju sa Liste 1.
• Za table_array (2. argument), dostavi cijelu Listu 2.
• Za col_index_num (3. argument), koristite 1 jer postoji samo jedan stupac u nizu.
• Za range_lookup (4. argument), postavite FALSE - tačno podudaranje.

Pretpostavimo da imate imena učesnika u koloni A (Lista 1) i imena onih koji su prošli kvalifikacione runde u koloni B (Lista 2). Želite da uporedite ove 2 liste da odredite koji su učesnici iz grupe A stigli do glavnog događaja. Da biste to učinili, koristite sljedećeformula.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Formula ide u ćeliju E2, a zatim je povlačite prema dolje kroz onoliko ćelija koliko ima stavki na Listi 1.

Primijetite da table_array je zaključan sa apsolutnim referencama ($C$2:$C$9) tako da ostaje konstantan kada kopirate formulu u ćelije ispod.

Kao što možete vidjeti, imena kvalifikovani sportisti se pojavljuju u koloni E. Za preostale učesnike pojavljuje se greška #N/A koja pokazuje da njihova imena nisu dostupna na Listi 2.

Maskiranje #N/ Greške

Formula VLOOKUP o kojoj smo gore govorili savršeno ispunjava svoj glavni cilj - vraća uobičajene vrijednosti i identifikuje nedostajuće tačke podataka. Međutim, isporučuje gomilu grešaka #N/A, koje mogu zbuniti neiskusne korisnike i navesti ih da misle da nešto nije u redu s formulom.

Da zamijenite greške sa praznim ćelijama , koristite VLOOKUP u kombinaciji sa funkcijom IFNA ili IFERROR na ovaj način:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Naša poboljšana formula vraća prazan niz ("") umjesto #N/ A. Također možete vratiti svoj prilagođeni tekst kao što je "Nije na listi 2", "Nije prisutan" ili "Nije dostupno". Na primjer:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

To je osnovna formula VLOOKUP za poređenje dvije kolone u Excelu. Ovisno o vašem konkretnom zadatku, može se modificirati kao što je prikazano u daljnjim primjerima.

Uporedite dvije kolone u različitim Excel listovima koristeći VLOOKUP

U stvarnom životu, kolone kojepotrebe za poređenjem nisu uvijek na istom listu. U malom skupu podataka, možete pokušati uočiti razlike ručno gledajući dva lista jedan pored drugog.

Da biste pretraživali u drugom radnom listu ili radnoj knjizi sa formulama, morate koristiti eksternu referencu. Najbolja praksa je da počnete kucati formulu u svoj glavni list, a zatim se prebacite na drugi radni list i odaberete listu pomoću miša - odgovarajuća referenca opsega će se automatski dodati u formulu.

Pod pretpostavkom da je Lista 1 u stupcu A na Sheet1 i listi 2 je u stupcu A na Sheet2 , možete uporediti dvije kolone i pronaći podudaranja koristeći ovu formulu:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Za više informacija pogledajte:

• VLOOKUP sa drugog lista
• VLOOKUP iz druge radne knjige

Usporedite dvije kolone i vratite uobičajene vrijednosti (podudaranja)

U prethodnim primjerima raspravljali smo o VLOOKUP formuli u njenom najjednostavnijem obliku:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Rezultat te formule je spisak vrijednosti koje postoje u oba stupca i praznim ćelijama umjesto vrijednosti koje nisu dostupne u drugoj koloni.

Da biste dobili listu uobičajenih vrijednosti bez praznina, samo dodajte automatski filter u rezultirajuću kolonu i filtrirajte prazna mjesta.

U Excelu za Microsoft 365 i Excel 2021 to je podržavajući dinamičke nizove, možete koristiti funkciju FILTER da dinamički procijedite praznine. Za ovo koristite formulu IFNA VLOOKUP kaokriterij za FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Obratite pažnju da u ovom slučaju dobavljamo cijelu Listu 1 (A2:A14) u lookup_value argument VLOOKUP-a. Funkcija uspoređuje svaku od vrijednosti pretraživanja sa Listom 2 (C2:C9) i vraća niz podudaranja i #N/A grešaka koje predstavljaju vrijednosti koje nedostaju. Funkcija IFNA zamjenjuje greške praznim nizovima i servira rezultate funkciji FILTER, koja filtrira praznine ("") i kao konačni rezultat daje niz podudaranja.

Alternativno, možete koristiti ISNA funkciju da provjerite rezultat VLOOKUP-a i filtrirate stavke koje procjenjuju na FALSE, tj. vrijednosti koje nisu #N/A greške:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Isti rezultat može može se postići pomoću funkcije XLOOKUP, što formulu čini još jednostavnijom. Zbog mogućnosti XLOOKUP-a da interno obrađuje #N/A greške (opcijski argument if_not_found ), možemo bez IFNA ili ISNA omotača:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Uporedi dva stupca i pronađite vrijednosti koje nedostaju (razlike)

Da biste usporedili 2 stupca u Excelu kako biste pronašli razlike, možete nastaviti na ovaj način:

1. Napišite osnovnu formulu za traženje prve vrijednost sa Liste 1 (A2) na Listi 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Ugnijezdite gornju formulu u ISNA funkciji za provjeru izlaza VLOOKUP-a za #N/A greške. U slučaju greške, ISNA daje TRUE, u suprotnom FALSE:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. Koristite formulu ISNA VLOOKUP za logički test funkcije IF. Ako test procijeni na TRUE (#N/A greška), vratite vrijednost sa Liste 1 u istom redu. Ako test procijeni na FALSE (pronađeno je podudaranje na Listi 2), vratite prazan niz.

Kompletna formula ima ovaj oblik:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Da biste se riješili praznina, primijenite Excelov filter kao što je prikazano u gornjem primjeru.

U Excel 365 i Excel 2021, listu rezultata možete dinamički filtrirati. Za ovo jednostavno stavite formulu ISNA VLOOKUP u argument include funkcije FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Drugi način je da koristite XLOOKUP za kriterije - funkcija vraća prazne nizove ("") za nedostajuće točke podataka, a vi filtrirate vrijednosti na Listi 1 za koje je XLOOKUP vratio prazne nizove (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP formula za identifikaciju podudaranja i razlika između dvije kolone

Ako želite dodati tekstualne oznake na prvu listu koje pokazuju koje su vrijednosti dostupne na drugoj listi, a koje nisu, koristite formulu VLOOKUP zajedno sa Funkcije IF i ISNA/ISERROR.

Na primjer, za identifikaciju imena koja se nalaze u oba stupca A i D i onih koja se nalaze samo u stupcu A, formula je:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Ovdje, ISNA funkcija hvata #N/A greške koje je generirao VLOOKUP i prosljeđuje taj međurezultat funkciji IF da bivratite navedeni tekst za greške i drugi tekst za uspješno traženje.

U ovom primjeru smo koristili oznake "Nije kvalificirano"/"Kvalificirano", koje su prikladne za naš skup uzoraka podataka. Možete ih zamijeniti sa "Nije na Listi 2"/"Na Listi 2", "Nije dostupno"/"Dostupno" ili bilo kojim drugim oznakama koje smatrate prikladnim.

Ovu formulu je najbolje umetnuti u kolonu pored Liste 1 i kopirano kroz onoliko ćelija koliko ima stavki na vašoj listi.

Još jedan način da identifikujete podudaranja i razlike u 2 kolone je korištenje funkcije MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Uporedite 2 kolone i vratite vrijednost iz trećeg

Kada radite s tabelama koje sadrže povezane podatke, ponekad ćete morati usporedite dvije kolone u dvije različite tabele i vratite odgovarajuću vrijednost iz druge kolone. Zapravo, to je primarna upotreba funkcije VLOOKUP, svrha za koju je dizajnirana.

Na primjer, da se uporede imena u kolonama A i D u dvije tabele ispod i vrati vrijeme iz kolone E , formula je:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Da biste sakrili #N/A greške, koristite dokazano rješenje - IFNA funkciju:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Umjesto praznina, možete vratiti bilo koji tekst koji želite za nedostajuće podatke - samo ga unesite u posljednji argument. Na primjer:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Osim VLOOKUP-a, zadatak se može ispuniti s nekoliko drugih funkcija pretraživanja.

Osobno, ja bih se oslonio na fleksibilniji INDEXMATCH formula:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Ili koristite moderni nasljednik VLOOKUP-a - funkciju XLOOKUP, dostupnu u Excel 365 i Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Za dobijte imena kvalificiranih sudionika iz grupe A i njihove rezultate, jednostavno filtrirajte prazne ćelije u stupcu B:

=FILTER(A3:B15, B3:B15"")

Alati za poređenje

Ako često radite upoređivanje datoteka ili podataka u Excelu, ovi pametni alati uključeni u naš Ultimate Suite mogu vam uštedjeti vrijeme!

Uporedite tabele - brz način da pronađete duplikate (podudaranja) i jedinstvene vrijednosti (razlike) u bilo koja dva skupa podataka kao što su kolone, liste ili tabele.

Uporedi dva lista - pronađite i istaknite razlike između dva radna lista.

Uporedite više listova - pronađite i istaknite razlike u više listova odjednom .

Vježbajte radnu svesku za preuzimanje

VLOOKUP u Excelu za poređenje stupaca - primjeri (.xlsx datoteka)