Die tutoriaal wys hoe om VLOOKUP-formule in Excel te gebruik om twee kolomme te vergelyk om algemene waardes (passings) terug te gee of ontbrekende data (verskille) te vind.

Wanneer jy data in twee het verskillende lyste, sal jy hulle dalk dikwels moet vergelyk om te sien watter inligting in een van die lyste ontbreek of watter data in albei teenwoordig is. Vergelyking kan op baie verskillende maniere gedoen word - watter metode om te gebruik hang af presies wat jy daarvan wil hê.

Hoe om twee kolomme in Excel te vergelyk met VLOOKUP

Wanneer jy het twee kolomme data en wil uitvind watter datapunte van een lys in die ander lys bestaan, kan jy die VLOOKUP-funksie gebruik om die lyste vir algemene waardes te vergelyk.

Om 'n VLOOKUP-formule te bou in sy basiese vorm, dit is wat jy moet doen:

• Vir opsoekwaarde (1ste argument), gebruik die boonste sel van Lys 1.
• Vir tabel_skikking (2de argument), verskaf die hele Lys 2.
• Vir kol_indeks_num (3de argument), gebruik 1 aangesien daar net een kolom in die skikking is.
• Vir reekssoek (4de argument), stel ONWAAR - presiese passing.

Gestel jy het die name van deelnemers in kolom A (Lys 1) en die name daarvan wat deur die kwalifiseringsrondtes in kolom B (Lys 2) geslaag het. Jy wil hierdie 2 lyste vergelyk om te bepaal watter deelnemers van Groep A hul pad na die hoofbyeenkoms gemaak het. Om dit te doen, gebruik die volgendeformule.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Die formule gaan na sel E2, en dan sleep jy dit af deur soveel selle as wat daar items in Lys 1 is.

Let asseblief op dat tabel_skikking is gesluit met absolute verwysings ($C$2:$C$9) sodat dit konstant bly wanneer jy die formule na die onderstaande selle kopieer.

Soos jy kan sien, is die name van die gekwalifiseerde atlete verskyn in kolom E. Vir die oorblywende deelnemers verskyn 'n #N/A-fout wat aandui dat hul name nie in Lys 2 beskikbaar is nie.

Vermomming #N/ A Foute

Die VLOOKUP-formule wat hierbo bespreek is, vervul sy hoofdoelwit perfek - gee algemene waardes terug en identifiseer ontbrekende datapunte. Dit lewer egter 'n klomp #N/A-foute, wat onervare gebruikers kan verwar wat hulle laat dink dat iets fout is met die formule.

Om foute met leë selle te vervang, gebruik VLOOKUP in kombinasie met die IFNA- of IFERROR-funksie op hierdie manier:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Ons verbeterde formule gee 'n leë string ("") in plaas van #N/ A. Jy kan ook jou pasgemaakte teks terugstuur soos "Nie in Lys 2", "Nie teenwoordig nie" of "Nie beskikbaar nie". Byvoorbeeld:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Dit is die basiese VLOOKUP-formule om twee kolomme in Excel te vergelyk. Afhangende van jou spesifieke taak, kan dit gewysig word soos in verdere voorbeelde aangetoon word.

Vergelyk twee kolomme in verskillende Excel-blaaie deur VLOOKUP te gebruik

In die werklike lewe is die kolomme wat jymoet vergelyk is nie altyd op dieselfde blad nie. In 'n klein datastel kan jy probeer om die verskille met die hand op te spoor deur twee velle langs mekaar te bekyk.

Om in 'n ander werkblad of werkboek met formules te soek, moet jy eksterne verwysing gebruik. Die beste praktyk is om die formule in jou hoofblad te begin tik, dan na die ander werkblad oor te skakel en die lys met die muis te kies - 'n toepaslike reeksverwysing sal outomaties by die formule gevoeg word.

Aanvaar Lys 1 is in kolom A op Blad1 en lys 2 is in kolom A op Blad2 , kan jy twee kolomme vergelyk en passings vind deur hierdie formule te gebruik:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Vir meer inligting, sien asseblief:

• VLOOKUP van 'n ander blad
• VLOOKUP van ander werkboek

Vergelyk twee kolomme en gee algemene waardes (passings) terug

In die vorige voorbeelde het ons 'n VLOOKUP-formule in sy eenvoudigste vorm bespreek:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Die resultaat van daardie formule is 'n lys waardes wat in beide kolomme en leë selle bestaan ​​in die plek van die waardes wat nie in die tweede kolom beskikbaar is nie.

Om 'n lys van algemene waardes sonder gapings te kry, voeg net outo-filter by die resulterende kolom en filtreer spasies uit.

In Excel vir Microsoft 365 en Excel 2021 is dit dinamiese skikkings opspoor, kan jy van die FILTER-funksie gebruik maak om spasies dinamies uit te sif. Gebruik hiervoor die IFNA VLOOKUP formule as diekriteria vir FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")"")

Let asseblief daarop dat ons in hierdie geval die hele Lys 1 (A2:A14) verskaf aan die opsoekwaarde -argument van VLOOKUP. Die funksie vergelyk elk van die opsoekwaardes met Lys 2 (C2:C9) en gee 'n verskeidenheid passings en #N/A-foute wat ontbrekende waardes verteenwoordig, terug. Die IFNA-funksie vervang foute met leë stringe en dien die resultate aan die FILTER-funksie, wat spasies ("") uitfiltreer en 'n verskeidenheid passings as die finale resultaat uitstuur.

Alternatiewelik kan jy die ISNA-funksie gebruik om die resultaat van VLOOKUP na te gaan en die items wat evalueer word na ONWAAR te filter, dit wil sê waardes anders as #N/A-foute:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Dieselfde resultaat kan bereik word met die XLOOKUP-funksie, wat die formule nog eenvoudiger maak. As gevolg van die vermoë van XLOOKUP om #N/A-foute intern te hanteer (opsionele as_nie_gevind -argument), kan ons sonder die IFNA- of ISNA-omhulsel klaarkom:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Vergelyk twee kolomme en vind ontbrekende waardes (verskille)

Om 2 kolomme in Excel te vergelyk om verskille te vind, kan jy op hierdie manier voortgaan:

1. Skryf die kernformule om na die eerste te soek waarde van Lys 1 (A2) in Lys 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Neste die bogenoemde formule in die ISNA-funksie om die VLOOKUP se uitset na te gaan vir #N/A-foute. In die geval van 'n fout, lewer ISNA WAAR, anders ONWAAR:

   ISNA(VLOOKUP(A2,$C$2:$C$9, 1, FALSE))

3. Gebruik die ISNA VLOOKUP-formule vir die logiese toets van die IF-funksie. As die toets evalueer na WAAR (#N/A fout), gee 'n waarde van Lys 1 in dieselfde ry terug. As die toets na ONWAAR evalueer ('n passing in Lys 2 word gevind), gee 'n leë string terug.

Die volledige formule neem hierdie vorm aan:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Om van die spasies ontslae te raak, pas Excel se Filter toe soos in die voorbeeld hierbo gedemonstreer.

In Excel 365 en Excel 2021 kan jy die resultatelys dinamies laat filter. Hiervoor plaas eenvoudig die ISNA VLOOKUP-formule in die insluit -argument van die FILTER-funksie:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

'n Ander manier is om gebruik XLOOKUP vir kriteria - die funksie gee leë stringe ("") vir ontbrekende datapunte terug, en jy filtreer die waardes in Lys 1 waarvoor XLOOKUP leë stringe (="") teruggestuur het:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

VLOOKUP formule om passings en verskille tussen twee kolomme te identifiseer

As jy teksetikette by die eerste lys wil voeg wat aandui watter waardes in die tweede lys beskikbaar is en watter nie, gebruik die VLOOKUP formule saam met die IF- en ISNA/ISERROR-funksies.

Om byvoorbeeld name te identifiseer wat in beide kolomme A en D is en dié wat slegs in kolom A is, is die formule:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Not qualified", "Qualified")

Hier vang die ISNA-funksie die #N/A-foute op wat deur VLOOKUP gegenereer word en gee daardie tussenresultaat na die IF-funksie deur sodat ditgee die gespesifiseerde teks terug vir foute en 'n ander teks vir suksesvolle soektogte.

In hierdie voorbeeld het ons "Not qualified"/"Qualified"-etikette gebruik, wat geskik is vir ons voorbeelddatastel. Jy kan hulle vervang met "Nie in Lys 2"/"In Lys 2", "Nie beskikbaar nie"/"Beskikbaar" of enige ander etikette wat jy goeddink.

Hierdie formule is die beste om in 'n kolom in te voeg aangrensend aan Lys 1 en gekopieer deur soveel selle as wat daar items in jou lys is.

Nog 'n manier om passings en verskille in 2 kolomme te identifiseer, is om die MATCH-funksie te gebruik:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Vergelyk 2 kolomme en gee 'n waarde van derde terug

Wanneer jy met tabelle werk wat verwante data bevat, sal jy soms nodig hê om vergelyk twee kolomme in twee verskillende tabelle en gee 'n ooreenstemmende waarde van 'n ander kolom terug. Trouens, dit is die primêre gebruik van die VLOOKUP-funksie, die doel waarvoor dit ontwerp is.

Om byvoorbeeld die name in kolomme A en D in die twee tabelle hieronder te vergelyk en 'n tyd uit kolom E terug te gee , die formule is:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Om #N/A-foute te versteek, gebruik die bewese oplossing - die IFNA-funksie:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

In plaas van spasies, kan jy enige teks wat jy wil hê vir ontbrekende datapunte terugstuur - tik dit net in die laaste argument. Byvoorbeeld:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Not available")

Behalwe VLOOKUP, kan die taak met 'n paar ander opsoekfunksies vervul word.

Persoonlik sal ek staatmaak op 'n meer buigsame INDEKSMATCH formule:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Of gebruik die moderne opvolger van VLOOKUP - die XLOOKUP-funksie, beskikbaar in Excel 365 en Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

To kry die name van gekwalifiseerde deelnemers uit groep A en hul resultate, filter bloot leë selle in kolom B uit:

=FILTER(A3:B15, B3:B15"")

Vergelykingsnutsmiddels

As jy gereeld lêer- of datavergelyking in Excel doen, kan hierdie slim gereedskap wat in ons Ultimate Suite ingesluit is, jou tyd geweldig bespaar!

Vergelyk tabelle - vinnige manier om duplikate (passings) en unieke waardes (verskille) te vind. in enige twee datastelle soos kolomme, lys of tabelle.

Vergelyk twee velle - vind en merk verskille tussen twee werkblaaie.

Vergelyk veelvuldige velle - vind en merk verskille in veelvuldige velle gelyktydig uit. .

Oefenwerkboek vir aflaai

VLOOKUP in Excel om kolomme te vergelyk - voorbeelde (.xlsx-lêer)