Das Tutorial zeigt, wie man die VLOOKUP-Formel in Excel verwendet, um zwei Spalten zu vergleichen und gemeinsame Werte (Übereinstimmungen) oder fehlende Daten (Unterschiede) zu finden.

Wenn Sie Daten in zwei verschiedenen Listen haben, müssen Sie diese oft vergleichen, um zu sehen, welche Informationen in einer der Listen fehlen oder welche Daten in beiden vorhanden sind. Der Vergleich kann auf viele verschiedene Arten durchgeführt werden - welche Methode Sie verwenden, hängt davon ab, was Sie genau wollen.

Wie man zwei Spalten in Excel mit VLOOKUP vergleicht

Wenn Sie zwei Datenspalten haben und herausfinden möchten, welche Datenpunkte aus einer Liste in der anderen Liste vorhanden sind, können Sie die Funktion VLOOKUP verwenden, um die Listen auf gemeinsame Werte zu vergleichen.

Um eine VLOOKUP-Formel in ihrer Grundform zu erstellen, müssen Sie wie folgt vorgehen:

• Für lookup_value (1. Argument) die oberste Zelle aus Liste 1 verwenden.
• Für table_array (2. Argument), geben Sie die gesamte Liste 2.
• Für col_index_num (3. Argument), verwenden Sie 1, da es nur eine Spalte im Array gibt.
• Für bereich_lookup (4. Argument), FALSE setzen - exakte Übereinstimmung.

Angenommen, Sie haben die Namen der Teilnehmer in Spalte A (Liste 1) und die Namen derjenigen, die die Qualifikationsrunden durchlaufen haben, in Spalte B (Liste 2). Sie möchten diese beiden Listen miteinander vergleichen, um festzustellen, welche Teilnehmer aus Gruppe A es in die Hauptveranstaltung geschafft haben. Verwenden Sie dazu die folgende Formel.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Die Formel geht in die Zelle E2, und dann ziehen Sie sie nach unten durch so viele Zellen, wie es Elemente in Liste 1 gibt.

Bitte beachten Sie, dass table_array ist mit absoluten Referenzen ($C$2:$C$9) gesperrt, so dass sie konstant bleibt, wenn Sie die Formel in die darunter liegenden Zellen kopieren.

Wie Sie sehen, erscheinen die Namen der qualifizierten Athleten in Spalte E. Für die übrigen Teilnehmer erscheint ein #N/A-Fehler, der anzeigt, dass ihre Namen in Liste 2 nicht verfügbar sind.

Verkleidung #N/A Fehler

Die oben beschriebene VLOOKUP-Formel erfüllt ihren Hauptzweck perfekt - sie liefert gemeinsame Werte und identifiziert fehlende Datenpunkte. Allerdings liefert sie eine Reihe von #N/A-Fehlern, die unerfahrene Benutzer verwirren können und sie glauben lassen, dass mit der Formel etwas nicht stimmt.

So ersetzen Sie Fehler durch leere Zellen Verwenden Sie VLOOKUP in Kombination mit der Funktion IFNA oder IFERROR auf diese Weise:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Unsere verbesserte Formel liefert eine leere Zeichenkette ("") anstelle von #N/A. Sie können auch Ihre benutzerdefinierter Text wie "Nicht in Liste 2", "Nicht vorhanden" oder "Nicht verfügbar", zum Beispiel:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Nicht in Liste 2")

Dies ist die grundlegende VLOOKUP-Formel für den Vergleich zweier Spalten in Excel, die je nach Aufgabenstellung wie in den weiteren Beispielen gezeigt modifiziert werden kann.

Zwei Spalten in verschiedenen Excel-Blättern mit VLOOKUP vergleichen

In der Praxis befinden sich die zu vergleichenden Spalten nicht immer auf demselben Blatt. Bei einem kleinen Datensatz können Sie versuchen, die Unterschiede manuell festzustellen, indem Sie zwei Blätter nebeneinander betrachten.

Um in einem anderen Arbeitsblatt oder einer Arbeitsmappe mit Formeln zu suchen, müssen Sie einen externen Bezug verwenden. Am besten beginnen Sie mit der Eingabe der Formel in Ihrem Hauptarbeitsblatt, wechseln dann zum anderen Arbeitsblatt und wählen die Liste mit der Maus aus - ein entsprechender Bereichsbezug wird der Formel automatisch hinzugefügt.

Angenommen, Liste 1 steht in Spalte A auf Blatt1 und Liste 2 steht in Spalte A auf Blatt2 können Sie mit dieser Formel zwei Spalten vergleichen und Übereinstimmungen finden:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Weitere Informationen finden Sie unter:

• VLOOKUP aus einem anderen Blatt
• VLOOKUP aus einer anderen Arbeitsmappe

Zwei Spalten vergleichen und gemeinsame Werte zurückgeben (Übereinstimmungen)

In den vorherigen Beispielen haben wir eine VLOOKUP-Formel in ihrer einfachsten Form besprochen:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Das Ergebnis dieser Formel ist eine Liste von Werten, die in beiden Spalten vorhanden sind, und leere Zellen anstelle der Werte, die in der zweiten Spalte nicht vorhanden sind.

Um eine Liste gemeinsamer Werte ohne Lücken zu erhalten, fügen Sie der resultierenden Spalte einfach einen Autofilter hinzu und filtern Leerzeichen heraus.

In Excel für Microsoft 365 und Excel 2021, die dynamische Arrays unterstützen, können Sie die Funktion FILTER verwenden, um Leerzeichen dynamisch auszusieben. Verwenden Sie dazu die IFNA VLOOKUP-Formel als Kriterium für FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Bitte beachten Sie, dass wir in diesem Fall die gesamte Liste 1 (A2:A14) an den lookup_value Die Funktion vergleicht jeden der Nachschlagewerte mit der Liste 2 (C2:C9) und gibt ein Array mit Übereinstimmungen und #N/A-Fehlern zurück, die fehlende Werte darstellen. Die Funktion IFNA ersetzt Fehler durch leere Zeichenfolgen und gibt die Ergebnisse an die Funktion FILTER weiter, die Leerzeichen ("") herausfiltert und ein Array mit Übereinstimmungen als Endergebnis ausgibt.

Alternativ können Sie die Funktion ISNA verwenden, um das Ergebnis von VLOOKUP zu prüfen und die Elemente herauszufiltern, die mit FALSE bewertet werden, d. h. andere Werte als #N/A-Fehler:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Das gleiche Ergebnis kann mit der Funktion XLOOKUP erzielt werden, was die Formel noch einfacher macht. Da XLOOKUP intern #N/A-Fehler behandeln kann (optional if_not_found Argument), können wir auf den IFNA- oder ISNA-Wrapper verzichten:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Zwei Spalten vergleichen und fehlende Werte finden (Unterschiede)

Um 2 Spalten in Excel zu vergleichen, um Unterschiede zu finden, können Sie folgendermaßen vorgehen:

1. Schreiben Sie die Kernformel für die Suche nach dem ersten Wert aus Liste 1 (A2) in Liste 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Verschachteln Sie die obige Formel in die ISNA-Funktion, um die VLOOKUP-Ausgabe auf #N/A-Fehler zu überprüfen. Im Falle eines Fehlers liefert ISNA TRUE, ansonsten FALSE:

   ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))

3. Verwenden Sie die ISNA VLOOKUP-Formel für den logischen Test der IF-Funktion. Wenn der Test TRUE ergibt (#N/A-Fehler), geben Sie einen Wert aus Liste 1 in derselben Zeile zurück. Wenn der Test FALSE ergibt (eine Übereinstimmung in Liste 2 wird gefunden), geben Sie eine leere Zeichenfolge zurück.

Die vollständige Formel sieht so aus:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Um die Leerzeichen loszuwerden, wenden Sie den Excel-Filter an, wie im obigen Beispiel gezeigt.

In Excel 365 und Excel 2021 können Sie die Ergebnisliste dynamisch filtern lassen, indem Sie die ISNA VLOOKUP-Formel in den Bereich einschließen. Argument der Funktion FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Eine andere Möglichkeit ist die Verwendung von XLOOKUP für die Kriterien - die Funktion gibt leere Zeichenfolgen ("") für fehlende Datenpunkte zurück, und Sie filtern die Werte in Liste 1, für die XLOOKUP leere Zeichenfolgen (="") zurückgegeben hat:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP-Formel zur Ermittlung von Übereinstimmungen und Unterschieden zwischen zwei Spalten

Wenn Sie der ersten Liste Textbeschriftungen hinzufügen möchten, die angeben, welche Werte in der zweiten Liste verfügbar sind und welche nicht, verwenden Sie die VLOOKUP-Formel zusammen mit den Funktionen IF und ISNA/ISERROR.

Um z. B. Namen zu identifizieren, die sowohl in Spalte A als auch in Spalte D stehen, und solche, die nur in Spalte A stehen, lautet die Formel:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Nicht qualifiziert", "Qualifiziert")

Hier fängt die ISNA-Funktion die von VLOOKUP erzeugten #N/A-Fehler ab und gibt dieses Zwischenergebnis an die IF-Funktion weiter, damit diese den angegebenen Text für Fehler und einen anderen Text für erfolgreiche Suchvorgänge zurückgibt.

In diesem Beispiel haben wir die Bezeichnungen "Nicht qualifiziert"/"Qualifiziert" verwendet, die für unseren Beispieldatensatz geeignet sind. Sie können sie durch "Nicht in Liste 2"/"In Liste 2", "Nicht verfügbar"/"Verfügbar" oder jede andere Bezeichnung ersetzen, die Sie für geeignet halten.

Diese Formel wird am besten in eine Spalte neben der Liste 1 eingefügt und in so viele Zellen kopiert, wie Einträge in der Liste vorhanden sind.

Eine weitere Möglichkeit, Übereinstimmungen und Unterschiede in 2 Spalten zu identifizieren, ist die Verwendung der MATCH-Funktion:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Nicht in Liste 2", "In Liste 2")

2 Spalten vergleichen und einen Wert aus der dritten Spalte zurückgeben

Bei der Arbeit mit Tabellen, die zusammenhängende Daten enthalten, kann es manchmal erforderlich sein, zwei Spalten in zwei verschiedenen Tabellen zu vergleichen und einen übereinstimmenden Wert aus einer anderen Spalte zurückzugeben. Dies ist die Hauptanwendung der Funktion VLOOKUP, für die sie entwickelt wurde.

Um zum Beispiel die Namen in den Spalten A und D in den beiden unten stehenden Tabellen zu vergleichen und eine Zeit aus Spalte E zurückzugeben, lautet die Formel:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Um #N/A-Fehler auszublenden, verwenden Sie die bewährte Lösung - die IFNA-Funktion:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Anstelle von Leerzeichen können Sie für fehlende Datenpunkte jeden beliebigen Text zurückgeben - geben Sie ihn einfach in das letzte Argument ein, zum Beispiel:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Nicht verfügbar")

Neben VLOOKUP kann die Aufgabe auch mit einigen anderen Nachschlagefunktionen erfüllt werden.

Ich persönlich würde mich auf eine flexiblere INDEX MATCH Formel verlassen:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Oder verwenden Sie den modernen Nachfolger von VLOOKUP - die XLOOKUP-Funktion, die in Excel 365 und Excel 2021 verfügbar ist:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Um die Namen der qualifizierten Teilnehmer aus Gruppe A und deren Ergebnisse zu erhalten, filtern Sie einfach die leeren Zellen in Spalte B heraus:

=FILTER(A3:B15, B3:B15"")

Vergleichstools

Wenn Sie häufig Datei- oder Datenvergleiche in Excel durchführen, können Sie mit diesen intelligenten Tools, die in unserer Ultimate Suite enthalten sind, viel Zeit sparen!

Tabellen vergleichen - schnelle Möglichkeit, Duplikate (Übereinstimmungen) und eindeutige Werte (Unterschiede) in zwei beliebigen Datensätzen wie Spalten, Listen oder Tabellen zu finden.

Zwei Blätter vergleichen - Unterschiede zwischen zwei Arbeitsblättern finden und hervorheben.

Mehrere Blätter vergleichen - finden und markieren Sie Unterschiede in mehreren Blättern auf einmal.

Übungsheft zum Herunterladen

VLOOKUP in Excel zum Vergleichen von Spalten - Beispiele (.xlsx-Datei)