De zelfstudie toont hoe u de VLOOKUP-formule in Excel kunt gebruiken om twee kolommen te vergelijken om gemeenschappelijke waarden (overeenkomsten) te verkrijgen of ontbrekende gegevens (verschillen) te vinden.

Wanneer u gegevens hebt in twee verschillende lijsten, moet u ze vaak vergelijken om te zien welke informatie ontbreekt in een van de lijsten of welke gegevens in beide aanwezig zijn. Vergelijken kan op veel verschillende manieren - welke methode u gebruikt hangt af van wat u er precies mee wilt.

Hoe twee kolommen vergelijken in Excel met behulp van VLOOKUP

Wanneer u twee kolommen met gegevens hebt en wilt weten welke gegevenspunten uit de ene lijst voorkomen in de andere lijst, kunt u de functie VLOOKUP gebruiken om de lijsten te vergelijken op gemeenschappelijke waarden.

Dit is wat u moet doen om een VLOOKUP-formule in zijn basisvorm op te stellen:

• Voor lookup_waarde (1e argument), gebruikt u de bovenste cel van lijst 1.
• Voor tabel_array (2e argument), levert de volledige lijst 2.
• Voor col_index_num (3e argument), gebruik 1 omdat er slechts één kolom in de matrix is.
• Voor range_lookup (4e argument), stel FALSE in - exacte overeenkomst.

Stel u heeft de namen van de deelnemers in kolom A (lijst 1) en de namen van degenen die door de kwalificatierondes zijn gekomen in kolom B (lijst 2). U wilt deze 2 lijsten vergelijken om te bepalen welke deelnemers uit groep A zijn doorgegaan naar het hoofdevenement. Gebruik daarvoor de volgende formule.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

De formule gaat naar cel E2, en dan sleep je hem naar beneden door zoveel cellen als er items zijn in lijst 1.

Merk op dat tabel_array is vergrendeld met absolute referenties ($C$2:$C$9) zodat hij constant blijft wanneer u de formule kopieert naar de onderstaande cellen.

Zoals u ziet, verschijnen de namen van de gekwalificeerde atleten in kolom E. Voor de overige deelnemers verschijnt een #N/A foutmelding dat hun namen niet beschikbaar zijn in lijst 2.

Vermomming #N/A fouten

De hierboven besproken VLOOKUP-formule voldoet perfect aan haar hoofddoel - gemeenschappelijke waarden teruggeven en ontbrekende gegevenspunten identificeren. Zij levert echter een hoop #N/A-fouten op, die onervaren gebruikers in verwarring kunnen brengen, waardoor zij denken dat er iets mis is met de formule.

Om fouten te vervangen door lege cellen Gebruik VLOOKUP in combinatie met de IFNA- of IFERROR-functie op deze manier:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Onze verbeterde formule geeft een lege tekenreeks ("") in plaats van #N/A. U kunt ook uw aangepaste tekst zoals "Niet in lijst 2", "Niet aanwezig", of "Niet beschikbaar". Bijvoorbeeld:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Niet in lijst 2")

Dat is de basisformule van VLOOKUP om twee kolommen in Excel te vergelijken. Afhankelijk van uw specifieke taak kan deze formule worden aangepast zoals in verdere voorbeelden wordt getoond.

Twee kolommen in verschillende Excel-bladen vergelijken met VLOOKUP

In het echte leven staan de kolommen die u moet vergelijken niet altijd op hetzelfde blad. In een kleine dataset kunt u proberen de verschillen handmatig op te sporen door twee bladen naast elkaar te bekijken.

Om in een ander werkblad of werkmap met formules te zoeken, moet u een externe referentie gebruiken. De beste werkwijze is om de formule te beginnen typen in uw hoofdblad, dan over te schakelen naar het andere werkblad en de lijst te selecteren met de muis - een passende bereikverwijzing zal automatisch aan de formule worden toegevoegd.

Aangenomen dat lijst 1 in kolom A staat op Blad1 en lijst 2 staat in kolom A op Sheet2 kunt u twee kolommen vergelijken en overeenkomsten vinden met deze formule:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Voor meer informatie, zie:

• VLOOKUP van een ander blad
• VLOOKUP vanuit een andere werkmap

Twee kolommen vergelijken en gemeenschappelijke waarden teruggeven (overeenkomsten)

In de vorige voorbeelden bespraken we een VLOOKUP-formule in zijn eenvoudigste vorm:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Het resultaat van die formule is een lijst van waarden die in beide kolommen voorkomen en lege cellen in plaats van de waarden die niet beschikbaar zijn in de tweede kolom.

Om een lijst van gemeenschappelijke waarden zonder hiaten te krijgen, voeg je gewoon een autofilter toe aan de resulterende kolom en filter je de spaties eruit.

In Excel voor Microsoft 365 en Excel 2021 die dynamische matrices ondersteunen, kunt u gebruikmaken van de functie FILTER om blanco's dynamisch uit te filteren. Gebruik hiervoor de IFNA VLOOKUP-formule als criterium voor FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")")

Let op: in dit geval leveren wij de volledige lijst 1 (A2:A14) aan de lookup_waarde De functie vergelijkt elk van de opzoekwaarden met lijst 2 (C2:C9) en geeft een matrix van overeenkomsten en #N/A-fouten die ontbrekende waarden weergeven. De IFNA-functie vervangt fouten door lege tekenreeksen en geeft de resultaten door aan de FILTER-functie, die spaties ("") eruit filtert en een matrix van overeenkomsten als eindresultaat geeft.

U kunt ook de functie ISNA gebruiken om het resultaat van VLOOKUP te controleren en de items te filteren die op FALSE uitkomen, d.w.z. andere waarden dan #N/A fouten:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Hetzelfde resultaat kan worden bereikt met de XLOOKUP-functie, die de formule nog eenvoudiger maakt. Doordat XLOOKUP intern #N/A-fouten kan verwerken (optioneel if_not_found argument), kunnen we zonder de IFNA- of ISNA-wrapper:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")")

Twee kolommen vergelijken en ontbrekende waarden vinden (verschillen)

Om in Excel 2 kolommen te vergelijken om verschillen te vinden, kunt u op deze manier te werk gaan:

1. Schrijf de kernformule om de eerste waarde uit lijst 1 (A2) te zoeken in lijst 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Nest de bovenstaande formule in de ISNA-functie om de uitvoer van de VLOOKUP te controleren op #N/A-fouten. In geval van een fout geeft ISNA WAAR, anders ONWAAR:

   ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))

3. Gebruik de ISNA VLOOKUP-formule voor de logische test van de IF-functie. Als de test op TRUE uitkomt (#N/A-fout), retourneer dan een waarde uit lijst 1 in dezelfde rij. Als de test op FALSE uitkomt (er is een overeenkomst in lijst 2 gevonden), retourneer dan een lege tekenreeks.

De volledige formule heeft deze vorm:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Om de spaties te verwijderen, past u Excel's Filter toe zoals in het bovenstaande voorbeeld.

In Excel 365 en Excel 2021 kunt u de resultatenlijst dynamisch laten filteren. Plaats hiervoor eenvoudig de ISNA VLOOKUP-formule in de omvatten argument van de FILTER-functie:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))

Een andere manier is om XLOOKUP te gebruiken voor criteria - de functie retourneert lege tekenreeksen ("") voor ontbrekende gegevenspunten, en u filtert de waarden in lijst 1 waarvoor XLOOKUP lege tekenreeksen (="") retourneerde:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP-formule om overeenkomsten en verschillen tussen twee kolommen vast te stellen

Als u tekstlabels wilt toevoegen aan de eerste lijst die aangeven welke waarden beschikbaar zijn in de tweede lijst en welke niet, gebruikt u de VLOOKUP-formule in combinatie met de functies IF en ISNA/ISERROR.

Bijvoorbeeld, om namen te identificeren die zowel in kolom A als D staan en die welke alleen in kolom A staan, is de formule:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Niet gekwalificeerd", "Gekwalificeerd")

Hier vangt de ISNA-functie de door VLOOKUP gegenereerde #N/A-fouten op en geeft dat tussenresultaat door aan de IF-functie zodat deze de opgegeven tekst voor fouten en een andere tekst voor succesvolle opzoekingen teruggeeft.

In dit voorbeeld hebben we de labels "Niet gekwalificeerd"/"Gekwalificeerd" gebruikt, die geschikt zijn voor onze voorbeelddataset. U kunt ze vervangen door "Niet in lijst 2"/"In lijst 2", "Niet beschikbaar"/"Beschikbaar" of andere labels die u geschikt acht.

Deze formule kunt u het beste invoegen in een kolom naast Lijst 1 en kopiëren door zoveel cellen als er items in uw lijst staan.

Een andere manier om overeenkomsten en verschillen in 2 kolommen te identificeren is met behulp van de MATCH-functie:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Niet in lijst 2", "In lijst 2")

Vergelijk 2 kolommen en geef een waarde terug van de derde

Wanneer u werkt met tabellen die gerelateerde gegevens bevatten, moet u soms twee kolommen in twee verschillende tabellen vergelijken en een overeenkomende waarde uit een andere kolom retourneren. In feite is dit het primaire gebruik van de VLOOKUP-functie, het doel waarvoor zij is ontworpen.

Bijvoorbeeld, om de namen in de kolommen A en D in de twee onderstaande tabellen te vergelijken en een tijd in kolom E terug te geven, is de formule:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Om #N/A-fouten te verbergen, gebruikt u de beproefde oplossing - de IFNA-functie:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

In plaats van spaties kunt u voor ontbrekende gegevenspunten elke gewenste tekst teruggeven - typ die gewoon in het laatste argument. Bijvoorbeeld:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Niet beschikbaar")

Naast VLOOKUP kan de taak worden vervuld met enkele andere opzoekfuncties.

Persoonlijk zou ik vertrouwen op een meer flexibele INDEX MATCH formule:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Of gebruik de moderne opvolger van VLOOKUP - de XLOOKUP-functie, beschikbaar in Excel 365 en Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Om de namen van gekwalificeerde deelnemers uit groep A en hun resultaten te krijgen, hoeft u alleen maar de lege cellen in kolom B uit te filteren:

=FILTER(A3:B15, B3:B15"")

Vergelijkingsinstrumenten

Als u vaak bestanden of gegevens vergelijkt in Excel, kunnen deze slimme tools in onze Ultimate Suite uw tijd enorm besparen!

Tabellen vergelijken - snelle manier om duplicaten (overeenkomsten) en unieke waarden (verschillen) te vinden in twee gegevensverzamelingen, zoals kolommen, lijsten of tabellen.

Vergelijk twee bladen - zoek en markeer verschillen tussen twee werkbladen.

Vergelijk meerdere bladen - zoek en markeer verschillen in meerdere bladen tegelijk.

Praktijk werkboek om te downloaden

VLOOKUP in Excel om kolommen te vergelijken - voorbeelden (.xlsx bestand)