പൊതു മൂല്യങ്ങൾ (പൊരുത്തങ്ങൾ) നൽകുന്നതിന് അല്ലെങ്കിൽ നഷ്ടപ്പെട്ട ഡാറ്റ (വ്യത്യാസങ്ങൾ) കണ്ടെത്തുന്നതിന് രണ്ട് നിരകൾ താരതമ്യം ചെയ്യാൻ Excel-ൽ VLOOKUP ഫോർമുല എങ്ങനെ ഉപയോഗിക്കാമെന്ന് ട്യൂട്ടോറിയൽ കാണിക്കുന്നു.

നിങ്ങൾക്ക് രണ്ടിൽ ഡാറ്റ ഉള്ളപ്പോൾ. വ്യത്യസ്‌ത ലിസ്‌റ്റുകൾ, ലിസ്റ്റുകളിലൊന്നിൽ എന്ത് വിവരമാണ് നഷ്‌ടമായതെന്നോ രണ്ടിലും ഏത് ഡാറ്റയാണ് ഉള്ളതെന്നോ കാണാൻ നിങ്ങൾ അവ താരതമ്യം ചെയ്യേണ്ടതായി വന്നേക്കാം. താരതമ്യം പല തരത്തിൽ ചെയ്യാം - ഏത് രീതിയാണ് ഉപയോഗിക്കേണ്ടത് എന്നതിനെ ആശ്രയിച്ചിരിക്കും.

VLOOKUP ഉപയോഗിച്ച് Excel-ലെ രണ്ട് നിരകൾ എങ്ങനെ താരതമ്യം ചെയ്യാം

എപ്പോൾ നിങ്ങൾക്ക് രണ്ട് കോളം ഡാറ്റയുണ്ട്, ഒരു ലിസ്റ്റിൽ നിന്നുള്ള ഡാറ്റാ പോയിന്റുകൾ മറ്റേ ലിസ്റ്റിൽ ഉണ്ടെന്ന് കണ്ടെത്താൻ ആഗ്രഹിക്കുന്നു, പൊതുവായ മൂല്യങ്ങൾക്കായുള്ള ലിസ്റ്റുകൾ താരതമ്യം ചെയ്യാൻ നിങ്ങൾക്ക് VLOOKUP ഫംഗ്ഷൻ ഉപയോഗിക്കാം.

അതിൽ ഒരു VLOOKUP ഫോർമുല നിർമ്മിക്കുന്നതിന്. അടിസ്ഥാന ഫോം, നിങ്ങൾ ചെയ്യേണ്ടത് ഇതാണ്:

• lookup_value (1st ആർഗ്യുമെന്റ്), ലിസ്റ്റ് 1-ൽ നിന്ന് ഏറ്റവും ഉയർന്ന സെൽ ഉപയോഗിക്കുക.
• <1-ന്>table_array (രണ്ടാം ആർഗ്യുമെന്റ്), മുഴുവൻ ലിസ്റ്റ് 2 നൽകൂ.
• col_index_num (3rd ആർഗ്യുമെന്റ്), അറേയിൽ ഒരു കോളം മാത്രമുള്ളതിനാൽ 1 ഉപയോഗിക്കുക.
• range_lookup (4th ആർഗ്യുമെന്റ്), FALSE - കൃത്യമായ പൊരുത്തം സജ്ജമാക്കുക.

നിങ്ങൾക്ക് A കോളത്തിൽ (ലിസ്റ്റ് 1) പങ്കാളികളുടെ പേരുകളും അവരുടെ പേരുകളും ഉണ്ടെന്ന് കരുതുക. ബി കോളത്തിലെ (ലിസ്റ്റ് 2) യോഗ്യതാ റൗണ്ടുകളിലൂടെ കടന്നു പോയവർ. പ്രധാന ഇവന്റിലേക്ക് ഗ്രൂപ്പ് എയിൽ നിന്ന് ഏതൊക്കെ പങ്കാളികളാണ് എത്തിയതെന്ന് നിർണ്ണയിക്കാൻ ഈ 2 ലിസ്റ്റുകൾ താരതമ്യം ചെയ്യാൻ നിങ്ങൾ ആഗ്രഹിക്കുന്നു. ഇത് ചെയ്യുന്നതിന്, ഇനിപ്പറയുന്നവ ഉപയോഗിക്കുകഫോർമുല.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

ഫോർമുല E2 സെല്ലിലേക്ക് പോകുന്നു, തുടർന്ന് ലിസ്റ്റ് 1-ൽ എത്ര ഇനങ്ങളുണ്ടോ അത്രയും സെല്ലുകളിലൂടെ നിങ്ങൾ അത് താഴേക്ക് വലിച്ചിടുക.

ദയവായി അത് ശ്രദ്ധിക്കുക table_array സമ്പൂർണ്ണ റഫറൻസുകളാൽ ($C$2:$C$9) ലോക്ക് ചെയ്‌തിരിക്കുന്നതിനാൽ നിങ്ങൾ ഫോർമുല ചുവടെയുള്ള സെല്ലുകളിലേക്ക് പകർത്തുമ്പോൾ അത് സ്ഥിരമായി നിലനിൽക്കും.

നിങ്ങൾക്ക് കാണാനാകുന്നതുപോലെ, ഇതിന്റെ പേരുകൾ യോഗ്യതയുള്ള അത്‌ലറ്റുകൾ E കോളത്തിൽ കാണിക്കുന്നു. ശേഷിക്കുന്ന പങ്കാളികൾക്ക്, അവരുടെ പേരുകൾ ലിസ്റ്റ് 2 ൽ ലഭ്യമല്ലെന്ന് സൂചിപ്പിക്കുന്ന ഒരു #N/A പിശക് ദൃശ്യമാകുന്നു.

Disguise #N/ ഒരു പിശക്

മുകളിൽ ചർച്ച ചെയ്ത VLOOKUP ഫോർമുല അതിന്റെ പ്രധാന ലക്ഷ്യം പൂർണ്ണമായും നിറവേറ്റുന്നു - പൊതുവായ മൂല്യങ്ങൾ നൽകുകയും നഷ്‌ടമായ ഡാറ്റ പോയിന്റുകൾ തിരിച്ചറിയുകയും ചെയ്യുന്നു. എന്നിരുന്നാലും, ഇത് ഒരു കൂട്ടം #N/A പിശകുകൾ നൽകുന്നു, ഇത് സൂത്രവാക്യത്തിൽ എന്തോ കുഴപ്പമുണ്ടെന്ന് അനുഭവപരിചയമില്ലാത്ത ഉപയോക്താക്കളെ ആശയക്കുഴപ്പത്തിലാക്കിയേക്കാം.

തെറ്റുകൾ ശൂന്യമായ സെല്ലുകൾ ഉപയോഗിച്ച് മാറ്റിസ്ഥാപിക്കാൻ, VLOOKUP ഉപയോഗിക്കുക ഈ രീതിയിൽ IFNA അല്ലെങ്കിൽ IFERROR ഫംഗ്‌ഷനുമായി സംയോജിപ്പിച്ച്:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

ഞങ്ങളുടെ മെച്ചപ്പെടുത്തിയ ഫോർമുല #N/ എന്നതിന് പകരം ഒരു ശൂന്യമായ സ്‌ട്രിംഗ് ("") നൽകുന്നു എ. "ലിസ്റ്റ് 2-ൽ ഇല്ല", "നിലവിൽ ഇല്ല", അല്ലെങ്കിൽ "ലഭ്യമല്ല" എന്നിങ്ങനെയുള്ള നിങ്ങളുടെ ഇഷ്‌ടാനുസൃത വാചകം നിങ്ങൾക്ക് തിരികെ നൽകാനും കഴിയും. ഉദാഹരണത്തിന്:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Excel-ലെ രണ്ട് നിരകൾ താരതമ്യം ചെയ്യുന്നതിനുള്ള അടിസ്ഥാന VLOOKUP ഫോർമുല അതാണ്. നിങ്ങളുടെ പ്രത്യേക ടാസ്‌ക്കിനെ ആശ്രയിച്ച്, കൂടുതൽ ഉദാഹരണങ്ങളിൽ കാണിച്ചിരിക്കുന്നതുപോലെ ഇത് പരിഷ്‌ക്കരിക്കാവുന്നതാണ്.

VLOOKUP ഉപയോഗിച്ച് വ്യത്യസ്ത Excel ഷീറ്റുകളിലെ രണ്ട് നിരകൾ താരതമ്യം ചെയ്യുക

യഥാർത്ഥ ജീവിതത്തിൽ, നിങ്ങൾ നിരകൾതാരതമ്യം ചെയ്യേണ്ടത് എല്ലായ്പ്പോഴും ഒരേ ഷീറ്റിലല്ല. ഒരു ചെറിയ ഡാറ്റാസെറ്റിൽ, രണ്ട് ഷീറ്റുകൾ വശങ്ങളിലായി കാണുന്നതിലൂടെ നിങ്ങൾക്ക് വ്യത്യാസങ്ങൾ സ്വമേധയാ കണ്ടെത്താൻ ശ്രമിക്കാം.

ഫോർമുലകളുള്ള മറ്റൊരു വർക്ക്‌ഷീറ്റിലോ വർക്ക്‌ബുക്കിലോ തിരയാൻ, നിങ്ങൾ ബാഹ്യ റഫറൻസ് ഉപയോഗിക്കേണ്ടതുണ്ട്. നിങ്ങളുടെ പ്രധാന ഷീറ്റിൽ ഫോർമുല ടൈപ്പുചെയ്യാൻ തുടങ്ങുക എന്നതാണ് ഏറ്റവും നല്ല രീതി, തുടർന്ന് മറ്റ് വർക്ക്ഷീറ്റിലേക്ക് മാറുകയും മൗസ് ഉപയോഗിച്ച് ലിസ്റ്റ് തിരഞ്ഞെടുക്കുക - ഫോർമുലയിലേക്ക് ഉചിതമായ ശ്രേണി റഫറൻസ് സ്വയമേവ ചേർക്കപ്പെടും.

ലിസ്റ്റ് 1 എന്ന് കരുതുക ഷീറ്റ്1 -ലെ A കോളത്തിലും ലിസ്റ്റ് 2 ഷീറ്റ്2 -ലെ A കോളത്തിലും ഉണ്ട്, നിങ്ങൾക്ക് ഈ ഫോർമുല ഉപയോഗിച്ച് രണ്ട് കോളങ്ങൾ താരതമ്യം ചെയ്യാനും പൊരുത്തങ്ങൾ കണ്ടെത്താനും കഴിയും:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

കൂടുതൽ വിവരങ്ങൾക്ക്, ദയവായി കാണുക:

• മറ്റൊരു ഷീറ്റിൽ നിന്നുള്ള VLOOKUP
• വ്യത്യസ്‌ത വർക്ക്‌ബുക്കിൽ നിന്നുള്ള VLOOKUP

രണ്ട് നിരകൾ താരതമ്യം ചെയ്ത് പൊതുവായ മൂല്യങ്ങൾ തിരികെ നൽകുക (പൊരുത്തങ്ങൾ)

മുമ്പത്തെ ഉദാഹരണങ്ങളിൽ, ഞങ്ങൾ ഒരു VLOOKUP ഫോർമുലയെ അതിന്റെ ഏറ്റവും ലളിതമായ രൂപത്തിൽ ചർച്ചചെയ്തു:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

ആ ഫോർമുലയുടെ ഫലം ഇതാണ് രണ്ടാമത്തെ കോളത്തിൽ ലഭ്യമല്ലാത്ത മൂല്യങ്ങളുടെ സ്ഥാനത്ത് കോളങ്ങളിലും ശൂന്യമായ സെല്ലുകളിലും നിലനിൽക്കുന്ന മൂല്യങ്ങളുടെ ഒരു ലിസ്റ്റ്.

വിടവുകളില്ലാതെ പൊതുവായ മൂല്യങ്ങളുടെ ഒരു ലിസ്റ്റ് ലഭിക്കുന്നതിന്, തത്ഫലമായുണ്ടാകുന്ന കോളത്തിലേക്ക് സ്വയമേവയുള്ള ഫിൽട്ടർ ചേർക്കുക. ശൂന്യമായവ ഫിൽട്ടർ ചെയ്യുക.

Microsoft 365, Excel 2021 എന്നിവയ്‌ക്കായുള്ള Excel-ൽ ഡൈനാമിക് അറേകൾ സപ്പോർട്ട് ചെയ്യുക, ശൂന്യമായവ ഡൈനാമിക് ആയി വേർതിരിച്ചെടുക്കാൻ നിങ്ങൾക്ക് ഫിൽറ്റർ ഫംഗ്ഷൻ ഉപയോഗിക്കാം. ഇതിനായി, IFNA VLOOKUP ഫോർമുല ഉപയോഗിക്കുകFILTER-നുള്ള മാനദണ്ഡം:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

ഈ സാഹചര്യത്തിൽ VLOOKUP-ന്റെ lookup_value ആർഗ്യുമെന്റിലേക്ക് ഞങ്ങൾ ലിസ്റ്റ് 1 (A2:A14) മുഴുവനും നൽകുന്നു എന്നത് ശ്രദ്ധിക്കുക. ഫംഗ്‌ഷൻ ഓരോ ലുക്ക്അപ്പ് മൂല്യങ്ങളെയും ലിസ്‌റ്റ് 2 (C2:C9) മായി താരതമ്യം ചെയ്യുകയും നഷ്‌ടമായ മൂല്യങ്ങളെ പ്രതിനിധീകരിക്കുന്ന പൊരുത്തങ്ങളുടെ ഒരു നിരയും #N/A പിശകുകളും നൽകുകയും ചെയ്യുന്നു. IFNA ഫംഗ്‌ഷൻ പിശകുകളെ ശൂന്യമായ സ്‌ട്രിംഗുകൾ ഉപയോഗിച്ച് മാറ്റിസ്ഥാപിക്കുകയും ഫലങ്ങളെ FILTER ഫംഗ്‌ഷനിലേക്ക് നൽകുകയും ചെയ്യുന്നു, ഇത് ശൂന്യമായവ ("") ഫിൽട്ടർ ചെയ്യുകയും അന്തിമ ഫലമായി ഒരു കൂട്ടം പൊരുത്തങ്ങൾ നൽകുകയും ചെയ്യുന്നു.

പകരം, നിങ്ങൾക്ക് VLOOKUP-ന്റെ ഫലം പരിശോധിക്കാൻ ISNA ഫംഗ്‌ഷൻ ഉപയോഗിക്കാം, കൂടാതെ FALSE-ലേക്ക് മൂല്യനിർണ്ണയം നടത്തുന്ന ഇനങ്ങൾ ഫിൽട്ടർ ചെയ്യാം, അതായത് #N/A പിശകുകൾ ഒഴികെയുള്ള മൂല്യങ്ങൾ:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

അതേ ഫലത്തിന് കഴിയും XLOOKUP ഫംഗ്‌ഷൻ ഉപയോഗിച്ച് നേടാം, ഇത് ഫോർമുല കൂടുതൽ ലളിതമാക്കുന്നു. ആന്തരികമായി #N/A പിശകുകൾ കൈകാര്യം ചെയ്യാനുള്ള XLOOKUP-ന്റെ കഴിവ് കാരണം (ഓപ്ഷണൽ ഇഫ്_കണ്ടെത്താത്തത് ആർഗ്യുമെന്റ്), IFNA അല്ലെങ്കിൽ ISNA റാപ്പർ ഇല്ലാതെ നമുക്ക് ചെയ്യാൻ കഴിയും:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

താരതമ്യം ചെയ്യുക രണ്ട് നിരകൾ കാണുകയും നഷ്‌ടമായ മൂല്യങ്ങൾ കണ്ടെത്തുകയും ചെയ്യുക (വ്യത്യാസങ്ങൾ)

വ്യത്യാസങ്ങൾ കണ്ടെത്തുന്നതിന് Excel-ലെ 2 നിരകൾ താരതമ്യം ചെയ്യാൻ, നിങ്ങൾക്ക് ഈ രീതിയിൽ തുടരാം:

1. ആദ്യത്തേത് തിരയാൻ കോർ ഫോർമുല എഴുതുക ലിസ്റ്റ് 2 ലെ ലിസ്റ്റ് 1 (A2) ൽ നിന്നുള്ള മൂല്യം ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. നെസ്റ്റ് ദി #N/A പിശകുകൾക്കായി VLOOKUP-ന്റെ ഔട്ട്‌പുട്ട് പരിശോധിക്കാൻ ISNA ഫംഗ്‌ഷനിലെ ഫോർമുലയ്ക്ക് മുകളിൽ. ഒരു പിശക് സംഭവിച്ചാൽ, ISNA TRUE നൽകുന്നു, അല്ലാത്തപക്ഷം FALSE:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. IF ഫംഗ്‌ഷന്റെ ലോജിക്കൽ ടെസ്റ്റിനായി ISNA VLOOKUP ഫോർമുല ഉപയോഗിക്കുക. ടെസ്റ്റ് മൂല്യനിർണ്ണയം TRUE ആണെങ്കിൽ (#N/A പിശക്), അതേ വരിയിലെ ലിസ്റ്റ് 1-ൽ നിന്ന് ഒരു മൂല്യം തിരികെ നൽകുക. ടെസ്റ്റ് മൂല്യനിർണ്ണയം FALSE ആണെങ്കിൽ (ലിസ്റ്റ് 2 ലെ ഒരു പൊരുത്തം കണ്ടെത്തി), ഒരു ശൂന്യമായ സ്ട്രിംഗ് തിരികെ നൽകുക.

പൂർണ്ണമായ ഫോർമുല ഈ ഫോം എടുക്കുന്നു:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

ശൂന്യത ഇല്ലാതാക്കാൻ, മുകളിലെ ഉദാഹരണത്തിൽ കാണിച്ചിരിക്കുന്നതുപോലെ Excel ന്റെ ഫിൽട്ടർ പ്രയോഗിക്കുക.

Excel 365, Excel 2021 എന്നിവയിൽ, നിങ്ങൾക്ക് ഫലങ്ങളുടെ ലിസ്റ്റ് ഡൈനാമിക് ആയി ഫിൽട്ടർ ചെയ്യാം. ഇതിനായി, FILTER ഫംഗ്‌ഷന്റെ include ആർഗ്യുമെന്റിൽ ISNA VLOOKUP ഫോർമുല സ്ഥാപിക്കുക:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

മറ്റൊരു മാർഗ്ഗം മാനദണ്ഡങ്ങൾക്കായി XLOOKUP ഉപയോഗിക്കുക - നഷ്‌ടമായ ഡാറ്റ പോയിന്റുകൾക്കായി ഫംഗ്‌ഷൻ ശൂന്യമായ സ്‌ട്രിംഗുകൾ ("") നൽകുന്നു, കൂടാതെ XLOOKUP ശൂന്യമായ സ്‌ട്രിംഗുകൾ (="") തിരികെ നൽകിയ ലിസ്റ്റ് 1 ലെ മൂല്യങ്ങൾ നിങ്ങൾ ഫിൽട്ടർ ചെയ്യുന്നു:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

രണ്ട് നിരകൾ തമ്മിലുള്ള പൊരുത്തങ്ങളും വ്യത്യാസങ്ങളും തിരിച്ചറിയാൻ VLOOKUP ഫോർമുല

രണ്ടാമത്തെ ലിസ്റ്റിൽ ഏതൊക്കെ മൂല്യങ്ങളാണ് ലഭ്യമാണെന്നും അല്ലാത്തതെന്നും സൂചിപ്പിക്കുന്ന ടെക്സ്റ്റ് ലേബലുകൾ ആദ്യ ലിസ്റ്റിലേക്ക് ചേർക്കണമെങ്കിൽ, VLOOKUP ഫോർമുല ഉപയോഗിക്കുക IF, ISNA/ISERROR ഫംഗ്‌ഷനുകൾ.

ഉദാഹരണത്തിന്, A, D എന്നീ കോളങ്ങളിലും A കോളത്തിലും മാത്രമുള്ള പേരുകൾ തിരിച്ചറിയാൻ, ഫോർമുല ഇതാണ്:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

ഇവിടെ, ISNA ഫംഗ്‌ഷൻ VLOOKUP സൃഷ്‌ടിച്ച #N/A പിശകുകൾ പിടിച്ചെടുക്കുകയും ആ ഇന്റർമീഡിയറ്റ് ഫലം അതിനായി IF ഫംഗ്‌ഷനിലേക്ക് കൈമാറുകയും ചെയ്യുന്നു.പിശകുകൾക്കായി നിർദ്ദിഷ്ട വാചകവും വിജയകരമായ തിരയലുകൾക്കായി മറ്റൊരു വാചകവും തിരികെ നൽകുക.

ഈ ഉദാഹരണത്തിൽ, ഞങ്ങളുടെ സാമ്പിൾ ഡാറ്റാസെറ്റിന് അനുയോജ്യമായ "യോഗ്യതയില്ലാത്ത"/"യോഗ്യതയുള്ള" ലേബലുകൾ ഞങ്ങൾ ഉപയോഗിച്ചു. നിങ്ങൾക്ക് അവയെ "ലിസ്‌റ്റ് 2ൽ ഇല്ല"/"ലിസ്‌റ്റ് 2ൽ", "ലഭ്യമല്ല"/"ലഭ്യം" അല്ലെങ്കിൽ നിങ്ങൾക്ക് അനുയോജ്യമെന്ന് തോന്നുന്ന മറ്റേതെങ്കിലും ലേബലുകൾ ഉപയോഗിച്ച് മാറ്റിസ്ഥാപിക്കാം.

ഈ ഫോർമുല ഒരു കോളത്തിൽ ചേർക്കുന്നതാണ് നല്ലത്. ലിസ്റ്റ് 1 ന് സമീപമുള്ളതും നിങ്ങളുടെ ലിസ്റ്റിൽ എത്ര ഇനങ്ങളുണ്ടോ അത്രയും സെല്ലുകളിലൂടെ പകർത്തി.

2 നിരകളിലെ പൊരുത്തങ്ങളും വ്യത്യാസങ്ങളും തിരിച്ചറിയാനുള്ള മറ്റൊരു മാർഗ്ഗം MATCH ഫംഗ്‌ഷൻ ഉപയോഗിക്കുന്നു:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

2 നിരകൾ താരതമ്യം ചെയ്‌ത് മൂന്നാമത്തേതിൽ നിന്ന് ഒരു മൂല്യം തിരികെ നൽകുക

അനുബന്ധ ഡാറ്റ അടങ്ങിയ ടേബിളുകളിൽ പ്രവർത്തിക്കുമ്പോൾ, നിങ്ങൾക്ക് ചിലപ്പോൾ ആവശ്യമായി വന്നേക്കാം രണ്ട് വ്യത്യസ്ത പട്ടികകളിലെ രണ്ട് നിരകൾ താരതമ്യം ചെയ്ത് മറ്റൊരു കോളത്തിൽ നിന്ന് പൊരുത്തപ്പെടുന്ന മൂല്യം തിരികെ നൽകുക. വാസ്തവത്തിൽ, ഇത് VLOOKUP ഫംഗ്‌ഷന്റെ പ്രാഥമിക ഉപയോഗമാണ്, അത് രൂപകൽപ്പന ചെയ്‌തിരിക്കുന്ന ഉദ്ദേശ്യമാണ്.

ഉദാഹരണത്തിന്, ചുവടെയുള്ള രണ്ട് പട്ടികകളിലെ A, D നിരകളിലെ പേരുകൾ താരതമ്യം ചെയ്‌ത് E കോളത്തിൽ നിന്ന് ഒരു സമയം നൽകുന്നതിന് , ഫോർമുല ഇതാണ്:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

#N/A പിശകുകൾ മറയ്‌ക്കാൻ, തെളിയിക്കപ്പെട്ട പരിഹാരം ഉപയോഗിക്കുക - IFNA ഫംഗ്‌ഷൻ:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

ശൂന്യമായവയ്‌ക്ക് പകരം, നഷ്‌ടമായ ഡാറ്റാ പോയിന്റുകൾക്കായി നിങ്ങൾക്ക് ആവശ്യമുള്ള ഏത് വാചകവും തിരികെ നൽകാം - അവസാന ആർഗ്യുമെന്റിൽ അത് ടൈപ്പ് ചെയ്യുക. ഉദാഹരണത്തിന്:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

VLOOKUP കൂടാതെ, മറ്റ് ചില ലുക്ക്അപ്പ് ഫംഗ്‌ഷനുകൾ ഉപയോഗിച്ച് ടാസ്‌ക്ക് പൂർത്തീകരിക്കാനാകും.

വ്യക്തിപരമായി, ഞാൻ കൂടുതൽ വഴക്കമുള്ള INDEX-നെ ആശ്രയിക്കും.MATCH ഫോർമുല:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

അല്ലെങ്കിൽ VLOOKUP-ന്റെ ആധുനിക പിൻഗാമി ഉപയോഗിക്കുക - XLOOKUP ഫംഗ്‌ഷൻ, Excel 365, Excel 2021 എന്നിവയിൽ ലഭ്യമാണ്:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

ലേക്ക് ഗ്രൂപ്പ് എയിൽ നിന്ന് യോഗ്യതയുള്ള പങ്കാളികളുടെ പേരുകളും അവയുടെ ഫലങ്ങളും നേടുക, കോളം ബിയിലെ ശൂന്യമായ സെല്ലുകൾ ഫിൽട്ടർ ചെയ്യുക:

=FILTER(A3:B15, B3:B15"")

താരതമ്യ ഉപകരണങ്ങൾ

നിങ്ങൾ പതിവായി Excel-ൽ ഫയലോ ഡാറ്റയോ താരതമ്യം ചെയ്യുകയാണെങ്കിൽ, ഞങ്ങളുടെ അൾട്ടിമേറ്റ് സ്യൂട്ടിൽ ഉൾപ്പെടുത്തിയിരിക്കുന്ന ഈ സ്മാർട്ട് ടൂളുകൾക്ക് നിങ്ങളുടെ സമയം വളരെയധികം ലാഭിക്കാൻ കഴിയും!

പട്ടികകൾ താരതമ്യം ചെയ്യുക - ഡ്യൂപ്ലിക്കേറ്റുകളും (പൊരുത്തങ്ങളും) അതുല്യമായ മൂല്യങ്ങളും (വ്യത്യാസങ്ങൾ) കണ്ടെത്താനുള്ള ദ്രുത മാർഗം കോളങ്ങൾ, ലിസ്റ്റ് അല്ലെങ്കിൽ പട്ടികകൾ എന്നിങ്ങനെയുള്ള ഏതെങ്കിലും രണ്ട് ഡാറ്റാ സെറ്റുകളിൽ.

രണ്ട് ഷീറ്റുകൾ താരതമ്യം ചെയ്യുക - രണ്ട് വർക്ക്ഷീറ്റുകൾ തമ്മിലുള്ള വ്യത്യാസങ്ങൾ കണ്ടെത്തി ഹൈലൈറ്റ് ചെയ്യുക.

ഒന്നിലധികം ഷീറ്റുകൾ താരതമ്യം ചെയ്യുക - ഒന്നിലധികം ഷീറ്റുകളിലെ വ്യത്യാസങ്ങൾ ഒരേസമയം കണ്ടെത്തി ഹൈലൈറ്റ് ചെയ്യുക. .

കോളങ്ങൾ താരതമ്യപ്പെടുത്തുന്നതിന് Excel-ൽ ഡൗൺലോഡ് ചെയ്യാൻ വർക്ക്ബുക്ക് പരിശീലിക്കുക

VLOOKUP - ഉദാഹരണങ്ങൾ (.xlsx ഫയൽ)