Tabela e përmbajtjes
Udhëzuesi tregon se si të përdorni formulën VLOOKUP në Excel për të krahasuar dy kolona për të kthyer vlerat e zakonshme (përputhje) ose për të gjetur të dhëna që mungojnë (dallimet).
Kur keni të dhëna në dy lista të ndryshme, shpesh mund t'ju duhet t'i krahasoni ato për të parë se çfarë informacioni mungon në njërën nga listat ose cilat të dhëna janë të pranishme në të dyja. Krahasimi mund të bëhet në shumë mënyra të ndryshme - cila metodë të përdoret varet saktësisht nga ajo që dëshironi prej saj.
Si të krahasoni dy kolona në Excel duke përdorur VLOOKUP
Kur ju keni dy kolona të dhënash dhe dëshironi të gjeni se cilat pika të dhënash nga një listë ekzistojnë në listën tjetër, mund të përdorni funksionin VLOOKUP për të krahasuar listat për vlerat e zakonshme.
Për të ndërtuar një formulë VLOOKUP në të forma bazë, kjo është ajo që duhet të bëni:
- Për lookup_value (argumenti i parë), përdorni qelizën më të lartë nga Lista 1.
- Për table_array (argumenti i dytë), jepni të gjithë Listën 2.
- Për col_index_num (argumenti i tretë), përdorni 1 pasi ka vetëm një kolonë në grup.
- Për range_lookup (argumenti i 4-të), vendosni FALSE - përputhje e saktë.
Supozoni se keni emrat e pjesëmarrësve në kolonën A (Lista 1) dhe emrat e atyre të cilët kanë kaluar nëpër raundet e kualifikimit në kolonën B (Lista 2). Ju dëshironi t'i krahasoni këto 2 lista për të përcaktuar se cilët pjesëmarrës nga Grupi A arritën në ngjarjen kryesore. Për ta bërë këtë, përdorni sa vijonformula.
=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
Formula shkon në qelizën E2 dhe më pas e tërhiqni poshtë nëpër aq qeliza sa ka artikuj në listën 1.
Ju lutemi vini re se array_tabela është i kyçur me referenca absolute ($C$2:$C$9) në mënyrë që të mbetet konstante kur kopjoni formulën në qelizat e mëposhtme.
Siç mund ta shihni, emrat e atletët e kualifikuar shfaqen në kolonën E. Për pjesëmarrësit e mbetur, shfaqet një gabim #N/A që tregon se emrat e tyre nuk janë të disponueshëm në listën 2.
Disguise #N/ Një gabim
Formula VLOOKUP e diskutuar më sipër përmbush në mënyrë të përsosur objektivin e saj kryesor - kthen vlerat e zakonshme dhe identifikon pikat e të dhënave që mungojnë. Megjithatë, ai jep një sërë gabimesh #N/A, të cilat mund të ngatërrojnë përdoruesit e papërvojë duke i bërë të mendojnë se diçka nuk shkon me formulën.
Për të zëvendësuar gabimet me qeliza bosh , përdorni VLOOKUP në kombinim me funksionin IFNA ose IFERROR në këtë mënyrë:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Formula jonë e përmirësuar kthen një varg bosh ("") në vend të #N/ A. Ju gjithashtu mund të ktheni tekstin tuaj të personalizuar si "Jo në listën 2", "Nuk është i pranishëm" ose "Nuk disponohet". Për shembull:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")
Kjo është formula bazë VLOOKUP për të krahasuar dy kolona në Excel. Në varësi të detyrës suaj të veçantë, ajo mund të modifikohet siç tregohet në shembujt e mëtejshëm.
Krahasoni dy kolona në fletë të ndryshme Excel duke përdorur VLOOKUP
Në jetën reale, kolonat që junevoja për të krahasuar nuk janë gjithmonë në të njëjtën fletë. Në një grup të vogël të dhënash, mund të provoni të dalloni ndryshimet me dorë duke parë dy fletë krah për krah.
Për të kërkuar në një fletë pune ose libër tjetër pune me formula, duhet të përdorni referencë të jashtme. Praktika më e mirë është të filloni të shkruani formulën në fletën tuaj kryesore, më pas të kaloni në fletën tjetër të punës dhe të zgjidhni listën duke përdorur miun - një referencë e përshtatshme e diapazonit do t'i shtohet formulës automatikisht.
Duke supozuar se Lista 1 është në kolonën A në Fleta1 dhe lista 2 është në kolonën A në Fleta2 , mund të krahasoni dy kolona dhe të gjeni përputhje duke përdorur këtë formulë:
=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")
Për më shumë informacion, ju lutemi shikoni:
- VLOOKUP nga një fletë tjetër
- VLOOKUP nga një libër tjetër pune
Krahasoni dy kolona dhe ktheni vlerat e zakonshme (përputhen)
Në shembujt e mëparshëm, ne diskutuam një formulë VLOOKUP në formën e saj më të thjeshtë:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Rezultati i asaj formule është një listë vlerash që ekzistojnë në të dy kolonat dhe në qelizat bosh në vend të vlerave që nuk disponohen në kolonën e dytë.
Për të marrë një listë të vlerave të zakonshme pa boshllëqe, thjesht shtoni një filtër automatik në kolonën që rezulton dhe filtro boshllëqet.
Në Excel për Microsoft 365 dhe Excel 2021 që s duke mbështetur vargjet dinamike, mund të përdorni funksionin FILTER për të shoshitur boshllëqet në mënyrë dinamike. Për këtë, përdorni formulën IFNA VLOOKUP sikriteret për FILTER:
=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")
Ju lutemi, kushtojini vëmendje që në këtë rast ne e furnizojmë të gjithë Listën 1 (A2:A14) me argumentin vlera_lookup të VLOOKUP. Funksioni krahason secilën nga vlerat e kërkimit me Listën 2 (C2:C9) dhe kthen një sërë ndeshjesh dhe gabime #N/A që përfaqësojnë vlerat që mungojnë. Funksioni IFNA zëvendëson gabimet me vargje boshe dhe i shërben rezultatet funksionit FILTER, i cili filtron boshllëqet ("") dhe nxjerr një sërë ndeshjesh si rezultat përfundimtar.
Përndryshe, mund të përdorni funksionin ISNA për të kontrolluar rezultatin e VLOOKUP-it dhe për të filtruar artikujt që vlerësohen në FALSE, d.m.th. vlera të tjera nga gabimet #N/A:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)
I njëjti rezultat mund të të arrihet me funksionin XLOOKUP, i cili e bën formulën edhe më të thjeshtë. Për shkak të aftësisë së XLOOKUP për të trajtuar gabimet #N/A brenda vetes (argumenti opsional nëse_nuk_found ), ne mund të bëjmë pa mbështjellësin IFNA ose ISNA:
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")
Krahaso dy kolona dhe gjeni vlerat që mungojnë (ndryshimet)
Për të krahasuar 2 kolona në Excel për të gjetur dallimet, mund të vazhdoni në këtë mënyrë:
- Shkruani formulën bazë për të kërkuar të parën vlera nga Lista 1 (A2) në listën 2 ($C$2:$C$9):
VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
- Folje formulën e mësipërme në funksionin ISNA për të kontrolluar daljen e VLOOKUP për gabimet #N/A. Në rast gabimi, ISNA jep TRUE, përndryshe FALSE:
ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))
- Përdor formulën ISNA VLOOKUP për testin logjik të funksionit IF. Nëse testi vlerësohet në TRUE (#N/A gabim), ktheni një vlerë nga Lista 1 në të njëjtin rresht. Nëse testi vlerësohet në FALSE (gjendet një përputhje në listën 2), ktheni një varg bosh.
Formula e plotë merr këtë formë:
=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")
Për të hequr qafe boshllëqet, aplikoni filtrin e Excel-it siç tregohet në shembullin e mësipërm.
Në Excel 365 dhe Excel 2021, mund ta keni listën e rezultateve të filtruar në mënyrë dinamike. Për këtë, thjesht vendosni formulën ISNA VLOOKUP në argumentin përfshi të funksionit FILTER:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))
Një mënyrë tjetër është të përdorni XLOOKUP për kritere - funksioni kthen vargje boshe ("") për pikat e të dhënave që mungojnë dhe ju filtroni vlerat në listën 1 për të cilat XLOOKUP ktheu vargjet boshe (=""):
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")
Formula VLOOKUP për të identifikuar përputhjet dhe dallimet midis dy kolonave
Nëse dëshironi të shtoni etiketa teksti në listën e parë që tregon se cilat vlera janë të disponueshme në listën e dytë dhe cilat jo, përdorni formulën VLOOKUP së bashku me Funksionet IF dhe ISNA/ISERROR.
Për shembull, për të identifikuar emrat që janë në të dy kolonat A dhe D dhe ata që janë vetëm në kolonën A, formula është:
=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")
Këtu, funksioni ISNA kap gabimet #N/A të krijuara nga VLOOKUP dhe ia kalon atë rezultat të ndërmjetëm funksionit IF për tëktheni tekstin e specifikuar për gabime dhe një tekst tjetër për kërkime të suksesshme.
Në këtë shembull, ne kemi përdorur etiketat "Jo i kualifikuar"/"Të kualifikuar", të cilat janë të përshtatshme për grupin tonë të të dhënave të mostrës. Mund t'i zëvendësoni me "Jo në listën 2"/"Në listën 2", "Nuk disponohet"/"E disponueshme" ose ndonjë etiketë tjetër që ju duket e përshtatshme.
Kjo formulë është më mirë të futet në një kolonë ngjitur me Listën 1 dhe kopjohet nëpër aq qeliza sa ka artikuj në listën tuaj.
Një mënyrë tjetër për të identifikuar përputhjet dhe dallimet në 2 kolona është përdorimi i funksionit MATCH:
=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")
Krahasoni 2 kolona dhe ktheni një vlerë nga e treta
Kur punoni me tabela që përmbajnë të dhëna të lidhura, ndonjëherë mund t'ju duhet të krahasoni dy kolona në dy tabela të ndryshme dhe ktheni një vlerë që përputhet nga një kolonë tjetër. Në fakt, është përdorimi parësor i funksionit VLOOKUP, qëllimi për të cilin është krijuar.
Për shembull, për të krahasuar emrat në kolonat A dhe D në dy tabelat më poshtë dhe për të kthyer një kohë nga kolona E , formula është:
=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)
Për të fshehur gabimet #N/A, përdorni zgjidhjen e provuar - funksionin IFNA:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")
Në vend të boshllëqeve, mund të ktheni çdo tekst që dëshironi për pikat e të dhënave që mungojnë - thjesht shkruani atë në argumentin e fundit. Për shembull:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")
Përveç VLOOKUP-it, detyra mund të përmbushet me disa funksione të tjera kërkimi.
Personalisht, do të mbështetesha në një INDEX më fleksibëlFormula MATCH:
=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")
Ose përdorni pasardhësin modern të VLOOKUP - funksionin XLOOKUP, i disponueshëm në Excel 365 dhe Excel 2021:
=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")
Për merrni emrat e pjesëmarrësve të kualifikuar nga grupi A dhe rezultatet e tyre, thjesht filtroni qelizat bosh në kolonën B:
=FILTER(A3:B15, B3:B15"")
Mjetet e krahasimit
Nëse bëni shpesh krahasime skedarësh ose të dhënash në Excel, këto mjete inteligjente të përfshira në Ultimate Suite mund t'ju kursejnë jashtëzakonisht shumë kohën!
Krahasoni tabelat - mënyrë e shpejtë për të gjetur dublikatat (përputhjet) dhe vlerat unike (ndryshimet) në çdo dy grupe të dhënash si kolona, lista ose tabela.
Krahaso dy fletë - gjej dhe thekso dallimet midis dy fletëve të punës.
Krahaso fletë të shumta - gjej dhe thekso dallimet në disa fletë menjëherë .
Praktikoni librin e punës për shkarkim
VLOOKUP në Excel për të krahasuar kolonat - shembujt (skedari .xlsx)
