টিউটোরিয়ালটি দেখায় কিভাবে Excel-এ VLOOKUP সূত্র ব্যবহার করে সাধারণ মান (মিল) ফেরাতে বা অনুপস্থিত ডেটা (পার্থক্য) খুঁজে পেতে দুটি কলামের তুলনা করতে হয়।

যখন আপনার কাছে দুটি ডেটা থাকে বিভিন্ন তালিকা, তালিকাগুলির একটিতে কোন তথ্য অনুপস্থিত বা উভয়টিতে কোন ডেটা উপস্থিত রয়েছে তা দেখতে আপনাকে প্রায়শই তাদের তুলনা করতে হতে পারে। তুলনা বিভিন্ন উপায়ে করা যেতে পারে - কোন পদ্ধতিটি ব্যবহার করবেন তা নির্ভর করে আপনি এটি থেকে ঠিক কী চান তার উপর৷

VLOOKUP ব্যবহার করে কিভাবে Excel এ দুটি কলাম তুলনা করবেন

কখন আপনার কাছে দুটি কলাম ডেটা আছে এবং একটি তালিকার কোন ডেটা পয়েন্ট অন্য তালিকায় বিদ্যমান তা খুঁজে বের করতে চান, আপনি সাধারণ মানের তালিকার তুলনা করতে VLOOKUP ফাংশন ব্যবহার করতে পারেন।

এর মধ্যে একটি VLOOKUP সূত্র তৈরি করতে মৌলিক ফর্ম, এটি আপনাকে যা করতে হবে:

• lookup_value (1ম আর্গুমেন্ট) এর জন্য, তালিকা 1 থেকে শীর্ষ সেল ব্যবহার করুন।
• এর জন্য টেবিল_অ্যারে (২য় আর্গুমেন্ট), সম্পূর্ণ তালিকা ২ সরবরাহ করুন।
• এর জন্য col_index_num (৩য় আর্গুমেন্ট), 1 ব্যবহার করুন কারণ অ্যারেতে শুধুমাত্র একটি কলাম রয়েছে।
• রেঞ্জ_লুকআপ (৪র্থ আর্গুমেন্ট) এর জন্য, FALSE - সঠিক মিল সেট করুন।

ধরুন আপনার কলাম A (তালিকা 1) তে অংশগ্রহণকারীদের নাম এবং তাদের নাম রয়েছে যারা কলাম B (তালিকা 2) এর যোগ্যতা রাউন্ডের মধ্য দিয়ে গেছে। গ্রুপ A থেকে কোন অংশগ্রহণকারীরা মূল ইভেন্টে তাদের পথ তৈরি করেছে তা নির্ধারণ করতে আপনি এই 2টি তালিকার তুলনা করতে চান। এটি করার জন্য, নিম্নলিখিত ব্যবহার করুনসূত্র।

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

সূত্রটি E2 কক্ষে যায়, এবং তারপর আপনি তালিকা 1-এ যতগুলি আইটেম আছে ততগুলি কোষের মধ্যে দিয়ে নিচে টেনে আনেন।

দয়া করে লক্ষ্য করুন যে টেবিল_অ্যারে পরম রেফারেন্স ($C$2:$C$9) সহ লক করা হয়েছে যাতে আপনি নীচের কক্ষে সূত্রটি অনুলিপি করার সময় এটি স্থির থাকে।

যেমন আপনি দেখতে পাচ্ছেন, এর নাম যোগ্য ক্রীড়াবিদরা কলাম E-তে প্রদর্শিত হবে। অবশিষ্ট অংশগ্রহণকারীদের জন্য, একটি #N/A ত্রুটি দেখা যাচ্ছে যা নির্দেশ করে যে তাদের নাম তালিকা 2-এ উপলব্ধ নেই।

ছদ্মবেশ #N/ একটি ত্রুটি

উপরে আলোচনা করা VLOOKUP সূত্রটি পুরোপুরি তার মূল উদ্দেশ্য পূরণ করে - সাধারণ মান প্রদান করে এবং অনুপস্থিত ডেটা পয়েন্ট সনাক্ত করে। যাইহোক, এটি #N/A ত্রুটির একটি গুচ্ছ সরবরাহ করে, যা অনভিজ্ঞ ব্যবহারকারীদের বিভ্রান্ত করতে পারে যাতে তারা মনে করে যে সূত্রটিতে কিছু ভুল আছে।

ত্রুটিগুলিকে খালি কক্ষ দিয়ে প্রতিস্থাপন করতে, VLOOKUP ব্যবহার করুন IFNA বা IFERROR ফাংশনের সাথে এইভাবে:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

আমাদের উন্নত সূত্রটি #N/ এর পরিবর্তে একটি খালি স্ট্রিং ("") প্রদান করে ক. এছাড়াও আপনি আপনার কাস্টম পাঠ্য যেমন "তালিকা 2-এ নেই", "বর্তমান নেই", বা "উপলব্ধ নয়" ফেরত দিতে পারেন। উদাহরণস্বরূপ:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

এটি হল এক্সেলের দুটি কলাম তুলনা করার জন্য মৌলিক VLOOKUP সূত্র। আপনার নির্দিষ্ট কাজের উপর নির্ভর করে, আরও উদাহরণে দেখানো হিসাবে এটি পরিবর্তন করা যেতে পারে।

VLOOKUP ব্যবহার করে বিভিন্ন এক্সেল শীটে দুটি কলাম তুলনা করুন

বাস্তব জীবনে, কলামগুলি আপনিতুলনা করতে হবে সবসময় একই শীটে থাকে না। একটি ছোট ডেটাসেটে, আপনি পাশাপাশি দুটি শীট দেখে ম্যানুয়ালি পার্থক্যগুলি চিহ্নিত করার চেষ্টা করতে পারেন।

সূত্র সহ অন্য ওয়ার্কশীট বা ওয়ার্কবুকে অনুসন্ধান করতে, আপনাকে বাহ্যিক রেফারেন্স ব্যবহার করতে হবে। সর্বোত্তম অভ্যাস হল আপনার প্রধান শীটে সূত্রটি টাইপ করা শুরু করা, তারপরে অন্য ওয়ার্কশীটে স্যুইচ করুন এবং মাউস ব্যবহার করে তালিকাটি নির্বাচন করুন - একটি উপযুক্ত পরিসরের রেফারেন্স স্বয়ংক্রিয়ভাবে সূত্রটিতে যুক্ত হবে৷

অনুমান করা হচ্ছে তালিকা 1 কলাম A-তে শিট1 এবং তালিকা 2 আছে কলাম A-তে শিট2 , আপনি দুটি কলাম তুলনা করতে পারেন এবং এই সূত্রটি ব্যবহার করে মিল খুঁজে পেতে পারেন:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

আরো তথ্যের জন্য, অনুগ্রহ করে দেখুন:

• অন্য শীট থেকে VLOOKUP
• ভিন্ন ওয়ার্কবুক থেকে VLOOKUP

দুটি কলাম তুলনা করুন এবং সাধারণ মান (মিলগুলি) প্রদান করুন

পূর্ববর্তী উদাহরণগুলিতে, আমরা একটি VLOOKUP সূত্রটি তার সবচেয়ে সহজ আকারে আলোচনা করেছি:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

সেই সূত্রটির ফলাফল হল দ্বিতীয় কলামে উপলব্ধ নয় এমন মানগুলির জায়গায় কলাম এবং ফাঁকা কক্ষে বিদ্যমান মানগুলির একটি তালিকা৷

শূন্যতা ছাড়াই সাধারণ মানের একটি তালিকা পেতে, ফলাফল কলামে অটো-ফিল্টার যোগ করুন এবং খালি জায়গাগুলি ফিল্টার করুন৷

Excel-এ Microsoft 365 এবং Excel 2021 এর জন্য ডাইনামিক অ্যারে আপপোর্ট করুন, আপনি গতিশীলভাবে ফাঁকাগুলি বের করতে ফিল্টার ফাংশন ব্যবহার করতে পারেন। এর জন্য, IFNA VLOOKUP সূত্রটি হিসাবে ব্যবহার করুনফিল্টারের মানদণ্ড:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

দয়া করে মনোযোগ দিন যে এই ক্ষেত্রে আমরা VLOOKUP-এর lookup_value আর্গুমেন্টে সম্পূর্ণ তালিকা 1 (A2:A14) সরবরাহ করি। ফাংশনটি তালিকা 2 (C2:C9) এর সাথে প্রতিটি লুকআপ মানের তুলনা করে এবং অনুপস্থিত মানগুলি উপস্থাপন করে মিলের একটি অ্যারে এবং #N/A ত্রুটি প্রদান করে। IFNA ফাংশন খালি স্ট্রিংগুলির সাথে ত্রুটিগুলি প্রতিস্থাপন করে এবং FILTER ফাংশনে ফলাফলগুলি পরিবেশন করে, যা খালি ("") ফিল্টার করে এবং চূড়ান্ত ফলাফল হিসাবে মিলগুলির একটি অ্যারে আউটপুট করে৷

বিকল্পভাবে, আপনি ISNA ফাংশন ব্যবহার করে VLOOKUP-এর ফলাফল পরীক্ষা করতে পারেন এবং FALSE-এ মূল্যায়ন করা আইটেমগুলিকে ফিল্টার করতে পারেন, যেমন #N/A ত্রুটি ছাড়া অন্য মানগুলি:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

একই ফলাফল হতে পারে XLOOKUP ফাংশন দিয়ে অর্জন করা যায়, যা সূত্রটিকে আরও সহজ করে তোলে। XLOOKUP অভ্যন্তরীণভাবে #N/A ত্রুটিগুলি পরিচালনা করার ক্ষমতার কারণে (ঐচ্ছিক if_not_found যুক্তি), আমরা IFNA বা ISNA র্যাপার ছাড়া করতে পারি:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

তুলনা দুটি কলাম এবং অনুপস্থিত মানগুলি সন্ধান করুন (পার্থক্য)

পার্থক্য খুঁজে পেতে এক্সেলে 2টি কলাম তুলনা করতে, আপনি এইভাবে এগিয়ে যেতে পারেন:

1. প্রথমটি অনুসন্ধান করতে মূল সূত্রটি লিখুন তালিকা 2 এর তালিকা 1 (A2) থেকে মান ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. নেস্ট দ্য #N/A ত্রুটির জন্য VLOOKUP-এর আউটপুট পরীক্ষা করতে ISNA ফাংশনে উপরের সূত্রটি। একটি ত্রুটির ক্ষেত্রে, ISNA থেকে সত্য পাওয়া যায়, অন্যথায় FALSE:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. IF ফাংশনের লজিক্যাল পরীক্ষার জন্য ISNA VLOOKUP সূত্রটি ব্যবহার করুন। যদি পরীক্ষাটি সত্যে মূল্যায়ন করে (#N/A ত্রুটি), একই সারিতে তালিকা 1 থেকে একটি মান ফেরত দিন। যদি পরীক্ষাটি FALSE তে মূল্যায়ন করে (তালিকা 2 এ একটি মিল পাওয়া যায়), একটি খালি স্ট্রিং ফেরত দিন।

সম্পূর্ণ সূত্রটি এই ফর্মটি নেয়:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

খালি জায়গাগুলি থেকে পরিত্রাণ পেতে, উপরের উদাহরণে প্রদর্শিত হিসাবে এক্সেলের ফিল্টার প্রয়োগ করুন৷

Excel 365 এবং Excel 2021-এ, আপনি ফলাফলের তালিকাটি গতিশীলভাবে ফিল্টার করতে পারেন৷ এর জন্য, FILTER ফাংশনের include আর্গুমেন্টে ISNA VLOOKUP সূত্রটি রাখুন:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

অন্য উপায় হল মানদণ্ডের জন্য XLOOKUP ব্যবহার করুন - ফাংশনটি অনুপস্থিত ডেটা পয়েন্টের জন্য খালি স্ট্রিং ("") প্রদান করে এবং আপনি তালিকা 1-এর মানগুলি ফিল্টার করেন যার জন্য XLOOKUP খালি স্ট্রিংগুলি (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

দুটি কলামের মধ্যে মিল এবং পার্থক্য সনাক্ত করতে VLOOKUP সূত্র

যদি আপনি প্রথম তালিকায় পাঠ্য লেবেল যোগ করতে চান যা নির্দেশ করে যে কোন মানগুলি দ্বিতীয় তালিকায় উপলব্ধ এবং কোনটি নয়, তাহলে VLOOKUP সূত্রটি একসাথে ব্যবহার করুন IF এবং ISNA/ISERROR ফাংশন।

উদাহরণস্বরূপ, যে নামগুলি A এবং D উভয় কলামে আছে এবং যেগুলি শুধুমাত্র A কলামে আছে, সেই নামগুলি সনাক্ত করতে, সূত্রটি হল:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

এখানে, ISNA ফাংশন VLOOKUP দ্বারা উত্পন্ন #N/A ত্রুটিগুলি ক্যাচ করে এবং সেই মধ্যবর্তী ফলাফলটি এটির জন্য IF ফাংশনে পাস করেত্রুটির জন্য নির্দিষ্ট টেক্সট এবং সফল লুকআপের জন্য অন্য একটি টেক্সট ফেরত দিন।

এই উদাহরণে, আমরা "যোগ্য নয়"/"যোগ্য" লেবেল ব্যবহার করেছি, যা আমাদের নমুনা ডেটাসেটের জন্য উপযুক্ত। আপনি এগুলিকে "তালিকা 2-এ নেই"/"তালিকা 2-এ", "উপলব্ধ নয়"/"উপলব্ধ" বা অন্য যেকোনও লেবেল দিয়ে প্রতিস্থাপন করতে পারেন।

এই সূত্রটি একটি কলামে ঢোকানো ভাল তালিকা 1 এর সংলগ্ন এবং আপনার তালিকায় যতগুলি আইটেম রয়েছে ততগুলি কক্ষের মাধ্যমে অনুলিপি করা হয়েছে৷

2টি কলামে মিল এবং পার্থক্য সনাক্ত করার আরও একটি উপায় হল MATCH ফাংশন ব্যবহার করা:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

2টি কলাম তুলনা করুন এবং তৃতীয় থেকে একটি মান ফেরত দিন

সম্পর্কিত ডেটা সম্বলিত সারণীগুলির সাথে কাজ করার সময়, আপনাকে কখনও কখনও প্রয়োজন হতে পারে দুটি ভিন্ন টেবিলে দুটি কলাম তুলনা করুন এবং অন্য একটি কলাম থেকে একটি মিলিত মান ফেরত দিন। প্রকৃতপক্ষে, এটি VLOOKUP ফাংশনের প্রাথমিক ব্যবহার, যে উদ্দেশ্যে এটি ডিজাইন করা হয়েছিল।

উদাহরণস্বরূপ, নীচের দুটি টেবিলের কলাম A এবং D-এ নাম তুলনা করা এবং কলাম E থেকে একটি সময় ফেরত দেওয়া , সূত্রটি হল:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

#N/A ত্রুটিগুলি আড়াল করতে, প্রমাণিত সমাধানটি ব্যবহার করুন - IFNA ফাংশন:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

খালি স্থানের পরিবর্তে, আপনি হারিয়ে যাওয়া ডেটা পয়েন্টের জন্য যে কোনও পাঠ্য ফেরত দিতে পারেন - শুধু শেষ আর্গুমেন্টে এটি টাইপ করুন। উদাহরণস্বরূপ:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

VLOOKUP ছাড়াও, কাজটি আরও কয়েকটি লুকআপ ফাংশন দিয়ে সম্পন্ন করা যেতে পারে।

ব্যক্তিগতভাবে, আমি আরও নমনীয় INDEX-এর উপর নির্ভর করবম্যাচ সূত্র:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

অথবা VLOOKUP-এর আধুনিক উত্তরসূরী ব্যবহার করুন - XLOOKUP ফাংশন, Excel 365 এবং Excel 2021-এ উপলব্ধ:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

প্রতি গ্রুপ A থেকে যোগ্য অংশগ্রহণকারীদের নাম এবং তাদের ফলাফল পান, কেবল B কলামে ফাঁকা ঘরগুলিকে ফিল্টার করুন:

=FILTER(A3:B15, B3:B15"")

তুলনা সরঞ্জাম

আপনি যদি এক্সেলে প্রায়শই ফাইল বা ডেটা তুলনা করেন, তাহলে আমাদের আলটিমেট স্যুটে অন্তর্ভুক্ত এই স্মার্ট টুলগুলি আপনার সময় বাঁচাতে পারে!

টেবিল তুলনা করুন - ডুপ্লিকেট (মিল) এবং অনন্য মান (পার্থক্য) খুঁজে বের করার দ্রুত উপায় কলাম, তালিকা বা টেবিলের মতো যেকোনো দুটি ডেটা সেটে।

দুটি পত্রকের তুলনা করুন - দুটি ওয়ার্কশীটের মধ্যে পার্থক্য খুঁজুন এবং হাইলাইট করুন।

একাধিক পত্রকের তুলনা করুন - একাধিক পত্রকের মধ্যে পার্থক্যগুলি একবারে খুঁজুন এবং হাইলাইট করুন