Ձեռնարկը ցույց է տալիս, թե ինչպես օգտագործել VLOOKUP բանաձևը Excel-ում՝ համեմատելու երկու սյունակները՝ վերադարձնելու ընդհանուր արժեքները (համընկնում) կամ գտնել բացակայող տվյալները (տարբերությունները):

Երբ դուք ունեք տվյալներ երկուսի մեջ։ տարբեր ցուցակներ, դուք կարող եք հաճախ կարիք ունենալ դրանք համեմատել՝ տեսնելու, թե ինչ տեղեկատվություն է բացակայում ցուցակներից մեկում կամ ինչ տվյալներ կան երկուսում: Համեմատությունը կարող է կատարվել տարբեր ձևերով. որ մեթոդն օգտագործել կախված է հենց նրանից, թե ինչ եք ուզում դրանից:

Ինչպես համեմատել երկու սյունակ Excel-ում VLOOKUP-ի միջոցով

Երբ դուք ունեք տվյալների երկու սյունակ և ցանկանում եք պարզել, թե մեկ ցուցակի տվյալների որ կետերն են գտնվում մյուս ցուցակում, կարող եք օգտագործել VLOOKUP ֆունկցիան՝ ցուցակները ընդհանուր արժեքների համեմատելու համար:

Նրա մեջ VLOOKUP բանաձև կառուցելու համար հիմնական ձևը, սա այն է, ինչ դուք պետք է անեք.

• lookup_value (1-ին արգումենտ), օգտագործեք 1-ին ցուցակի ամենավերին բջիջը:
• <1-ի համար>աղյուսակ_զանգված (2-րդ արգումենտ), տրամադրեք ամբողջ Ցուցակ 2-ը:
• col_index_num (3-րդ արգումենտ) համար օգտագործեք 1, քանի որ զանգվածում ընդամենը մեկ սյունակ կա:
• range_lookup (4-րդ արգումենտ) սահմանեք FALSE - ճշգրիտ համընկնում:

Ենթադրենք, դուք ունեք A սյունակի մասնակիցների անունները (Ցուցակ 1) և նրանց անունները: ովքեր անցել են Բ սյունակի որակավորման փուլերը (ցանկ 2): Ցանկանում եք համեմատել այս 2 ցուցակները՝ որոշելու համար, թե Ա խմբից որ մասնակիցներն են ճանապարհ ընկել դեպի գլխավոր իրադարձություն: Դա անելու համար օգտագործեք հետեւյալըբանաձև:

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Բանաձևը գնում է E2 բջիջ, այնուհետև այն քաշում եք ներքև այնքան բջիջների միջով, որքան կետեր կան 1-ին ցուցակում:

Խնդրում ենք նկատի ունենալ, որ աղյուսակի_զանգվածը կողպված է բացարձակ հղումներով ($C$2:$C$9), այնպես որ այն մնում է հաստատուն, երբ դուք պատճենում եք բանաձևը ստորև բերված բջիջներում:

Ինչպես տեսնում եք, անունները որակավորված մարզիկները հայտնվում են E սյունակում: Մնացած մասնակիցների համար հայտնվում է #N/A սխալ, որը ցույց է տալիս, որ նրանց անունները հասանելի չեն ցանկ 2-ում:

Քողարկել #N/ Սխալներ

Վերևում քննարկված VLOOKUP բանաձևը կատարելապես կատարում է իր հիմնական նպատակը՝ վերադարձնում է ընդհանուր արժեքները և բացահայտում բացակայող տվյալների կետերը: Այնուամենայնիվ, այն տալիս է մի շարք #N/A սխալներ, որոնք կարող են շփոթեցնել անփորձ օգտատերերին՝ ստիպելով նրանց մտածել, որ բանաձևի հետ ինչ-որ բան այն չէ:

Սխալները դատարկ բջիջներով փոխարինելու համար օգտագործեք VLOOKUP-ը: IFNA կամ IFERROR ֆունկցիայի հետ համակցված հետևյալ կերպ.

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Մեր բարելավված բանաձևը վերադարձնում է դատարկ տող ("") #N/-ի փոխարեն: Ա. Կարող եք նաև վերադարձնել ձեր հարմարեցված տեքստը , ինչպես օրինակ՝ «Ցուցակ 2-ում չէ», «Ներկա չէ» կամ «Անհասանելի»: Օրինակ՝

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Սա VLOOKUP-ի հիմնական բանաձևն է՝ Excel-ում երկու սյունակ համեմատելու համար: Կախված ձեր կոնկրետ առաջադրանքից, այն կարող է փոփոխվել, ինչպես ցույց է տրված հետագա օրինակներում:

Համեմատեք երկու սյունակներ Excel-ի տարբեր թերթերում՝ օգտագործելով VLOOKUP-ը

Իրական կյանքում, այն սյունակները, որոնք դուքպետք է համեմատել միշտ չէ, որ նույն թերթիկում են: Փոքր տվյալների բազայում դուք կարող եք փորձել ձեռքով նկատել տարբերությունները՝ դիտելով երկու թերթ կողք կողքի:

Բանաձևերով մեկ այլ աշխատաթերթում կամ աշխատանքային գրքում որոնելու համար դուք պետք է օգտագործեք արտաքին հղում: Լավագույն պրակտիկան այն է, որ սկսեք մուտքագրել բանաձևը ձեր հիմնական թերթիկում, այնուհետև անցեք մյուս աշխատաթերթին և մկնիկի միջոցով ընտրեք ցուցակը. բանաձևին ավտոմատ կերպով կավելացվի համապատասխան տիրույթի հղում:

Ենթադրելով, որ ցուցակը 1-ն է: Թերթ 1 -ի A սյունակում և Թերթ 2 -ի A սյունակում 2-ում, կարող եք համեմատել երկու սյունակ և գտնել համընկնումներ՝ օգտագործելով այս բանաձևը.

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Լրացուցիչ տեղեկությունների համար տես՝

• VLOOKUP այլ թերթից
• VLOOKUP տարբեր աշխատանքային գրքույկից

Համեմատեք երկու սյունակ և վերադարձրեք ընդհանուր արժեքներ (համընկնում)

Նախորդ օրինակներում մենք քննարկեցինք VLOOKUP բանաձևը իր ամենապարզ ձևով.

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Այդ բանաձևի արդյունքը հետևյալն է. արժեքների ցանկ, որոնք առկա են և՛ սյունակներում, և՛ դատարկ բջիջներում՝ երկրորդ սյունակում անհասանելի արժեքների փոխարեն:

Ընդհանուր արժեքների ցանկն առանց բացերի ստանալու համար պարզապես ավելացրեք ավտոմատ զտիչ ստացված սյունակում և զտել դատարկ տեղերը:

Excel-ում Microsoft 365-ի և Excel 2021-ի համար աջակցեք դինամիկ զանգվածներին, դուք կարող եք օգտագործել FILTER ֆունկցիան՝ դինամիկ կերպով բացերը մաղելու համար: Դրա համար օգտագործեք IFNA VLOOKUP բանաձևը որպեսFILTER-ի չափանիշները՝

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Խնդրում ենք ուշադրություն դարձնել, որ այս դեպքում մենք տրամադրում ենք ամբողջ Ցուցակը 1 (A2:A14) VLOOKUP-ի lookup_value արգումենտին: Ֆունկցիան համեմատում է որոնման արժեքներից յուրաքանչյուրը Ցուցակ 2-ի հետ (C2:C9) և վերադարձնում է համընկնումների զանգված և #N/A սխալներ, որոնք ներկայացնում են բացակայող արժեքները: IFNA ֆունկցիան սխալները փոխարինում է դատարկ տողերով և արդյունքները մատուցում FILTER ֆունկցիային, որը զտում է դատարկ տեղերը ("") և որպես վերջնական արդյունք դուրս է բերում համընկնումների զանգված:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Նույն արդյունքը կարող է լինել: կարելի է հասնել XLOOKUP ֆունկցիայի միջոցով, որն էլ ավելի պարզ է դարձնում բանաձևը: XLOOKUP-ի՝ #N/A սխալները ներսից կարգավորելու ունակության շնորհիվ (ըստ ցանկության եթե_չգտնվեց արգումենտ), մենք կարող ենք անել առանց IFNA կամ ISNA փաթաթման.

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Համեմատել երկու սյունակ և գտնել բացակայող արժեքները (տարբերությունները)

Excel-ում 2 սյունակները համեմատելու համար տարբերություններ գտնելու համար կարող եք շարունակել հետևյալ կերպ. արժեքը ցուցակ 1-ից (A2) Ցուցակ 2-ում ($C$2:$C$9).

VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Ամբողջական բանաձևն ունի հետևյալ ձևը.

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Դատարկներից ազատվելու համար կիրառեք Excel-ի զտիչը, ինչպես ցույց է տրված վերը նշված օրինակում:

Excel 365-ում և Excel 2021-ում դուք կարող եք արդյունքների ցանկը դինամիկ զտել: Դրա համար պարզապես տեղադրեք ISNA VLOOKUP բանաձևը FILTER ֆունկցիայի include արգումենտում.

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Մեկ այլ եղանակ է. օգտագործեք XLOOKUP-ը չափորոշիչների համար. ֆունկցիան վերադարձնում է դատարկ տողեր ("") տվյալների բացակայող կետերի համար, և դուք զտում եք 1-ին ցուցակի արժեքները, որոնց համար XLOOKUP-ը վերադարձրել է դատարկ տողեր (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP բանաձև՝ երկու սյունակների միջև համընկնումներն ու տարբերությունները բացահայտելու համար

Եթե ցանկանում եք առաջին ցուցակում ավելացնել տեքստային պիտակներ, որոնք ցույց են տալիս, թե որ արժեքներն են հասանելի երկրորդ ցուցակում, և որոնք՝ ոչ, օգտագործեք VLOOKUP բանաձևը հետ միասին: IF և ISNA/ISERROR ֆունկցիաները:

Օրինակ, A և D սյունակներում և միայն A սյունակներում գտնվող անունները նույնականացնելու համար, բանաձևը հետևյալն է.

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Այստեղ ISNA ֆունկցիան բռնում է VLOOKUP-ի կողմից ստեղծված #N/A սխալները և այդ միջանկյալ արդյունքը փոխանցում IF ֆունկցիային, որպեսզի այնվերադարձրեք նշված տեքստը սխալների համար, և մեկ այլ տեքստ՝ հաջող որոնումների համար:

Այս օրինակում մենք օգտագործել ենք «Ոչ որակավորված»/«Որակավորված» պիտակները, որոնք հարմար են մեր ընտրանքային տվյալների համար: Դուք կարող եք դրանք փոխարինել «Ցուցակ 2-ում չէ»/«Ցուցակ 2-ում», «Հասանելի չէ»/«Հասանելի է» կամ ցանկացած այլ պիտակներով, որոնք հարմար եք համարում:

Այս բանաձևը լավագույնս տեղադրվի սյունակում: Ցուցակ 1-ին կից և պատճենվում է այնքան բջիջներով, որքան տարրեր կան ձեր ցուցակում:

2 սյունակներում համընկնումները և տարբերությունները հայտնաբերելու ևս մեկ միջոց է MATCH ֆունկցիայի օգտագործումը.

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Համեմատեք 2 սյունակ և վերադարձրեք արժեքը երրորդից

Երբ աշխատում եք առնչվող տվյալներ պարունակող աղյուսակների հետ, երբեմն ձեզ կարող է անհրաժեշտ լինել. համեմատեք երկու սյունակ երկու տարբեր աղյուսակներում և վերադարձրեք համապատասխան արժեք մեկ այլ սյունակից: Փաստորեն, դա VLOOKUP ֆունկցիայի առաջնային օգտագործումն է, նպատակը, որի համար նախատեսված է:

Օրինակ՝ համեմատել A և D սյունակների անունները ստորև բերված երկու աղյուսակներում և վերադարձնել ժամանակը E սյունակից: , բանաձևը հետևյալն է.

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

#N/A սխալները թաքցնելու համար օգտագործեք ապացուցված լուծումը՝ IFNA ֆունկցիան.

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Դատարկ տեղերի փոխարեն կարող եք վերադարձնել ցանկացած տեքստ, որը ցանկանում եք տվյալների բացակայող կետերի համար, պարզապես մուտքագրեք այն վերջին արգումենտում: Օրինակ՝

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Բացի VLOOKUP-ից, առաջադրանքը կարող է իրականացվել մի քանի այլ որոնման գործառույթներով:

Անձամբ ես կվստահեի ավելի ճկուն INDEX-ի վրա:MATCH բանաձև՝

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Կամ օգտագործեք VLOOKUP-ի ժամանակակից իրավահաջորդը՝ XLOOKUP ֆունկցիան, որը հասանելի է Excel 365-ում և Excel 2021-ում՝

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

To Ստացեք A խմբի որակավորված մասնակիցների անունները և դրանց արդյունքները, պարզապես զտեք B սյունակի դատարկ բջիջները.

=FILTER(A3:B15, B3:B15"")

Համեմատության գործիքներ

Եթե դուք հաճախ եք կատարում ֆայլերի կամ տվյալների համեմատություն Excel-ում, ապա մեր Ultimate Suite-ում ներառված այս խելացի գործիքները կարող են անչափ խնայել ձեր ժամանակը:

Համեմատեք աղյուսակները. կրկնօրինակներ (համընկնումներ) և եզակի արժեքներ (տարբերություններ) գտնելու արագ միջոց: ցանկացած երկու տվյալների հավաքածուներում, ինչպիսիք են սյունակները, ցուցակները կամ աղյուսակները:

Համեմատեք երկու թերթ - գտեք և ընդգծեք տարբերությունները երկու աշխատաթերթերի միջև:

Համեմատեք բազմաթիվ թերթիկներ - գտեք և ընդգծեք տարբերությունները միանգամից մի քանի թերթերում .

Պրակտիկ աշխատանքային գրքույկ ներբեռնելու համար

VLOOKUP Excel-ում սյունակներ - օրինակներ (.xlsx ֆայլ) համեմատելու համար