Daftar Isi
Tutorial ini menunjukkan cara menggunakan rumus VLOOKUP di Excel untuk membandingkan dua kolom untuk mengembalikan nilai yang sama (cocok) atau menemukan data yang hilang (perbedaan).
Ketika Anda memiliki data dalam dua daftar yang berbeda, Anda mungkin sering perlu membandingkannya untuk melihat informasi apa yang hilang di salah satu daftar atau data apa yang ada di keduanya. Perbandingan dapat dilakukan dengan berbagai cara - metode mana yang akan digunakan tergantung pada apa yang Anda inginkan darinya.
Cara membandingkan dua kolom di Excel menggunakan VLOOKUP
Saat Anda memiliki dua kolom data dan ingin mengetahui titik data mana dari satu daftar yang ada di daftar lainnya, Anda dapat menggunakan fungsi VLOOKUP untuk membandingkan daftar untuk nilai umum.
Untuk membuat rumus VLOOKUP dalam bentuk dasarnya, inilah yang perlu kamu lakukan:
- Untuk lookup_value (argumen pertama), gunakan sel paling atas dari Daftar 1.
- Untuk table_array (argumen ke-2), berikan seluruh Daftar 2.
- Untuk col_index_num (argumen ke-3), gunakan 1 karena hanya ada satu kolom dalam array.
- Untuk range_lookup (argumen ke-4), atur FALSE - pencocokan persis.
Misalkan Anda memiliki nama-nama peserta dalam kolom A (Daftar 1) dan nama-nama peserta yang telah melewati babak kualifikasi dalam kolom B (Daftar 2). Anda ingin membandingkan kedua daftar ini untuk menentukan peserta mana dari Grup A yang berhasil lolos ke babak utama. Untuk melakukan ini, gunakan rumus berikut.
=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
Rumusnya masuk ke sel E2, lalu Anda menyeretnya ke bawah melalui sel sebanyak item dalam Daftar 1.
Harap perhatikan bahwa table_array dikunci dengan referensi absolut ($ C $ 2: $ C $ 9) sehingga tetap konstan saat Anda menyalin rumus ke sel di bawah ini.
Seperti yang bisa Anda lihat, nama-nama atlet yang memenuhi syarat muncul dalam kolom E. Untuk peserta lainnya, muncul kesalahan #N/A yang menunjukkan bahwa nama mereka tidak tersedia dalam Daftar 2.
Menyamarkan kesalahan #N/A
Rumus VLOOKUP yang dibahas di atas dengan sempurna memenuhi tujuan utamanya - mengembalikan nilai umum dan mengidentifikasi titik data yang hilang. Namun, rumus ini memberikan banyak kesalahan #N/A, yang dapat membingungkan pengguna yang tidak berpengalaman sehingga membuat mereka berpikir bahwa ada sesuatu yang salah dengan rumus tersebut.
Untuk mengganti kesalahan dengan sel kosong , gunakan VLOOKUP dalam kombinasi dengan fungsi IFNA atau IFERROR dengan cara ini:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Formula kami yang telah ditingkatkan mengembalikan string kosong ("") alih-alih #N/A. Anda juga dapat mengembalikan teks khusus seperti "Tidak ada dalam Daftar 2", "Tidak ada", atau "Tidak tersedia". Misalnya:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Tidak ada dalam Daftar 2")
Itulah rumus dasar VLOOKUP untuk membandingkan dua kolom di Excel. Bergantung pada tugas khusus Anda, ini dapat dimodifikasi seperti yang ditunjukkan pada contoh selanjutnya.
Bandingkan dua kolom di lembar Excel yang berbeda menggunakan VLOOKUP
Dalam kehidupan nyata, kolom-kolom yang perlu Anda bandingkan tidak selalu berada pada lembar yang sama. Dalam dataset kecil, Anda bisa mencoba melihat perbedaan secara manual dengan melihat dua lembar berdampingan.
Untuk mencari di lembar kerja atau buku kerja lain dengan rumus, Anda harus menggunakan referensi eksternal. Praktik terbaik adalah mulai mengetik rumus di lembar utama Anda, lalu beralih ke lembar kerja lain dan pilih daftar menggunakan mouse - referensi rentang yang sesuai akan ditambahkan ke rumus secara otomatis.
Dengan mengasumsikan Daftar 1 berada di kolom A pada Sheet1 dan daftar 2 berada di kolom A pada Sheet2 Anda dapat membandingkan dua kolom dan menemukan kecocokan menggunakan rumus ini:
=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")
Untuk informasi selengkapnya, silakan lihat:
- VLOOKUP dari lembar lain
- VLOOKUP dari buku kerja yang berbeda
Bandingkan dua kolom dan kembalikan nilai yang sama (cocok)
Pada contoh-contoh sebelumnya, kita sudah membahas rumus VLOOKUP dalam bentuknya yang paling sederhana:
=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")
Hasil dari rumus tersebut adalah daftar nilai yang ada di kedua kolom dan sel kosong sebagai pengganti nilai yang tidak tersedia di kolom kedua.
Untuk mendapatkan daftar nilai umum tanpa celah, cukup tambahkan filter otomatis ke kolom yang dihasilkan dan saring kosong.
Di Excel untuk Microsoft 365 dan Excel 2021 yang mendukung array dinamis, Anda dapat menggunakan fungsi FILTER untuk menyaring kekosongan secara dinamis. Untuk ini, manfaatkan rumus IFNA VLOOKUP sebagai kriteria untuk FILTER:
=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")""")
Harap perhatikan bahwa dalam hal ini kami menyediakan seluruh Daftar 1 (A2:A14) ke lookup_value Fungsi ini membandingkan setiap nilai pencarian dengan Daftar 2 (C2: C9) dan mengembalikan larik kecocokan dan kesalahan # N / A yang mewakili nilai yang hilang. Fungsi IFNA menggantikan kesalahan dengan string kosong dan menyajikan hasilnya ke fungsi FILTER, yang menyaring kosong ("") dan mengeluarkan larik kecocokan sebagai hasil akhir.
Alternatifnya, Anda bisa menggunakan fungsi ISNA untuk memeriksa hasil VLOOKUP dan memfilter item-item yang bernilai FALSE, yaitu nilai selain kesalahan #N/A:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)
Hasil yang sama dapat dicapai dengan fungsi XLOOKUP, yang membuat rumusnya menjadi lebih sederhana. Karena kemampuan XLOOKUP untuk menangani error #N/A secara internal (opsional if_not_found argumen), kita bisa melakukannya tanpa pembungkus IFNA atau ISNA:
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,""")""")
Bandingkan dua kolom dan temukan nilai yang hilang (perbedaan)
Untuk membandingkan 2 kolom di Excel untuk menemukan perbedaan, Anda dapat melanjutkan dengan cara ini:
- Tuliskan rumus inti untuk mencari nilai pertama dari Daftar 1 (A2) dalam Daftar 2 ($C$2:$C$9):
VLOOKUP(A2, $C$2:$C$9, 1, FALSE)
- Sarang rumus di atas dalam fungsi ISNA untuk memeriksa keluaran VLOOKUP untuk kesalahan # N / A. Jika terjadi kesalahan, ISNA menghasilkan TRUE, jika tidak, FALSE:
ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))
- Gunakan rumus ISNA VLOOKUP untuk tes logis dari fungsi IF. Jika tes mengevaluasi ke TRUE (kesalahan # N / A), kembalikan nilai dari Daftar 1 di baris yang sama. Jika tes mengevaluasi ke FALSE (kecocokan dalam Daftar 2 ditemukan), kembalikan string kosong.
Rumus lengkapnya mengambil bentuk ini:
=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")
Untuk menghilangkan bagian yang kosong, terapkan Filter Excel seperti yang ditunjukkan pada contoh di atas.
Di Excel 365 dan Excel 2021, Anda dapat memiliki daftar hasil yang difilter secara dinamis. Untuk ini, cukup tempatkan rumus ISNA VLOOKUP di termasuk argumen dari fungsi FILTER:
=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))
Cara lain adalah dengan menggunakan XLOOKUP untuk kriteria - fungsi mengembalikan string kosong ("") untuk poin data yang hilang, dan Anda memfilter nilai dalam Daftar 1 yang XLOOKUP mengembalikan string kosong (= ""):
=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")
Rumus VLOOKUP untuk mengidentifikasi kecocokan dan perbedaan antara dua kolom
Jika Anda ingin menambahkan label teks ke daftar pertama yang menunjukkan nilai mana yang tersedia di daftar kedua dan mana yang tidak, gunakan rumus VLOOKUP bersama dengan fungsi IF dan ISNA/ISERROR.
Misalnya, untuk mengidentifikasi nama-nama yang berada di kolom A dan D dan yang hanya berada di kolom A, rumusnya adalah:
=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Tidak memenuhi syarat", "Memenuhi syarat")
Di sini, fungsi ISNA menangkap kesalahan # N / A yang dihasilkan oleh VLOOKUP dan meneruskan hasil antara itu ke fungsi IF untuk mengembalikan teks yang ditentukan untuk kesalahan dan teks lain untuk pencarian yang berhasil.
Dalam contoh ini, kami menggunakan label "Tidak memenuhi syarat"/"Memenuhi syarat", yang cocok untuk dataset sampel kami. Anda dapat menggantinya dengan "Tidak dalam Daftar 2"/"Dalam Daftar 2", "Tidak tersedia"/"Tersedia" atau label lain yang Anda anggap cocok.
Rumus ini paling baik disisipkan di kolom yang berdekatan dengan Daftar 1 dan disalin melalui sel sebanyak item dalam daftar Anda.
Satu lagi cara untuk mengidentifikasi kecocokan dan perbedaan dalam 2 kolom adalah menggunakan fungsi MATCH:
=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Tidak dalam Daftar 2", "Dalam Daftar 2")
Bandingkan 2 kolom dan kembalikan nilai dari kolom ketiga
Ketika bekerja dengan tabel yang berisi data terkait, terkadang Anda mungkin perlu membandingkan dua kolom dalam dua tabel yang berbeda dan mengembalikan nilai yang cocok dari kolom lain. Faktanya, ini adalah penggunaan utama fungsi VLOOKUP, tujuan fungsi ini dirancang untuk itu.
Misalnya, untuk membandingkan nama-nama dalam kolom A dan D dalam dua tabel di bawah ini dan mengembalikan waktu dari kolom E, rumusnya adalah:
=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)
Untuk menyembunyikan kesalahan #N/A, gunakan solusi yang sudah terbukti - fungsi IFNA:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")
Alih-alih kosong, Anda dapat mengembalikan teks apa pun yang Anda inginkan untuk titik data yang hilang - cukup ketik di argumen terakhir. Misalnya:
=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Tidak tersedia")
Di samping VLOOKUP, tugas ini bisa dipenuhi dengan beberapa fungsi lookup lainnya.
Secara pribadi, saya akan mengandalkan formula INDEX MATCH yang lebih fleksibel:
=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")
Atau gunakan penerus modern VLOOKUP - fungsi XLOOKUP, tersedia di Excel 365 dan Excel 2021:
=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")
Untuk mendapatkan nama-nama peserta yang memenuhi syarat dari kelompok A dan hasilnya, cukup saring sel-sel kosong di kolom B:
=FILTER(A3:B15, B3:B15"")
Alat perbandingan
Jika Anda sering melakukan perbandingan file atau data di Excel, alat pintar yang disertakan dalam Ultimate Suite kami ini dapat sangat menghemat waktu Anda!
Bandingkan Tabel - cara cepat untuk menemukan duplikat (kecocokan) dan nilai unik (perbedaan) dalam dua set data seperti kolom, daftar atau tabel.
Bandingkan Dua Lembar - temukan dan sorot perbedaan antara dua lembar kerja.
Bandingkan Beberapa Lembar - temukan dan sorot perbedaan dalam beberapa lembar sekaligus.
Buku kerja latihan untuk diunduh
VLOOKUP di Excel untuk membandingkan kolom - contoh (file .xlsx)
