Meskipun jumlah kata dan karakter di Google Sheets digunakan dalam kasus-kasus yang jarang terjadi, itu masih merupakan fungsi yang beberapa dari kita harapkan untuk melihat langsung di menu. Tetapi tidak seperti Google Docs, untuk Google Sheets, fungsi LEN-lah yang melakukan itu.

Meskipun ada banyak cara berbeda untuk menghitung karakter di spreadsheet, posting blog hari ini akan membahas fungsi LEN karena tujuan utamanya dalam tabel adalah untuk - yah, menghitung :) Namun, hampir tidak pernah digunakan sendiri. Di bawah ini Anda akan belajar cara menggunakan Google Sheets LEN dengan benar dan menemukan rumus yang paling dicari untuk menghitung karakter dalam spreadsheet.

Fungsi Google Sheets LEN - penggunaan dan sintaksis

Tujuan utama dan satu-satunya tujuan fungsi LEN di Google Sheets adalah mendapatkan panjang string. Ini sangat sederhana sehingga bahkan hanya membutuhkan 1 argumen:

• dapat mengambil teks itu sendiri dalam tanda kutip ganda:

  =LEN("Yggdrasil")

• atau referensi ke sel dengan teks yang diinginkan:

  =LEN(A2)

Mari kita lihat apakah ada keanehan dalam menggunakan fungsi dalam spreadsheet.

Jumlah karakter di Google Sheets

Saya akan mulai dengan operasi paling sederhana: lakukan penghitungan karakter di Google Sheets dengan cara yang paling umum - dengan mereferensikan sel dengan teks menggunakan fungsi LEN.

Saya memasukkan rumus ke B2 dan menyalinnya ke seluruh kolom untuk menghitung karakter di setiap baris:

=LEN(A2)

Catatan. Fungsi LEN menghitung semua karakter: huruf, angka, spasi, tanda baca, dll.

Anda mungkin berpikir bahwa dengan cara yang sama Anda bisa melakukan penghitungan karakter untuk seluruh rentang sel, seperti ini: LEN(A2:A6) Tetapi, seaneh-anehnya, tidak hanya bekerja dengan cara ini.

Untuk menjumlahkan karakter dalam beberapa sel, Anda harus membungkus LEN Anda di SUMPRODUCT - fungsi yang menghitung angka dari rentang yang dimasukkan. Dalam kasus saya, rentang dikembalikan oleh fungsi LEN:

=SUMPRODUCT(LEN(A2:A6))

Tentu saja, Anda bisa memasukkan fungsi SUM sebagai gantinya. Tetapi SUM di Google Sheets tidak memproses array dari fungsi lain. Untuk membuatnya berfungsi, Anda harus menambahkan fungsi lain - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Cara menghitung karakter tanpa spasi di Google Sheets

Seperti yang saya catat di atas, fungsi LEN Google Sheets menghitung setiap karakter yang dilihatnya termasuk spasi.

Tetapi, bagaimana jika ada spasi ekstra yang ditambahkan secara tidak sengaja dan Anda tidak ingin mempertimbangkannya untuk hasilnya?

Untuk kasus seperti ini, ada fungsi TRIM di Google Sheets. Ini memeriksa teks untuk spasi terdepan, tertinggal, dan berulang di antaranya. Ketika TRIM dipasangkan dengan LEN, yang terakhir tidak menghitung semua spasi ganjil itu.

Berikut ini contohnya. Saya menambahkan spasi di posisi yang berbeda di kolom A. Seperti yang bisa Anda lihat, ketika sendiri, Google Sheets LEN menghitung semuanya:

=LEN(A2)

Tetapi begitu Anda mengintegrasikan TRIM, semua spasi ekstra diabaikan:

=LEN(TRIM(A2))

Kamu bisa melangkah lebih jauh dan membuat rumusmu mengabaikan spasi tunggal di antara kata-kata. Fungsi SUBSTITUTE akan membantu. Meskipun tujuan utamanya adalah mengganti satu karakter dengan karakter lainnya, namun ada trik untuk membuatnya mengurangi spasi sepenuhnya:

• text_to_search adalah rentang yang Anda gunakan: kolom A, atau A2 tepatnya.
• search_for harus berupa karakter spasi dalam tanda kutip ganda: " "
• replace_with Jika Anda akan mengabaikan spasi, Anda harus menggantinya dengan tidak ada apa-apa (string kosong): ""
• occurence_number biasanya digunakan untuk menentukan instance yang akan diganti. Tetapi karena saya menjelaskan cara menghitung karakter tanpa semua spasi, saya sarankan Anda menghilangkan argumen ini karena bersifat opsional.

Sekarang coba dan kumpulkan semua ini ke dalam Google Sheets LEN dan Anda akan melihat bahwa tidak ada ruang yang diperhitungkan:

=LEN(SUBSTITUTE(A2, " ", ""))

Google Sheets: menghitung karakter tertentu

Tandem yang sama dari Google Sheets LEN dan SUBSTITUTE digunakan kapan pun Anda perlu menghitung karakter, huruf, atau angka tertentu.

Dalam contoh saya, saya akan mencari tahu jumlah kemunculan untuk huruf 's'. Dan kali ini, saya akan mulai dengan rumus yang sudah jadi:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Mari kita uraikan menjadi beberapa bagian untuk memahami cara kerjanya:

1. SUBSTITUTE(A2, "s", "") mencari huruf 's' di A2 dan menggantikan semua kejadian dengan "nothing", atau string kosong ("").
2. LEN(SUBSTITUTE(A2, "s", "") menghitung jumlah semua karakter kecuali 's' di A2.
3. LEN(A2) menghitung semua karakter dalam A2.
4. Akhirnya, Anda mengurangi satu dari yang lainnya.

Perbedaan hasil menunjukkan berapa banyak 's' yang ada di dalam sel:

Catatan. Anda mungkin bertanya-tanya mengapa B1 mengatakan hanya ada 1 's' di A2 sementara Anda bisa melihat 3?

Masalahnya adalah, fungsi SUBSTITUTE peka huruf besar-kecil. Saya memintanya untuk mengambil semua contoh 's' dalam huruf kecil dan memang demikian.

Untuk membuatnya mengabaikan kasus teks dan memproses huruf dalam kasus bawah dan atas, Anda harus memanggil satu lagi fungsi Google Sheets untuk bantuan: LOWER.

Tip. Lihat cara lain yang mengubah kasus teks di Google Sheets.

Ini sesederhana Google Sheets LEN dan TRIM karena yang dibutuhkan hanyalah teks:

=LOWER(teks)

Dan semua yang dilakukannya adalah mengubah seluruh string teks menjadi huruf kecil. Trik ini persis seperti apa yang Anda butuhkan untuk membuat Google Sheets menghitung karakter tertentu tidak peduli kasus teksnya:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Tip. Dan seperti sebelumnya, untuk menghitung total karakter tertentu dalam rentang, bungkus LEN Anda dalam SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Menghitung kata di Google Sheets

Ketika ada beberapa kata dalam sel, kemungkinan Anda perlu memiliki nomornya alih-alih panjang string Google Sheets.

Dan meskipun ada beberapa cara untuk melakukannya, hari ini saya akan menyebutkan bagaimana Google Sheets LEN melakukan pekerjaan itu.

Ingat rumus yang saya gunakan untuk menghitung karakter tertentu di Google Spreadsheet? Sebenarnya, rumus ini juga akan berguna di sini. Karena saya tidak akan menghitung kata-kata secara harfiah. Sebaliknya, saya akan menghitung jumlah spasi di antara kata-kata dan kemudian cukup menambahkan 1. Coba lihat:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) menghitung jumlah semua karakter dalam sel.
2. LEN(SUBSTITUTE((A2)," ","")) menghapus semua spasi dari string teks dan menghitung karakter yang tersisa.
3. Kemudian Anda mengurangi satu dari yang lain, dan perbedaan yang Anda dapatkan adalah jumlah spasi dalam sel.
4. Karena kata-kata selalu melebihi jumlah spasi dalam kalimat dengan satu, Anda menambahkan 1 di akhir.

Google Sheets: menghitung kata-kata tertentu

Terakhir, saya ingin berbagi formula Google Sheets yang dapat Anda gunakan untuk menghitung kata-kata tertentu.

Di sini saya memiliki Lagu Penyu Tiruan dari Alice's Adventures in Wonderland:

Saya ingin tahu berapa kali kata 'akan' muncul di setiap baris. Saya yakin Anda tidak akan terkejut jika saya memberi tahu Anda bahwa rumus yang saya butuhkan terdiri dari fungsi yang sama seperti sebelumnya: Google Sheets LEN, SUBSTITUTE, dan LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Formulanya mungkin terlihat menakutkan, tetapi saya dapat meyakinkan Anda bahwa ini mudah dipahami, jadi bersabarlah dengan saya :)

1. Karena kasus teks tidak penting bagi saya, saya menggunakan LEBIH RENDAH(A2) untuk mengubah segalanya menjadi huruf kecil.
2. Lalu pergi SUBSTITUTE(LOWER(A2), "will","")))) - itu akan menyingkirkan semua kemunculan 'will' dengan menggantinya dengan string kosong ("").
3. Setelah itu, saya mengurangi jumlah karakter tanpa kata 'will' dari total panjang string. Angka yang saya dapatkan menghitung semua karakter dalam semua kemunculan 'will' di setiap baris.

   Jadi, jika 'will' muncul satu kali, angkanya adalah 4, karena ada 4 huruf dalam kata tersebut. Jika muncul dua kali, angkanya adalah 8, dan seterusnya.

4. Akhirnya, saya membagi angka ini dengan panjang kata tunggal 'will'.

Dan lagi, jika Anda lebih suka mendapatkan jumlah total dari semua kemunculan kata 'akan', cukup apit seluruh rumus dengan SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Seperti yang Anda lihat, semua kasus jumlah karakter ini diselesaikan dengan pola yang sama dari fungsi yang sama untuk Google Sheets: LEN, SUBSTITUTE, LOWER, dan SUMPRODUCT.

Jika beberapa rumus masih membingungkan Anda, atau jika Anda tidak yakin bagaimana menerapkan semuanya untuk tugas khusus Anda, jangan malu-malu dan tanyakan di bagian komentar di bawah ini!