Mafunzo yanaonyesha jinsi ya kutumia fomula ya VLOOKUP katika Excel ili kulinganisha safu wima mbili ili kurejesha thamani za kawaida (zinazolingana) au kupata data inayokosekana (tofauti).

Unapokuwa na data katika sehemu mbili. orodha tofauti, mara nyingi unaweza kuhitaji kuzilinganisha ili kuona ni taarifa gani inakosekana katika mojawapo ya orodha au ni data gani iliyopo katika zote mbili. Ulinganisho unaweza kufanywa kwa njia nyingi tofauti - ni njia gani ya kutumia inategemea hasa unachotaka kutoka kwayo.

Jinsi ya kulinganisha safu wima mbili katika Excel kwa kutumia VLOOKUP

Lini una safu wima mbili za data na unataka kujua ni sehemu gani za data kutoka kwa orodha moja zipo katika orodha nyingine, unaweza kutumia kitendakazi cha VLOOKUP kulinganisha orodha za thamani zinazofanana.

Ili kuunda fomula ya VLOOKUP katika yake. fomu ya msingi, hivi ndivyo unahitaji kufanya:

• Kwa lookup_value (hoja ya kwanza), tumia kisanduku cha juu kabisa kutoka kwa Orodha ya 1.
• Kwa jedwali_array (hoja ya 2), toa Orodha nzima 2.
• Kwa col_index_num (hoja ya 3), tumia 1 kwani kuna safu wima moja tu katika safu.
• Kwa range_lookup (hoja ya 4), weka FALSE - inayolingana kabisa.

Tuseme una majina ya washiriki katika safu wima A (Orodha ya 1) na majina ya hao. ambao wamepitia raundi za kufuzu katika safu B (Orodha ya 2). Unataka kulinganisha orodha hizi 2 ili kubaini ni washiriki gani kutoka Kundi A waliofika kwenye tukio kuu. Ili kufanya hivyo, tumia zifuatazoformula.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Mchanganyiko huenda kwa kisanduku E2, na kisha uinburute chini kupitia visanduku vingi kama vilivyo kwenye Orodha ya 1.

Tafadhali kumbuka kuwa jedwali_array limefungwa kwa marejeleo kamili ($C$2:$C$9) ili lisalie bila kubadilika unaponakili fomula kwenye visanduku vilivyo hapa chini.

Kama unavyoona, majina ya wanariadha waliohitimu watajitokeza katika safu wima E. Kwa washiriki waliosalia, hitilafu ya #N/A inaonekana kuonyesha kwamba majina yao hayapatikani katika Orodha ya 2.

Disguise #N/ Hitilafu

Mfumo wa VLOOKUP uliojadiliwa hapo juu hutimiza lengo lake kuu kikamilifu - hurejesha thamani zinazofanana na kubainisha pointi za data zinazokosekana. Hata hivyo, hutoa rundo la hitilafu za #N/A, jambo ambalo linaweza kuwachanganya watumiaji wasio na uzoefu na kuwafanya wafikirie kuwa kuna tatizo katika fomula.

Ili kubadilisha hitilafu kwa kisanduku tupu , tumia VLOOKUP. pamoja na chaguo za kukokotoa za IFNA au IFERROR kwa njia hii:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Mchanganyiko wetu ulioboreshwa hurejesha mfuatano tupu ("") badala ya #N/ A. Unaweza pia kurudisha maandishi yako maalum kama vile "Haiko kwenye Orodha ya 2", "Haipo", au "Haipatikani". Kwa mfano:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Hiyo ndiyo fomula ya msingi ya VLOOKUP ya kulinganisha safu wima mbili katika Excel. Kulingana na kazi yako mahususi, inaweza kurekebishwa kama inavyoonyeshwa katika mifano zaidi.

Linganisha safu wima mbili katika laha tofauti za Excel kwa kutumia VLOOKUP

Katika maisha halisi, safu wima unazozitumia.haja ya kulinganisha sio kila wakati kwenye karatasi moja. Katika mkusanyiko mdogo wa data, unaweza kujaribu kuona tofauti hizo mwenyewe kwa kutazama laha mbili kando.

Ili kutafuta katika lahakazi nyingine au kitabu cha kazi kilicho na fomula, lazima utumie marejeleo ya nje. Mbinu bora ni kuanza kuandika fomula katika laha yako kuu, kisha ubadilishe hadi laha nyingine ya kazi na uchague orodha kwa kutumia kipanya - marejeleo yanayofaa ya masafa yataongezwa kwa fomula kiotomatiki.

Kuchukulia kuwa Orodha ya 1 ni katika safu wima A kwenye Jedwali1 na orodha ya 2 iko kwenye safu wima A kwenye Jedwali2 , unaweza kulinganisha safu wima mbili na kupata zinazolingana ukitumia fomula hii:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Kwa maelezo zaidi, tafadhali angalia:

• VLOOKUP kutoka laha nyingine
• VLOOKUP kutoka kitabu tofauti cha kazi

Linganisha safu wima mbili na urudishe thamani zinazofanana (zinazolingana)

Katika mifano iliyotangulia, tulijadili fomula ya VLOOKUP kwa njia rahisi zaidi:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

matokeo ya fomula hiyo ni orodha ya thamani zilizopo katika safu wima zote mbili na seli tupu badala ya thamani ambazo hazipatikani katika safu wima ya pili.

Ili kupata orodha ya thamani za kawaida bila mapengo, ongeza kichujio otomatiki kwenye safu wima inayotokana na. chuja nafasi zilizoachwa wazi.

Katika Excel kwa Microsoft 365 na Excel 2021 hiyo sasisha safu zinazobadilika, unaweza kutumia kitendakazi cha FILTER kupepeta nafasi zilizoachwa wazi kwa nguvu. Kwa hili, tumia fomula ya IFNA VLOOKUP kamavigezo vya FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Tafadhali zingatia kwamba katika kesi hii tunasambaza Orodha nzima ya 1 (A2:A14) kwa thamani_ya_kuangalia hoja ya VLOOKUP. Chaguo hili la kukokotoa linalinganisha kila thamani ya utafutaji dhidi ya Orodha ya 2 (C2:C9) na hurejesha safu ya zinazolingana na hitilafu za #N/A zinazowakilisha thamani zinazokosekana. Chaguo za kukokotoa za IFNA hubadilisha hitilafu kwa mifuatano tupu na kutumikia matokeo kwa kitendakazi cha FILTER, ambacho huchuja nafasi zilizo wazi ("") na kutoa safu ya mechi kama tokeo la mwisho.

Vinginevyo, unaweza kutumia kitendakazi cha ISNA kuangalia matokeo ya VLOOKUP na kuchuja vipengee vinavyotathminiwa hadi FALSE, yaani, thamani zingine isipokuwa hitilafu za #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

matokeo sawa yanaweza ipatikane kwa kutumia kitendakazi cha XLOOKUP, ambacho hurahisisha fomula. Kutokana na uwezo wa XLOOKUP kushughulikia hitilafu za #N/A ndani (hiari ikiwa_haijapatikana hoja), tunaweza kufanya bila IFNA au ISNA wrapper:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Linganisha safu wima mbili na kupata thamani zinazokosekana (tofauti)

Ili kulinganisha safu wima 2 katika Excel ili kupata tofauti, unaweza kuendelea kwa njia hii:

1. Andika fomula ya msingi kutafuta ya kwanza. thamani kutoka kwa Orodha ya 1 (A2) katika Orodha ya 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Nest the fomula iliyo hapo juu katika chaguo za kukokotoa za ISNA ili kuangalia matokeo ya VLOOKUP kwa hitilafu za #N/A. Ikiwa kuna hitilafu, ISNA itatoa TRUE, vinginevyo FALSE:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. Tumia fomula ya ISNA VLOOKUP kwa jaribio la kimantiki la chaguo za kukokotoa za IF. Jaribio likitathmini kuwa TRUE (hitilafu #N/A), rudisha thamani kutoka kwa Orodha ya 1 katika safu mlalo sawa. Jaribio likitathmini kuwa FALSE (kinacholingana katika Orodha ya 2 kimepatikana), rudisha mfuatano tupu.

Mfumo kamili huchukua fomu hii:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Ili kuondoa nafasi zilizoachwa wazi, tumia Kichujio cha Excel kama inavyoonyeshwa kwenye mfano ulio hapo juu.

Katika Excel 365 na Excel 2021, unaweza kufanya orodha ya matokeo kuchujwa kwa kasi. Kwa hili, weka kwa urahisi fomula ya ISNA VLOOKUP katika jumuisha hoja ya kitendakazi cha FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Njia nyingine ni tumia XLOOKUP kwa vigezo - chaguo la kukokotoa hurejesha mifuatano tupu ("") kwa pointi za data zinazokosekana, na unachuja thamani katika Orodha ya 1 ambayo XLOOKUP ilirudisha mifuatano tupu (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Mchanganyiko wa VLOOKUP wa kutambua ulinganifu na tofauti kati ya safu wima mbili

Ikiwa ungependa kuongeza lebo za maandishi kwenye orodha ya kwanza inayoonyesha ni thamani zipi zinazopatikana katika orodha ya pili na zipi hazipo, tumia fomula ya VLOOKUP pamoja na IF na ISNA/ISERROR vitendaji.

Kwa mfano, ili kutambua majina yaliyo katika safu wima A na D na yale ambayo yako katika safu wima A pekee, fomula ni:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Hapa, chaguo za kukokotoa za ISNA hunasa hitilafu za #N/A zinazozalishwa na VLOOKUP na kupitisha matokeo hayo ya kati kwa chaguo za kukokotoa za IF ilirudisha maandishi yaliyobainishwa kwa hitilafu na maandishi mengine kwa utafutaji uliofanikiwa.

Katika mfano huu, tulitumia lebo za "Sijahitimu"/"Hazijahitimu", ambazo zinafaa kwa sampuli ya mkusanyiko wetu wa data. Unaweza kuzibadilisha na "Hazipo kwenye Orodha ya 2"/"Katika Orodha ya 2", "Haipatikani"/"Inapatikana" au lebo zingine zozote unazoona zinafaa.

Mfumo huu ni bora zaidi kuingizwa kwenye safu wima. iliyo karibu na Orodha ya 1 na kunakiliwa kupitia visanduku vingi kadiri vilivyo kwenye orodha yako.

Njia nyingine ya kutambua zinazolingana na tofauti katika safu wima 2 ni kutumia chaguo la kukokotoa la MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Linganisha safu wima 2 na urudishe thamani kutoka ya tatu

Unapofanya kazi na majedwali yaliyo na data inayohusiana, huenda ukahitaji wakati mwingine linganisha safu wima mbili katika jedwali mbili tofauti na urudishe thamani inayolingana kutoka safu wima nyingine. Kwa hakika, ndiyo matumizi ya msingi ya chaguo za kukokotoa za VLOOKUP, madhumuni ambayo iliundwa kwa ajili yake.

Kwa mfano, kulinganisha majina katika safu wima A na D katika majedwali mawili yaliyo hapa chini na kurudisha muda kutoka safu wima E. , fomula ni:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Ili kuficha hitilafu za #N/A, tumia suluhisho lililothibitishwa - chaguo la kukokotoa la IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Badala ya nafasi zilizoachwa wazi, unaweza kurejesha maandishi yoyote unayotaka kwa kukosa pointi za data - charaza tu katika hoja ya mwisho. Kwa mfano:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Kando na VLOOKUP, kazi inaweza kukamilishwa kwa vitendaji vingine vichache vya kutafuta.

Binafsi, ningetegemea INDEX inayoweza kunyumbulika zaidi.Fomula ya MATCH:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Au tumia kirithi cha kisasa cha VLOOKUP - chaguo la kukokotoa la XLOOKUP, linalopatikana katika Excel 365 na Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Kwa pata majina ya washiriki waliohitimu kutoka kwa kikundi A na matokeo yao, chuja tu visanduku tupu kwenye safu wima B:

=FILTER(A3:B15, B3:B15"")

Zana za kulinganisha

Ikiwa mara kwa mara unalinganisha faili au data katika Excel, zana hizi mahiri zilizojumuishwa katika Ultimate Suite yetu zinaweza kuokoa muda wako kwa kiasi kikubwa!

Linganisha Majedwali - njia ya haraka ya kupata nakala (zinazolingana) na thamani za kipekee (tofauti) katika seti zozote mbili za data kama vile safu wima, orodha au majedwali.

Linganisha Laha Mbili - tafuta na uangazie tofauti kati ya laha mbili za kazi.

Linganisha Laha Nyingi - tafuta na uangazie tofauti katika laha nyingi kwa wakati mmoja. .

Fanya mazoezi ya kupakuliwa kwa kitabu cha kazi

VLOOKUP katika Excel ili kulinganisha safu wima - mifano (faili.xlsx)