A bemutató bemutatja, hogyan használhatja a VLOOKUP képletet az Excelben két oszlop összehasonlítására, hogy közös értékeket adjon vissza (egyezések) vagy hiányzó adatokat találjon (különbségek).

Ha két különböző listában vannak adatai, gyakran szükség lehet arra, hogy összehasonlítsa őket, hogy lássa, milyen információ hiányzik az egyik listából, vagy milyen adatok vannak jelen mindkettőben. Az összehasonlítás többféleképpen is elvégezhető - hogy melyik módszert használja, az attól függ, hogy pontosan mit szeretne elérni vele.

Hogyan hasonlítsunk össze két oszlopot az Excelben a VLOOKUP segítségével?

Ha két adatoszlop áll rendelkezésére, és szeretné kideríteni, hogy az egyik lista mely adatpontjai szerepelnek a másik listában, a VLOOKUP funkcióval összehasonlíthatja a listákat a közös értékek keresésére.

A VLOOKUP-képlet alapvető formájának felépítéséhez a következőket kell tennie:

• A oldalon. lookup_value (1. argumentum), az 1. lista legfelső celláját használja.
• A oldalon. table_array (2. érv), adja meg a teljes List 2.
• A oldalon. col_index_num (3. argumentum), használjuk az 1-et, mivel csak egy oszlop van a tömbben.
• A oldalon. range_lookup (4. argumentum), FALSE - pontos egyezés.

Tegyük fel, hogy az A oszlopban (1. lista) a résztvevők nevei szerepelnek, a B oszlopban (2. lista) pedig a selejtezőkön továbbjutottak nevei. Ezt a két listát szeretné összehasonlítani, hogy megállapítsa, hogy az A csoportból mely résztvevők jutottak be a főversenyre. Ehhez használja a következő képletet.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

A képlet az E2 cellába kerül, majd annyi cellán keresztül húzza lefelé, ahány elem van az 1. listában.

Kérjük, vegye figyelembe, hogy table_array abszolút hivatkozásokkal van rögzítve ($C$2:$C$9), így állandó marad, amikor a képletet az alábbi cellákba másolja.

Amint láthatja, a minősített sportolók nevei az E oszlopban jelennek meg. A többi résztvevő esetében egy #N/A hiba jelenik meg, amely azt jelzi, hogy nevük nem elérhető a 2. listában.

Álca #N/A hibák

A fent tárgyalt VLOOKUP formula tökéletesen teljesíti fő célját - közös értékeket ad vissza és azonosítja a hiányzó adatpontokat. Azonban egy csomó #N/A hibát ad, ami összezavarhatja a tapasztalatlan felhasználókat, és azt gondolják, hogy valami baj van a formulával.

A hibák helyettesítésére üres cellák , használja a VLOOKUP-ot az IFNA vagy IFERROR funkcióval kombinálva:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

A javított képletünk #N/A helyett egy üres karakterláncot ("") ad vissza. egyéni szöveg például "Nincs a 2. listán", "Nincs jelen" vagy "Nem elérhető". Például:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Nincs a 2. listában")

Ez az alapvető VLOOKUP-képlet két oszlop összehasonlítására az Excelben. Az adott feladattól függően a további példák szerint módosítható.

Két oszlop összehasonlítása különböző Excel táblázatokban a VLOOKUP segítségével

A való életben az összehasonlítandó oszlopok nem mindig ugyanazon a lapon vannak. Egy kis adathalmazban megpróbálhatja manuálisan kiszúrni a különbségeket, ha két lapot egymás mellett nézeget.

Ha egy másik munkalapon vagy munkafüzetben szeretne képleteket keresni, külső hivatkozást kell használnia. A legjobb gyakorlat az, ha a képletet a fő lapon kezdi el begépelni, majd átvált a másik munkalapra, és az egérrel kiválasztja a listát - a képlethez automatikusan hozzáadódik egy megfelelő tartományhivatkozás.

Feltételezve, hogy az 1. lista az A oszlopban található a Sheet1 a 2. lista pedig az A oszlopban található Sheet2 , összehasonlíthat két oszlopot, és találhat egyezéseket ezzel a képlettel:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

További információkért lásd:

• VLOOKUP egy másik lapról
• VLOOKUP különböző munkafüzetből

Két oszlop összehasonlítása és közös értékek (egyezések) visszaadása

Az előző példákban a VLOOKUP-képletet a legegyszerűbb formában tárgyaltuk:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

A képlet eredménye a két oszlopban szereplő értékek listája, valamint a második oszlopban nem elérhető értékek helyén üres cellák.

Ha a közös értékek listáját szeretné hézagok nélkül megkapni, csak adjon automatikus szűrőt a kapott oszlophoz, és szűrje ki az üres részeket.

A dinamikus tömböket támogató Excel for Microsoft 365 és Excel 2021 programokban a FILTER funkciót használhatja az üres részek dinamikus kiszűrésére. Ehhez használja az IFNA VLOOKUP képletet a FILTER kritériumaként:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")""")

Kérjük, figyeljen arra, hogy ebben az esetben a teljes 1. listát (A2:A14) a lookup_value A függvény összehasonlítja az egyes keresési értékeket a 2. listával (C2:C9), és visszaadja a találatok és a hiányzó értékeket jelölő #N/A hibák tömbjét. Az IFNA függvény a hibákat üres karakterláncokkal helyettesíti, és az eredményeket a FILTER függvénynek adja, amely kiszűri az üres részeket (""), és végeredményként egy találatokból álló tömböt ad ki.

Alternatívaként használhatja az ISNA függvényt a VLOOKUP eredményének ellenőrzésére, és szűrheti a FALSE értékű elemeket, azaz a #N/A hibáktól eltérő értékeket:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Ugyanez az eredmény érhető el az XLOOKUP függvénnyel, ami még egyszerűbbé teszi a képletet. Mivel az XLOOKUP képes a #N/A hibák belső kezelésére (opcionális if_not_found argumentum), az IFNA vagy ISNA csomagolást nélkülözhetjük:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")""")

Két oszlop összehasonlítása és hiányzó értékek (különbségek) keresése

Ha 2 oszlopot szeretne összehasonlítani az Excelben, hogy megtalálja a különbségeket, akkor így járhat el:

1. Írja meg az alapképletet, amely az 1. lista első értékét (A2) keresi a 2. listában ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Fészkelje be a fenti képletet az ISNA függvénybe, hogy ellenőrizze a VLOOKUP kimenetét #N/A hibák szempontjából. Hiba esetén az ISNA TRUE, egyébként FALSE eredményt ad:

   ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))

3. Használja az ISNA VLOOKUP formulát az IF függvény logikai tesztjéhez. Ha a teszt értéke TRUE (#N/A hiba), akkor az 1. listából adjon vissza egy értéket ugyanabban a sorban. Ha a teszt értéke FALSE (talál egyezést a 2. listában), akkor adjon vissza egy üres karakterláncot.

A teljes képlet a következő formát ölti:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Az üres részektől való megszabaduláshoz alkalmazza az Excel szűrőjét a fenti példában bemutatott módon.

Az Excel 365 és az Excel 2021 programban az eredménylistát dinamikusan szűrheti. Ehhez egyszerűen helyezze az ISNA VLOOKUP képletet az ISNA VLOOKUP képletbe. tartalmazza a címet. a FILTER függvény argumentuma:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Egy másik lehetőség az XLOOKUP használata a kritériumokhoz - a függvény üres karakterláncokat ("") ad vissza a hiányzó adatpontok esetében, és az 1. listában azokat az értékeket szűrjük, amelyekre az XLOOKUP üres karakterláncokat (="") adott vissza:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP formula két oszlop közötti egyezések és különbségek azonosítására

Ha az első listához szöveges címkéket szeretne hozzáadni, amelyek jelzik, hogy a második listában mely értékek állnak rendelkezésre, és melyek nem, használja a VLOOKUP képletet az IF és ISNA/ISERROR függvényekkel együtt.

Például, az A és D oszlopban egyaránt szereplő nevek és a csak az A oszlopban szereplő nevek azonosításához a képlet a következő:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Nem képzett", "Képzett")

Itt az ISNA függvény elkapja a VLOOKUP által generált #N/A hibákat, és átadja ezt a közbenső eredményt az IF függvénynek, hogy az hibák esetén a megadott szöveget, sikeres keresések esetén pedig egy másik szöveget adjon vissza.

Ebben a példában a "Nem minősített"/"Minősített" címkéket használtuk, amelyek megfelelnek a mintaadatkészletünknek. Ezeket helyettesítheti a "Nincs a 2. listán"/"A 2. listán", "Nem elérhető"/"Elérhető" vagy bármilyen más, Ön által megfelelőnek ítélt címkével.

Ezt a képletet a legjobb, ha az 1. lista melletti oszlopba illeszti be, és annyi cellán keresztül másolja, ahány elem van a listában.

Még egy módja a 2 oszlopban lévő egyezések és különbségek azonosításának a MATCH függvény használatával:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Nincs a 2. listában", "A 2. listában")

2 oszlop összehasonlítása és a harmadik oszlop értékének visszaadása

Összefüggő adatokat tartalmazó táblázatokkal való munka során néha szükség lehet arra, hogy két különböző táblázat két oszlopát összehasonlítsa, és egy másik oszlopból visszaadja a megfelelő értéket. Valójában ez a VLOOKUP függvény elsődleges felhasználási módja, erre a célra tervezték.

Ha például az alábbi két táblázat A és D oszlopában lévő neveket akarjuk összehasonlítani, és az E oszlopban lévő időt akarjuk visszaadni, a képlet a következő:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Az #N/A hibák elrejtéséhez használja a bevált megoldást - az IFNA funkciót:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Üresek helyett bármilyen szöveget visszaküldhet a hiányzó adatpontokra - csak írja be az utolsó argumentumba. Például:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Nem elérhető")

A VLOOKUP mellett a feladatot néhány más keresési függvénnyel is el lehet látni.

Én személy szerint egy rugalmasabb INDEX MATCH képletre támaszkodnék:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Vagy használja a VLOOKUP modern utódját, az XLOOKUP függvényt, amely az Excel 365 és az Excel 2021 programban érhető el:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Az A csoportból származó minősített résztvevők nevének és eredményeinek a megismeréséhez egyszerűen szűrje ki a B oszlop üres celláit:

=FILTER(A3:B15, B3:B15"")

Összehasonlító eszközök

Ha gyakran végez fájl- vagy adatösszehasonlítást az Excelben, ezek az Ultimate Suite-ban található intelligens eszközök rengeteg időt takaríthatnak meg!

Táblák összehasonlítása - gyors módja a duplikátumok (egyezések) és egyedi értékek (különbségek) keresésének bármely két adathalmazban, például oszlopokban, listában vagy táblázatokban.

Két lap összehasonlítása - két munkalap közötti különbségek keresése és kiemelése.

Több lap összehasonlítása - egyszerre több lapon keresi és emeli ki a különbségeket.

Gyakorlati munkafüzet letölthető

VLOOKUP az Excelben az oszlopok összehasonlítására - példák (.xlsx fájl)