Ynhâldsopjefte
De tutorial lit sjen hoe't jo VLOOKUP-formule yn Excel brûke om twa kolommen te fergelykjen om mienskiplike wearden (oerienkomsten) werom te jaan of ûntbrekkende gegevens (ferskillen) te finen.
As jo gegevens yn twa hawwe ferskate listen, kinne jo faaks moatte ferlykje se om te sjen hokker ynformaasje ûntbrekt yn ien fan de listen of hokker gegevens is oanwêzich yn beide. Fergeliking kin op in protte ferskillende manieren dien wurde - hokker metoade te brûken hinget ôf fan krekt wat jo derfan wolle.
Hoe kinne jo twa kolommen yn Excel fergelykje mei VLOOKUP
Wannear jo hawwe twa kolommen mei gegevens en wolle útfine hokker gegevenspunten fan de iene list yn de oare list besteane, kinne jo de VLOOKUP-funksje brûke om de listen te fergelykjen foar mienskiplike wearden.
Om in VLOOKUP-formule te bouwen yn har basisfoarm, dit is wat jo moatte dwaan:
- Foar lookup_value (1e argumint), brûk de boppeste sel fan List 1.
- Foar tabel_array (2e argumint), leverje de hiele List 2.
- Foar col_index_num (3e argumint), brûk 1 om't der mar ien kolom yn 'e array is.
- Foar range_lookup (4e argumint), set FALSE - exact match.
Stel dat jo de nammen hawwe fan dielnimmers yn kolom A (List 1) en de nammen fan dy dy't troch de kwalifikaasjerûndes yn kolom B (List 2) trochgien binne. Jo wolle dizze 2 listen fergelykje om te bepalen hokker dielnimmers fan groep A har wei nei it haadevenemint makken. Om dit te dwaan, brûk de folgjendeformule.
=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
De formule giet nei sel E2, en dan slepe jo it nei ûnderen troch safolle sellen as der items yn List 1 binne.
Tink derom dat tabel_array is beskoattele mei absolute referinsjes ($C$2:$C$9), sadat it konstant bliuwt as jo de formule nei de ûndersteande sellen kopiearje.
Sa't jo sjen kinne, binne de nammen fan de kwalifisearre atleten ferskine yn kolom E. Foar de oerbleaune dielnimmers ferskynt in #N/A flater dy't oanjout dat harren nammen net beskikber binne yn List 2.
Disguise #N/ A flaters
De hjirboppe besprutsen VLOOKUP-formule foldocht perfekt oan syn haaddoel - jout mienskiplike wearden werom en identifisearret ûntbrekkende gegevenspunten. It leveret lykwols in bulte #N/A flaters, dy't sûnder ûnderfining brûkers betize kinne meitsje dat se tinke dat der wat mis is mei de formule.
Om flaters te ferfangen troch lege sellen , brûk VLOOKUP yn kombinaasje mei de IFNA- of IFERROR-funksje op dizze manier:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Us ferbettere formule jout in lege tekenrige ("") ynstee fan #N/ IN. Jo kinne ek jo oanpaste tekst weromjaan, lykas "Net yn list 2", "Net oanwêzich", of "Net beskikber". Bygelyks:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")
Dat is de basis VLOOKUP-formule om twa kolommen yn Excel te fergelykjen. Ofhinklik fan jo bepaalde taak, kin it wizige wurde lykas werjûn yn fierdere foarbylden.
Fergelykje twa kolommen yn ferskate Excel-blêden mei VLOOKUP
Yn it echte libben binne de kolommen dy't jomoatte fergelykje binne net altyd op itselde blêd. Yn in lytse dataset kinne jo besykje de ferskillen manuell te spotten troch twa blêden njonken inoar te besjen.
Om te sykjen yn in oar wurkblêd of wurkboek mei formules, moatte jo eksterne referinsje brûke. De bêste praktyk is om te begjinnen mei it typen fan de formule yn jo haadblêd, wikselje dan nei it oare wurkblêd en selektearje de list mei de mûs - in passende berikferwizing sil automatysk oan de formule tafoege wurde.
Ungeande fan List 1 is yn kolom A op Blêd1 en list 2 is yn kolom A op Blêd2 , kinne jo twa kolommen fergelykje en wedstriden fine mei dizze formule:
=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")
Sjoch foar mear ynformaasje:
- VLOOKUP fan in oar blêd
- VLOOKUP fan in oar wurkboek
Fergelykje twa kolommen en jouwe mienskiplike wearden (oerienkomsten) werom
Yn 'e foargeande foarbylden hawwe wy in VLOOKUP-formule besprutsen yn syn ienfâldichste foarm:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
It resultaat fan dy formule is in list mei wearden dy't besteane yn sawol kolommen as lege sellen yn plak fan de wearden dy't net beskikber binne yn 'e twadde kolom.
Om in list mei mienskiplike wearden sûnder gatten te krijen, foegje gewoan auto-filter ta oan 'e resultearjende kolom en filterje blanks.
Yn Excel foar Microsoft 365 en Excel 2021 is dat opport dynamyske arrays, kinne jo gebrûk meitsje fan de FILTER funksje foar in sift út blanks dynamysk. Brûk hjirfoar de IFNA VLOOKUP-formule as dekritearia foar FILTER:
=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")
Tink asjebleaft dat wy yn dit gefal de hiele List 1 (A2:A14) leverje oan it argumint lookup_value fan VLOOKUP. De funksje fergeliket elk fan 'e opsykwearden tsjin List 2 (C2: C9) en jout in array fan wedstriden en #N/A-flaters dy't ûntbrekkende wearden fertsjintwurdigje. De IFNA-funksje ferfangt flaters mei lege snaren en tsjinnet de resultaten oan de FILTER-funksje, dy't blanks filtert ("") en in array fan wedstriden as einresultaat útfiert.
Alternatyf kinne jo de ISNA-funksje brûke om it resultaat fan VLOOKUP te kontrolearjen en de items dy't evaluearje nei FALSE te filterjen, dus oare wearden dan #N/A flaters:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)
Itselde resultaat kin wurde berikt mei de XLOOKUP-funksje, dy't de formule noch ienfâldiger makket. Troch de mooglikheid fan XLOOKUP om #N/A flaters yntern te behanneljen (opsjoneel if_not_found argumint), kinne wy sûnder de IFNA- of ISNA-wrapper:
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")
Fergelykje twa kolommen en fyn ûntbrekkende wearden (ferskillen)
Om 2 kolommen yn Excel te fergelykjen om ferskillen te finen, kinne jo op dizze manier trochgean:
- Skriuw de kearnformule om te sykjen nei de earste wearde fan List 1 (A2) yn List 2 ($C$2:$C$9):
VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
- Nest de boppesteande formule yn 'e ISNA-funksje om de útfier fan' e VLOOKUP te kontrolearjen op #N/A-flaters. Yn gefal fan in flater jout ISNA TRUE, oars FALSE:
ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))
- Brûk de ISNA VLOOKUP-formule foar de logyske test fan de IF-funksje. As de test evaluearret nei TRUE (#N / A flater), werom in wearde út List 1 yn deselde rige. As de test evaluearret op FALSE (in oerienkomst yn List 2 wurdt fûn), jou in lege tekenrige werom.
De folsleine formule nimt dizze foarm oan:
=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")
Om de blanks kwyt te reitsjen, tapasse jo Excel's Filter lykas oantoand yn it boppesteande foarbyld.
Yn Excel 365 en Excel 2021 kinne jo de resultatenlist dynamysk filterje. Pleats hjirfoar gewoan de ISNA VLOOKUP-formule yn it argumint include fan 'e FILTER-funksje:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))
In oare manier is om brûk XLOOKUP foar kritearia - de funksje jout lege stringen ("") werom foar ûntbrekkende gegevenspunten, en jo filterje de wearden yn List 1 wêrfoar XLOOKUP lege stringen (="") weromjout:
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")
VLOOKUP-formule om oerienkomsten en ferskillen tusken twa kolommen te identifisearjen
As jo tekstlabels tafoegje wolle oan de earste list dy't oanjaan hokker wearden beskikber binne yn de twadde list en hokker net, brûk dan de VLOOKUP-formule tegearre mei de IF- en ISNA/ISERROR-funksjes.
Om bygelyks nammen te identifisearjen dy't yn beide kolommen A en D steane en dyjingen dy't allinich yn kolom A steane, is de formule:
=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")
Hjir fangt de ISNA-funksje de #N/A-flaters oanmakke troch VLOOKUP en jout dat tuskenresultaat troch oan de IF-funksje foar itjout de opjûne tekst werom foar flaters en in oare tekst foar suksesfolle opsykjen.
Yn dit foarbyld hawwe wy "Net kwalifisearre"/"Kwalifisearre" labels brûkt, dy't geskikt binne foar ús sample dataset. Jo kinne se ferfange troch "Net yn List 2"/"Yn List 2", "Net beskikber"/"Beskikber" of oare labels dy't jo goed fine.
Dizze formule is it bêste om yn in kolom yn te foegjen neist List 1 en kopiearre troch safolle sellen as der items yn jo list binne.
Ien mear manier om wedstriden en ferskillen yn 2 kolommen te identifisearjen is mei de MATCH-funksje:
=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")
Fergelykje 2 kolommen en jou in wearde werom fan tredde
As jo wurkje mei tabellen dy't relatearre gegevens befetsje, kinne jo soms nedich wêze ferlykje twa kolommen yn twa ferskillende tabellen en werom in oerienkommende wearde út in oare kolom. Yn feite is it it primêre gebrûk fan de VLOOKUP-funksje, it doel dêr't it foar ûntwurpen is.
Bygelyks om de nammen yn kolommen A en D yn 'e twa tabellen hjirûnder te fergelykjen en in tiid werom te jaan út kolom E , de formule is:
=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)
Om #N/A flaters te ferbergjen, brûk de bewezen oplossing - de IFNA-funksje:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")
Ynstee fan blanks, kinne jo elke tekst weromjaan dy't jo wolle foar ûntbrekkende gegevenspunten - typ it gewoan yn it lêste argumint. Bygelyks:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")
Njonken VLOOKUP kin de taak folbrocht wurde mei in pear oare opsykfunksjes.
Persoanlik soe ik fertrouwe op in fleksibeler INDEXMATCH formule:
=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")
Of brûk de moderne opfolger fan VLOOKUP - de XLOOKUP-funksje, beskikber yn Excel 365 en Excel 2021:
=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")
Om Krij de nammen fan kwalifisearre dielnimmers út groep A en har resultaten, filterje gewoan lege sellen yn kolom B:
=FILTER(A3:B15, B3:B15"")
Fergelikingsark
As jo faak bestân- of gegevensfergeliking dogge yn Excel, kinne dizze tûke ark opnommen yn ús Ultimate Suite jo tiid enoarm besparje!
Tabellen fergelykje - rappe manier om duplikaten (oerienkomsten) en unike wearden (ferskillen) te finen yn twa gegevenssets lykas kolommen, list of tabellen.
Twa blêden fergelykje - ferskillen tusken twa wurkblêden fine en markearje.
Mearde blêden fergelykje - ferskillen yn meardere blêden tagelyk fine en markearje .
Oefeningswurkboek foar download
VLOOKUP yn Excel om kolommen te fergelykjen - foarbylden (.xlsx-bestân)
