ټیوټوریل ښیې چې څنګه په Excel کې د VLOOKUP فارمول وکاروئ ترڅو دوه کالمونه پرتله کړئ ترڅو عام ارزښتونه بیرته راوباسئ (میچونه) یا ورک شوي ډاټا ومومئ (توپیرونه).

کله چې تاسو په دوه کې ډاټا لرئ. مختلف لیستونه، تاسو ممکن ډیری وختونه د دوی پرتله کولو ته اړتیا ولرئ ترڅو وګورئ چې کوم معلومات په یو لیست کې ورک دي یا کوم معلومات په دواړو کې شتون لري. پرتله کول په ډیری بیلابیلو لارو ترسره کیدی شي - کوم میتود کارول کیږي په هغه څه پورې اړه لري چې تاسو یې غواړئ.

5>6>د VLOOKUP په کارولو سره په Excel کې دوه کالمونه څنګه پرتله کړئ

کله تاسو د ډیټا دوه کالمونه لرئ او غواړئ معلومه کړئ چې د یو لیست څخه کوم ډیټا ټکي په بل لیست کې شتون لري، تاسو کولی شئ د VLOOKUP فعالیت وکاروئ ترڅو د عام ارزښتونو لیست پرتله کړئ.

هم وګوره: په ګوګل شیټونو کې د اسعارو تبادله

د VLOOKUP فورمول جوړ کړئ بنسټیزه بڼه، دا هغه څه دي چې تاسو یې کولو ته اړتیا لرئ:

• د lookup_value (لومړی دلیل) لپاره، د لیست 1 څخه تر ټولو لوړ حجره وکاروئ.
• د <1 لپاره>table_array (دوهم دلیل)، ټول لیست 2 وړاندې کړئ.
• د col_index_num (دریم دلیل) لپاره، 1 وکاروئ ځکه چې په صف کې یوازې یو کالم شتون لري.
• د range_lookup (څلورم دلیل) لپاره، FALSE - دقیق میچ ترتیب کړئ.

فرض کړئ چې تاسو په A کالم کې د برخه اخیستونکو نومونه لرئ (1 لیست) او د هغو نومونه څوک چې د B کالم (لیست 2) کې د وړتیا دورې څخه تیر شوي دي. تاسو غواړئ دا 2 لیستونه پرتله کړئ ترڅو معلومه کړئ چې د ګروپ A څخه کوم ګډون کونکي اصلي پیښې ته لاره موندلې. د دې کولو لپاره، لاندې وکاروئفورمول.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

> 1> table_array د مطلق حوالې سره تړل شوی دی ($C$2:$C$9) نو دا ثابت پاتې کیږي کله چې تاسو لاندې حجرو ته فورمول کاپي کړئ.

لکه څنګه چې تاسو لیدلی شئ، د نومونو نومونه وړ ورزشکاران په E کالم کې ښودل کیږي. د پاتې برخه اخیستونکو لپاره، د #N/A تېروتنه ښکاري چې د دوی نومونه په 2 لیست کې شتون نلري.



پټو #N/ یوه تېروتنه

د VLOOKUP فورمول چې پورته بحث شوی په بشپړ ډول خپل اصلي هدف پوره کوي - ګډ ارزښتونه بیرته راګرځوي او د معلوماتو ورک شوي ټکي پیژني. په هرصورت، دا د #N/A غلطیو یوه ډله وړاندې کوي، کوم چې کیدای شي بې تجربه کاروونکي مغشوش کړي چې دوی فکر کوي چې په فورمول کې یو څه غلط دی.

د خالي حجرو سره د غلطیو بدلولو لپاره، VLOOKUP وکاروئ د IFNA یا IFERROR فعالیت سره په دې ډول ترکیب کې:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")



زموږ اصلاح شوی فورمول د #N/ پر ځای یو خالي تار ("") راګرځوي. الف تاسو کولی شئ خپل دودیز متن هم بیرته راولیږئ لکه "په لیست 2 کې نه دی"، "موجود ندی"، یا "د شتون نلري". د مثال په توګه:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

دا په Excel کې د دوه کالمونو پرتله کولو لپاره اصلي VLOOKUP فورمول دی. ستاسو د ځانګړي دندې پورې اړه لري، دا کولی شي بدلون ومومي لکه څنګه چې په نورو مثالونو کې ښودل شوي.

د VLOOKUP په کارولو سره په مختلف Excel شیټونو کې دوه کالمونه پرتله کړئ

په ریښتیني ژوند کې، کالمونه تاسود پرتله کولو اړتیا تل په ورته پاڼه کې نه وي. په یو کوچني ډیټاسیټ کې ، تاسو کولی شئ په لاسي ډول د دوه شیټونو په څنګ کې په لیدو سره د توپیرونو موندلو هڅه وکړئ.

د فورمولونو سره په بل ورکشاپ یا کاري کتاب کې د لټون لپاره، تاسو باید بهرنۍ حواله وکاروئ. غوره عمل دا دی چې په خپل اصلي پاڼه کې د فورمول ټایپ کول پیل کړئ، بیا بل ورک شیټ ته لاړ شئ او د موږک په کارولو سره لیست غوره کړئ - یو مناسب رینج حواله به په اتوماتيک ډول فورمول ته اضافه شي.

فرض کړئ لیست 1 دی په A کالم کې په Sheet1 کې او لیست 2 په کالم A کې په Sheet2 کې، تاسو کولی شئ دوه کالمونه پرتله کړئ او د دې فورمول په کارولو سره میچونه ومومئ:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")



د نورو معلوماتو لپاره، مهرباني وکړئ وګورئ:

• VLOOKUP د بل شیټ څخه
• VLOOKUP د مختلف کاري کتاب څخه

دوه کالمونه پرتله کړئ او ګډ ارزښتونه (میچونه) بیرته راوباسئ

په تیرو مثالونو کې، موږ د VLOOKUP فورمول په ساده بڼه بحث وکړ:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

د دې فورمول پایله ده د ارزښتونو لیست چې په دواړو کالمونو او خالي حجرو کې شتون لري د هغه ارزښتونو پرځای چې په دوهم کالم کې شتون نلري.

پرته له تشو څخه د عام ارزښتونو لیست ترلاسه کولو لپاره ، یوازې په پایله کې کالم ته اتومات فلټر اضافه کړئ او خالي ځایونه فلټر کړئ.



په Excel کې د مایکروسافټ 365 او Excel 2021 لپاره چې د متحرک صفونو پورته کول، تاسو کولی شئ د فلټر فنکشن څخه کار واخلئ ترڅو په متحرک ډول خالي ځایونه پاک کړئ. د دې لپاره، د IFNA VLOOKUP فورمول په توګه وکاروئد فلټر لپاره معیارونه:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

مهرباني وکړئ په دې حالت کې موږ ټول لیست 1 (A2:A14) د VLOOKUP دلیل lookup_value ته وړاندې کوو. فنکشن د لیست 2 (C2:C9) سره هر یو د لټون ارزښتونه پرتله کوي او د میچونو لړۍ او #N/A غلطۍ بیرته راګرځوي چې د ورک شوي ارزښتونو استازیتوب کوي. د IFNA فنکشن د خالي تارونو سره غلطۍ بدلوي او پایلې د FILTER فنکشن ته وړاندې کوي، کوم چې خالي ځایونه ("") فلټر کوي او د وروستۍ پایلې په توګه د میچونو لړۍ تولیدوي.



<0 په بدیل سره، تاسو کولی شئ د ISNA فعالیت وکاروئ ترڅو د VLOOKUP پایله وګورئ او هغه توکي فلټر کړئ چې ارزول کیږي FALSE ته، د بیلګې په توګه د #N/A غلطیو پرته نور ارزښتونه:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

ورته پایله کولی شي د XLOOKUP فنکشن سره ترلاسه کیدی شي، کوم چې فورمول نور هم ساده کوي. د XLOOKUP د وړتیا له امله چې په داخلي توګه د #N/A غلطیو اداره کول (اختیاري if_not_found دلیل)، موږ کولی شو د IFNA یا ISNA ریپر پرته ترسره کړو:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

پرتله دوه کالمونه او ورک شوي ارزښتونه ومومئ (توپیرونه)

د توپیرونو موندلو لپاره په Excel کې د 2 کالمونو پرتله کولو لپاره ، تاسو کولی شئ پدې ډول پرمخ لاړ شئ:

1. د لومړي لټون لپاره اصلي فورمول ولیکئ ارزښت د لیست 1 (A2) څخه په لیست 2 کې ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. نسټ دی پورته فورمول د ISNA فعالیت کې د #N/A غلطیو لپاره د VLOOKUP محصول چک کولو لپاره. د یوې تېروتنې په صورت کې، ISNA ریښتیا راوړي، که نه غلط:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. د IF فنکشن د منطقي ازموینې لپاره د ISNA VLOOKUP فورمول وکاروئ. که ازموینه سمه ارزونه وکړي (#N/A تېروتنه)، په ورته قطار کې د لیست 1 څخه یو ارزښت بیرته راستانه کړئ. که ازموینه ناسمه ارزونه وکړي (په لیست 2 کې یوه لوبه وموندل شوه)، یو خالي تار بیرته راګرځوئ.

بشپړ فورمول دا بڼه اخلي:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

د خالي ځایونو څخه د خلاصون لپاره ، د ایکسل فلټر پلي کړئ لکه څنګه چې پورته مثال کې ښودل شوي.



په Excel 365 او Excel 2021 کې ، تاسو کولی شئ د پایلو لیست په متحرک ډول فلټر کړئ. د دې لپاره، په ساده ډول د ISNA VLOOKUP فورمول د فلټر فنکشن دلیل شامل کړئ کې ځای په ځای کړئ:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

22>

بله لاره ده. د معیارونو لپاره XLOOKUP وکاروئ - فنکشن د ورک شوي ډیټا پوائنټونو لپاره خالي تارونه ("") بیرته راګرځوي، او تاسو په لیست 1 کې ارزښتونه فلټر کړئ د کوم لپاره چې XLOOKUP خالي تارونه (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

د VLOOKUP فورمول د دوو کالمونو ترمنځ د میچونو او توپیرونو پیژندلو لپاره

که تاسو غواړئ په لومړي لیست کې د متن لیبلونه اضافه کړئ چې دا په ګوته کوي چې کوم ارزښتونه په دویم لیست کې شتون لري او کوم ندي، د VLOOKUP فورمول سره یوځای وکاروئ. IF او ISNA/ISERROR فعالیت کوي.

د مثال په توګه، د نومونو پیژندلو لپاره چې په A او D دواړو کالمونو کې دي او هغه چې یوازې په A کالم کې دي، فورمول دا دی:

هم وګوره: په Excel کې د دوو حروفونو څخه مخکې، وروسته یا تر منځ متن لرې کړئ

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

دلته، د ISNA فنکشن د VLOOKUP لخوا رامینځته شوي #N/A تېروتنې نیسي او د دې لپاره IF فنکشن ته منځمهاله پایله لیږدوي.ټاکل شوی متن د تېروتنو لپاره او بل متن د بریالي لیدو لپاره بیرته راګرځوئ.

په دې مثال کې، موږ "وړ نه"/" وړ" لیبلونه کارولي، کوم چې زموږ د نمونې ډیټا سیټ لپاره مناسب دي. تاسو کولی شئ دوی د "په لیست کې 2 کې نه وي"/"په لیست 2 کې"، "د شتون نلري"/"موجود" یا کوم بل لیبل سره چې تاسو یې مناسب ګورئ بدل کړئ.

دا فورمول غوره دی چې په یوه کالم کې دننه شي. د لیست 1 سره نږدې او د ډیری حجرو له لارې کاپي شوي څومره چې ستاسو په لیست کې توکي شتون لري.

23>

په 2 کالمونو کې د میچونو او توپیرونو پیژندلو یوه بله لاره د MATCH فنکشن کارول دي:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

24>

2 کالمونه پرتله کړئ او له دریم څخه یو ارزښت بیرته راګرځئ

کله چې د اړونده معلوماتو لرونکي جدولونو سره کار کوئ، تاسو ممکن ځینې وختونه اړتیا ولرئ دوه کالمونه په دوه مختلف جدولونو کې پرتله کړئ او د بل کالم څخه ورته ارزښت بیرته راوباسئ. په حقیقت کې، دا د VLOOKUP فنکشن لومړنی کار دی، د هغه هدف لپاره چې ډیزاین شوی.

د مثال په توګه، په لاندې دوو جدولونو کې د A او D کالمونو نومونه پرتله کول او د کالم E څخه یو وخت بیرته راګرځول. , فورمول دا دی:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

25>

د #N/A غلطیو پټولو لپاره، ثابت حل وکاروئ - د IFNA فعالیت:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")



د خالي ځایونو پرځای، تاسو کولی شئ هر هغه متن چې تاسو یې د ورک شوي ډیټا پوائنټونو لپاره غواړئ بیرته راشئ - یوازې دا په وروستي دلیل کې ټایپ کړئ. د مثال په توګه:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

د VLOOKUP سربیره، دا دنده د یو څو نورو دندو سره سرته رسولی شي.

شخصي توګه، زه په ډیر انعطاف وړ INDEX باندې تکیه کومد میچ فورمول:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

یا د VLOOKUP عصري جانشین وکاروئ - د XLOOKUP فنکشن چې په Excel 365 او Excel 2021 کې شتون لري:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

ته د A ګروپ څخه د وړ ګډون کونکو نومونه او د دوی پایلې ترلاسه کړئ، په ساده ډول په B کالم کې خالي حجرې فلټر کړئ:

=FILTER(A3:B15, B3:B15"")

27>

د پرتله کولو وسیلې

که تاسو په پرله پسې ډول په Excel کې فایل یا ډیټا پرتله کوئ، دا سمارټ وسیلې چې زموږ په الټیمیټ سویټ کې شامل دي کولی شي ستاسو وخت په پراخه کچه خوندي کړي!

مقابلې جدولونه - د نقلونو (میچونو) او ځانګړي ارزښتونو (توپیرونو) موندلو چټکه لاره په هر دوه ډیټا سیټونو کې لکه کالمونه، لیست یا جدولونه.

دوه پاڼې پرتله کړئ - د دوو ورک شیټونو ترمنځ توپیرونه ومومئ او روښانه کړئ.

ډیری شیټونه پرتله کړئ - په یوځل کې په څو شیټونو کې توپیرونه ومومئ او روښانه کړئ .

د ډانلوډ لپاره د کار کتاب تمرین کړئ

په Excel کې VLOOKUP د کالمونو پرتله کولو لپاره - مثالونه (.xlsx فایل)