Днес ще разгледаме как да използваме VLOOKUP в Excel с много подробни примери стъпка по стъпка. Ще научите как да използвате VLOOKUP от друг лист и друга работна книга, да търсите с подредба и много други.

С тази статия започваме поредица от статии, посветени на VLOOKUP - една от най-полезните функции на Excel и в същото време една от най-сложните и най-малко разбираемите. Ще се опитаме да обясним основите на много прост език, за да направим обучението на неопитен потребител възможно най-лесно. Ще предоставим и примери за формули, които обхващат най-типичните употреби на VLOOKUP в Excel, и ще се опитаме да направимте са едновременно информативни и забавни.

Функция VLOOKUP на Excel

Какво е VLOOKUP? Като начало, това е функция на Excel :) Какво прави тя? Търси зададената от вас стойност и връща съответстваща стойност от друга колона. По-технически, функцията VLOOKUP търси стойност в първата колона на даден диапазон и връща стойност в същия ред от друга колона.

При обичайната си употреба Excel VLOOKUP претърсва набора от данни въз основа на уникалния идентификатор и ви предоставя част от информацията, свързана с този уникален идентификатор.

Буквата "V" означава "вертикален" и се използва за разграничаване на VLOOKUP от функцията HLOOKUP, която търси стойност в ред, а не в колона (H означава "хоризонтален").

Функцията е налична във всички версии на Excel 365 до Excel 2007.

Съвет. В Excel 365 и Excel 2021 можете да използвате функцията XLOOKUP, която е по-гъвкав и мощен наследник на VLOOKUP.

Синтаксис на VLOOKUP

Синтаксисът на функцията VLOOKUP е следният:

Къде:

• Lookup_value (задължително) - това е стойността, която ще се търси.

  Това може да бъде стойност (число, дата или текст), препратка към клетка (препратка към клетка, съдържаща стойност за търсене) или стойност, върната от друга функция. За разлика от числата и препратките към клетките, текстовите стойности трябва винаги да бъдат затворени в "двойни кавички".

• Таблица_масив (задължително) - това е диапазонът от клетки, в който да се търси стойността за търсене и от който да се извлича съвпадение. Функцията VLOOKUP винаги търси в първата колона на масива от таблици , които могат да съдържат различни текстови стойности, числа, дати и логически стойности.
• Col_index_num (задължително) - е номерът на колоната, от която да се върне стойност. Броенето започва от най-лявата колона в масива на таблицата, която е 1.
• Range_lookup (по избор) - определя дали да се търси приблизително или точно съвпадение:
  • TRUE или пропуснато (по подразбиране) - приблизително съвпадение. Ако не е намерено точно съвпадение, формулата търси най-голямата стойност, която е по-малка от стойността на търсене. Изисква сортиране на колоната за търсене във възходящ ред.
  • FALSE - точно съвпадение. Формулата търси стойност, която е точно равна на стойността за търсене. Ако не бъде намерено точно съвпадение, се връща стойност #N/A.

Основна формула на VLOOKUP

Ето един пример за формулата VLOOKUP на Excel в най-простия ѝ вид. Моля, разгледайте формулата по-долу и се опитайте да я "преведете" на български език:

=VLOOKUP("лъв", A2:B11, 2, FALSE)

• Първият аргумент ( lookup_value ) ясно показва, че формулата търси думата "лъв".
• Вторият аргумент ( table_array ) е A2:B11. Като имате предвид, че търсенето се извършва в най-лявата колона, можете да прочетете горната формула малко по-подробно: търсете "лъв" в диапазона A2:A11. Дотук добре, нали?
• Третият аргумент col_index_num е 2. Това означава, че искаме да върнем съвпадаща стойност от колона B, която е втора в масива на таблицата.
• Четвъртият аргумент range_lookup е FALSE, което означава, че търсим точно съвпадение.

След като сте установили всички аргументи, не би трябвало да имате проблем с прочитането на цялата формула: търсене на "lion" в A2:A11, намиране на точно съвпадение и връщане на стойност от колона B в същия ред.

За удобство можете да въведете интересуващата ви стойност в някоя клетка, например E1, да замените "твърдо кодирания" текст с препратката към клетката и да накарате формулата да търси всяка стойност, въведена в E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Остава ли нещо неясно? Опитайте се да погледнете на това по този начин:

Как да направите Vlookup в Excel

Когато използвате формулите VLOOKUP в реални работни листове, основното правило е следното: масив от таблици за заключване с абсолютни препратки към клетките (например $A$2:$C$11), за да се предотврати промяната им при копиране на формула в други клетки.

Сайтът стойност за търсене в повечето случаи трябва да бъде относителна референция (като E2) или можете да заключите само координатата на колоната ($E2). Когато формулата се копира надолу по колоната, референцията ще се коригира автоматично за всеки ред.

За да видите как работи на практика, разгледайте следния пример. Към нашата примерна таблица добавихме още една колона, която класира животните по скорост (колона А), и искаме да намерим първия, петия и десетия най-бърз спринтьор в света. За тази цел въведете редиците за търсене в някои клетки (E2:E4 на снимката по-долу) и използвайте следните формули:

Изтегляне на имената на животните от колона В:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Извличане на скоростта от колона C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Въведете горните формули в клетките F2 и G2, изберете тези клетки и плъзнете формулите към долните редове:

Ако разгледате формулата в по-долен ред, ще забележите, че референтната стойност за търсене е коригирана за този конкретен ред, докато масивът на таблицата е непроменен:

По-долу ще намерите още няколко полезни съвета, които ще ви спестят много главоболия и време за отстраняване на проблеми.

Excel VLOOKUP - 5 неща, които трябва да запомните!

1. Функцията VLOOKUP не може да гледа в лявата си част . Винаги се търси в най-лявата колона на масива на таблицата и връща стойност от колона вдясно. Ако трябва да изтеглите стойности отляво, използвайте комбинацията INDEX MATCH (или INDEX XMATCH в Excel 365), която не се интересува от позиционирането на колоните за търсене и връщане.
2. Функцията VLOOKUP не се различава по размер на буквите. , което означава, че главните и малките букви се третират като еквивалентни. За да разграничите размера на буквите, използвайте VLOOKUP формули, които отчитат размера на буквите.
3. Не забравяйте за важността на последния параметър. Използвайте TRUE за приблизително съвпадение и FALSE за точно съвпадение. За повече информация вижте VLOOKUP TRUE vs. FALSE.
4. При търсене на приблизително съвпадение се уверете, че данните в колоната за търсене са подредени във възходящ ред.
5. Ако стойността за търсене не е намерена, се връща грешка #N/A. За информация относно други грешки, моля, вижте Защо Excel VLOOKUP не работи.

Примери за VLOOKUP в Excel

Надявам се, че вертикалното търсене започва да ви изглежда малко по-познато. За да затвърдите знанията си, нека създадем още няколко формули VLOOKUP.

Как да прегледате от друг лист в Excel

В практиката функцията VLOOKUP на Excel рядко се използва с данни в същия работен лист. Най-често се налага да изтеглите съвпадащите данни от друг работен лист.

За да направите Vlookup от друг лист на Excel, поставете името на работния лист, последвано от възклицателен знак в полето table_array например, за да търсите в диапазона A2:B10 на лист 2, използвайте тази формула:

=VLOOKUP("Product1", Sheet2!A2:B10, 2)

Разбира се, не е необходимо да въвеждате името на листа ръчно. Просто започнете да въвеждате формулата и когато се стигне до table_array преминавате към работния лист за търсене и избирате диапазона с помощта на мишката.

Така например можете да потърсите стойността A2 в диапазона A2:A9 в Цени и да върне съответстваща стойност от колона C:

=VLOOKUP(A2, Prices!$A$2:$C$9, 3, FALSE)

Забележки:

• Ако името на електронната таблица съдържа интервали или неалфабетни символи , то трябва да бъде затворено в единични кавички, например "Ценова листа"!$A$2:$C$9.
• В случай че използвате формула VLOOKUP за няколко клетки, не забравяйте да заключване на table_array със знака $, например $A$2:$C$9.

Как да прегледате от друга работна книга в Excel

За да направите Vlookup от друга работна книга на Excel, поставете името на работната книга, затворено в квадратни скоби, преди името на работния лист.

Например, ето формулата за търсене на стойността A2 в листа с име Цени в Price_List.xlsx работна тетрадка:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Ако името на работната книга или на работния лист съдържа интервали или неабстрактни символи, трябва да ги оградите с единични кавички по следния начин:

=VLOOKUP(A2, '[Price List.xlsx]Prices'!$A$2:$C$9, 3, FALSE)

Най-лесният начин за създаване на формула VLOOKUP, която се отнася до друга работна книга, е следният:

1. Отворете и двата файла.
2. Започнете да въвеждате формулата си, преминете към другата работна книга и изберете масива от таблици с помощта на мишката.
3. Въведете останалите аргументи и натиснете клавиша Enter, за да завършите формулата си.

Резултатът ще изглежда като на снимката по-долу:

След като затворете файла с таблицата за търсене, формулата VLOOKUP ще продължи да работи, но вече ще показва пълния път до затворената работна книга:

За повече информация вижте Как да се препрати към друг лист или работна книга на Excel.

Как да прегледате от именуван диапазон в друг лист

В случай че планирате да използвате един и същ диапазон за търсене в много формули, можете да създадете именуван диапазон за него и да въведете името директно в table_array аргумент.

За да създадете именуван диапазон, просто изберете клетките и въведете желаното име в полето Име полето вляво от лентата Formula. За подробни стъпки вижте Как да именуваме диапазон в Excel.

За този пример дадохме името Цени_2020 към клетките с данни (A2:C9) в листа за търсене и получавате тази компактна формула:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Повечето имена в Excel се отнасят за цялата работна книга , така че не е необходимо да посочвате името на работния лист, когато използвате именувани диапазони.

Ако посоченият диапазон е в друга работна книга , поставете името на работната книга преди името на обхвата, например:

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

Такива формули са много по-разбираеми, нали? Освен това използването на именувани диапазони може да бъде добра алтернатива на абсолютните препратки. Тъй като именуваният диапазон не се променя, можете да сте сигурни, че масивът на таблицата ви ще остане заключен, независимо от това къде е преместена или копирана формулата.

Ако сте преобразували диапазона за търсене в пълнофункционална таблица на Excel, можете да направите Vlookup въз основа на името на таблицата, напр. Таблица на цените (Price_table) във формулата по-долу:

=VLOOKUP(A2, Price_table, 3, FALSE)

Препратките към таблици, наричани още структурирани препратки, са устойчиви и неподатливи на много манипулации с данни. Например можете да премахвате или добавяте нови редове в таблицата за търсене, без да се притеснявате за актуализирането на препратките.

Използване на заместващи символи във формулата VLOOKUP

Подобно на много други формули, функцията VLOOKUP на Excel приема следните заместващи символи:

• Въпросник (?), за да съответства на всеки отделен символ.
• Звездичка (*), за да съответства на всяка последователност от символи.

Заместващите символи са наистина полезни в много ситуации:

• Когато не си спомняте точния текст, който търсите.
• Когато търсите текстов низ, който е част от съдържанието на клетката.
• Когато колоната за търсене съдържа водещи или завършващи интервали, може да се опитате да разберете защо обикновената формула не работи.

Пример 1. Търсене на текст, започващ или завършващ с определени символи

Да предположим, че искате да намерите определен клиент в базата данни по-долу. Не помните фамилията, но сте сигурни, че тя започва с "ack".

За да върнете фамилното име от колона А, използвайте следната формула Vlookup със заместител:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

За извличане на лицензния ключ от колона В използвайте тази колона (разликата е само в номера на индекса на колоната):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Можете също така да въведете известната част от името в някоя клетка, например E1, и да комбинирате заместващия символ с препратката към клетката:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Резултатите са показани на снимката по-долу:

По-долу са дадени още няколко VLOOKUP формули със заместващи символи.

Намерете фамилното име, завършващо на "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Вземете името, което започва с "joh" и завършва с "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Изтеглете 5-символно фамилно име:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Пример 2. Заместващ символ VLOOKUP въз основа на стойността на клетката

От предишния пример вече знаете, че е възможно да съедините амперсанд (&) и препратка към клетка, за да създадете низ за търсене. За да намерите стойност, която съдържа даден символ(и) на всяка позиция, поставете амперсанд преди и след препратката към клетката.

Да речем, че искате да получите име, съответстващо на определен лицензен ключ, но не знаете целия ключ, а само няколко символа. С ключовете в колона A, имената в колона B и част от целевия ключ в E1 можете да направите заместващ Vlookup по този начин:

Извлечете ключа:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Извлечете името:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Забележки:

• За да работи правилно формулата VLOOKUP със заместващ символ, използвайте точно съвпадение (последният аргумент е FALSE).
• Ако е намерено повече от едно съвпадение, се връща първото. .

VLOOKUP TRUE vs FALSE

А сега е време да разгледаме по-отблизо последния аргумент на функцията VLOOKUP на Excel. range_lookup В зависимост от това дали сте избрали TRUE или FALSE, формулата ви може да даде различни резултати.

Точно съвпадение на Excel VLOOKUP (FALSE)

Ако range_lookup е зададено на FALSE, формулата Vlookup търси стойност, която е точно равна на стойността за търсене. Ако бъдат намерени две или повече съвпадения, се връща първото. Ако не бъде намерено точно съвпадение, се появява грешка #N/A.

Приблизително съвпадение на Excel VLOOKUP (TRUE)

Ако range_lookup Ако е зададена стойност TRUE или е пропусната (по подразбиране), формулата търси най-близкото съответствие. По-точно, първо се търси точното съответствие, а ако то не е намерено, се търси следващата най-голяма стойност, която е по-малка от стойността за търсене.

Приблизителното съвпадение Vlookup работи със следните забележки:

• Колоната за търсене трябва да бъде сортирана в възходящ ред , от най-малката към най-голямата, в противен случай може да не бъде намерена правилна стойност.
• Ако стойността за търсене е по-малка от най-малката стойност в масива за търсене, се връща грешка #N/A.

Следващите примери ще ви помогнат да разберете по-добре разликата между точно съвпадение и приблизително съвпадение на Vlookup и кога е най-добре да се използва всяка формула.

Пример 1. как да направите точно съвпадение на Vlookup

За да потърсите точно съвпадение, просто въведете FALSE в последния аргумент.

За този пример нека вземем таблицата за скоростта на животните, разменим колоните и се опитаме да намерим животните, които могат да се движат с 80, 50 и 30 мили в час. Със стойностите за търсене в D2, D3 и D4 въведете следната формула в E2 и след това я копирайте в още две клетки:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Както можете да видите, формулата връща "Lion" в E3, тъй като те се изпълняват точно 50 на час. За другите две стойности за търсене не е намерено точно съвпадение и се появяват грешки #N/A.

Пример 2. Как да търсите приблизително съвпадение чрез Vlookup

За да потърсите приблизително съвпадение, трябва да направите две основни неща:

• Сортиране на първата колона на table_array от най-малкия до най-големия.
• Използвайте TRUE за range_lookup или го пропуснете.

Сортирането на колоната за търсене е много важно, тъй като функцията VLOOKUP спира търсенето веднага щом открие близко съвпадение, по-малко от стойността за търсене. Ако данните не са сортирани правилно, може да получите наистина странни резултати или множество грешки #N/A.

За нашите примерни данни формулата за приблизително съвпадение на Vlookup е следната:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

И връща следните резултати:

• За стойност на търсене "80" се връща "Cheetah", тъй като неговата скорост (70) е най-близкото съвпадение, което е по-малко от стойността на търсене.
• За стойност на търсене "50" се връща точно съвпадение (Lion).
• За стойност на търсене "30" се връща грешка #N/A, тъй като стойността на търсене е по-малка от най-малката стойност в колоната за търсене.

Специални инструменти за Vlookup в Excel

Без съмнение VLOOKUP е една от най-мощните и полезни функции на Excel, но също така е и една от най-объркващите. За да направим кривата на обучението по-малко стръмна и преживяването по-приятно, включихме няколко спестяващи време инструмента в нашия Ultimate Suite for Excel.

Съветник VLOOKUP - лесен начин за писане на сложни формули

Интерактивният съветник за VLOOKUP ще ви преведе през опциите за конфигуриране, за да изградите перфектна формула за зададените от вас критерии. В зависимост от структурата на данните ще се използва стандартната функция VLOOKUP или формула INDEX MATCH, която може да извлича стойности отляво.

За да получите персонализираната си формула, трябва да направите следното:

1. Стартирайте съветника VLOOKUP.

1. Изберете основната си таблица и таблицата за търсене.
2. Посочете следните колони (в много случаи те се избират автоматично):
   • Ключова колона - колоната в основната ви таблица, съдържаща стойностите, които трябва да се търсят.
   • Колона за търсене - колоната, срещу която да гледате.
   • Колона за връщане - колоната, от която се извличат стойности.
3. Щракнете върху Вмъкване на бутон.

Следващите примери показват съветника в действие.

Стандартна визуализация

Когато колоната за търсене ( Животни ) е най-лявата колона в таблицата за търсене, се вмъква нормална формула VLOOKUP за точно съвпадение:

Vlookup вляво

Когато колоната за търсене ( Животни ) се намира от дясната страна на колоната за връщане ( Скорост ), съветникът вмъква формулата INDEX MATCH за Vlookup отдясно наляво:

Допълнителен бонус! Благодарение на умелото използване на препратки към клетките формулите могат да се копират или преместват във всяка колона, без да се налага да актуализирате препратките.

Сливане на две таблици - алтернатива на Excel VLOOKUP без формули

Ако файловете ви в Excel са изключително големи и сложни, крайният срок на проекта е близо и търсите някой, който може да ви подаде ръка, опитайте съветника за сливане на таблици.

Този инструмент е нашата визуална и безпроблемна алтернатива на функцията VLOOKUP на Excel, която работи по този начин:

1. Изберете основната си маса.
2. Изберете таблицата за търсене.
3. Изберете една или няколко общи колони като уникален(и) идентификатор(и).
4. Посочете кои колони да се актуализират.
5. По желание изберете колоните, които да добавите.
6. Оставете няколко секунди на съветника за сливане на таблици за обработка... и се насладете на резултатите :)

Това е начинът за използване на VLOOKUP в Excel на базово ниво. В следващата част на нашето ръководство ще обсъдим примери за напреднали VLOOKUP, които ще ви научат как да търсите по няколко критерия, да връщате всички съвпадения или N-тото появяване, да извършвате двойно Vlookup, да търсите в няколко листа с една формула и др. Благодаря ви за четенето и се надявам да се видим следващата седмица!

Налични изтегляния

Примери за формулата VLOOKUP на Excel (.xlsx файл)

Ultimate Suite 14-дневна напълно функционална версия (.exe файл)