Mundarija
O'quv qo'llanma Excelda VLOOKUP formulasidan umumiy qiymatlarni (mosliklarni) qaytarish yoki etishmayotgan ma'lumotlarni (farqlarni) topish uchun ikkita ustunni solishtirish uchun qanday ishlatishni ko'rsatadi.
Agar sizda ikkita ma'lumot mavjud bo'lsa. turli roʻyxatlar boʻlsa, roʻyxatlardan birida qanday maʼlumotlar etishmayotganligini yoki ikkalasida ham qaysi maʼlumotlar mavjudligini koʻrish uchun ularni solishtirish kerak boʻlishi mumkin. Taqqoslash turli yo'llar bilan amalga oshirilishi mumkin - qaysi usuldan foydalanish aynan siz undan nimani xohlayotganingizga bog'liq.
VLOOKUP yordamida Excelda ikkita ustunni qanday solishtirish mumkin
Qachon sizda ikkita maʼlumot ustuni bor va bitta roʻyxatdagi qaysi maʼlumotlar nuqtalari boshqa roʻyxatda mavjudligini bilmoqchi boʻlsangiz, umumiy qiymatlar boʻyicha roʻyxatlarni solishtirish uchun VLOOKUP funksiyasidan foydalanishingiz mumkin.
Unda VLOOKUP formulasini yaratish uchun asosiy shaklda, buni qilishingiz kerak:
- qidiruv_qiymati (1-argument) uchun 1-roʻyxatdagi eng yuqori katakchadan foydalaning.
- <1 uchun>jadval_massivi (2-argument), butun roʻyxat 2ni taqdim eting.
- col_index_num (3-argument) uchun massivda faqat bitta ustun borligi sababli 1 dan foydalaning.
- diapazon_qidiruv (4-argument) uchun FALSE - aniq moslikni o'rnating.
Sizda A ustunida (1-ro'yxat) ishtirokchilarning ismlari va ularning nomlari bor deylik. B ustunidagi saralash bosqichlaridan o'tganlar (2-ro'yxat). A guruhidan qaysi ishtirokchilar asosiy tadbirga yo'l olganini aniqlash uchun ushbu 2 ro'yxatni solishtirmoqchisiz. Buning uchun quyidagilardan foydalaningformula.
=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
Formula E2 yacheykaga o'tadi va keyin siz uni 1-ro'yxatdagi qancha elementlar bo'lsa, shuncha katakchalar bo'ylab pastga tortasiz.
E'tibor bering, jadval_massivi mutlaq havolalar ($C$2:$C$9) bilan bloklangan, shuning uchun formulani quyidagi katakchalarga nusxalashda u doimiy boʻlib qoladi.
Koʻrib turganingizdek, malakali sportchilar E ustunida ko'rsatiladi. Qolgan ishtirokchilar uchun ularning ismlari 2-ro'yxatda mavjud emasligini ko'rsatuvchi #N/A xatosi paydo bo'ladi.
Maska #N/ Xatolar
Yuqorida muhokama qilingan VLOOKUP formulasi o'zining asosiy maqsadini mukammal darajada bajaradi - umumiy qiymatlarni qaytaradi va etishmayotgan ma'lumotlar nuqtalarini aniqlaydi. Biroq, u #N/A bir qator xatolarni yetkazib beradi, bu esa tajribasiz foydalanuvchilarni chalkashtirib yuborishi, ularni formulada nimadir noto‘g‘ri deb o‘ylashiga sabab bo‘lishi mumkin.
Xatolarni bo‘sh katakchalar bilan almashtirish uchun VLOOKUP-dan foydalaning. IFNA yoki IFERROR funksiyasi bilan birgalikda shu tarzda:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Bizning yaxshilangan formulamiz #N/ o'rniga bo'sh qatorni ("") qaytaradi. A. Shuningdek, "2-ro'yxatda yo'q", "Mavjud emas" yoki "Mavjud emas" kabi maxsus matnni qaytarishingiz mumkin. Masalan:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")
Bu Excelda ikkita ustunni solishtirish uchun asosiy VLOOKUP formulasi. Muayyan vazifangizga qarab, u keyingi misollarda ko'rsatilganidek o'zgartirilishi mumkin.
VLOOKUP yordamida turli Excel varaqlaridagi ikkita ustunni solishtiring
Haqiqiy hayotda siz ustunlarsolishtirish kerak har doim ham bir varaqda emas. Kichik ma'lumotlar to'plamida siz ikkita varaqni yonma-yon ko'rish orqali farqlarni qo'lda aniqlashga harakat qilishingiz mumkin.
Boshqa ishchi varaqda yoki formulalar bilan ish kitobida qidirish uchun siz tashqi havoladan foydalanishingiz kerak. Eng yaxshi amaliyot formulani asosiy varaqda yozishni boshlash, keyin boshqa ish varag‘iga o‘tish va sichqoncha yordamida ro‘yxatni tanlashdir – formulaga avtomatik ravishda tegishli diapazon havolasi qo‘shiladi.
Ro‘yxat 1 deb faraz qilinadi. Sheet1 da A ustunida va 2-ro'yxat Vraq2 da A ustunida joylashgan bo'lsa, quyidagi formula yordamida ikkita ustunni solishtirishingiz va mosliklarni topishingiz mumkin:
=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")
Qo'shimcha ma'lumot olish uchun qarang:
- Boshqa varaqdan VLOOKUP
- Turli ish kitobidan VLOOKUP
Ikkita ustunni solishtiring va umumiy qiymatlarni (mosliklarni) qaytaring
Oldingi misollarda biz VLOOKUP formulasini eng oddiy shaklda muhokama qildik:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Ushbu formulaning natijasi: Ikkinchi ustunda mavjud bo'lmagan qiymatlar o'rniga ikkala ustun va bo'sh kataklarda mavjud bo'lgan qiymatlar ro'yxati.
Bo'shliqlarsiz umumiy qiymatlar ro'yxatini olish uchun natijada paydo bo'lgan ustunga avtomatik filtr qo'shing va bo'sh joylarni filtrlang.
Microsoft 365 va Excel 2021 uchun Excelda bu s dinamik massivlarni qo'llab-quvvatlasangiz, bo'sh joylarni dinamik ravishda saralash uchun FILTER funksiyasidan foydalanishingiz mumkin. Buning uchun IFNA VLOOKUP formulasidan foydalaningFILTER mezonlari:
=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")
Iltimos, diqqat qiling, bu holda biz 1-roʻyxatni (A2:A14) VLOOKUPning qidiruv_qiymati argumentiga taqdim etamiz. Funksiya har bir qidiruv qiymatlarini 2-ro‘yxat (C2:C9) bilan solishtiradi va etishmayotgan qiymatlarni ifodalovchi moslik va #Yo‘q xatolar qatorini qaytaradi. IFNA funksiyasi xatolarni bo'sh satrlar bilan almashtiradi va natijalarni bo'sh joylarni ("") filtrlaydigan va yakuniy natija sifatida mos keladigan qatorni chiqaradigan FILTER funksiyasiga xizmat qiladi.
Shuningdek, siz VLOOKUP natijasini tekshirish uchun ISNA funksiyasidan foydalanishingiz va FALSE deb baholanadigan elementlarni filtrlashingiz mumkin, yaʼni #N/A xatolaridan boshqa qiymatlar:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)
Xuddi shu natija boʻlishi mumkin XLOOKUP funksiyasi yordamida erishish mumkin, bu formulani yanada soddalashtiradi. XLOOKUP ning #N/A xatolarini ichki boshqarish qobiliyati tufayli (ixtiyoriy agar_topilmasa argumenti), biz IFNA yoki ISNA oʻramisiz ishlay olamiz:
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")
Solishtiring ikkita ustun va etishmayotgan qiymatlarni (farqlarni) toping
Farqlarni topish uchun Excelda 2 ta ustunni solishtirish uchun quyidagi yoʻl bilan harakat qilishingiz mumkin:
- Birinchisini qidirish uchun asosiy formulani yozing. 2-roʻyxatdagi 1 (A2) qiymati ($C$2:$C$9):
VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
- Uyaga joylashtirish VLOOKUP chiqishida #N/A xatolarini tekshirish uchun ISNA funksiyasidagi yuqoridagi formuladan foydalaning. Xato boʻlsa, ISNA TRUE, aks holda FALSE:
ISNA(VLOOKUP(A2,)$C$2:$C$9, 1, FALSE))
- IF funksiyasini mantiqiy tekshirish uchun ISNA VLOOKUP formulasidan foydalaning. Agar test TRUE (#N/A xatosi) deb baholansa, xuddi shu qatordagi 1-roʻyxatdagi qiymatni qaytaring. Agar test FALSE deb baholansa (2-roʻyxatda moslik topilsa), boʻsh qatorni qaytaring.
Toʻliq formula quyidagi shaklni oladi:
=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")
Bo'shliqlardan xalos bo'lish uchun yuqoridagi misolda ko'rsatilgandek Excel filtrini qo'llang.
Excel 365 va Excel 2021 da siz natijalar ro'yxatini dinamik ravishda filtrlashingiz mumkin. Buning uchun FILTER funksiyasining include argumentiga ISNA VLOOKUP formulasini qo'ying:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))
Boshqa usul - mezonlar uchun XLOOKUP dan foydalaning - funksiya etishmayotgan ma'lumotlar nuqtalari uchun bo'sh satrlarni ("") qaytaradi va siz XLOOKUP bo'sh satrlarni (="" qaytargan 1-ro'yxatdagi qiymatlarni filtrlaysiz):
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")
Ikki ustun oʻrtasidagi moslik va farqlarni aniqlash uchun VLOOKUP formulasi
Agar siz birinchi roʻyxatga ikkinchi roʻyxatda qaysi qiymatlar mavjudligi va qaysi biri yoʻqligini koʻrsatuvchi matn teglarini qoʻshishni istasangiz, VLOOKUP formulasidan foydalaning. IF va ISNA/ISERROR funksiyalari.
Masalan, A va D ustunlaridagi va faqat A ustunidagi nomlarni aniqlash uchun formula:
=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")
Bu yerda ISNA funksiyasi VLOOKUP tomonidan yaratilgan #N/A xatolarini ushlaydi va bu oraliq natijani IF funktsiyasiga uzatadi.xatolar uchun belgilangan matnni va muvaffaqiyatli qidirish uchun boshqa matnni qaytaring.
Ushbu misolda biz namunaviy maʼlumotlar toʻplamimiz uchun mos boʻlgan “Malakali emas”/“Malakali” yorliqlardan foydalandik. Siz ularni "2-ro'yxatda yo'q"/"2-ro'yxatda", "Mavjud emas"/"Mavjud" yoki o'zingizga mos keladigan boshqa yorliqlar bilan almashtirishingiz mumkin.
Bu formulani ustunga kiritish yaxshidir. 1-roʻyxatga qoʻshni boʻlib, roʻyxatingizda qancha elementlar boʻlsa, shuncha katakchadan koʻchiriladi.
2 ustundagi moslik va farqlarni aniqlashning yana bir usuli bu MATCH funksiyasidan foydalanish:
=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")
2 ustunni solishtiring va uchinchidan qiymatni qaytaring
Tegishli ma'lumotlarni o'z ichiga olgan jadvallar bilan ishlashda ba'zan sizga kerak bo'lishi mumkin. ikki xil jadvaldagi ikkita ustunni solishtiring va boshqa ustundan mos qiymatni qaytaring. Darhaqiqat, bu VLOOKUP funksiyasining asosiy qo'llanilishi, u mo'ljallangan maqsaddir.
Masalan, quyidagi ikkita jadvaldagi A va D ustunlaridagi nomlarni solishtirish va E ustunidan vaqtni qaytarish. , formula:
=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)
#N/A xatolarini yashirish uchun tasdiqlangan yechimdan foydalaning - IFNA funktsiyasi:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")
Bo'sh joylar o'rniga etishmayotgan ma'lumotlar nuqtalari uchun istalgan matnni qaytarishingiz mumkin - uni oxirgi argumentga kiriting. Masalan:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")
VLOOKUP bilan bir qatorda, topshiriq bir nechta boshqa qidirish funksiyalari bilan ham bajarilishi mumkin.
Shaxsan men yanada moslashuvchan INDEXga tayangan bo'lardim.MATCH formulasi:
=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")
Yoki VLOOKUP-ning zamonaviy vorisi - Excel 365 va Excel 2021-da mavjud XLOOKUP funksiyasidan foydalaning:
=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")
To A guruhidagi malakali ishtirokchilarning ismlarini va ularning natijalarini oling, shunchaki B ustunidagi bo'sh kataklarni filtrlang:
=FILTER(A3:B15, B3:B15"")
Taqqoslash vositalari
Agar siz Excelda fayl yoki maʼlumotlarni tez-tez taqqoslash bilan shugʻullansangiz, bizning Ultimate Suite tarkibiga kiritilgan ushbu aqlli vositalar vaqtingizni sezilarli darajada tejaydi!
Jadvallarni solishtiring – takroriy (mosliklar) va noyob qiymatlarni (farqlar) topishning tezkor usuli ustunlar, roʻyxatlar yoki jadvallar kabi istalgan ikkita maʼlumotlar toʻplamida.
Ikki varaqni solishtiring – ikkita ish varaqlari orasidagi farqlarni toping va ajratib koʻrsating.
Bir nechta varaqlarni solishtiring – bir vaqtning oʻzida bir nechta varaqlardagi farqlarni toping va ajratib koʻrsating. .
Yuklab olish uchun mashq kitobi
Ustunlarni solishtirish uchun Excelda VLOOKUP - misollar (.xlsx fayli)
