El tutorial mostra com utilitzar la fórmula BUSCAR V a Excel per comparar dues columnes per retornar valors comuns (coincidències) o trobar dades que falten (diferències).

Quan teniu dades en dos diferents llistes, sovint haureu de comparar-les per veure quina informació falta en una de les llistes o quines dades hi ha en totes dues. La comparació es pot fer de moltes maneres diferents: quin mètode s'utilitza depèn exactament del que en vulgueu.

Com comparar dues columnes a Excel mitjançant BUSCAR V

Quan tens dues columnes de dades i vols esbrinar quins punts de dades d'una llista existeixen a l'altra llista, pots utilitzar la funció BUSCAR V per comparar les llistes de valors comuns.

Per crear una fórmula BUSCAR V en la seva llista. forma bàsica, això és el que heu de fer:

• Per a valor_cerca (1r argument), utilitzeu la cel·la superior de la llista 1.
• Per a table_array (segon argument), proporcioneu tota la llista 2.
• Per a col_index_num (3r argument), utilitzeu 1 ja que només hi ha una columna a la matriu.
• Per a range_lookup (4t argument), establiu FALSE - coincidència exacta.

Suposem que teniu els noms dels participants a la columna A (Llista 1) i els noms d'aquests. que hagin superat les rondes de classificació de la columna B (Llista 2). Voleu comparar aquestes 2 llistes per determinar quins participants del grup A van arribar a l'esdeveniment principal. Per fer-ho, utilitzeu el següentfórmula.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

La fórmula va a la cel·la E2 i, a continuació, l'arrossegueu cap avall per tantes cel·les com elements hi hagi a la llista 1.

Si us plau, tingueu en compte que table_array està bloquejat amb referències absolutes ($C$2:$C$9) de manera que es mantingui constant quan copieu la fórmula a les cel·les següents.

Com podeu veure, els noms dels els atletes qualificats apareixen a la columna E. Per als participants restants, apareix un error #N/A que indica que els seus noms no estan disponibles a la llista 2.

Disfressa #N/ Errors

La fórmula BUSCAR V que s'ha comentat anteriorment compleix perfectament el seu objectiu principal: retorna valors comuns i identifica els punts de dades que falten. Tanmateix, ofereix un munt d'errors #N/A, que poden confondre els usuaris sense experiència fent-los pensar que hi ha alguna cosa malament amb la fórmula.

Per substituir els errors per cel·les en blanc , feu servir BUSCAR V. en combinació amb la funció IFNA o IFERROR d'aquesta manera:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

La nostra fórmula millorada retorna una cadena buida ("") en lloc de #N/ A. També podeu tornar el vostre text personalitzat com ara "No a la llista 2", "No present" o "No disponible". Per exemple:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Aquesta és la fórmula bàsica de BUSCAR V per comparar dues columnes a Excel. Depenent de la vostra tasca particular, es pot modificar tal com es mostra en exemples addicionals.

Compareu dues columnes en diferents fulls d'Excel mitjançant BUSCARV

En la vida real, les columnes quecal comparar no sempre estan al mateix full. En un conjunt de dades petit, podeu provar de detectar les diferències manualment visualitzant dos fulls junts.

Per cercar en un altre full de treball o llibre de treball amb fórmules, heu d'utilitzar una referència externa. La millor pràctica és començar a escriure la fórmula al full principal, després canviar a l'altre full de treball i seleccionar la llista amb el ratolí; una referència d'interval adequada s'afegirà automàticament a la fórmula.

Suposant que la llista 1 és a la columna A del Full1 i la llista 2 a la columna A del Full2 , podeu comparar dues columnes i trobar coincidències amb aquesta fórmula:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Per obtenir més informació, consulteu:

• CERCA V d'un altre full
• CERCA V d'un llibre de treball diferent

Compareu dues columnes i retorneu valors comuns (coincidències)

En els exemples anteriors, vam parlar d'una fórmula BUSCAR V en la seva forma més simple:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

El resultat d'aquesta fórmula és una llista de valors que existeixen a les dues columnes i cel·les en blanc en lloc dels valors no disponibles a la segona columna.

Per obtenir una llista de valors comuns sense espais, només cal que afegiu un filtre automàtic a la columna resultant i filtreu els espais en blanc.

A Excel per a Microsoft 365 i Excel 2021, això és suportar matrius dinàmiques, podeu fer servir la funció FILTER per filtrar els espais en blanc de manera dinàmica. Per a això, utilitzeu la fórmula IFNA VLOOKUP com acriteris per a FILTRE:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Si us plau, tingueu en compte que en aquest cas proporcionem tota la llista 1 (A2:A14) a l'argument lookup_value de BUSCARV. La funció compara cadascun dels valors de cerca amb la llista 2 (C2:C9) i retorna una matriu de coincidències i errors #N/A que representen els valors que falten. La funció IFNA substitueix els errors per cadenes buides i envia els resultats a la funció FILTER, que filtra els espais en blanc ("") i genera una matriu de coincidències com a resultat final.

Com a alternativa, podeu utilitzar la funció ISNA per comprovar el resultat de VLOOKUP i filtrar els elements que s'avaluen com a FALSE, és a dir, valors diferents dels errors #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

El mateix resultat pot s'aconsegueix amb la funció XLOOKUP, que fa que la fórmula sigui encara més senzilla. A causa de la capacitat de XLOOKUP per gestionar els errors #N/A internament (argument opcional if_not_found ), podem prescindir de l'embolcall IFNA o ISNA:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Compara dues columnes i trobar els valors que falten (diferències)

Per comparar 2 columnes a Excel per trobar diferències, podeu procedir d'aquesta manera:

1. Escriu la fórmula bàsica per cercar la primera valor de la Llista 1 (A2) a la Llista 2 ($C$2:$C$9):

   CERCA V(A2, $C$2:$C$9, 1, FALSE)

2. Anuleu el fórmula anterior a la funció ISNA per comprovar la sortida de VLOOKUP per a errors #N/A. En cas d'error, ISNA dóna TRUE, en cas contrari FALSE:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. Utilitzeu la fórmula ISNA VLOOKUP per a la prova lògica de la funció SI. Si la prova s'avalua com a TRUE (error #N/A), retorneu un valor de la llista 1 a la mateixa fila. Si la prova s'avalua com a FALSA (es troba una coincidència a la llista 2), retorneu una cadena buida.

La fórmula completa pren aquesta forma:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Per desfer-se dels espais en blanc, apliqueu el filtre d'Excel tal com es mostra a l'exemple anterior.

A Excel 365 i Excel 2021, podeu filtrar la llista de resultats de manera dinàmica. Per a això, simplement col·loqueu la fórmula ISNA VLOOKUP a l'argument include de la funció FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Una altra manera és utilitzeu XLOOKUP per als criteris: la funció retorna cadenes buides ("") per als punts de dades que falten i filtreu els valors de la llista 1 per als quals XLOOKUP ha retornat cadenes buides (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Fórmula BUSCAR V per identificar coincidències i diferències entre dues columnes

Si voleu afegir etiquetes de text a la primera llista indicant quins valors estan disponibles a la segona llista i quins no, utilitzeu la fórmula BUSCAR V juntament amb el Funcions IF i ISNA/ISERROR.

Per exemple, per identificar noms que es troben a les columnes A i D i els que només es troben a la columna A, la fórmula és:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Aquí, la funció ISNA captura els errors #N/A generats per BUSCARV i passa aquest resultat intermedi a la funció SI perquèretorna el text especificat per a errors i un altre text per a cerques correctes.

En aquest exemple, hem utilitzat etiquetes "No qualificat"/"Qualificat", que són adequades per al nostre conjunt de dades de mostra. Podeu substituir-los per "No a la llista 2"/"A la llista 2", "No disponible"/"Disponible" o qualsevol altra etiqueta que considereu adequada.

Aquesta fórmula és millor inserir-la en una columna. adjacent a la llista 1 i copiat a través de tantes cel·les com elements hi ha a la llista.

Una manera més d'identificar coincidències i diferències en 2 columnes és utilitzar la funció COINCORDA:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Compara 2 columnes i retorna un valor de la tercera

Quan treballes amb taules que contenen dades relacionades, és possible que de vegades hagis de compareu dues columnes en dues taules diferents i retorneu un valor coincident d'una altra columna. De fet, és l'ús principal de la funció BUSCAR V, el propòsit per al qual va ser dissenyada.

Per exemple, per comparar els noms de les columnes A i D a les dues taules següents i retornar un temps de la columna E , la fórmula és:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Per amagar errors #N/A, utilitzeu la solució provada: la funció IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

En lloc d'espais en blanc, podeu tornar el text que vulgueu per als punts de dades que falten; només heu d'escriure-lo a l'últim argument. Per exemple:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

A més de VLOOKUP, la tasca es pot complir amb algunes altres funcions de cerca.

Personalment, confiaria en un INDEX més flexible.Fórmula COINCIDENT:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

O utilitzeu el successor modern de BUSCARV: la funció BUSCAR XL, disponible a Excel 365 i Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Per obteniu els noms dels participants qualificats del grup A i els seus resultats, només heu de filtrar les cel·les en blanc de la columna B:

=FILTER(A3:B15, B3:B15"")

Eines de comparació

Si feu freqüentment comparacions de fitxers o dades a Excel, aquestes eines intel·ligents incloses a la nostra Suite Ultimate us poden estalviar molt temps!

Taules de comparació: manera ràpida de trobar duplicats (coincidències) i valors únics (diferències) en dos conjunts de dades, com ara columnes, llistes o taules.

Compara dos fulls: cerca i destaca les diferències entre dos fulls de treball.

Compara diversos fulls: troba i destaca les diferències en diversos fulls alhora. .

Practiqueu el llibre de treball per baixar

VLOOKUP a Excel per comparar columnes - exemples (fitxer .xlsx)