Падручнік паказвае, як выкарыстоўваць формулу VLOOKUP у Excel для параўнання двух слупкоў для вяртання агульных значэнняў (супадзенняў) або пошуку адсутных даных (адрозненняў).

Калі ў вас ёсць даныя ў двух слупках розныя спісы, часта вам можа спатрэбіцца параўнаць іх, каб убачыць, якой інфармацыі не хапае ў адным са спісаў або якія даныя прысутнічаюць у абодвух. Параўнанне можна зрабіць рознымі спосабамі - які метад выкарыстоўваць, залежыць ад таго, што менавіта вы хочаце ад яго.

Як параўнаць два слупкі ў Excel з дапамогай VLOOKUP

Калі у вас ёсць два слупкі даных і вы хочаце даведацца, якія пункты даных з аднаго спісу існуюць у іншым спісе, вы можаце выкарыстоўваць функцыю VLOOKUP, каб параўнаць спісы на агульныя значэнні.

Каб пабудаваць формулу VLOOKUP у сваім асноўная форма, вось што вам трэба зрабіць:

• Для значэння пошуку (1-ы аргумент) выкарыстоўвайце самую верхнюю ячэйку са спісу 1.
• Для table_array (2-і аргумент), падайце ўвесь спіс 2.
• Для col_index_num (3-ці аргумент) выкарыстоўвайце 1, бо ў масіве толькі адзін слупок.
• Для range_lookup (4-ы аргумент) усталюйце FALSE - дакладнае супадзенне.

Выкажам здагадку, у вас ёсць імёны ўдзельнікаў у слупку A (Спіс 1) і імёны іх якія прайшлі кваліфікацыйныя туры ў графе Б (Спіс 2). Вы хочаце параўнаць гэтыя 2 спісы, каб вызначыць, якія ўдзельнікі з групы А прабіліся ў галоўную падзею. Для гэтага скарыстайцеся наступнымформула.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Формула пераходзіць у ячэйку E2, а затым вы перацягваеце яе ўніз праз столькі вочак, колькі элементаў у спісе 1.

Звярніце ўвагу, што table_array заблакаваны абсалютнымі спасылкамі ($C$2:$C$9), так што ён застаецца нязменным, калі вы капіюеце формулу ў наступныя ячэйкі.

Як бачыце, назвы кваліфікаваныя спартсмены паказваюцца ў калонцы E. Для астатніх удзельнікаў з'яўляецца памылка #N/A, якая паказвае, што іх імёны недаступныя ў спісе 2.

Маскіроўка #N/ Памылкі

Разгледжаная вышэй формула VLOOKUP выдатна выконвае сваю асноўную задачу - вяртае агульныя значэнні і вызначае адсутныя пункты даных. Тым не менш, ён выдае кучу памылак #N/A, якія могуць збянтэжыць нявопытных карыстальнікаў і прымусіць іх падумаць, што з формулай нешта не так.

Каб замяніць памылкі пустымі ячэйкамі , выкарыстоўвайце VLOOKUP у спалучэнні з функцыяй IFNA або IFERROR такім чынам:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Наша палепшаная формула вяртае пусты радок ("") замест #N/ А. Вы таксама можаце вярнуць свой карыстальніцкі тэкст , напрыклад "Няма ў спісе 2", "Няма" ці "Недаступна". Напрыклад:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Гэта асноўная формула VLOOKUP для параўнання двух слупкоў у Excel. У залежнасці ад вашай канкрэтнай задачы яго можна змяніць, як паказана ў далейшых прыкладах.

Параўнайце два слупкі ў розных аркушах Excel з дапамогай VLOOKUP

У рэальным жыцці слупкі, якія вытрэба параўноўваць не заўсёды на адным аркушы. У невялікім наборы даных вы можаце паспрабаваць выявіць адрозненні ўручную, праглядаючы два аркушы побач.

Каб шукаць у іншым аркушы або кнізе з формуламі, вы павінны выкарыстоўваць знешнюю спасылку. Найлепшая практыка - пачаць уводзіць формулу на галоўным аркушы, затым пераключыцца на іншы аркуш і выбраць спіс з дапамогай мышы - адпаведная спасылка на дыяпазон будзе дададзена ў формулу аўтаматычна.

Калі выказаць здагадку, што спіс 1 з'яўляецца у слупку A на Sheet1 і спіс 2 знаходзіцца ў слупку A на Sheet2 , вы можаце параўнаць два слупкі і знайсці супадзенні з дапамогай гэтай формулы:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Для атрымання дадатковай інфармацыі, калі ласка, глядзіце:

• VLOOKUP з іншага аркуша
• VLOOKUP з іншай кнігі

Параўнанне двух слупкоў і вяртанне агульных значэнняў (супадзенняў)

У папярэдніх прыкладах мы абмяркоўвалі формулу VLOOKUP у яе самай простай форме:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Вынік гэтай формулы: спіс значэнняў, якія існуюць як у слупках, так і ў пустых ячэйках замест значэнняў, недаступных у другім слупку.

Каб атрымаць спіс агульных значэнняў без прабелаў, проста дадайце аўтаматычны фільтр да атрыманага слупка і адфільтраваць прабелы.

У Excel для Microsoft 365 і Excel 2021 гэта падтрымліваць дынамічныя масівы, вы можаце выкарыстоўваць функцыю FILTER, каб дынамічна адсеяць прабелы. Для гэтага выкарыстоўвайце формулу IFNA VLOOKUP у якасцікрытэрыі для FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Звярніце ўвагу, што ў гэтым выпадку мы пастаўляем увесь спіс 1 (A2:A14) у аргумент lookup_value VLOOKUP. Функцыя параўноўвае кожнае з значэнняў пошуку са спісам 2 (C2:C9) і вяртае масіў супадзенняў і памылак #N/A, якія прадстаўляюць адсутныя значэнні. Функцыя IFNA замяняе памылкі пустымі радкамі і перадае вынікі функцыі FILTER, якая адфільтроўвае прабелы ("") і выводзіць масіў супадзенняў у якасці канчатковага выніку.

У якасці альтэрнатывы вы можаце выкарыстоўваць функцыю ISNA, каб праверыць вынік VLOOKUP і адфільтраваць элементы з ацэнкай FALSE, г.зн. значэнні, адрозныя ад памылак #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Той самы вынік можа быць дасягнута з дапамогай функцыі XLOOKUP, што робіць формулу яшчэ больш простай. Дзякуючы здольнасці XLOOKUP унутрана апрацоўваць памылкі #N/A (неабавязковы аргумент if_not_found ), мы можам абысціся без абгорткі IFNA або ISNA:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Параўнаць два слупкі і знайдзіце адсутныя значэнні (адрозненні)

Каб параўнаць 2 слупкі ў Excel, каб знайсці адрозненні, вы можаце паступіць наступным чынам:

1. Напішыце асноўную формулу для пошуку першага значэнне са спісу 1 (A2) у спісе 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Укладзіце прыведзеная вышэй формула ў функцыі ISNA, каб праверыць выхад VLOOKUP на наяўнасць памылак #N/A. У выпадку памылкі ISNA выдае TRUE, у адваротным выпадку FALSE:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. Выкарыстоўвайце формулу ISNA VLOOKUP для лагічнай праверкі функцыі КАЛІ. Калі тэст дае значэнне TRUE (памылка #N/A), вярніце значэнне са спісу 1 у тым жа радку. Калі тэст дае ацэнку FALSE (знойдзена супадзенне ў спісе 2), верне пусты радок.

Поўная формула прымае наступны выгляд:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Каб пазбавіцца ад прабелаў, прымяніце фільтр Excel, як паказана ў прыкладзе вышэй.

У Excel 365 і Excel 2021 вы можаце дынамічна фільтраваць спіс вынікаў. Для гэтага проста змясціце формулу ISNA VLOOKUP у аргумент include функцыі FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Іншы спосаб - выкарыстоўвайце XLOOKUP для крытэраў - функцыя вяртае пустыя радкі ("") для адсутных пунктаў даных, і вы фільтруеце значэнні ў спісе 1, для якіх XLOOKUP вярнуў пустыя радкі (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Формула VLOOKUP для вызначэння супадзенняў і адрозненняў паміж двума слупкамі

Калі вы хочаце дадаць тэкставыя меткі ў першы спіс, якія паказваюць, якія значэнні даступныя ў другім спісе, а якія не, выкарыстоўвайце формулу VLOOKUP разам з Функцыі IF і ISNA/ISERROR.

Напрыклад, для ідэнтыфікацыі імёнаў, якія знаходзяцца як у слупках A, так і ў D, і тых, якія знаходзяцца толькі ў слупку A, формула:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Тут функцыя ISNA вылоўлівае памылкі #N/A, створаныя VLOOKUP, і перадае гэты прамежкавы вынік у функцыю IF, каб яна маглавяртае ўказаны тэкст для памылак і іншы тэкст для паспяховых пошукаў.

У гэтым прыкладзе мы выкарыстоўвалі меткі «Не кваліфікавана»/«Кваліфікавана», якія падыходзяць для нашага ўзору набору даных. Вы можаце замяніць іх на «Няма ў спісе 2»/«У спісе 2», «Недаступна»/«Даступна» або любымі іншымі цэтлікамі, якія вы лічыце патрэбнымі.

Гэтую формулу лепш за ўсё ўставіць у слупок побач са спісам 1 і скапіраваны праз столькі вочак, колькі элементаў у вашым спісе.

Яшчэ адзін спосаб вызначыць супадзенні і адрозненні ў 2 слупках - гэта выкарыстанне функцыі MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Параўнаць 2 слупкі і вярнуць значэнне з трэцяга

Пры працы з табліцамі, якія змяшчаюць звязаныя даныя, часам можа спатрэбіцца параўнаць два слупкі ў дзвюх розных табліцах і вярнуць адпаведнае значэнне з іншага слупка. Фактычна, гэта асноўнае выкарыстанне функцыі VLOOKUP, мэта, для якой яна была распрацавана.

Напрыклад, каб параўнаць імёны ў слупках A і D у дзвюх табліцах ніжэй і вярнуць час са слупка E , формула:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Каб схаваць памылкі #N/A, выкарыстоўвайце праверанае рашэнне - функцыю IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Замест прабелаў вы можаце вярнуць любы тэкст для адсутных пунктаў даных - проста ўвядзіце яго ў апошні аргумент. Напрыклад:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Акрамя VLOOKUP, задача можа быць выканана з дапамогай некалькіх іншых функцый пошуку.

Асабіста я хацеў бы спадзявацца на больш гнуткі INDEXMATCH formula:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Або выкарыстоўвайце сучасную пераемніцу VLOOKUP - функцыю XLOOKUP, даступную ў Excel 365 і Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Каб атрымаць імёны кваліфікаваных удзельнікаў з групы A і іх вынікі, проста адфільтраваць пустыя клеткі ў слупку B:

=FILTER(A3:B15, B3:B15"")

Інструменты параўнання

Калі вы часта параўноўваеце файлы або дадзеныя ў Excel, гэтыя разумныя інструменты, уключаныя ў наш Ultimate Suite, могуць значна зэканоміць ваш час!

Параўнанне табліц - хуткі спосаб знайсці дублікаты (супадзенні) і ўнікальныя значэнні (адрозненні) у любых двух наборах даных, такіх як слупкі, спісы або табліцы.

Параўнанне двух аркушаў - знайдзіце і вылучыце адрозненні паміж двума аркушамі.

Параўнайце некалькі аркушаў - знайдзіце і вылучыце адрозненні на некалькіх аркушах адначасова .

Практычны сшытак для загрузкі

ВПР у Excel для параўнання слупкоў - прыклады (файл .xlsx)