Το σεμινάριο δείχνει πώς να χρησιμοποιείτε τον τύπο VLOOKUP στο Excel για να συγκρίνετε δύο στήλες για να επιστρέψετε κοινές τιμές (αντιστοιχίες) ή να βρείτε δεδομένα που λείπουν (διαφορές).

Όταν έχετε δεδομένα σε δύο διαφορετικές λίστες, μπορεί συχνά να χρειαστεί να τις συγκρίνετε για να δείτε ποιες πληροφορίες λείπουν σε μία από τις λίστες ή ποια δεδομένα υπάρχουν και στις δύο. Η σύγκριση μπορεί να γίνει με πολλούς διαφορετικούς τρόπους - η μέθοδος που θα χρησιμοποιήσετε εξαρτάται από το τι ακριβώς θέλετε από αυτήν.

Πώς να συγκρίνετε δύο στήλες στο Excel χρησιμοποιώντας το VLOOKUP

Όταν έχετε δύο στήλες δεδομένων και θέλετε να μάθετε ποια σημεία δεδομένων από τη μία λίστα υπάρχουν στην άλλη λίστα, μπορείτε να χρησιμοποιήσετε τη συνάρτηση VLOOKUP για να συγκρίνετε τις λίστες για κοινές τιμές.

Για να δημιουργήσετε έναν τύπο VLOOKUP στη βασική του μορφή, πρέπει να κάνετε τα εξής:

• Για το lookup_value (1ο όρισμα), χρησιμοποιήστε το πιο πάνω κελί από τη λίστα 1.
• Για το table_array (2ο όρισμα), παρέχετε ολόκληρη τη λίστα 2.
• Για το col_index_num (3ο όρισμα), χρησιμοποιήστε το 1 καθώς υπάρχει μόνο μία στήλη στον πίνακα.
• Για το range_lookup (4ο όρισμα), ορίστε FALSE - ακριβής αντιστοιχία.

Ας υποθέσουμε ότι έχετε τα ονόματα των συμμετεχόντων στη στήλη Α (Λίστα 1) και τα ονόματα όσων πέρασαν από τους προκριματικούς γύρους στη στήλη Β (Λίστα 2). Θέλετε να συγκρίνετε αυτές τις 2 λίστες για να προσδιορίσετε ποιοι συμμετέχοντες από την ομάδα Α πέρασαν στην κύρια εκδήλωση. Για να το κάνετε αυτό, χρησιμοποιήστε τον ακόλουθο τύπο.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Ο τύπος πηγαίνει στο κελί E2 και στη συνέχεια τον σύρετε προς τα κάτω σε τόσα κελιά όσα είναι τα στοιχεία της λίστας 1.

Παρακαλώ σημειώστε ότι table_array είναι κλειδωμένη με απόλυτες αναφορές ($C$2:$C$9), ώστε να παραμένει σταθερή όταν αντιγράφετε τον τύπο στα παρακάτω κελιά.

Όπως μπορείτε να δείτε, τα ονόματα των αθλητών που πληρούν τις προϋποθέσεις εμφανίζονται στη στήλη Ε. Για τους υπόλοιπους συμμετέχοντες, εμφανίζεται ένα σφάλμα #N/A που υποδεικνύει ότι τα ονόματά τους δεν είναι διαθέσιμα στον κατάλογο 2.

Μεταμφίεση #N/A λάθη

Ο τύπος VLOOKUP που συζητήθηκε παραπάνω εκπληρώνει τέλεια τον κύριο στόχο του - επιστρέφει κοινές τιμές και εντοπίζει τα σημεία δεδομένων που λείπουν. Ωστόσο, παρέχει ένα σωρό σφάλματα #N/A, τα οποία μπορεί να μπερδέψουν τους άπειρους χρήστες κάνοντάς τους να νομίζουν ότι κάτι δεν πάει καλά με τον τύπο.

Για να αντικαταστήσετε τα σφάλματα με κενά κελιά , χρησιμοποιήστε την VLOOKUP σε συνδυασμό με τη συνάρτηση IFNA ή IFERROR με αυτόν τον τρόπο:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Ο βελτιωμένος τύπος μας επιστρέφει μια κενή συμβολοσειρά ("") αντί για #N/A. Μπορείτε επίσης να επιστρέψετε το προσαρμοσμένο κείμενο όπως "Δεν περιλαμβάνεται στον κατάλογο 2", "Δεν υπάρχει" ή "Δεν είναι διαθέσιμος". Για παράδειγμα:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Όχι στη λίστα 2")

Αυτός είναι ο βασικός τύπος VLOOKUP για τη σύγκριση δύο στηλών στο Excel. Ανάλογα με την εκάστοτε εργασία σας, μπορεί να τροποποιηθεί όπως φαίνεται σε περαιτέρω παραδείγματα.

Σύγκριση δύο στηλών σε διαφορετικά φύλλα του Excel χρησιμοποιώντας το VLOOKUP

Στην πραγματική ζωή, οι στήλες που πρέπει να συγκρίνετε δεν βρίσκονται πάντα στο ίδιο φύλλο. Σε ένα μικρό σύνολο δεδομένων, μπορείτε να προσπαθήσετε να εντοπίσετε τις διαφορές με το χέρι, βλέποντας δύο φύλλα το ένα δίπλα στο άλλο.

Για να κάνετε αναζήτηση σε άλλο φύλλο εργασίας ή βιβλίο εργασίας με τύπους, πρέπει να χρησιμοποιήσετε εξωτερική αναφορά. Η καλύτερη πρακτική είναι να αρχίσετε να πληκτρολογείτε τον τύπο στο κύριο φύλλο σας, στη συνέχεια να μεταβείτε στο άλλο φύλλο εργασίας και να επιλέξετε τη λίστα χρησιμοποιώντας το ποντίκι - μια κατάλληλη αναφορά περιοχής θα προστεθεί αυτόματα στον τύπο.

Υποθέτοντας ότι ο κατάλογος 1 βρίσκεται στη στήλη Α στο Φύλλο1 και ο κατάλογος 2 βρίσκεται στη στήλη A στο Φύλλο2 , μπορείτε να συγκρίνετε δύο στήλες και να βρείτε αντιστοιχίες χρησιμοποιώντας αυτόν τον τύπο:

=IFNA(VLOOKUP(A2, Sheet2!$A$2:$A$9, 1, FALSE), "")

Για περισσότερες πληροφορίες, βλ:

• VLOOKUP από άλλο φύλλο
• VLOOKUP από διαφορετικό βιβλίο εργασίας

Σύγκριση δύο στηλών και επιστροφή κοινών τιμών (matches)

Στα προηγούμενα παραδείγματα, συζητήσαμε έναν τύπο VLOOKUP στην απλούστερη μορφή του:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Το αποτέλεσμα αυτού του τύπου είναι ένας κατάλογος τιμών που υπάρχουν και στις δύο στήλες και κενά κελιά στη θέση των τιμών που δεν είναι διαθέσιμες στη δεύτερη στήλη.

Για να λάβετε μια λίστα κοινών τιμών χωρίς κενά, απλά προσθέστε αυτόματο φίλτρο στη στήλη που προκύπτει και φιλτράρετε τα κενά.

Στο Excel για το Microsoft 365 και το Excel 2021 που υποστηρίζουν δυναμικούς πίνακες, μπορείτε να χρησιμοποιήσετε τη συνάρτηση FILTER για να διαχωρίσετε δυναμικά τα κενά. Για το σκοπό αυτό, χρησιμοποιήστε τον τύπο IFNA VLOOKUP ως κριτήριο για το FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")""")

Παρακαλούμε προσέξτε ότι σε αυτή την περίπτωση παρέχουμε ολόκληρη τη λίστα 1 (A2:A14) στο lookup_value Η συνάρτηση συγκρίνει καθεμία από τις τιμές αναζήτησης με τη λίστα 2 (C2:C9) και επιστρέφει έναν πίνακα αντιστοιχιών και σφαλμάτων #N/A που αντιπροσωπεύουν τις ελλείπουσες τιμές. Η συνάρτηση IFNA αντικαθιστά τα σφάλματα με κενές συμβολοσειρές και παρέχει τα αποτελέσματα στη συνάρτηση FILTER, η οποία φιλτράρει τα κενά ("") και εξάγει έναν πίνακα αντιστοιχιών ως τελικό αποτέλεσμα.

Εναλλακτικά, μπορείτε να χρησιμοποιήσετε τη συνάρτηση ISNA για να ελέγξετε το αποτέλεσμα του VLOOKUP και να φιλτράρετε τα στοιχεία που αξιολογούνται ως FALSE, δηλαδή τιμές εκτός από τα σφάλματα #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Το ίδιο αποτέλεσμα μπορεί να επιτευχθεί με τη συνάρτηση XLOOKUP, η οποία κάνει τον τύπο ακόμη πιο απλό. Λόγω της δυνατότητας της XLOOKUP να χειρίζεται εσωτερικά τα σφάλματα #N/A (προαιρετική if_not_found argument), μπορούμε να κάνουμε χωρίς το περιτύλιγμα IFNA ή ISNA:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Σύγκριση δύο στηλών και εύρεση ελλιπών τιμών (διαφορές)

Για να συγκρίνετε 2 στήλες στο Excel για να βρείτε διαφορές, μπορείτε να προχωρήσετε με αυτόν τον τρόπο:

1. Γράψτε τον βασικό τύπο για την αναζήτηση της πρώτης τιμής από τη λίστα 1 (A2) στη λίστα 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Φωλιάστε τον παραπάνω τύπο στη συνάρτηση ISNA για να ελέγξετε την έξοδο του VLOOKUP για σφάλματα #N/A. Σε περίπτωση σφάλματος, η ISNA δίνει TRUE, διαφορετικά FALSE:

   ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))

3. Χρησιμοποιήστε τον τύπο ISNA VLOOKUP για το λογικό τεστ της συνάρτησης IF. Εάν το τεστ αποτιμηθεί σε TRUE (σφάλμα #N/A), επιστρέψτε μια τιμή από τον κατάλογο 1 στην ίδια γραμμή. Εάν το τεστ αποτιμηθεί σε FALSE (βρέθηκε μια αντιστοιχία στον κατάλογο 2), επιστρέψτε μια κενή συμβολοσειρά.

Ο πλήρης τύπος έχει την εξής μορφή:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Για να απαλλαγείτε από τα κενά, εφαρμόστε το Φίλτρο του Excel, όπως φαίνεται στο παραπάνω παράδειγμα.

Στο Excel 365 και στο Excel 2021, μπορείτε να έχετε τη λίστα αποτελεσμάτων φιλτραρισμένη δυναμικά. Για το σκοπό αυτό, απλά τοποθετήστε τον τύπο ISNA VLOOKUP στο πεδίο περιλαμβάνουν όρισμα της συνάρτησης FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Ένας άλλος τρόπος είναι να χρησιμοποιήσετε την XLOOKUP για κριτήρια - η συνάρτηση επιστρέφει κενές συμβολοσειρές ("") για τα σημεία δεδομένων που λείπουν και φιλτράρετε τις τιμές στη λίστα 1 για τις οποίες η XLOOKUP επέστρεψε κενές συμβολοσειρές (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Τύπος VLOOKUP για τον εντοπισμό αντιστοιχιών και διαφορών μεταξύ δύο στηλών

Εάν θέλετε να προσθέσετε ετικέτες κειμένου στον πρώτο κατάλογο που να υποδεικνύουν ποιες τιμές είναι διαθέσιμες στον δεύτερο κατάλογο και ποιες όχι, χρησιμοποιήστε τον τύπο VLOOKUP σε συνδυασμό με τις συναρτήσεις IF και ISNA/ISERROR.

Για παράδειγμα, για να προσδιορίσετε τα ονόματα που βρίσκονται και στις δύο στήλες Α και Δ και εκείνα που βρίσκονται μόνο στη στήλη Α, ο τύπος είναι:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Χωρίς προσόντα", "Προσόντα")

Εδώ, η συνάρτηση ISNA συλλαμβάνει τα σφάλματα #N/A που δημιουργούνται από το VLOOKUP και περνάει αυτό το ενδιάμεσο αποτέλεσμα στη συνάρτηση IF, ώστε αυτή να επιστρέψει το καθορισμένο κείμενο για τα σφάλματα και ένα άλλο κείμενο για τις επιτυχείς αναζητήσεις.

Σε αυτό το παράδειγμα, χρησιμοποιήσαμε τις ετικέτες "Not qualified"/"Qualified", οι οποίες είναι κατάλληλες για το σύνολο δεδομένων του δείγματός μας. Μπορείτε να τις αντικαταστήσετε με τις ετικέτες "Not in List 2"/"In List 2", "Not available"/"Available" ή οποιαδήποτε άλλη ετικέτα θεωρείτε κατάλληλη.

Αυτός ο τύπος είναι καλύτερο να εισαχθεί σε μια στήλη δίπλα στη λίστα 1 και να αντιγραφεί σε τόσα κελιά όσα είναι τα στοιχεία της λίστας σας.

Ένας ακόμη τρόπος για τον εντοπισμό ταυτοτήτων και διαφορών σε 2 στήλες είναι η χρήση της συνάρτησης MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Όχι στον κατάλογο 2", "Στον κατάλογο 2")

Σύγκριση 2 στηλών και επιστροφή μιας τιμής από την τρίτη

Όταν εργάζεστε με πίνακες που περιέχουν συναφή δεδομένα, μπορεί μερικές φορές να χρειαστεί να συγκρίνετε δύο στήλες σε δύο διαφορετικούς πίνακες και να επιστρέψετε μια αντίστοιχη τιμή από μια άλλη στήλη. Στην πραγματικότητα, αυτή είναι η κύρια χρήση της συνάρτησης VLOOKUP, ο σκοπός για τον οποίο σχεδιάστηκε.

Για παράδειγμα, για να συγκρίνετε τα ονόματα στις στήλες Α και Δ των δύο παρακάτω πινάκων και να επιστρέψετε μια ώρα από τη στήλη Ε, ο τύπος είναι ο εξής:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Για να αποκρύψετε σφάλματα #N/A, χρησιμοποιήστε την αποδεδειγμένη λύση - τη λειτουργία IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Αντί για κενά, μπορείτε να επιστρέψετε οποιοδήποτε κείμενο θέλετε για τα σημεία δεδομένων που λείπουν - απλά πληκτρολογήστε το στο τελευταίο όρισμα. Για παράδειγμα:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Μη διαθέσιμο")

Εκτός από το VLOOKUP, η εργασία μπορεί να εκπληρωθεί με μερικές άλλες συναρτήσεις αναζήτησης.

Προσωπικά, θα βασιζόμουν σε μια πιο ευέλικτη φόρμουλα INDEX MATCH:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Ή χρησιμοποιήστε τον σύγχρονο διάδοχο της VLOOKUP - τη συνάρτηση XLOOKUP, που είναι διαθέσιμη στο Excel 365 και στο Excel 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Για να λάβετε τα ονόματα των ειδικών συμμετεχόντων από την ομάδα Α και τα αποτελέσματά τους, απλά φιλτράρετε τα κενά κελιά της στήλης Β:

=FILTER(A3:B15, B3:B15"")

Εργαλεία σύγκρισης

Αν κάνετε συχνά συγκρίσεις αρχείων ή δεδομένων στο Excel, αυτά τα έξυπνα εργαλεία που περιλαμβάνονται στην Ultimate Suite μπορούν να σας εξοικονομήσουν πολύ χρόνο!

Σύγκριση πινάκων - γρήγορος τρόπος για να βρείτε διπλότυπα (αντιστοιχίες) και μοναδικές τιμές (διαφορές) σε δύο σύνολα δεδομένων, όπως στήλες, λίστες ή πίνακες.

Σύγκριση δύο φύλλων - βρείτε και επισημάνετε τις διαφορές μεταξύ δύο φύλλων εργασίας.

Σύγκριση πολλαπλών φύλλων - βρείτε και επισημάνετε τις διαφορές σε πολλά φύλλα ταυτόχρονα.

Βιβλίο ασκήσεων για κατέβασμα

VLOOKUP στο Excel για σύγκριση στηλών - παραδείγματα (.xlsx αρχείο)