Ipinapaliwanag ng tutorial kung paano gamitin ang COUNTIF at COUNTIFS function ng Excel upang mabilang ang mga cell na may maraming OR kundisyon, hal. kung ang isang cell ay naglalaman ng X, Y o Z.

Tulad ng alam ng lahat, ang Excel COUNTIF function ay idinisenyo upang magbilang ng mga cell batay lamang sa isang criterion habang sinusuri ng COUNTIFS ang maraming pamantayan gamit ang AND logic. Ngunit paano kung ang iyong gawain ay nangangailangan ng OR logic - kapag maraming kundisyon ang ibinigay, sinuman ang maaaring tumugma upang maisama sa bilang?

May ilang posibleng solusyon sa gawaing ito, at ang tutorial na ito ay sasakupin ang lahat ng ito sa buong detalye. Ang mga halimbawa ay nagpapahiwatig na mayroon kang mahusay na kaalaman sa syntax at pangkalahatang paggamit ng parehong mga function. Kung hindi, maaaring gusto mong magsimula sa pagbabago ng mga pangunahing kaalaman:

Excel COUNTIF function - binibilang ang mga cell na may isang pamantayan.

Excel COUNTIFS function - binibilang ang mga cell na may maramihang AT pamantayan.

Ngayong lahat ay nasa parehong pahina, sumisid tayo sa:

Bilangin ang mga cell na may OR kundisyon sa Excel

Sinasaklaw ng seksyong ito ang pinakasimpleng senaryo - pagbibilang ng mga cell na matugunan ang alinman (kahit isa) sa mga tinukoy na kundisyon.

Formula 1. COUNTIF + COUNTIF

Ang pinakamadaling paraan upang mabilang ang mga cell na may isang value o iba pa (Countif a o b ) ay sumulat ng isang regular na formula ng COUNTIF upang mabilang ang bawat item nang paisa-isa, at pagkatapos ay idagdag ang mga resulta:

Bilang isanghalimbawa, alamin natin kung gaano karaming mga cell sa column A ang naglalaman ng alinman sa "mansanas" o "saging":

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

Sa totoong buhay na mga worksheet, isang magandang kasanayan na magpatakbo sa mga hanay sa halip kaysa sa buong column para gumana nang mas mabilis ang formula. Upang maiwasan ang problema sa pag-update ng iyong formula sa tuwing nagbabago ang mga kundisyon, i-type ang mga item ng interes sa paunang natukoy na mga cell, sabihin ang F1 at G1, at i-reference ang mga cell na iyon. Halimbawa:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Ang diskarteng ito ay gumagana nang maayos para sa ilang pamantayan, ngunit ang pagdaragdag ng tatlo o higit pang mga function ng COUNTIF nang magkasama ay gagawing masyadong mahirap ang formula. Sa kasong ito, mas mabuting manatili ka sa isa sa mga sumusunod na alternatibo.

Formula 2. COUNTIF na may array constant

Narito ang isang mas compact na bersyon ng SUMIF na may OR condition formula sa Excel:

Ang formula ay ginawa sa ganitong paraan:

Una, i-package mo ang lahat ng kundisyon sa array constant - mga indibidwal na item na pinaghihiwalay ng mga kuwit at ang array na nakapaloob sa mga kulot na brace tulad ng {"apples", "bananas', "lemons"}.

Pagkatapos, isasama mo ang array constant sa criteria argument ng isang normal na COUNTIF formula: COUNTIF(A2:A10, {"apples","bananas","lemon"})

Sa wakas, i-warp ang COUNTIF formula sa SUM function. Ito ay kinakailangan dahil magbabalik ang COUNTIF ng 3 indibidwal na bilang para sa "mansanas", "saging" at"lemon", at kailangan mong idagdag ang mga bilang na iyon nang magkasama.

Ang aming kumpletong formula ay sumusunod:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

Kung ikaw Mas gugustuhin mong ibigay ang iyong pamantayan bilang mga sanggunian sa hanay , kakailanganin mong ilagay ang formula gamit ang Ctrl + Shift + Enter upang gawin itong array formula. Halimbawa:

=SUM(COUNTIF(A2:A10,F1:H1))

Pakipansin ang mga kulot na brace sa screenshot sa ibaba - ito ang pinaka-malinaw na indikasyon ng array formula sa Excel:

Formula 3. SUMPRODUCT

Ang isa pang paraan upang mabilang ang mga cell na may OR logic sa Excel ay ang paggamit ng SUMPRODUCT function sa ganitong paraan:

Upang mas mailarawan ang logic, maaari rin itong isulat bilang:

Sinusubukan ng formula ang bawat cell sa range laban sa bawat criterion at nagbabalik ng TAMA kung ang criterion ay natugunan, MALI kung hindi. Bilang isang intermediate na resulta, makakakuha ka ng ilang array ng TRUE at FALSE value (ang bilang ng array ay katumbas ng bilang ng iyong pamantayan). Pagkatapos, ang mga elemento ng array sa parehong posisyon ay idinagdag nang magkasama, ibig sabihin, ang mga unang elemento sa lahat ng mga array, ang pangalawang elemento, at iba pa. Ang pagpapatakbo ng karagdagan ay nagko-convert ng mga lohikal na halaga sa mga numero, kaya napupunta ka sa isang hanay ng 1 (isa sa mga pamantayang tumutugma) at 0 (wala sa mga pamantayan ang tumutugma). Dahil lahat ng pamantayan aynasubok laban sa parehong mga cell, walang paraan na maaaring lumitaw ang anumang iba pang numero sa resultang array - isang paunang array lamang ang maaaring magkaroon ng TRUE sa isang partikular na posisyon, ang iba ay magkakaroon ng FALSE. Panghuli, idinaragdag ng SUMPRODUCT ang mga elemento ng nagreresultang array, at makukuha mo ang gustong bilang.

Ang unang formula ay gumagana sa katulad na paraan, na may pagkakaiba na nagbabalik ito ng isang 2-dimentional na hanay ng TRUE at FALSE value , na iyong i-multiply sa 1 upang i-convert ang mga lohikal na halaga sa 1 at 0, ayon sa pagkakabanggit.

Inilapat sa aming sample na set ng data, ang mga formula ay may sumusunod na hugis:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

O

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Palitan ang hardcoded array constant ng isang range reference, at makakakuha ka ng mas eleganteng solusyon:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Tandaan. Ang function ng SUMPRODUCT ay mas mabagal kaysa sa COUNTIF, kaya naman ang formula na ito ay pinakamahusay na gamitin sa medyo maliit na set ng data.

Bilangin ang mga cell na may OR pati na rin ang AND logic

Kapag nagtatrabaho sa malaking data mga set na mayroong multi-level at cross-level na mga ugnayan sa pagitan ng mga elemento, malamang na kakailanganin mong magbilang ng mga cell na may mga kundisyon ng OR at AT nang sabay-sabay.

Bilang halimbawa, kumuha tayo ng bilang ng "mansanas" , "saging" at "lemon" na "delivery". Paano natin gagawin iyon? Bilang panimula, isalin natin ang ating mga kundisyon sa wika ng Excel:

• Column A: "mansanas" o "saging" o "lemon"
• Column C: "delivered"

Naghahanap mula saisa pang anggulo, kailangan nating magbilang ng mga row na may "mga mansanas at inihatid" O "saging at inihatid" O "mga limon at inihatid". Sa ganitong paraan, ang gawain ay bumababa sa pagbibilang ng mga cell na may 3 O kundisyon - kung ano mismo ang ginawa namin sa nakaraang seksyon! Ang pagkakaiba lang ay gagamitin mo ang COUNTIFS sa halip na COUNTIF upang suriin ang AND criterion sa loob ng bawat OR na kundisyon.

Formula 1. COUNTIFS + COUNTIFS

Ito ang pinakamahabang formula, na siyang pinakamadaling isulat :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Ang screenshot sa ibaba ay nagpapakita ng parehong formula na may mga cell reference:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formula 2. COUNTIFS na may array constant

Maaaring gumawa ng mas compact na COUNTIFS formula na may AND/OR logic sa pamamagitan ng packaging O pamantayan sa array constant:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

Kapag gamit ang isang saklaw na reference para sa pamantayan, kailangan mo ng array formula, na kinumpleto sa pamamagitan ng pagpindot sa Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Tip. Kung kinakailangan, malaya kang gumamit ng mga wildcard sa pamantayan ng anumang mga formula na tinalakay sa itaas. Halimbawa, para mabilang ang lahat ng uri ng saging gaya ng "green bananas" o "goldfinger bananas" maaari mong gamitin ang formula na ito:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Sa katulad na paraan, maaari kang bumuo ng formula para magbilang ng mga cell batay sa iba pang uri ng pamantayan. Halimbawa, para makakuha ng bilang ng "mansanas" o "saging" o "lemon" na "naihatid" at ang halaga ay higit sa 200, magdagdag ng isa pang pamantayang hanay/pares ng pamantayan saCOUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

O, gamitin ang array formula na ito (inilagay sa pamamagitan ng Ctrl + Shift + Enter ):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Bilangin ang mga cell na may maraming kundisyon ng OR

Sa nakaraang halimbawa, natutunan mo kung paano subukan ang isang hanay ng mga kundisyon ng OR. Ngunit paano kung mayroon kang dalawa o higit pang mga set at naghahanap ka upang makakuha ng kabuuan ng lahat ng posibleng OR na relasyon?

Depende sa kung gaano karaming mga kundisyon ang kailangan mong hawakan, maaari mong gamitin ang alinman sa COUNTIFS na may array constant o SUMPRODUCT may ISNUMBER MATCH. Ang dating ay medyo madaling itayo, ngunit ito ay limitado lamang sa 2 set ng OR kundisyon. Maaaring suriin ng huli ang anumang bilang ng mga kundisyon (siyempre, isang makatwirang numero, dahil sa limitasyon ng Excel sa 255 argumento at 8192 character sa kabuuang haba ng formula), ngunit maaaring tumagal ng ilang pagsisikap upang maunawaan ang lohika ng formula.

Bilangin ang mga cell na may 2 set ng mga kundisyon ng OR

Kapag nakikitungo lamang sa dalawang hanay ng OR na pamantayan, magdagdag lamang ng isa pang array constant sa COUNTIFS formula na tinalakay sa itaas.

Para gumana ang formula, isa minuto ngunit kailangan ang kritikal na pagbabago: gumamit ng horizontal array (mga elementong pinaghihiwalay ng kuwit) para sa isang set ng pamantayan at vertical array (mga elementong pinaghihiwalay ng semicolon) para sa isa pa. Sinasabi nito sa Excel na "ipares" o "cross-calculate" ang mga elemento sa dalawang array, at magbalik ng two-dimensional array ng mga resulta.

Bilang halimbawa, bilangin natin ang "mansanas", "saging" o"lemon" na maaaring "delivered" o "in transit":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Pakitandaan ang semicolon sa pangalawang array constant:

Dahil ang Excel ay isang 2-dimentional na program, hindi posible na bumuo ng 3-dimentional o 4-dimentuional array, at samakatuwid ang formula na ito ay gumagana lamang para sa dalawang set ng OR na pamantayan. Upang mabilang na may higit pang pamantayan, kailangan mong lumipat sa isang mas kumplikadong formula ng SUMPRODUCT na ipinaliwanag sa susunod na halimbawa.

Bilangin ang mga cell na may maraming hanay ng O kundisyon

Upang bilangin ang mga cell na may higit sa dalawa hanay ng OR pamantayan, gamitin ang function na SUMPRODUCT kasama ng ISNUMBER MATCH.

Halimbawa, kumuha tayo ng bilang ng "mansanas", "saging" o "lemon" na maaaring "inihatid" o "intransit" at nakabalot sa alinman sa "bag" o "tray":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"bag","tray"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","in transit"},0)))

Sa gitna ng formula, sinusuri ng MATCH function ang pamantayan sa pamamagitan ng paghahambing ng bawat cell sa tinukoy na hanay na may kaukulang array constant. Kung ang tugma ay natagpuan, ito ay nagbabalik ng isang kaugnay na posisyon ng halaga kung ang array, N/A kung hindi. Kino-convert ng ISNUMBER ang mga value na ito sa TRUE at FALSE, na katumbas ng 1 at 0, ayon sa pagkakabanggit. Kinukuha ito ng SUMPRODUCT mula doon, at pinaparami ang mga elemento ng arrays. Dahil ang pag-multiply sa zero ay nagbibigay ng zero, tanging ang mga cell na may 1 sa lahat ng mga array ay mabubuhay atsummed.

Ipinapakita ng screenshot sa ibaba ang resulta:

Ganito mo ginagamit ang COUNTIF at COUNTIFS function sa Excel upang mabilang ang mga cell na may maramihang AT bilang pati na rin ang O kundisyon. Upang mas masusing tingnan ang mga formula na tinalakay sa tutorial na ito, malugod kang i-download ang aming sample na workbook sa ibaba. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Practice workbook

Excel COUNTIF na may OR kundisyon - mga halimbawa (.xlsx file)