Udžbenik pokazuje kako koristiti VLOOKUP formulu u programu Excel za usporedbu dva stupca za vraćanje zajedničkih vrijednosti (podudaranja) ili pronalaženje podataka koji nedostaju (razlike).

Kada imate podatke u dva različite popise, možda ćete ih često morati usporediti kako biste vidjeli koje informacije nedostaju na jednom od popisa ili koji su podaci prisutni na oba. Usporedba se može napraviti na mnogo različitih načina - koju metodu koristiti ovisi o tome što točno želite od nje.

Kako usporediti dva stupca u Excelu pomoću VLOOKUP-a

Kada imate dva stupca podataka i želite saznati koje podatkovne točke s jednog popisa postoje na drugom popisu, možete upotrijebiti funkciju VLOOKUP za usporedbu popisa za zajedničke vrijednosti.

Da biste izgradili VLOOKUP formulu u svom osnovnom obliku, ovo je ono što trebate učiniti:

• Za lookup_value (1. argument), koristite najvišu ćeliju s Liste 1.
• Za table_array (2. argument), navedite cijeli popis 2.
• Za col_index_num (3. argument), koristite 1 jer postoji samo jedan stupac u nizu.
• Za range_lookup (4. argument), postavite FALSE - točno podudaranje.

Pretpostavimo da imate imena sudionika u stupcu A (Lista 1) i imena onih koji su prošli kroz kvalifikacije u stupcu B (Lista 2). Želite usporediti ova 2 popisa kako biste utvrdili koji su se sudionici iz grupe A probili do glavnog događaja. Da biste to učinili, upotrijebite sljedećeformula.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Formula ide u ćeliju E2, a zatim je povlačite prema dolje kroz onoliko ćelija koliko ima stavki na popisu 1.

Uočite da table_array je zaključan s apsolutnim referencama ($C$2:$C$9) tako da ostaje konstantan kada kopirate formulu u donje ćelije.

Kao što vidite, nazivi kvalificirani sportaši pojavljuju se u stupcu E. Za preostale sudionike pojavljuje se pogreška #N/A koja označava da njihova imena nisu dostupna na popisu 2.

Prikrivanje #N/ Pogreške

VLOOKUP formula o kojoj se govori gore savršeno ispunjava svoj glavni cilj - vraća zajedničke vrijednosti i identificira nedostajuće podatkovne točke. Međutim, isporučuje hrpu pogrešaka #N/A, koje mogu zbuniti neiskusne korisnike i natjerati ih da pomisle da nešto nije u redu s formulom.

Da biste zamijenili pogreške s praznim ćelijama , koristite VLOOKUP u kombinaciji s funkcijom IFNA ili IFERROR na ovaj način:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Naša poboljšana formula vraća prazan niz ("") umjesto #N/ A. Također možete vratiti svoj prilagođeni tekst kao što je "Nije na popisu 2", "Nije prisutan" ili "Nije dostupan". Na primjer:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

To je osnovna VLOOKUP formula za usporedbu dva stupca u Excelu. Ovisno o vašem određenom zadatku, može se modificirati kao što je prikazano u daljnjim primjerima.

Usporedite dva stupca u različitim Excel listovima koristeći VLOOKUP

U stvarnom životu, stupci kojepotrebe za usporedbom nisu uvijek na istom listu. U malom skupu podataka možete pokušati ručno uočiti razlike gledajući dva lista jedan pored drugog.

Za pretraživanje u drugom radnom listu ili radnoj knjizi s formulama, morate koristiti vanjsku referencu. Najbolja praksa je da počnete upisivati ​​formulu u svoj glavni list, zatim se prebacite na drugi radni list i odaberete popis pomoću miša - odgovarajuća referenca raspona automatski će se dodati formuli.

Pretpostavimo da je popis 1 u stupcu A na Sheet1 , a lista 2 je u stupcu A na Sheet2 , možete usporediti dva stupca i pronaći podudaranja pomoću ove formule:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Za više informacija pogledajte:

• VLOOKUP s drugog lista
• VLOOKUP iz druge radne knjige

Usporedite dva stupca i vratite zajedničke vrijednosti (podudaranja)

U prethodnim primjerima raspravljali smo o VLOOKUP formuli u njenom najjednostavnijem obliku:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Rezultat te formule je popis vrijednosti koje postoje u stupcima i praznim ćelijama umjesto vrijednosti koje nisu dostupne u drugom stupcu.

Da biste dobili popis uobičajenih vrijednosti bez praznina, samo dodajte automatski filtar rezultirajućem stupcu i filtrirajte praznine.

U Excelu za Microsoft 365 i Excel 2021 to s podržavaju dinamičke nizove, možete koristiti funkciju FILTER za dinamičko izdvajanje praznina. Za to upotrijebite formulu IFNA VLOOKUP kaokriteriji za FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Molimo obratite pozornost da u ovom slučaju dostavljamo cijelu listu 1 (A2:A14) argumentu lookup_value VLOOKUP-a. Funkcija uspoređuje svaku vrijednost pretraživanja s popisom 2 (C2:C9) i vraća niz podudaranja i pogreške #N/A koje predstavljaju vrijednosti koje nedostaju. Funkcija IFNA zamjenjuje pogreške praznim nizovima i poslužuje rezultate funkciji FILTER, koja filtrira praznine ("") i daje niz podudaranja kao konačni rezultat.

Alternativno, možete koristiti funkciju ISNA za provjeru rezultata VLOOKUP-a i filtriranje stavki koje procjenjuju na FALSE, tj. vrijednosti koje nisu pogreške #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Isti rezultat može može se postići funkcijom XLOOKUP, što formulu čini još jednostavnijom. Zbog mogućnosti XLOOKUP-a da interno obrađuje greške #N/A (neobavezni argument if_not_found ), možemo bez IFNA ili ISNA omotača:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Usporedi dva stupca i pronađite vrijednosti koje nedostaju (razlike)

Da biste usporedili 2 stupca u Excelu da biste pronašli razlike, možete nastaviti na ovaj način:

1. Napišite temeljnu formulu za traženje prvog vrijednost s popisa 1 (A2) u popisu 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Ugniježdite gornju formulu u funkciji ISNA za provjeru VLOOKUP izlaza za pogreške #N/A. U slučaju pogreške, ISNA daje TRUE, inače FALSE:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. Koristite formulu ISNA VLOOKUP za logički test funkcije IF. Ako test procijeni TRUE (pogreška #N/A), vratite vrijednost s Liste 1 u istom retku. Ako test procijeni FALSE (pronađeno je podudaranje na popisu 2), vrati prazan niz.

Kompletna formula ima ovaj oblik:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Da biste se riješili praznina, primijenite Excelov filtar kao što je prikazano u gornjem primjeru.

U Excelu 365 i Excelu 2021 popis rezultata možete dinamički filtrirati. U tu svrhu jednostavno postavite formulu ISNA VLOOKUP u argument include funkcije FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Drugi način je koristite XLOOKUP za kriterije - funkcija vraća prazne nizove ("") za podatkovne točke koje nedostaju, a vi filtrirate vrijednosti na popisu 1 za koje je XLOOKUP vratio prazne nizove (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP formula za identificiranje podudarnosti i razlika između dva stupca

Ako želite dodati tekstualne oznake prvom popisu koje pokazuju koje su vrijednosti dostupne na drugom popisu, a koje nisu, koristite VLOOKUP formulu zajedno s Funkcije IF i ISNA/ISERROR.

Na primjer, za identifikaciju imena koja su u stupcima A i D i onih koja su samo u stupcu A, formula je:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Ovdje funkcija ISNA hvata pogreške #N/A koje generira VLOOKUP i prosljeđuje taj međurezultat funkciji IF kako bi onavrati navedeni tekst za pogreške i drugi tekst za uspješna pretraživanja.

U ovom primjeru koristili smo oznake "Nije kvalificirano"/"Kvalificirano" koje su prikladne za naš ogledni skup podataka. Možete ih zamijeniti s "Nije na popisu 2"/"Na popisu 2", "Nije dostupno"/"Dostupno" ili bilo kojim drugim oznakama koje smatrate prikladnima.

Ovu je formulu najbolje umetnuti u stupac uz popis 1 i kopiran kroz onoliko ćelija koliko ima stavki na vašem popisu.

Još jedan način za prepoznavanje podudaranja i razlika u 2 stupca je korištenje funkcije MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Usporedite 2 stupca i vratite vrijednost iz trećeg

Kada radite s tablicama koje sadrže povezane podatke, ponekad ćete morati usporedite dva stupca u dvije različite tablice i vratite odgovarajuću vrijednost iz drugog stupca. Zapravo, to je primarna upotreba funkcije VLOOKUP, svrha za koju je dizajnirana.

Na primjer, za usporedbu imena u stupcima A i D u dvije tablice u nastavku i vraćanje vremena iz stupca E , formula je:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Da biste sakrili pogreške #N/A, koristite provjereno rješenje - funkciju IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Umjesto praznina, možete vratiti bilo koji tekst koji želite za podatke koji nedostaju - samo ga upišite u zadnji argument. Na primjer:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Osim VLOOKUP-a, zadatak se može ispuniti s nekoliko drugih funkcija pretraživanja.

Osobno bih se oslonio na fleksibilniji INDEXMATCH formula:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Ili upotrijebite modernog nasljednika VLOOKUP-a - funkciju XLOOKUP, dostupnu u Excel 365 i Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Za saznajte imena kvalificiranih sudionika iz skupine A i njihove rezultate, jednostavno filtrirajte prazne ćelije u stupcu B:

=FILTER(A3:B15, B3:B15"")

Alati za usporedbu

Ako često uspoređujete datoteke ili podatke u Excelu, ovi pametni alati uključeni u naš Ultimate Suite mogu vam uvelike uštedjeti vrijeme!

Usporedite tablice - brz način za pronalaženje duplikata (podudaranja) i jedinstvenih vrijednosti (razlike) u bilo koja dva skupa podataka kao što su stupci, popisi ili tablice.

Usporedite dva lista - pronađite i istaknite razlike između dva radna lista.

Usporedite više listova - pronađite i istaknite razlike u više listova odjednom .

Radna knjiga za vježbanje za preuzimanje

VLOOKUP u Excelu za usporedbu stupaca - primjeri (.xlsx datoteka)