Ipinapakita ng tutorial kung paano gamitin ang VLOOKUP formula sa Excel para paghambingin ang dalawang column para magbalik ng mga karaniwang value (mga tugma) o maghanap ng nawawalang data (mga pagkakaiba).

Kapag mayroon kang data sa dalawa magkaibang listahan, maaaring kailanganin mong ikumpara ang mga ito para makita kung anong impormasyon ang nawawala sa isa sa mga listahan o kung anong data ang nasa pareho. Ang paghahambing ay maaaring gawin sa maraming iba't ibang paraan - kung aling paraan ang gagamitin ay depende sa kung ano mismo ang gusto mo mula dito.

Paano ihambing ang dalawang column sa Excel gamit ang VLOOKUP

Kailan mayroon kang dalawang column ng data at gusto mong malaman kung aling mga data point mula sa isang listahan ang umiiral sa kabilang listahan, maaari mong gamitin ang VLOOKUP function para ihambing ang mga listahan para sa mga karaniwang value.

Upang bumuo ng VLOOKUP formula sa kanyang basic form, ito ang kailangan mong gawin:

• Para sa lookup_value (1st argument), gamitin ang pinakamataas na cell mula sa Listahan 1.
• Para sa table_array (2nd argument), ibigay ang buong Listahan 2.
• Para sa col_index_num (3rd argument), gumamit ng 1 dahil may isang column lang sa array.
• Para sa range_lookup (ika-4 na argumento), itakda ang FALSE - eksaktong tugma.

Ipagpalagay na mayroon kang mga pangalan ng mga kalahok sa column A (Listahan 1) at ang mga pangalan ng mga iyon na nakapasa sa mga qualification round sa column B (Listahan 2). Gusto mong paghambingin ang 2 listahang ito upang matukoy kung sinong mga kalahok mula sa Pangkat A ang pumunta sa pangunahing kaganapan. Upang gawin ito, gamitin ang sumusunodformula.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Pumunta ang formula sa cell E2, at pagkatapos ay i-drag mo ito pababa sa kasing dami ng mga cell na mayroong mga item sa Listahan 1.

Pakipansin na table_array ay naka-lock ng mga ganap na sanggunian ($C$2:$C$9) upang manatiling pare-pareho ito kapag kinopya mo ang formula sa mga cell sa ibaba.

Tulad ng nakikita mo, ang mga pangalan ng lalabas ang mga kwalipikadong atleta sa column E. Para sa mga natitirang kalahok, may lalabas na #N/A error na nagsasaad na hindi available ang kanilang mga pangalan sa Listahan 2.

Disguise #N/ Ang mga error

Ang formula ng VLOOKUP na tinalakay sa itaas ay ganap na natutupad ang pangunahing layunin nito - nagbabalik ng mga karaniwang halaga at kinikilala ang mga nawawalang punto ng data. Gayunpaman, naghahatid ito ng grupo ng #N/A error, na maaaring makalito sa mga bagitong user na nagpapaisip sa kanila na may mali sa formula.

Upang palitan ang mga error ng blank cell , gamitin ang VLOOKUP kasama ng IFNA o IFERROR function sa ganitong paraan:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Ang aming pinahusay na formula ay nagbabalik ng walang laman na string ("") sa halip na #N/ A. Maaari mo ring ibalik ang iyong pasadyang teksto gaya ng "Wala sa Listahan 2", "Wala," o "Hindi available." Halimbawa:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Iyon ang pangunahing formula ng VLOOKUP upang ihambing ang dalawang column sa Excel. Depende sa iyong partikular na gawain, maaari itong baguhin gaya ng ipinapakita sa mga karagdagang halimbawa.

Ihambing ang dalawang column sa magkaibang mga Excel sheet gamit ang VLOOKUP

Sa totoong buhay, ang mga column na iyongkailangang ihambing ay hindi palaging nasa parehong sheet. Sa isang maliit na dataset, maaari mong subukang manu-manong makita ang mga pagkakaiba sa pamamagitan ng pagtingin sa dalawang sheet na magkatabi.

Upang maghanap sa isa pang worksheet o workbook na may mga formula, kailangan mong gumamit ng panlabas na sanggunian. Ang pinakamahusay na kagawian ay simulan ang pag-type ng formula sa iyong pangunahing sheet, pagkatapos ay lumipat sa iba pang worksheet at piliin ang listahan gamit ang mouse - isang naaangkop na sanggunian sa hanay ay awtomatikong idaragdag sa formula.

Ipagpalagay na ang Listahan 1 ay sa column A sa Sheet1 at ang listahan 2 ay nasa column A sa Sheet2 , maaari kang maghambing ng dalawang column at maghanap ng mga tugma gamit ang formula na ito:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Para sa higit pang impormasyon, pakitingnan ang:

• VLOOKUP mula sa isa pang sheet
• VLOOKUP mula sa ibang workbook

Paghambingin ang dalawang column at ibalik ang mga karaniwang value (mga tugma)

Sa mga nakaraang halimbawa, tinalakay namin ang isang VLOOKUP formula sa pinakasimpleng anyo nito:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Ang resulta ng formula na iyon ay isang listahan ng mga value na umiiral sa parehong column at blangkong cell bilang kapalit ng mga value na hindi available sa pangalawang column.

Upang makakuha ng listahan ng mga karaniwang value na walang gaps, magdagdag lang ng auto-filter sa resultang column at i-filter ang mga blangko.

Sa Excel para sa Microsoft 365 at Excel 2021 na upport dynamic arrays, maaari mong gamitin ang FILTER function upang salain ang mga blangko nang pabago-bago. Para dito, gamitin ang IFNA VLOOKUP formula bilang angpamantayan para sa FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Mangyaring bigyang-pansin na sa kasong ito ibinibigay namin ang buong Listahan 1 (A2:A14) sa lookup_value argument ng VLOOKUP. Inihahambing ng function ang bawat isa sa mga value ng lookup laban sa Listahan 2 (C2:C9) at nagbabalik ng hanay ng mga tugma at #N/A error na kumakatawan sa mga nawawalang value. Pinapalitan ng IFNA function ang mga error ng walang laman na string at inihahatid ang mga resulta sa FILTER function, na nagpi-filter ng mga blangko ("") at naglalabas ng hanay ng mga tugma bilang huling resulta.

Bilang kahalili, maaari mong gamitin ang ISNA function upang suriin ang resulta ng VLOOKUP at i-filter ang mga item na sinusuri sa FALSE, ibig sabihin, mga value maliban sa #N/A error:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Ang parehong resulta ay maaaring ay makakamit gamit ang XLOOKUP function, na ginagawang mas simple ang formula. Dahil sa kakayahan ng XLOOKUP na pangasiwaan ang mga #N/A error sa loob (opsyonal if_not_found argument), magagawa namin nang wala ang IFNA o ISNA wrapper:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Ihambing dalawang column at maghanap ng mga nawawalang value (mga pagkakaiba)

Upang paghambingin ang 2 column sa Excel para maghanap ng mga pagkakaiba, maaari kang magpatuloy sa ganitong paraan:

1. Isulat ang pangunahing formula para hanapin ang una value mula sa Listahan 1 (A2) sa Listahan 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. I-nest ang formula sa itaas sa function ng ISNA upang suriin ang output ng VLOOKUP para sa mga #N/A error. Sa kaso ng isang error, ang ISNA ay magbubunga ng TRUE, kung hindi man MALI:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

   Tingnan din: Excel: Hatiin ang string ayon sa delimiter o pattern, magkahiwalay na text at mga numero
3. Gamitin ang ISNA VLOOKUP formula para sa lohikal na pagsubok ng IF function. Kung ang pagsubok ay magiging TRUE (#N/A error), magbalik ng value mula sa Listahan 1 sa parehong row. Kung ang pagsubok ay naging FALSE (may nakitang tugma sa Listahan 2), magbalik ng walang laman na string.

Ang kumpletong formula ay ganito ang form:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Upang maalis ang mga blangko, ilapat ang Filter ng Excel tulad ng ipinakita sa halimbawa sa itaas.

Sa Excel 365 at Excel 2021, maaari mong i-filter ang listahan ng resulta nang dynamic na paraan. Para dito, ilagay lang ang ISNA VLOOKUP formula sa include argument ng FILTER function:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Ang isa pang paraan ay ang gamitin ang XLOOKUP para sa pamantayan - ang function ay nagbabalik ng mga walang laman na string ("") para sa mga nawawalang punto ng data, at sinasala mo ang mga halaga sa Listahan 1 kung saan ang XLOOKUP ay nagbalik ng mga walang laman na string (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP formula para matukoy ang mga tugma at pagkakaiba sa pagitan ng dalawang column

Kung gusto mong magdagdag ng mga text label sa unang listahan na nagsasaad kung aling mga value ang available sa pangalawang listahan at alin ang hindi, gamitin ang VLOOKUP formula kasama ang IF at ISNA/ISERROR functions.

Halimbawa, upang matukoy ang mga pangalan na nasa parehong column A at D at ang mga nasa column A lang, ang formula ay:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Dito, kinukuha ng ISNA function ang #N/A error na nabuo ng VLOOKUP at ipinapasa ang intermediate na resulta sa IF function para ditoibalik ang tinukoy na text para sa mga error at isa pang text para sa matagumpay na paghahanap.

Sa halimbawang ito, gumamit kami ng mga label na "Not qualified"/"Qualified", na angkop para sa aming sample na dataset. Maaari mong palitan ang mga ito ng "Wala sa Listahan 2"/"Sa Listahan 2", "Hindi available"/"Available" o anumang iba pang mga label na sa tingin mo ay angkop.

Ang formula na ito ay pinakamainam na ilagay sa isang column katabi ng Listahan 1 at kinopya sa kasing dami ng mga cell na mayroong mga item sa iyong listahan.

Ang isa pang paraan upang matukoy ang mga tugma at pagkakaiba sa 2 column ay ang paggamit ng MATCH function:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Ihambing ang 2 column at ibalik ang isang value mula sa pangatlo

Kapag nagtatrabaho sa mga talahanayan na naglalaman ng nauugnay na data, maaaring kailanganin mong minsan ihambing ang dalawang column sa dalawang magkaibang talahanayan at magbalik ng katumbas na halaga mula sa isa pang column. Sa katunayan, ito ang pangunahing paggamit ng VLOOKUP function, ang layunin kung saan ito idinisenyo.

Halimbawa, upang ihambing ang mga pangalan sa column A at D sa dalawang talahanayan sa ibaba at magbalik ng oras mula sa column E , ang formula ay:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Upang itago ang #N/A error, gamitin ang napatunayang solusyon - ang function ng IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Sa halip na mga blangko, maaari mong ibalik ang anumang text na gusto mo para sa mga nawawalang punto ng data - i-type lang ito sa huling argumento. Halimbawa:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Bukod sa VLOOKUP, maaaring matupad ang gawain sa ilang iba pang function ng paghahanap.

Personal, aasa ako sa isang mas nababaluktot na INDEXMATCH formula:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

O gamitin ang modernong kahalili ng VLOOKUP - ang XLOOKUP function, na available sa Excel 365 at Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Para kunin ang mga pangalan ng mga kwalipikadong kalahok mula sa pangkat A at ang kanilang mga resulta, i-filter lang ang mga blangkong cell sa column B:

=FILTER(A3:B15, B3:B15"")

Mga tool sa paghahambing

Kung madalas kang gumagawa ng paghahambing ng file o data sa Excel, ang mga matalinong tool na ito na kasama sa aming Ultimate Suite ay makakatipid sa iyong oras nang husto!

Ihambing ang Mga Talahanayan - mabilis na paraan upang makahanap ng mga duplicate (mga tugma) at natatanging halaga (mga pagkakaiba) sa alinmang dalawang set ng data gaya ng mga column, listahan o talahanayan.

Ihambing ang Dalawang Sheet - hanapin at i-highlight ang mga pagkakaiba sa pagitan ng dalawang worksheet.

Paghambingin ang Maramihang Sheet - hanapin at i-highlight ang mga pagkakaiba sa maraming sheet nang sabay-sabay .

Magsanay ng workbook para sa pag-download

VLOOKUP sa Excel upang ihambing ang mga column - mga halimbawa (.xlsx file)