В урока е показано как да напишете оператор IF OR в Excel, за да проверите различни условия "това ИЛИ онова".

Функцията IF е една от най-популярните функции на Excel и е много полезна сама по себе си. В комбинация с логически функции като AND, OR и NOT функцията IF има още по-голяма стойност, тъй като позволява тестване на множество условия в желани комбинации. В този урок ще се съсредоточим върху използването на формулата IF и OR в Excel.

Изявление IF OR в Excel

За да оцените две или повече условия и да върнете един резултат, ако някое от условията е TRUE, и друг резултат, ако всички условия са FALSE, вградете функцията OR в логическия тест на IF:

На обикновен английски език логиката на формулата може да се формулира по следния начин: Ако дадена клетка е "това" ИЛИ "това", предприемете едно действие, ако не е, направете нещо друго.

Ето един пример за формулата IF OR в най-прост вид:

=IF(OR(B2="доставено", B2="платено"), "затворено", "отворено")

Формулата гласи следното: Ако клетка B2 съдържа "доставено" или "платено", маркирайте поръчката като "затворена", в противен случай като "отворена".

В случай че искате да връщане на нищо ако логическият тест се оценява на FALSE , включете празен низ ("") в последния аргумент:

=IF(OR(B2="доставено", B2="платено"), "Затворено", "")

Същата формула може да бъде записана и в по-компактна форма, като се използва константа на масив:

=IF(OR(B2={"доставено", "платено"}), "Затворено", "")

В случай че последният аргумент е пропуснат, формулата ще покаже FALSE, когато нито едно от условията не е изпълнено.

Забележка: Моля, обърнете внимание, че формулата IF OR в Excel не прави разлика между малки и големи букви, тъй като функцията OR е без значение на размера на буквите . В нашия случай "доставено", "Delivered" и "DELIVERED" се считат за една и съща дума. Ако искате да разграничите случаите на текста, обвийте всеки аргумент на функцията OR в EXACT, както е показано в този пример.

Примери за формула на Excel IF OR

По-долу ще намерите още няколко примера за съвместно използване на функциите IF и OR на Excel, които ще ви дадат повече идеи за това какви логически тестове можете да проведете.

Формула 1. IF с няколко условия OR

Няма конкретно ограничение за броя на условията OR, вградени във формулата IF, стига да са в съответствие с общите ограничения на Excel:

• В Excel 2007 и по-нови версии са разрешени до 255 аргумента, като общата им дължина не може да надвишава 8 192 символа.
• В Excel 2003 и по-ниски версии можете да използвате до 30 аргумента, като общата им дължина не трябва да надвишава 1024 символа.

Като пример, нека проверим колони A, B и C за празни клетки и да върнем "Incomplete", ако поне една от трите клетки е празна. Задачата може да се изпълни със следната функция IF OR:

=IF(OR(A2="",B2="",),"Incomplete","")

Резултатът ще изглежда по следния начин:

Формула 2. Ако дадена клетка е това ИЛИ онова, тогава изчислете

Търсите формула, която може да прави нещо по-сложно от връщане на предварително зададен текст? Просто вмъкнете друга функция или аритметично уравнение в value_if_true и/или value_if_false аргументи на IF.

Да речем, че изчислявате общата сума за дадена поръчка ( Количество. умножен по Единична цена ) и искате да приложите отстъпката от 10%, ако някое от тези условия е изпълнено:

• в B2 е по-голямо или равно на 10, или
• Единична цена в С2 е по-голямо или равно на 5 USD.

Затова използвате функцията OR, за да проверите двете условия, и ако резултатът е TRUE, намалете общата сума с 10% (B2*C2*0,9), в противен случай върнете пълната цена (B2*C2):

=IF(OR(B2>=10, C2>=5), B2*C2*0.9, B2*C2)

Освен това можете да използвате следната формула, за да посочите изрично поръчките с отстъпка:

=IF(OR(B2>=10, C2>=5), "Да", "Не")

Снимката на екрана по-долу показва двете формули в действие:

Формула 3. Формула IF OR, чувствителна към малки и големи букви

Както вече беше споменато, функцията OR на Excel по природа е безразлична към малки и големи букви. Въпреки това вашите данни може да са чувствителни към малки и големи букви и затова бихте искали да изпълните тестове OR с отчитане на големи и малки букви В този случай извършете всеки отделен логически тест във функцията EXACT и вложете тези функции в оператора OR.

В този пример нека намерим и маркираме идентификаторите на поръчките "AA-1" и "BB-1":

=IF(OR(EXACT(A2, "AA-1"), EXACT(A2, "BB-1")), "x", "")

В резултат на това само два идентификационни номера на поръчки, в които всички букви са главни, са маркирани с "x"; подобни идентификационни номера като "aa-1" или "Bb-1" не са маркирани:

Формула 4. Вложени изявления IF OR в Excel

Когато искате да тествате няколко набора от критерии ИЛИ и да върнете различни стойности в зависимост от резултатите от тези тестове, напишете отделна формула IF за всеки набор от критерии "това ИЛИ онова" и вложете тези IF един в друг.

За да демонстрираме концепцията, нека проверим имената на артикулите в колона А и да върнем "Fruit" за Apple или Orange и "Vegetable" за Домати или Краставица :

=IF(OR(A2="ябълка", A2="портокал"), "Плод", IF(OR(A2="домат", A2="краставица"), "Зеленчук", ""))

За повече информация вижте раздел Вложен IF с условия OR/AND.

Формула 5. твърдение IF И ИЛИ

За да оцените различни комбинации от различни условия, можете да правите логически тестове AND и OR в рамките на една формула.

Като пример ще маркираме редове, в които елементът в колона А е или Apple или Orange а количеството в колона В е по-голямо от 10:

=IF(AND(OR(A2="ябълка",A2="портокал"), B2>10), "x", "")

За повече информация вижте Excel IF с няколко условия AND/OR.

Ето как се използват заедно функциите IF и OR. За да разгледате по-отблизо формулите, разгледани в този кратък урок, можете да изтеглите нашата примерна работна книга на Excel IF OR. Благодаря ви за прочетеното и се надявам да се видим в нашия блог следващата седмица!