La lernilo montras kiel uzi VLOOKUP-formulon en Excel por kompari du kolumnojn por redoni komunajn valorojn (kongruoj) aŭ trovi mankantajn datumojn (diferencoj).

Kiam vi havas datumojn en du. malsamaj listoj, vi eble ofte bezonos kompari ilin por vidi kiajn informojn mankas en unu el la listoj aŭ kiaj datumoj ĉeestas en ambaŭ. Komparo povas esti farita en multaj malsamaj manieroj - kiun metodo uzi dependas de precize kion vi volas de ĝi.

Kiel kompari du kolumnojn en Excel uzante VLOOKUP

Kiam vi havas du kolumnojn da datumoj kaj volas ekscii, kiuj datumpunktoj el unu listo ekzistas en la alia listo, vi povas uzi la funkcion VLOOKUP por kompari la listojn por komunaj valoroj.

Por konstrui VLOOKUP formulon en ĝia baza formo, jen kion vi devas fari:

• Por serĉa_valoro (1a argumento), uzu la plej supran ĉelon de Listo 1.
• Por table_array (dua argumento), liveru la tutan Liston 2.
• Por col_index_num (3a argumento), uzu 1 ĉar estas nur unu kolumno en la tabelo.
• Por range_lookup (4-a argumento), agordu FALSE - ĝustan kongruon.

Supozi vi havas la nomojn de partoprenantoj en kolumno A (Listo 1) kaj la nomojn de tiuj. kiuj trapasis la kvalifikajn rondojn en kolumno B (Listo 2). Vi volas kompari ĉi tiujn 2 listojn por determini kiuj partoprenantoj de Grupo A iris al la ĉefa evento. Por fari tion, uzu la jenonformulo.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

La formulo iras al ĉelo E2, kaj poste vi trenas ĝin malsupren tra tiom da ĉeloj kiom estas eroj en Listo 1.

Bonvolu rimarki, ke table_array estas ŝlosita kun absolutaj referencoj ($C$2:$C$9) tiel ke ĝi restas konstanta kiam vi kopias la formulon al la subaj ĉeloj.

Kiel vi povas vidi, la nomoj de la kvalifikitaj atletoj aperas en kolumno E. Por la ceteraj partoprenantoj, #N/A eraro aperas indikante ke iliaj nomoj ne estas haveblaj en Listo 2.

Alvestiĝo #N/ Eraroj

La formulo VLOOKUP supre diskutita perfekte plenumas sian ĉefan celon - liveras komunajn valorojn kaj identigas mankantajn datumpunktojn. Tamen, ĝi liveras amason da #N/A-eraroj, kiuj povas konfuzi nespertajn uzantojn igante ilin pensi, ke io estas malĝusta kun la formulo.

Por anstataŭigi erarojn per malplenaj ĉeloj , uzu VLOOKUP. kombine kun la funkcio IFNA aŭ IFERROR tiamaniere:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Nia plibonigita formulo liveras malplenan ĉenon ("") anstataŭ #N/ A. Vi ankaŭ povas resendi vian propan tekston kiel "Ne en Listo 2", "Ne ĉeestas", aŭ "Ne disponeblas". Ekzemple:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Tio estas la baza VLOOKUP-formulo por kompari du kolumnojn en Excel. Depende de via speciala tasko, ĝi povas esti modifita kiel montrite en pliaj ekzemploj.

Komparu du kolumnojn en malsamaj Excel-folioj per VLOOKUP

En la reala vivo, la kolumnoj vinecesas kompari ne ĉiam estas sur la sama folio. En malgranda datumaro, vi povas provi ekvidi la diferencojn permane rigardante du foliojn unu apud la alia.

Por serĉi en alia laborfolio aŭ laborlibro kun formuloj, vi devas uzi eksteran referencon. La plej bona praktiko estas komenci tajpi la formulon en via ĉefa folio, tiam ŝanĝi al la alia laborfolio kaj elektu la liston per la muso - taŭga intervalreferenco estos aldonita aŭtomate al la formulo.

Supoze, ke Listo 1 estas. en kolumno A sur Sheet1 kaj listo 2 estas en kolumno A sur Sheet2 , vi povas kompari du kolumnojn kaj trovi kongruojn uzante ĉi tiun formulon:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Por pliaj informoj, bonvolu vidi:

• VLOOKUP el alia folio
• VLOOKUP el malsama laborlibro

Komparu du kolumnojn kaj redonu komunajn valorojn (kongruoj)

En la antaŭaj ekzemploj, ni diskutis VLOOKUP formulon en ĝia plej simpla formo:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

La rezulto de tiu formulo estas listo de valoroj kiuj ekzistas en ambaŭ kolumnoj kaj malplenaj ĉeloj anstataŭe de la valoroj ne disponeblaj en la dua kolumno.

Por akiri liston de komunaj valoroj sen interspacoj, simple aldonu aŭtomatan filtrilon al la rezulta kolumno kaj filtri malplenajn.

En Excel por Microsoft 365 kaj Excel 2021 tio estas subtenu dinamikajn tabelojn, vi povas uzi la funkcion FILTRO por dinamike kribri malplenajn. Por ĉi tio, uzu la formulon IFNA VLOOKUP kiel lakriterioj por FILTRO:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Bonvolu atenti, ke ĉi-kaze ni liveras la tutan Liston 1 (A2:A14) al la argumento serĉa_valoro de VSERĈO. La funkcio komparas ĉiun el la serĉvaloroj kontraŭ Listo 2 (C2:C9) kaj liveras tabelon de kongruoj kaj #N/A eraroj reprezentantaj mankantajn valorojn. La IFNA-funkcio anstataŭigas erarojn per malplenaj ĉenoj kaj servas la rezultojn al la FILTRO-funkcio, kiu filtras malplenajn ("") kaj eligas tabelon da kongruoj kiel la fina rezulto.

Alternative, vi povas uzi la ISNA-funkcion por kontroli la rezulton de VLOOKUP kaj filtri la erojn taksantajn al FALSA, t.e. valoroj krom #N/A eraroj:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

La sama rezulto povas esti atingita per la funkcio XLOOKUP, kiu faras la formulon eĉ pli simpla. Pro la kapablo de XLOOKUP pritrakti #N/A-erarojn interne (laŭvola if_ne_trovita argumento), ni povas malhavi la IFNA aŭ ISNA-envolvaĵon:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Komparu du kolumnoj kaj trovi mankantajn valorojn (diferencoj)

Por kompari 2 kolumnojn en Excel por trovi diferencojn, vi povas procedi tiamaniere:

1. Skribu la kernan formulon por serĉi la unuan valoro de Listo 1 (A2) en Listo 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSA)

2. Nestigi la supra formulo en la ISNA-funkcio por kontroli la eligon de VLOOKUP por #N/A-eraroj. En kazo de eraro, ISNA donas VERA, alie MALSA:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSA))

3. Uzu la formulon ISNA VLOOKUP por la logika testo de la IF-funkcio. Se la testo taksas VERA (#N/A eraro), redonu valoron de Listo 1 en la sama vico. Se la testo taksas FALSA (kongruo en Listo 2 estas trovita), redonu malplenan ĉenon.

La kompleta formulo prenas ĉi tiun formon:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Por forigi la malplenaĵojn, apliku la Filtrilon de Excel kiel montrite en la supra ekzemplo.

En Excel 365 kaj Excel 2021, vi povas havi la rezultoliston dinamike filtrita. Por ĉi tio, simple metu la formulon ISNA VLOOKUP en la argumenton inkluzivi de la funkcio FILTRO:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Alia maniero estas uzu XLOOKUP por kriterioj - la funkcio liveras malplenajn ĉenojn ("") por mankantaj datumpunktoj, kaj vi filtras la valorojn en Listo 1 por kiuj XLOOKUP resendis malplenajn ĉenojn (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP formulo por identigi kongruojn kaj diferencojn inter du kolumnoj

Se vi volas aldoni tekstajn etikedojn al la unua listo indikante kiuj valoroj disponeblas en la dua listo kaj kiuj ne estas, uzu la VLOOKUP formulon kune kun la Funkcioj IF kaj ISNA/ISERROR.

Ekzemple, por identigi nomojn kiuj estas en ambaŭ kolumnoj A kaj D kaj tiujn kiuj estas nur en kolumno A, la formulo estas:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Ĉi tie, la ISNA-funkcio kaptas la #N/A-erarojn generitajn de VLOOKUP kaj pasas tiun mezan rezulton al la IF-funkcio por ke ĝiresendu la specifitan tekston por eraroj kaj alian tekston por sukcesaj serĉoj.

En ĉi tiu ekzemplo, ni uzis etikedojn "Ne kvalifikitaj"/"Kvalifikitaj", kiuj taŭgas por nia ekzempla datumaro. Vi povas anstataŭigi ilin per "Ne en Listo 2"/"En Listo 2", "Ne disponebla"/"Havebla" aŭ iuj aliaj etikedoj, kiujn vi opinias taŭga.

Tiu formulo estas plej bone enmetita en kolumnon. apuda al Listo 1 kaj kopiita tra tiom da ĉeloj kiom estas eroj en via listo.

Unu plia maniero por identigi kongruojn kaj diferencojn en 2 kolumnoj estas uzi la funkcion MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Komparu 2 kolumnojn kaj redonu valoron de la tria

Kiam laboras kun tabeloj enhavantaj rilatajn datumojn, vi eble foje bezonos komparu du kolumnojn en du malsamaj tabeloj kaj redonu kongruan valoron de alia kolumno. Fakte, ĝi estas la ĉefa uzo de la funkcio VLOOKUP, la celo por kiu ĝi estis desegnita.

Ekzemple, por kompari la nomojn en kolumnoj A kaj D en la du subaj tabeloj kaj redoni tempon el kolumno E. , la formulo estas:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Por kaŝi #N/A-erarojn, uzu la pruvitan solvon - la IFNA-funkcion:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Anstataŭ vakoj, vi povas redoni ajnan tekston, kiun vi volas por mankantaj datumpunktoj - simple tajpu ĝin en la lasta argumento. Ekzemple:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Krom VLOOKUP, la tasko povas esti plenumita per kelkaj aliaj serĉfunkcioj.

Persone, mi fidus je pli fleksebla INDEXO.MATCH-formulo:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Aŭ uzu la modernan posteulon de VLOOKUP - la funkcio XLOOKUP, disponebla en Excel 365 kaj Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Al ricevu la nomojn de kvalifikitaj partoprenantoj de grupo A kaj iliajn rezultojn, simple filtri malplenajn ĉelojn en kolumno B:

=FILTER(A3:B15, B3:B15"")

Komparaj iloj

Se vi ofte komparas dosierojn aŭ datumojn en Excel, ĉi tiuj inteligentaj iloj inkluzivitaj en nia Ultimate Suite povas ege ŝpari vian tempon!

Komparu Tabelojn - rapida maniero trovi duplikatojn (kongruojn) kaj unikajn valorojn (diferencoj) en iuj du datumaro kiel ekzemple kolumnoj, listo aŭ tabeloj.

Komparu Du Foliojn - trovu kaj reliefigu diferencojn inter du laborfolioj.

Komparu Multoblaj folioj - trovu kaj reliefigu diferencojn en pluraj folioj samtempe. .

Praktiku laborlibron por elŝuto

VLOOKUP en Excel por kompari kolumnojn - ekzemplojn (.xlsx-dosiero)