İçindekiler
Bu eğitimde, ortak değerleri (eşleşmeler) döndürmek veya eksik verileri (farklılıklar) bulmak amacıyla iki sütunu karşılaştırmak için Excel'de DÜŞEYARA formülünün nasıl kullanılacağı gösterilmektedir.
İki farklı listede verileriniz olduğunda, listelerden birinde hangi bilgilerin eksik olduğunu veya her ikisinde de hangi verilerin bulunduğunu görmek için genellikle bunları karşılaştırmanız gerekebilir. Karşılaştırma birçok farklı şekilde yapılabilir - hangi yöntemi kullanacağınız, bundan tam olarak ne istediğinize bağlıdır.
DÜŞEYARA kullanarak Excel'de iki sütun nasıl karşılaştırılır
İki veri sütununuz olduğunda ve bir listedeki hangi veri noktalarının diğer listede bulunduğunu bulmak istediğinizde, listeleri ortak değerler açısından karşılaştırmak için DÜŞEYARA işlevini kullanabilirsiniz.
Temel haliyle bir DÜŞEYARA formülü oluşturmak için yapmanız gerekenler şunlardır:
- İçin lookup_value (1. bağımsız değişken), Liste 1'den en üstteki hücreyi kullanın.
- İçin table_array (2. bağımsız değişken), Liste 2'nin tamamını sağlayın.
- İçin col_index_num (3. bağımsız değişken), dizide yalnızca bir sütun olduğu için 1 kullanın.
- İçin range_lookup (4. bağımsız değişken), FALSE - tam eşleşme olarak ayarlayın.
Diyelim ki A sütununda (Liste 1) katılımcıların isimleri ve B sütununda (Liste 2) eleme turlarını geçenlerin isimleri var. A grubundan hangi katılımcıların ana etkinliğe katıldığını belirlemek için bu 2 listeyi karşılaştırmak istiyorsunuz. Bunu yapmak için aşağıdaki formülü kullanın.
=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
Formül E2 hücresine gider ve sonra Liste 1'deki öğe sayısı kadar hücre boyunca aşağı sürüklersiniz.
Lütfen şuna dikkat edin table_array mutlak referanslarla ($C$2:$C$9) kilitlenir, böylece formülü aşağıdaki hücrelere kopyaladığınızda sabit kalır.
Gördüğünüz gibi, nitelikli sporcuların isimleri E sütununda görünmektedir. Kalan katılımcılar için, isimlerinin Liste 2'de bulunmadığını belirten bir #N/A hatası görünür.
Kılık Değiştirme #N/A hataları
Yukarıda tartışılan DÜŞEYARA formülü ana hedefini mükemmel bir şekilde yerine getirir - ortak değerleri döndürür ve eksik veri noktalarını belirler. Ancak, deneyimsiz kullanıcıların kafasını karıştırarak formülde bir sorun olduğunu düşünmelerine neden olabilecek bir dizi #N/A hatası verir.
Hataları aşağıdakilerle değiştirmek için boş hücreler bu şekilde IFNA veya IFERROR işleviyle birlikte DÜŞEYARA'yı kullanın:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Geliştirilmiş formülümüz #N/A yerine boş bir dize ("") döndürür. özel metin Örneğin, "Liste 2'de yok", "Mevcut değil" veya "Kullanılamıyor" gibi:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Liste 2'de değil")
Bu, Excel'de iki sütunu karşılaştırmak için kullanılan temel DÜŞEYARA formülüdür. Özel görevinize bağlı olarak, diğer örneklerde gösterildiği gibi değiştirilebilir.
DÜŞEYARA kullanarak farklı Excel sayfalarındaki iki sütunu karşılaştırma
Gerçek hayatta, karşılaştırmanız gereken sütunlar her zaman aynı sayfada yer almaz. Küçük bir veri kümesinde, iki sayfayı yan yana görüntüleyerek farkları manuel olarak tespit etmeyi deneyebilirsiniz.
Başka bir çalışma sayfasında veya çalışma kitabında formüllerle arama yapmak için dış referans kullanmanız gerekir. En iyi uygulama, formülü ana sayfanızda yazmaya başlamak, ardından diğer çalışma sayfasına geçmek ve fareyi kullanarak listeyi seçmektir - formüle otomatik olarak uygun bir aralık referansı eklenecektir.
Liste 1'in A sütununda olduğunu varsayarsak Sayfa1 ve 2 numaralı liste A sütununda Sayfa2 formülünü kullanarak iki sütunu karşılaştırabilir ve eşleşmeleri bulabilirsiniz:
=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")
Daha fazla bilgi için lütfen bkz:
- Başka bir sayfadan DÜŞEYARA
- Farklı çalışma kitabından DÜŞEYARA
İki sütunu karşılaştırın ve ortak değerleri döndürün (eşleşmeler)
Önceki örneklerde, en basit haliyle bir DÜŞEYARA formülünü ele almıştık:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Bu formülün sonucu, her iki sütunda da bulunan değerlerin bir listesi ve ikinci sütunda bulunmayan değerlerin yerine boş hücrelerdir.
Boşluklar olmadan ortak değerlerin bir listesini elde etmek için, ortaya çıkan sütuna otomatik filtre ekleyin ve boşlukları filtreleyin.
Dinamik dizileri destekleyen Microsoft 365 için Excel ve Excel 2021'de, boşlukları dinamik olarak elemek için FILTER işlevinden yararlanabilirsiniz. Bunun için, FILTER ölçütü olarak IFNA DÜŞEYARA formülünü kullanın:
=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")
Lütfen bu durumda Liste 1'in tamamını (A2:A14) aşağıdaki adrese verdiğimize dikkat edin lookup_value Fonksiyon, arama değerlerinin her birini Liste 2 (C2:C9) ile karşılaştırır ve eksik değerleri temsil eden bir dizi eşleşme ve #N/A hatası döndürür. IFNA fonksiyonu hataları boş dizelerle değiştirir ve sonuçları boşlukları ("") filtreleyen ve nihai sonuç olarak bir dizi eşleşme çıktısı veren FILTER fonksiyonuna sunar.
Alternatif olarak, DÜŞEYARA sonucunu kontrol etmek ve FALSE olarak değerlendirilen öğeleri, yani #N/A hataları dışındaki değerleri filtrelemek için ISNA işlevini kullanabilirsiniz:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)
Aynı sonuç, formülü daha da basitleştiren XLOOKUP işleviyle de elde edilebilir. XLOOKUP'ın #N/A hatalarını dahili olarak işleme yeteneği nedeniyle (isteğe bağlı if_not_found argümanı), IFNA veya ISNA sargısı olmadan yapabiliriz:
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")
İki sütunu karşılaştırın ve eksik değerleri (farkları) bulun
Excel'de 2 sütunu karşılaştırarak farkları bulmak için şu şekilde ilerleyebilirsiniz:
- Liste 1'deki (A2) ilk değeri Liste 2'de ($C$2:$C$9) aramak için temel formülü yazın:
VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
Ayrıca bakınız: Excel'de doğrusal regresyon analizi - DÜŞEYARA'nın çıktısında #N/A hatası olup olmadığını kontrol etmek için yukarıdaki formülü ISNA işlevine yerleştirin. Hata olması durumunda ISNA DOĞRU, aksi takdirde YANLIŞ sonucunu verir:
ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))
- EĞER işlevinin mantıksal testi için ISNA DÜŞEYARA formülünü kullanın. Test DOĞRU olarak değerlendirilirse (#YOK hatası), aynı satırdaki Liste 1'den bir değer döndürün. Test YANLIŞ olarak değerlendirilirse (Liste 2'de bir eşleşme bulunursa), boş bir dize döndürün.
Formülün tamamı şu şekildedir:
=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")
Boşluklardan kurtulmak için, yukarıdaki örnekte gösterildiği gibi Excel'in Filtresini uygulayın.
Excel 365 ve Excel 2021'de sonuç listesinin dinamik olarak filtrelenmesini sağlayabilirsiniz. Bunun için ISNA DÜŞEYARA formülünü şunları içerir FILTER işlevinin bağımsız değişkeni:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))
Başka bir yol da kriterler için DÜŞEYARA kullanmaktır - fonksiyon eksik veri noktaları için boş dizeler ("") döndürür ve DÜŞEYARA'nın boş dizeler (="") döndürdüğü Liste 1'deki değerleri filtrelersiniz:
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")
İki sütun arasındaki eşleşmeleri ve farkları belirlemek için DÜŞEYARA formülü
İlk listeye, ikinci listede hangi değerlerin bulunduğunu ve hangilerinin bulunmadığını belirten metin etiketleri eklemek istiyorsanız, DÜŞEYARA formülünü EĞER ve ISNA/ISERROR işlevleriyle birlikte kullanın.
Örneğin, hem A hem de D sütunlarında bulunan adları ve yalnızca A sütununda bulunan adları belirlemek için formül şöyledir:
=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Nitelikli değil", "Nitelikli")
Burada, ISNA fonksiyonu DÜŞEYARA tarafından oluşturulan #N/A hatalarını yakalar ve hatalar için belirtilen metni ve başarılı aramalar için başka bir metni döndürmesi için bu ara sonucu EĞER fonksiyonuna aktarır.
Bu örnekte, örnek veri kümemiz için uygun olan "Nitelikli değil"/"Nitelikli" etiketlerini kullandık. Bunları "Liste 2'de değil"/"Liste 2'de", "Mevcut değil"/"Mevcut" veya uygun gördüğünüz diğer etiketlerle değiştirebilirsiniz.
Bu formülün Liste 1'e bitişik bir sütuna eklenmesi ve listenizdeki öğe sayısı kadar hücre boyunca kopyalanması en iyisidir.
İki sütundaki eşleşmeleri ve farklılıkları belirlemenin bir başka yolu da MATCH fonksiyonunu kullanmaktır:
=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Liste 2'de değil", "Liste 2'de")
2 sütunu karşılaştırın ve üçüncü sütundan bir değer döndürün
İlgili verileri içeren tablolarla çalışırken, bazen iki farklı tablodaki iki sütunu karşılaştırmanız ve başka bir sütundan eşleşen bir değer döndürmeniz gerekebilir. Aslında bu, DÜŞEYARA işlevinin tasarlanma amacı olan birincil kullanımıdır.
Örneğin, aşağıdaki iki tabloda A ve D sütunlarındaki adları karşılaştırmak ve E sütunundan bir zaman döndürmek için formül şöyledir:
=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)
N/A hatalarını gizlemek için kanıtlanmış çözüm olan IFNA işlevini kullanın:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")
Boşluklar yerine, eksik veri noktaları için istediğiniz metni döndürebilirsiniz - sadece son bağımsız değişkene yazın. Örneğin:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Mevcut değil")
VLOOKUP'ın yanı sıra, bu görev birkaç başka arama işleviyle de yerine getirilebilir.
Şahsen ben olsam daha esnek bir INDEX MATCH formülüne güvenirdim:
=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")
Ya da Excel 365 ve Excel 2021'de bulunan, DÜŞEYARA'nın modern halefi XLOOKUP işlevini kullanın:
=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")
A grubundan nitelikli katılımcıların adlarını ve sonuçlarını almak için B sütunundaki boş hücreleri filtrelemeniz yeterlidir:
=FILTER(A3:B15, B3:B15"")
Karşılaştırma araçları
Excel'de sık sık dosya veya veri karşılaştırması yapıyorsanız, Ultimate Suite'imizde bulunan bu akıllı araçlar zamandan büyük ölçüde tasarruf etmenizi sağlayabilir!
Tabloları Karşılaştır - sütunlar, liste veya tablolar gibi herhangi iki veri kümesinde yinelenenleri (eşleşmeleri) ve benzersiz değerleri (farklılıkları) bulmanın hızlı yolu.
İki Sayfayı Karşılaştır - iki çalışma sayfası arasındaki farkları bulun ve vurgulayın.
Birden Fazla Sayfayı Karşılaştırın - aynı anda birden fazla sayfadaki farklılıkları bulun ve vurgulayın.
İndirmek için pratik çalışma kitabı
Sütunları karşılaştırmak için Excel'de DÜŞEYARA - örnekler (.xlsx dosyası)
