Tutorialul arată cum se utilizează formula VLOOKUP în Excel pentru a compara două coloane pentru a returna valori comune (corespondențe) sau pentru a găsi date lipsă (diferențe).

Atunci când aveți date în două liste diferite, este posibil să aveți adesea nevoie să le comparați pentru a vedea ce informații lipsesc într-una dintre liste sau ce date sunt prezente în ambele. Compararea se poate face în mai multe moduri diferite - metoda pe care o utilizați depinde de ceea ce doriți exact de la ea.

Cum se compară două coloane în Excel folosind VLOOKUP

Atunci când aveți două coloane de date și doriți să aflați ce puncte de date dintr-o listă există în cealaltă listă, puteți utiliza funcția VLOOKUP pentru a compara listele pentru valori comune.

Pentru a construi o formulă VLOOKUP în forma sa de bază, iată ce trebuie să faceți:

• Pentru lookup_value (primul argument), se utilizează cea mai de sus celulă din lista 1.
• Pentru tabel_array (al doilea argument), se furnizează întreaga listă 2.
• Pentru col_index_num (al treilea argument), utilizați 1, deoarece există o singură coloană în matrice.
• Pentru range_lookup (al patrulea argument), setează FALSE - potrivire exactă.

Să presupunem că aveți numele participanților în coloana A (Lista 1) și numele celor care au trecut prin rundele de calificare în coloana B (Lista 2). Doriți să comparați aceste 2 liste pentru a determina ce participanți din grupa A au ajuns la evenimentul principal. Pentru a face acest lucru, utilizați următoarea formulă.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Formula se duce în celula E2, iar apoi o trageți în jos prin atâtea celule câte elemente există în Lista 1.

Vă rugăm să rețineți că tabel_array este blocată cu referințe absolute ($C$2:$C$9), astfel încât să rămână constantă atunci când copiați formula în celulele de mai jos.

După cum puteți vedea, numele sportivilor calificați apar în coloana E. Pentru ceilalți participanți, apare o eroare #N/A care indică faptul că numele lor nu sunt disponibile în lista 2.

Deghizare #N/A erori

Formula VLOOKUP discutată mai sus își îndeplinește perfect obiectivul principal - returnează valori comune și identifică punctele de date lipsă. Cu toate acestea, oferă o grămadă de erori #N/A, ceea ce poate deruta utilizatorii neexperimentați, făcându-i să creadă că ceva este în neregulă cu formula.

Pentru a înlocui erorile cu celule goale , utilizați VLOOKUP în combinație cu funcția IFNA sau IFERROR în acest mod:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Formula noastră îmbunătățită returnează un șir de caractere gol ("") în loc de #N/A. Puteți, de asemenea, să returnați șirul text personalizat cum ar fi "Not in List 2", "Not present" sau "Not available". De exemplu:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Not in List 2")

Aceasta este formula de bază VLOOKUP pentru a compara două coloane în Excel. În funcție de sarcina dvs. particulară, aceasta poate fi modificată, așa cum se arată în exemplele următoare.

Comparați două coloane din foi Excel diferite utilizând VLOOKUP

În viața reală, coloanele pe care trebuie să le comparați nu se află întotdeauna pe aceeași foaie. Într-un set de date mic, puteți încerca să identificați diferențele manual, vizualizând două foi una lângă alta.

Pentru a căuta într-o altă foaie de lucru sau registru de lucru cu formule, trebuie să utilizați o referință externă. Cea mai bună practică este să începeți să introduceți formula în foaia principală, apoi să treceți la cealaltă foaie de lucru și să selectați lista cu ajutorul mouse-ului - o referință de interval corespunzătoare va fi adăugată automat la formulă.

Presupunând că lista 1 se află în coloana A pe Foaie1 iar lista 2 se află în coloana A pe Foaie2 , puteți compara două coloane și găsi corespondențe folosind această formulă:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Pentru mai multe informații, vă rugăm să consultați:

• VLOOKUP din altă foaie
• VLOOKUP din alt registru de lucru

Compararea a două coloane și returnarea valorilor comune (matches)

În exemplele anterioare, am discutat o formulă VLOOKUP în forma sa cea mai simplă:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Rezultatul acestei formule este o listă de valori care există în ambele coloane și celule goale în locul valorilor care nu sunt disponibile în a doua coloană.

Pentru a obține o listă de valori comune fără spații libere, adăugați un filtru automat la coloana rezultată și filtrați spațiile libere.

În Excel pentru Microsoft 365 și Excel 2021 care acceptă matrice dinamice, puteți utiliza funcția FILTER pentru a elimina în mod dinamic spațiile libere. Pentru aceasta, utilizați formula IFNA VLOOKUP ca și criteriu pentru FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")")")

Vă rugăm să acordați atenție faptului că în acest caz furnizăm întreaga listă 1 (A2:A14) către lookup_value Funcția compară fiecare dintre valorile de căutare cu lista 2 (C2:C9) și returnează un tablou de corespondențe și erori #N/A reprezentând valori lipsă. Funcția IFNA înlocuiește erorile cu șiruri goale și transmite rezultatele funcției FILTER, care filtrează spațiile goale ("") și emite un tablou de corespondențe ca rezultat final.

Alternativ, puteți utiliza funcția ISNA pentru a verifica rezultatul VLOOKUP și pentru a filtra elementele care se evaluează la FALSE, adică alte valori decât erorile #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Același rezultat poate fi obținut cu ajutorul funcției XLOOKUP, ceea ce face ca formula să fie și mai simplă. Datorită capacității lui XLOOKUP de a gestiona intern erorile #N/A (opțional if_not_found argument), ne putem lipsi de învelișul IFNA sau ISNA:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")")")

Comparați două coloane și găsiți valorile lipsă (diferențe)

Pentru a compara 2 coloane în Excel pentru a găsi diferențe, puteți proceda în acest fel:

1. Scrieți formula de bază pentru a căuta prima valoare din lista 1 (A2) în lista 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Introduceți formula de mai sus în funcția ISNA pentru a verifica dacă există erori #N/A în rezultatul VLOOKUP. În cazul unei erori, ISNA produce TRUE, iar în caz contrar FALSE:

   ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))

3. Utilizați formula ISNA VLOOKUP pentru testul logic al funcției IF. Dacă testul se evaluează la TRUE (eroare #N/A), returnează o valoare din Lista 1 în același rând. Dacă testul se evaluează la FALSE (se găsește o potrivire în Lista 2), returnează un șir de caractere gol.

Formula completă are următoarea formă:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Pentru a scăpa de spațiile libere, aplicați filtrul Excel, așa cum se arată în exemplul de mai sus.

În Excel 365 și Excel 2021, puteți face ca lista de rezultate să fie filtrată dinamic. Pentru aceasta, este suficient să plasați formula ISNA VLOOKUP în fereastra include argument al funcției FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

O altă modalitate este de a utiliza XLOOKUP pentru criterii - funcția returnează șiruri de caractere goale (""") pentru punctele de date lipsă, iar dumneavoastră filtrați valorile din Lista 1 pentru care XLOOKUP a returnat șiruri de caractere goale (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Formula VLOOKUP pentru a identifica potrivirile și diferențele dintre două coloane

Dacă doriți să adăugați etichete de text la prima listă pentru a indica ce valori sunt disponibile în cea de-a doua listă și care nu sunt, utilizați formula VLOOKUP împreună cu funcțiile IF și ISNA/ISERROR.

De exemplu, pentru a identifica numele care se află atât în coloanele A și D, cât și cele care se află doar în coloana A, formula este:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Nu este calificat", "Calificat")

Aici, funcția ISNA captează erorile #N/A generate de VLOOKUP și transmite acest rezultat intermediar funcției IF pentru ca aceasta să returneze textul specificat pentru erori și un alt text pentru căutările reușite.

În acest exemplu, am utilizat etichetele "Not qualified"/"Qualified", care sunt adecvate pentru setul nostru de date de eșantionare. Le puteți înlocui cu "Not in List 2"/"In List 2", "Not available"/"Available" sau orice alte etichete pe care le considerați potrivite.

Cel mai bine este ca această formulă să fie inserată într-o coloană adiacentă Listei 1 și copiată în atâtea celule câte elemente există în listă.

O altă modalitate de a identifica potriviri și diferențe în 2 coloane este utilizarea funcției MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Not in List 2", "In List 2")

Compară 2 coloane și returnează o valoare din a treia

Atunci când lucrați cu tabele care conțin date legate între ele, este posibil ca uneori să aveți nevoie să comparați două coloane din două tabele diferite și să returnați o valoare corespunzătoare dintr-o altă coloană. De fapt, aceasta este principala utilizare a funcției VLOOKUP, scopul pentru care a fost concepută.

De exemplu, pentru a compara numele din coloanele A și D din cele două tabele de mai jos și a returna o oră din coloana E, formula este:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Pentru a ascunde erorile #N/A, utilizați soluția dovedită - funcția IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

În loc de spații goale, puteți returna orice text doriți pentru punctele de date lipsă - trebuie doar să-l introduceți în ultimul argument. De exemplu:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Nu este disponibil")

În afară de VLOOKUP, sarcina poate fi îndeplinită cu alte câteva funcții de căutare.

Personal, m-aș baza pe o formulă INDEX MATCH mai flexibilă:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Sau utilizați succesorul modern al VLOOKUP - funcția XLOOKUP, disponibilă în Excel 365 și Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Pentru a obține numele participanților calificați din grupul A și rezultatele acestora, este suficient să filtrați celulele goale din coloana B:

=FILTER(A3:B15, B3:B15"")

Instrumente de comparare

Dacă efectuați frecvent comparații de fișiere sau date în Excel, aceste instrumente inteligente incluse în suita noastră Ultimate Suite vă pot economisi foarte mult timp!

Comparare tabele - modalitate rapidă de a găsi duplicate (potriviri) și valori unice (diferențe) în oricare două seturi de date, cum ar fi coloane, liste sau tabele.

Comparați două foi - găsiți și evidențiați diferențele dintre două foi de lucru.

Comparați mai multe foi - găsiți și evidențiați diferențele în mai multe foi deodată.

Caietul de practică pentru descărcare

VLOOKUP în Excel pentru a compara coloane - exemple (fișier .xlsx)