Walaupun kiraan perkataan dan aksara dalam Helaian Google digunakan dalam kes yang jarang berlaku, ia masih merupakan fungsi yang diharapkan oleh sesetengah daripada kita untuk melihat terus dalam menu. Tetapi tidak seperti Dokumen Google, untuk Helaian Google, fungsi LEN yang melakukan perkara itu.

Walaupun terdapat banyak cara berbeza untuk mengira aksara dalam hamparan, catatan blog hari ini akan merangkumi fungsi LEN sebagai tujuan utama dalam jadual adalah untuk – baik, mengira :) Walau bagaimanapun, ia jarang digunakan sendiri. Di bawah anda akan belajar cara menggunakan Google Sheets LEN dengan betul dan mencari formula yang paling dikehendaki untuk mengira aksara dalam hamparan.

Fungsi Google Sheets LEN – penggunaan dan sintaks

The utama dan satu-satunya tujuan fungsi LEN dalam Helaian Google ialah mendapatkan panjang rentetan. Ia sangat mudah sehingga ia memerlukan hanya 1 hujah:

• ia boleh mengambil sama ada teks itu sendiri dalam petikan dua kali:

  =LEN("Yggdrasil")

• atau rujukan kepada sel dengan teks yang diminati:

  =LEN(A2)

Mari kita lihat sama ada terdapat sebarang keanehan dalam menggunakan fungsi dalam hamparan.

Watak kira dalam Helaian Google

Saya akan mulakan dengan operasi yang paling mudah: lakukan kiraan aksara dalam Helaian Google dengan cara yang paling biasa – dengan merujuk sel dengan teks menggunakan fungsi LEN.

I masukkan formula ke B2 dan salin ke bawah keseluruhan lajur untuk mengira aksara dalam setiap baris:

=LEN(A2)

Nota. Fungsi LENmengira semua aksara: huruf, nombor, ruang, tanda baca, dsb.

Anda mungkin berfikir bahawa dengan cara yang sama anda boleh melakukan kiraan aksara untuk keseluruhan julat sel, seperti ini: LEN(A2:A6) . Tetapi, seperti Walaupun pelik, ia tidak hanya berfungsi dengan cara ini.

Untuk jumlah aksara dalam beberapa sel, anda harus membungkus LEN anda dalam SUMPRODUCT – fungsi yang mengira nombor daripada julat yang dimasukkan. Dalam kes saya, julat dikembalikan oleh fungsi LEN:

=SUMPRODUCT(LEN(A2:A6))

Sudah tentu, anda boleh memasukkan fungsi SUM sebaliknya. Tetapi SUM dalam Helaian Google tidak memproses tatasusunan daripada fungsi lain. Untuk menjadikannya berfungsi, anda perlu menambah fungsi lain – ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Cara mengira aksara tanpa ruang dalam Helaian Google

Seperti yang saya nyatakan di atas, Helaian Google Fungsi LEN mengira setiap aksara yang dilihat termasuk ruang.

Tetapi bagaimana jika terdapat ruang tambahan ditambah secara tidak sengaja dan anda tidak mahu mempertimbangkannya untuk hasilnya?

Untuk kes seperti ini, terdapat fungsi TRIM dalam Helaian Google. Ia menyemak teks untuk mendahului, mengekori dan ruang berulang di antara. Apabila TRIM digandingkan dengan LEN, yang terakhir tidak mengira semua ruang ganjil tersebut.

Berikut ialah contohnya. Saya menambah ruang dalam kedudukan berbeza dalam lajur A. Seperti yang anda lihat, apabila sendiri, Helaian Google LEN mengira kesemuanya:

=LEN(A2)

Tetapi sebaik sahaja anda menyepadukan TRIM, semua tambahan ruang adalahdiabaikan:

=LEN(TRIM(A2))

Anda boleh pergi lebih jauh dan membuat formula anda mengabaikan walaupun ruang tunggal antara perkataan. Fungsi SUBSTITUTE akan membantu. Walaupun tujuan utamanya adalah untuk menggantikan satu aksara dengan yang lain, terdapat helah untuk menjadikannya mengurangkan ruang sepenuhnya:

• text_to_search ialah julat yang anda gunakan: lajur A atau A2 tepatnya.
• cari_untuk hendaklah menjadi aksara ruang dalam petikan dua kali: " "
• ganti_dengan hendaklah mengandungi petikan berganda kosong. Jika anda akan mengabaikan ruang, anda perlu menggantikannya dengan apa-apa (rentetan kosong): ""
• nombor_kejadian biasanya digunakan untuk menentukan kejadian untuk menggantikan. Tetapi kerana saya menerangkan cara mengira aksara tanpa semua ruang, saya cadangkan anda meninggalkan hujah ini kerana ia adalah pilihan.

Sekarang cuba dan kumpulkan semua ini ke dalam Helaian Google LEN dan anda akan melihatnya tiada ruang diambil kira:

=LEN(SUBSTITUTE(A2, " ", ""))

Helaian Google: kira aksara tertentu

Selaras yang sama bagi Helaian Google LEN dan SUBSTITUTE digunakan apabila anda perlu mengira aksara tertentu , huruf atau nombor.

Dalam contoh saya, saya akan mengetahui bilangan kejadian untuk huruf 's'. Dan kali ini, saya akan mulakan dengan formula sedia:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Mari kita pecahkan kepada bahagian untuk memahami caranyaberfungsi:

1. SUBSTITUTE(A2, "s", "") mencari huruf 's' dalam A2 dan menggantikan semua kejadian dengan "nothing", atau rentetan kosong ( "").
2. LEN(SUBSTITUTE(A2, "s", "") menyenaraikan nombor semua aksara tetapi 's' dalam A2.
3. LEN(A2) mengira semua aksara dalam A2.
4. Akhir sekali, anda menolak satu daripada yang lain.

Perbezaan hasil menunjukkan bilangan 's' yang terdapat dalam sel:

Nota. Anda mungkin tertanya-tanya mengapa B1 mengatakan hanya ada 1 's' dalam A2 sedangkan anda boleh melihat 3?

Perkaranya, fungsi SUBSTITUTE adalah sensitif huruf besar-besaran. Saya memintanya untuk mengambil semua contoh 's' dalam huruf kecil dan begitu juga.

Untuk menjadikannya mengabaikan kes teks dan memproses huruf dalam kedua-dua huruf kecil dan besar, anda perlu memanggil satu lagi fungsi Helaian Google untuk mendapatkan bantuan: RENDAH.

Petua. Lihat cara lain yang mengubah huruf besar kecil dalam Helaian Google.

Ia semudah Helaian Google LEN dan TRIM kerana ia hanya memerlukan teks:

=LOWER(text)

Dan semua yang dilakukannya ialah mengubah keseluruhan rentetan teks menjadi int o huruf kecil. Silap mata ini ialah perkara yang anda perlukan untuk membuat Helaian Google mengira aksara tertentu tidak kira kes teksnya:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Petua. Dan seperti sebelum ini, untuk mengira jumlah aksara tertentu dalam julat, bungkus LEN anda dalam SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Kira perkataan dalam Helaian Google

Apabila ada adalah berbilang perkataan dalam sel, kemungkinan besar anda perlu mempunyai nombornya dan bukannyapanjang rentetan Helaian Google.

Walaupun terdapat pelbagai cara untuk berbuat demikian, hari ini saya akan menyebut cara Google Sheets LEN menjalankan tugas.

Ingat formula yang saya gunakan untuk mengira aksara tertentu dalam Helaian Google? Malah, ia akan berguna di sini juga. Kerana saya tidak akan mengira perkataan secara literal. Sebaliknya, saya akan mengira bilangan ruang antara perkataan dan kemudian hanya menambah 1. Sila lihat:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) mengira bilangan semua aksara dalam sel.
2. LEN(SUBSTITUTE((A2)," ","")) mengalih keluar semua ruang daripada rentetan teks dan mengira aksara yang tinggal.
3. Kemudian anda tolak satu daripada yang lain, dan perbezaan yang anda dapat ialah bilangan ruang dalam sel.
4. Memandangkan perkataan sentiasa melebihi ruang dalam ayat dengan satu, anda menambah 1 pada penghujungnya.

Helaian Google: kira perkataan tertentu

Akhir sekali, saya ingin berkongsi formula Helaian Google yang boleh anda gunakan untuk mengira perkataan tertentu.

Di sini saya ada Lagu The Mock Turtle dari Alice's Adventures in Wonderland:

Saya ingin tahu berapa kali perkataan 'akan' muncul dalam setiap baris. Saya percaya anda tidak akan terkejut jika saya memberitahu anda bahawa formula yang saya perlukan terdiri daripada fungsi yang sama seperti sebelumnya: Helaian Google LEN, SUBSTITUTE dan LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Formula mungkin kelihatan menakutkan tetapi saya boleh memberi jaminan kepada anda bahawa ia mudah difahami, jadi bersabarlah dengan saya :)

1. Memandangkan kes teks tidakpenting bagi saya, saya menggunakan LOWER(A2) untuk menukar semuanya kepada huruf kecil.
2. Kemudian pergi SUBSTITUTE(LOWER(A2), "will",""))) – ia menyingkirkan semua kejadian 'akan' dengan menggantikannya dengan rentetan kosong ("").
3. Selepas itu, saya menolak bilangan aksara tanpa perkataan 'akan' daripada jumlah panjang rentetan . Nombor yang saya dapat mengira semua aksara dalam semua kejadian 'akan' dalam setiap baris.

   Oleh itu, jika 'akan' muncul sekali, nombornya ialah 4 kerana terdapat 4 huruf dalam perkataan itu. Jika ia muncul dua kali, nombornya ialah 8, dan seterusnya.

4. Akhir sekali, saya membahagikan nombor ini dengan panjang perkataan tunggal 'akan'.

Petua. Dan sekali lagi, jika anda lebih suka mendapatkan jumlah bilangan semua kemunculan perkataan 'akan', cuma sertakan keseluruhan formula mengikut SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Seperti yang anda lihat , semua kes kiraan aksara ini diselesaikan dengan corak yang sama bagi fungsi yang sama untuk Helaian Google: LEN, SUBSTITUTE, LOWER dan SUMPRODUCT.

Jika sesetengah formula masih mengelirukan anda atau jika anda tidak pasti bagaimana untuk menggunakan segala-galanya untuk tugas tertentu anda, jangan segan dan tanya di bahagian komen di bawah!