Le tutoriel montre comment utiliser la formule VLOOKUP dans Excel pour comparer deux colonnes afin de retourner des valeurs communes (concordances) ou trouver des données manquantes (différences).

Lorsque vous avez des données dans deux listes différentes, vous avez souvent besoin de les comparer pour voir quelles informations manquent dans l'une des listes ou quelles données sont présentes dans les deux. La comparaison peut se faire de plusieurs manières différentes - la méthode à utiliser dépend de ce que vous voulez exactement en tirer.

Comment comparer deux colonnes dans Excel en utilisant VLOOKUP

Lorsque vous disposez de deux colonnes de données et que vous souhaitez savoir quels points de données d'une liste existent dans l'autre liste, vous pouvez utiliser la fonction VLOOKUP pour comparer les listes et rechercher des valeurs communes.

Pour construire une formule VLOOKUP dans sa forme de base, voici ce que vous devez faire :

• Pour valeur de la recherche (1er argument), utilisez la cellule la plus haute de la liste 1.
• Pour tableau_réseau (2ème argument), fournir la liste entière 2.
• Pour col_index_num (3ème argument), utilisez 1 car il n'y a qu'une seule colonne dans le tableau.
• Pour recherche de plage (4ème argument), mettez FALSE - correspondance exacte.

Supposons que vous ayez les noms des participants dans la colonne A (liste 1) et les noms de ceux qui ont passé les tours de qualification dans la colonne B (liste 2). Vous voulez comparer ces 2 listes pour déterminer quels participants du groupe A ont accédé à l'épreuve principale. Pour ce faire, utilisez la formule suivante.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

La formule va dans la cellule E2, puis vous la faites glisser vers le bas dans autant de cellules qu'il y a d'éléments dans la liste 1.

Veuillez noter que tableau_réseau est verrouillée avec des références absolues ($C$2:$C$9) afin qu'elle reste constante lorsque vous copiez la formule dans les cellules ci-dessous.

Comme vous pouvez le constater, les noms des athlètes qualifiés apparaissent dans la colonne E. Pour les autres participants, une erreur #N/A apparaît, indiquant que leurs noms ne sont pas disponibles dans la liste 2.

Disguise #N/A errors

La formule VLOOKUP présentée ci-dessus remplit parfaitement son objectif principal - elle renvoie des valeurs communes et identifie les points de données manquants. Cependant, elle produit un grand nombre d'erreurs #N/A, qui peuvent dérouter les utilisateurs inexpérimentés en leur faisant croire que quelque chose ne va pas dans la formule.

Pour remplacer les erreurs par cellules vides Si vous utilisez VLOOKUP en combinaison avec la fonction IFNA ou IFERROR, vous pouvez le faire de cette manière :

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Notre formule améliorée renvoie une chaîne vide ("") au lieu de #N/A. Vous pouvez également renvoyer votre texte personnalisé comme "Pas dans la liste 2", "Pas présent", ou "Pas disponible". Par exemple :

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Pas dans la liste 2")

Il s'agit de la formule VLOOKUP de base pour comparer deux colonnes dans Excel. En fonction de votre tâche particulière, elle peut être modifiée comme le montrent les exemples suivants.

Comparer deux colonnes dans des feuilles Excel différentes à l'aide de VLOOKUP

Dans la réalité, les colonnes que vous devez comparer ne se trouvent pas toujours sur la même feuille. Dans un petit ensemble de données, vous pouvez essayer de repérer les différences manuellement en visualisant deux feuilles côte à côte.

Pour effectuer une recherche dans une autre feuille de calcul ou un autre classeur avec des formules, vous devez utiliser une référence externe. La meilleure pratique consiste à commencer à taper la formule dans votre feuille principale, puis à passer à l'autre feuille de calcul et à sélectionner la liste à l'aide de la souris - une référence de plage appropriée sera ajoutée automatiquement à la formule.

En supposant que la liste 1 est dans la colonne A sur Feuille 1 et la liste 2 est dans la colonne A sur Feuille 2 vous pouvez comparer deux colonnes et trouver des correspondances en utilisant cette formule :

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Pour plus d'informations, veuillez consulter :

• VLOOKUP à partir d'une autre feuille
• VLOOKUP à partir d'un autre classeur

Comparer deux colonnes et renvoyer les valeurs communes (correspondances)

Dans les exemples précédents, nous avons abordé une formule VLOOKUP dans sa forme la plus simple :

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Le résultat de cette formule est une liste des valeurs qui existent dans les deux colonnes et des cellules vides à la place des valeurs non disponibles dans la deuxième colonne.

Pour obtenir une liste de valeurs communes sans lacunes, il suffit d'ajouter un filtre automatique à la colonne résultante et de filtrer les blancs.

Dans Excel pour Microsoft 365 et Excel 2021 qui prennent en charge les tableaux dynamiques, vous pouvez utiliser la fonction FILTER pour éliminer les blancs de manière dynamique. Pour cela, utilisez la formule VLOOKUP IFNA comme critère pour FILTER :

=FILTRE(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")")

Veuillez noter que dans ce cas, nous fournissons la totalité de la liste 1 (A2:A14) à l'utilisateur. valeur de la recherche La fonction compare chacune des valeurs de recherche à la liste 2 (C2:C9) et renvoie un tableau de correspondances et d'erreurs #N/A représentant les valeurs manquantes. La fonction IFNA remplace les erreurs par des chaînes vides et transmet les résultats à la fonction FILTER, qui filtre les blancs ("") et produit un tableau de correspondances comme résultat final.

Vous pouvez également utiliser la fonction ISNA pour vérifier le résultat de VLOOKUP et filtrer les éléments évaluant FALSE, c'est-à-dire les valeurs autres que les erreurs #N/A :

=FILTRE(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Le même résultat peut être obtenu à l'aide de la fonction XLOOKUP, ce qui rend la formule encore plus simple. En raison de la capacité de XLOOKUP à traiter les erreurs #N/A en interne (facultatif si_non_trouvé ), nous pouvons nous passer de l'emballage de l'IFNA ou de l'ISNA :

=FILTRE(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")")

Comparer deux colonnes et trouver les valeurs manquantes (différences)

Pour comparer 2 colonnes dans Excel afin de trouver des différences, vous pouvez procéder de la manière suivante :

1. Écrivez la formule de base pour rechercher la première valeur de la liste 1 (A2) dans la liste 2 ($C$2:$C$9) :

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Introduisez la formule ci-dessus dans la fonction ISNA pour vérifier que la sortie du VLOOKUP ne contient pas d'erreurs #N/A. En cas d'erreur, ISNA donne VRAI, sinon FAUX :

   ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))

3. Utilisez la formule ISNA VLOOKUP pour le test logique de la fonction IF. Si le test donne la valeur TRUE (erreur #N/A), renvoyez une valeur de la liste 1 dans la même ligne. Si le test donne la valeur FALSE (une correspondance dans la liste 2 est trouvée), renvoyez une chaîne vide.

La formule complète prend cette forme :

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Pour éliminer les blancs, appliquez le filtre d'Excel comme indiqué dans l'exemple ci-dessus.

Dans Excel 365 et Excel 2021, vous pouvez faire en sorte que la liste des résultats soit filtrée de manière dynamique. Pour cela, il suffit de placer la formule VLOOKUP ISNA dans le champ inclure de la fonction FILTER :

=FILTRE(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Une autre méthode consiste à utiliser XLOOKUP comme critère - la fonction renvoie des chaînes vides ("") pour les points de données manquants, et vous filtrez les valeurs de la liste 1 pour lesquelles XLOOKUP a renvoyé des chaînes vides (= "") :

=FILTRE(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9, "")="")

Formule VLOOKUP pour identifier les concordances et les différences entre deux colonnes

Si vous souhaitez ajouter à la première liste des étiquettes de texte indiquant les valeurs disponibles dans la seconde liste et celles qui ne le sont pas, utilisez la formule VLOOKUP ainsi que les fonctions IF et ISNA/ISERROR.

Par exemple, pour identifier les noms qui figurent à la fois dans les colonnes A et D et ceux qui ne figurent que dans la colonne A, la formule est la suivante :

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Non qualifié", "Qualifié")

Ici, la fonction ISNA capture les erreurs #N/A générées par VLOOKUP et transmet ce résultat intermédiaire à la fonction IF pour qu'elle renvoie le texte spécifié pour les erreurs et un autre texte pour les recherches réussies.

Dans cet exemple, nous avons utilisé les étiquettes "Non qualifié"/"Qualifié", qui conviennent à notre échantillon de données. Vous pouvez les remplacer par "Pas dans la liste 2"/"Dans la liste 2", "Non disponible"/"Disponible" ou toute autre étiquette que vous jugez appropriée.

Il est préférable d'insérer cette formule dans une colonne adjacente à la liste 1 et de la copier dans autant de cellules qu'il y a d'éléments dans votre liste.

Une autre façon d'identifier les correspondances et les différences dans 2 colonnes est d'utiliser la fonction MATCH :

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Pas dans la liste 2", "Dans la liste 2")

Comparer 2 colonnes et retourner une valeur de la troisième

Lorsque vous travaillez avec des tables contenant des données apparentées, vous devez parfois comparer deux colonnes dans deux tables différentes et renvoyer une valeur correspondante d'une autre colonne. En fait, c'est la principale utilisation de la fonction VLOOKUP, le but pour lequel elle a été conçue.

Par exemple, pour comparer les noms des colonnes A et D des deux tableaux ci-dessous et renvoyer une heure de la colonne E, la formule est la suivante :

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Pour masquer les erreurs #N/A, utilisez la solution éprouvée - la fonction IFNA :

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Au lieu des blancs, vous pouvez renvoyer le texte de votre choix pour les points de données manquants - il suffit de le taper dans le dernier argument. Par exemple :

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Non disponible")

En plus de VLOOKUP, cette tâche peut être accomplie avec quelques autres fonctions de recherche.

Personnellement, je m'appuierais sur une formule INDEX MATCH plus souple :

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Ou bien utilisez le successeur moderne de VLOOKUP - la fonction XLOOKUP, disponible dans Excel 365 et Excel 2021 :

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Pour obtenir les noms des participants qualifiés du groupe A et leurs résultats, il suffit de filtrer les cellules vides de la colonne B :

=FILTRE(A3:B15, B3:B15"")

Outils de comparaison

Si vous effectuez fréquemment des comparaisons de fichiers ou de données dans Excel, ces outils intelligents inclus dans notre Ultimate Suite peuvent vous faire gagner énormément de temps !

Comparer des tableaux - un moyen rapide de trouver des doublons (correspondances) et des valeurs uniques (différences) dans deux ensembles de données tels que des colonnes, des listes ou des tableaux.

Comparez deux feuilles - trouvez et mettez en évidence les différences entre deux feuilles de travail.

Comparez plusieurs feuilles - trouvez et mettez en évidence les différences dans plusieurs feuilles à la fois.

Cahier d'exercices à télécharger

VLOOKUP dans Excel pour comparer des colonnes - exemples (fichier .xlsx)