Excel'de sözcükler nasıl sayılır - formül örnekleri

Michael Brown

28-05-2023 Excel
  • Bunu Paylaş
Michael Brown

Bu eğitim, LEN işlevini diğer Excel işlevleriyle birlikte kullanarak Excel'de sözcüklerin nasıl sayılacağını açıklar ve bir hücre veya aralıktaki toplam veya belirli sözcükleri/metni saymak için büyük/küçük harfe duyarlı ve büyük/küçük harfe duyarsız formüller sağlar.

Microsoft Excel neredeyse her şeyi sayabilen bir avuç yararlı işleve sahiptir: sayı içeren hücreleri saymak için COUNT işlevi, boş olmayan hücreleri saymak için COUNTA, hücreleri koşullu olarak saymak için COUNTIF ve COUNTIFS ve bir metin dizesinin uzunluğunu hesaplamak için LEN.

Ne yazık ki, Excel kelime sayısını saymak için herhangi bir yerleşik araç sağlamaz. Neyse ki, serval fonksiyonları birleştirerek neredeyse her görevi yerine getirmek için daha karmaşık formüller oluşturabilirsiniz. Ve Excel'de kelimeleri saymak için bu yaklaşımı kullanacağız.

    Bir hücredeki toplam sözcük sayısı nasıl sayılır

    Bir hücredeki sözcükleri saymak için LEN, SUBSTITUTE ve TRIM işlevlerinin aşağıdaki kombinasyonunu kullanın:

    LEN(TRIM( hücre ))-LEN(SUBSTITUTE( hücre ," ",""))+1

    Nerede hücre kelimeleri saymak istediğiniz hücrenin adresidir.

    Örneğin, A2 hücresindeki sözcükleri saymak için şu formülü kullanın:

    =LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1

    Ardından, A sütununun diğer hücrelerindeki sözcükleri saymak için formülü aşağıya kopyalayabilirsiniz:

    Bu kelime sayma formülü nasıl çalışır?

    İlk olarak, SUBSTITUTE işlevini kullanarak hücredeki tüm boşlukları kaldırır ve bunları boş bir metin dizesiyle ("") değiştirerek LEN işlevinin boşluksuz dizenin uzunluğunu döndürmesini sağlarsınız:

    LEN(SUBSTITUTE(A2," ",""))

    Bundan sonra, boşluksuz dize uzunluğunu dizenin toplam uzunluğundan çıkarırsınız ve son sözcük sayısına 1 eklersiniz, çünkü bir hücredeki sözcük sayısı boşluk sayısı artı 1'e eşittir.

    Ayrıca, varsa hücredeki fazladan boşlukları ortadan kaldırmak için TRIM işlevini kullanırsınız. Bazen bir çalışma sayfası çok sayıda görünmez boşluk içerebilir, örneğin sözcükler arasında iki veya daha fazla boşluk veya metnin başına veya sonuna yanlışlıkla yazılan boşluk karakterleri (yani baştaki ve sondaki boşluklar). Ve tüm bu fazladan boşluklar sözcük sayınızı bozabilir. Buna karşı korunmak için, önceDizenin toplam uzunluğunu hesaplarken, kelimeler arasındaki tek boşluklar hariç tüm fazla boşlukları kaldırmak için TRIM işlevini kullanırız.

    Boş hücreleri düzgün şekilde işleyen geliştirilmiş formül

    Excel'de kelimeleri saymak için yukarıdaki formül, bir dezavantajı olmasa mükemmel olarak adlandırılabilirdi - boş hücreler için 1 döndürür. Bunu düzeltmek için, boş hücreleri kontrol etmek üzere bir EĞER deyimi ekleyebilirsiniz:

    =IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)

    Yukarıdaki ekran görüntüsünde görebileceğiniz gibi, formül boş hücreler için sıfır ve boş olmayan hücreler için doğru sözcük sayısını döndürür.

    Bir hücredeki belirli kelimeler nasıl sayılır

    Belirli bir sözcüğün, metnin veya alt dizenin bir hücrede kaç kez göründüğünü saymak için aşağıdaki formülü kullanın:

    =(LEN( hücre )-LEN(SUBSTITUTE( hücre , kelime ,""))/LEN( kelime )

    Örneğin, " ay " ifadesinin A2 hücresinde geçtiği yerler:

    =(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")

    Sayılacak sözcüğü doğrudan formüle girmek yerine, bir hücreye yazabilir ve formülünüzde bu hücreye başvurabilirsiniz. Sonuç olarak, Excel'de sözcükleri saymak için daha çok yönlü bir formül elde edersiniz.

    İpucu Formülünüzü birden fazla hücreye kopyalamayı planlıyorsanız, sayılacak sözcüğü içeren hücreye yapılan başvuruyu $ işaretiyle sabitlediğinizden emin olun:

    =(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)

    Bu formül bir hücredeki belirli bir metnin oluşumlarını nasıl sayar?

    1. SUBSTITUTE işlevi, belirtilen sözcüğü orijinal metinden kaldırır.

    Bu örnekte, A2'de bulunan orijinal metinden B1 hücresindeki girdi kelimesini kaldırıyoruz:

    SUBSTITUTE(A2, $B$1,"")

  • Ardından, LEN işlevi belirtilen sözcük olmadan metin dizesinin uzunluğunu hesaplar.

    • Bu örnekte, LEN(SUBSTITUTE(A2, $B$1,"")) sözcüğünün tüm geçtiği yerlerde bulunan tüm karakterler çıkarıldıktan sonra A2 hücresindeki metnin uzunluğunu döndürür. ay ".

  • Bundan sonra, yukarıdaki sayı orijinal metin dizesinin toplam uzunluğundan çıkarılır:

    • (LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))

    Bu işlemin sonucu, hedef sözcüğün tüm oluşumlarında bulunan karakter sayısıdır ve bu örnekte 12'dir (sözcüğün 3 oluşumu " ay ", her biri 4 karakter).

  • Son olarak, yukarıdaki sayı kelimenin uzunluğuna bölünür. Başka bir deyişle, hedef kelimenin tüm oluşumlarında bulunan karakter sayısını, o kelimenin tek bir oluşumunda bulunan karakter sayısına bölersiniz. Bu örnekte, 12 4'e bölünür ve sonuç olarak 3 elde ederiz.

    • Bir hücredeki belirli kelimelerin sayısını saymanın yanı sıra, bu formülü herhangi bir metnin geçtiği yerler (alt dize). Örneğin, metnin kaç kez " seç " ifadesi A2 hücresinde görünür:

    Bir hücredeki belirli kelimeleri saymak için büyük/küçük harfe duyarlı formül

    Muhtemelen bildiğiniz gibi, Excel SUBSTITUTE büyük/küçük harfe duyarlı bir işlevdir ve bu nedenle SUBSTITUTE'a dayalı kelime sayma formülü varsayılan olarak büyük/küçük harfe duyarlıdır:

    Bir hücredeki belirli kelimeleri saymak için büyük/küçük harfe duyarlı olmayan formül

    Belirli bir sözcüğün hem büyük hem de küçük harfli oluşumlarını saymanız gerekiyorsa, orijinal metni ve saymak istediğiniz metni aynı büyük/küçük harfe dönüştürmek için SUBSTITUTE içindeki UPPER veya LOWER işlevini kullanın.

    =(LEN( hücre )-LEN(SUBSTITUTE(UPPER( hücre ),ÜST( Metin ),""))/LEN( Metin )

    Ya da

    =(LEN( hücre )-LEN(SUBSTITUTE(LOWER( hücre ),ALT( Metin ),""))/LEN( Metin )

    Örneğin, B1'deki sözcüğün A2 hücresinde büyük/küçük harf göz ardı edilerek geçme sayısını saymak için şu formülü kullanın:

    =(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),""))/LEN($B$1)

    Aşağıdaki ekran görüntüsünde gösterildiği gibi, formül, sözcüğün BÜYÜK HARF (B1 hücresi), küçük harf (D1 hücresi) veya Cümle harfi (C1 hücresi) ile yazılmış olmasına bakılmaksızın aynı sözcük sayısını döndürür:

    Bir aralıktaki toplam sözcük sayısını sayma

    Belirli bir aralığın kaç kelime içerdiğini bulmak için, bir hücredeki toplam kelimeleri sayan formülü alın ve bunu SUMPRODUCT veya SUM işlevine yerleştirin:

    =SUMPRODUCT(LEN(TRIM( aralık ))-LEN(SUBSTITUTE( aralık ," ",""))+1)

    Ya da

    =SUM(LEN(TRIM( aralık ))-LEN(SUBSTITUTE( aralık ," ",""))+1)

    SUMPRODUCT, dizileri işleyebilen birkaç Excel işlevinden biridir ve formülü her zamanki gibi Enter tuşuna basarak tamamlarsınız.

    SUM işlevinin dizileri hesaplayabilmesi için, normal Enter vuruşu yerine Ctrl+Shift+Enter tuşlarına basılarak tamamlanan bir dizi formülünde kullanılması gerekir.

    Örneğin, A2:A4 aralığındaki tüm sözcükleri saymak için aşağıdaki formüllerden birini kullanın:

    =SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

    =TOPLAM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

    Bir aralıktaki belirli kelimeleri sayma

    Belirli bir sözcüğün veya metnin bir hücre aralığında kaç kez göründüğünü saymak istiyorsanız, benzer bir yaklaşım kullanın - bir hücredeki belirli sözcükleri saymak için formülü alın ve bunu SUM veya SUMPRODUCT işleviyle birleştirin:

    =SUMPRODUCT((LEN( aralık )-LEN(SUBSTITUTE( aralık , kelime ,""))/LEN( kelime ))

    Ya da

    =TOPLA((LEN( aralık )-LEN(SUBSTITUTE( aralık , kelime ,""))/LEN( kelime ))

    Dizi TOPLA formülünü doğru şekilde tamamlamak için lütfen Ctrl+Shift+Enter tuşlarına basmayı unutmayın.

    Örneğin, C1 hücresine girilen sözcüğün A2:A4 aralığındaki tüm oluşumlarını saymak için şu formülü kullanın:

    =SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))

    Hatırlayacağınız gibi, SUBSTITUTE bir büyük/küçük harfe duyarlı işlevini kullanır ve bu nedenle yukarıdaki formül büyük ve küçük harfli metin arasında ayrım yapar:

    Formülü oluşturmak için büyük/küçük harf duyarsız , UPPER veya LOWER fonksiyonlarından birini kullanın:

    =SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),""))/LEN(C1))

    Ya da

    =SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),""))/LEN(C1))

    Excel'de kelimeleri bu şekilde sayabilirsiniz. Formülleri daha iyi anlamak ve muhtemelen tersine mühendislik yapmak için örnek Excel Kelime Sayma çalışma kitabını indirebilirsiniz.

    Bu eğitimde tartışılan formüllerden hiçbiri görevinizi çözmediyse, lütfen Excel'deki hücreleri, metinleri ve tek tek karakterleri saymak için diğer çözümleri gösteren aşağıdaki kaynak listesine göz atın.

    Önceki yazı Eşleşmeler ve farklılıklar için iki Google sayfasındaki veya sütunundaki verileri karşılaştırın
    Sonraki Gönderi Excel'de hücreleri kilitleme ve korumalı bir sayfadaki belirli hücrelerin kilidini açma

    Michael Brown, yazılım araçlarını kullanarak karmaşık süreçleri basitleştirme tutkusuna sahip, kendini adamış bir teknoloji meraklısıdır. Teknoloji endüstrisinde on yılı aşkın deneyimiyle Microsoft Excel ve Outlook'un yanı sıra Google E-Tablolar ve Dokümanlar'daki becerilerini geliştirdi. Michael'ın blogu, bilgisini ve uzmanlığını başkalarıyla paylaşmaya, üretkenliği ve verimliliği artırmaya yönelik takip etmesi kolay ipuçları ve eğitimler sağlamaya adamıştır. İster deneyimli bir profesyonel, ister yeni başlayan olun, Michael'ın blogu, bu temel yazılım araçlarından en iyi şekilde yararlanmak için değerli bilgiler ve pratik tavsiyeler sunar.