Ang ibig sabihin ng "Concatenate" ay karaniwang pag-uugnay ng isang bagay sa isang serye o isang chain. Ginagamit ang operasyong ito sa tuwing kailangan mong sumali sa text mula sa maraming Google Sheets cell. Kinokolekta ng artikulong ito ang pinakasikat at pinakamadaling solusyon upang matulungan kang malutas ang concatenation puzzle.

Gaano man kalaki ang iyong dataset, maaari mong makita ang gawain ng pagsasama-sama ng maraming cell sa Google Sheets. At walang pag-aalinlangan na gugustuhin mong hindi lang mawala ang lahat ng value, ngunit magdagdag din ng ilang kuwit, espasyo, o iba pang character, o kahit na paghiwalayin ang mga record na iyon sa ibang text.

Buweno, nag-aalok ang mga spreadsheet ng ilang tool para sa gawaing ito.

Google Sheets CONCAT function

Ang CONCAT function ay isang pinasimpleng bersyon ng Google Sheets CONCATENATE:

Upang pagsamahin ang mga cell gamit ang function na ito, kailangan mong ilista ang mga kinakailangang value:

• value1 – isang talaan kung saan dapat idagdag ang value2.
• value2 – ang value na sasalihan.

Upang makakuha ng isang string mula sa 2 text o numeric na unit, magiging ganito ang formula sa ibaba, na ang bawat record ay nasa double-quotes:

=CONCAT("2019:","The Lion King")

Sa totoo lang, malamang na nasa mga cell na ang iyong data. Maaari kang direktang sumangguni sa mga cell na iyon sa halip na ilagay ang bawat numero o teksto bilang argumento. Kaya ang formula ng real-data ay magiging ganito:

=CONCAT(A2,B2)

Tip. Upang kopyahin ang iyong formula sa buong column, piliin ang cellgamit ang formula at i-double click ang maliit na parisukat sa kanang sulok sa ibaba ng cell. Ang buong column ay awtomatikong mapupuno ng formula, hanggang sa pinakadulo ng talahanayan.

Tulad ng nakikita mo, ang function ay sobrang simple, ngunit mayroon itong mga pangunahing mahina na puntos :

• nagsasama-sama lamang ito ng dalawang cell sa Google Sheets nang sabay-sabay.
• hindi nito maaaring pagsamahin ang mga column, row, o iba pang malalaking hanay ng data, iisang cell lang ang kailangan nito. Kung susubukan mong sumali sa maraming cell, magkakaroon ka ng error o ang unang dalawang value lang ang isasama, tulad nito:

  =CONCAT(A2:A11,B2:B11)

  

Halili ng CONCAT: concatenation operator ampersand (&)

Maraming iba't ibang operator para sa iba't ibang layunin sa mga formula. Ang pagsasama ay hindi isang pagbubukod. Ang paggamit ng isang ampersand character (&) sa mga formula sa halip na ang CONCAT function ay magbibigay sa iyo ng parehong resulta:

=A2&B2

Ngunit kakaunti ang alam mo na ang concatenation operator na ito ay mas flexible. Narito kung ano ang magagawa nito:

1. Pagsamahin ang higit sa dalawang value sa isang pagkakataon:

   =A2&B2&C2

   

2. Hindi lang pagsamahin ang mga cell sa Google Sheets, ngunit paghiwalayin din ang mga ito gamit ang iba't ibang character:

   =A2&" "&B2&"; "&C2

   

Kung hindi mo pa rin makuha ang ninanais na resulta sa mga opsyong ito , may isa pang function na susubukan.

Paano gamitin ang CONCATENATE sa Google Sheets

Naniniwala ako na ang Google Sheets CONCATENATE function ang unang gagamitpagdating sa pagsasama-sama ng ilang talaan.

Pagsama-samahin ang mga string ng teksto at numero sa Google Sheets

Ang pattern ng formula ay binubuo ng mga sumusunod na argumento:

• string1 ang unang string na gusto mong dugtungan ng iba pang value. Kinakailangan ang argumentong ito.
• string2, … ay nangangahulugang lahat ng iba pang mga string na maaaring gusto mong idugtong. Opsyonal ang argumentong ito.

Tandaan. Ang talaan ng resulta ay binubuo ng mga string sa pagkakasunud-sunod ng kanilang hitsura sa formula.

Kung iaangkop ko ang formula sa aking data, makukuha ko ito:

=CONCATENATE(A2,B2,C2)

O, dahil tumatanggap ang function ng mga saklaw:

=CONCATENATE(A2:D2)

Maaari mong mapansin kaagad ang unang bentahe ng Google Sheets CONCATENATE: madali itong sumasali sa dalawang cell na may parehong text at numero.

Google Sheets: pagdugtungin ang mga string sa mga separator

Ang pagsasama-sama ng mga cell sa Google Sheets ay kalahati ng gawain. Ngunit para maging maganda at nababasa ang resulta, dapat kang magdagdag ng ilang dagdag na mga character.

Kung pananatilihin mo ang formula, pagsasama-samahin lang nito ang lahat: BonnieJacksonCA , BonnieJacksonIN , atbp. Ngunit ginagamit din ng Google Sheets CONCATENATE ang mga character bilang mga argumento.

Kaya, upang magdagdag ng ilang separator para madaling mabasa, banggitin ang mga ito sa double-quotes sa formula:

=CONCATENATE(A2," ",B2,", ",C2)

Dito gusto kong pagsamahin ang A2 & B2 na may espasyo at hiwalay ang B2 sa C2 na may kuwit atspace:

Malaya kang gumamit ng halos anumang character sa function na tulad nito, ngunit nangangailangan ng ibang diskarte ang isang line break.

Tip. Kung sakaling may mga walang laman na cell sa ilan sa mga column na pinagsasama-sama mo, may isa pang function na maaaring interesado ka. TEXTJOIN hindi lang nagsasama ng mga cell sa Google Sheets ngunit binabalewala ang mga blangko:

=TEXTJOIN(" ",TRUE,A2:C2)

Narito kung paano ito gumagana:

1. Isaad ang gustong delimiter bilang unang argumento – space (" ") para sa akin.
2. Ilagay ang TRUE bilang pangalawang argumento para laktawan ang mga blangkong cell o FALSE para isama ang mga ito sa resulta.
3. Ipasok ang hanay na isasama.

Pagdugtungin ang line break sa Google Sheets

Bagama't malinaw kung paano ilagay ang karamihan sa mga delimiter sa function, hindi ka maaaring mag-type ng line break sa parehong paraan doon. Ngunit sa kabutihang palad, hinahayaan ka ng Google na maglaro ng maraming iba't ibang card.

May isang function na tumutulong upang makakuha ng mga espesyal na character – tinatawag itong CHAR. Tingnan mo, ang bawat character ay may lugar sa Unicode table. Kailangan mo lang i-feed ang ordinal number ng character mula sa table na iyon sa function at ibabalik ng huli ang character mismo.

Narito ang isang formula para makuha ang line break:

=CHAR(10)

Idagdag ito sa formula na isasama sa line break sa Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Pagsamahin ang petsa at oras sa Google Sheets

Kung susubukan mong pagsamahin ang petsa at oras sa Google Sheets gamit ang isa sa mga pamamaraansa itaas, hindi ito gagana. Ang iyong spreadsheet ay magbabalik ng mga numero:

Upang pagsamahin nang tama ang petsa at oras sa Google Sheets, gamitin ang TEXT function:

• kung saan ang numero ay anumang numero, petsa, o oras na gusto mong makuha sa gustong format
• at format ang pattern na gusto mong makuha makita bilang resulta.

Tip. Sa aking halimbawa, ire-refer ko ang mga cell na may mga petsa at oras, ngunit malaya kang gumamit ng mga yunit ng petsa/oras o kahit na mga function tulad ng DATE o TIME nang direkta sa formula.

1. Ginagamit ko ang unang formula ng TEXT para baguhin ang format ng petsa mula 7/9/2019 hanggang 9 Hul 2019 :

   =TEXT(B2,"D MMM YYYY")

2. Ibinabalik ng pangalawang TEXT ang oras:

   =TEXT(C2,"HH:MM:SS")

3. Gamit ang mga ito sa CONCATENATE, hinahayaan ako ng Google Sheets na pagsamahin ang petsa at oras sa gustong format sa iba pang mga character o text:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Pagsamahin ang mga column sa Google Sheets

Na may kaunting pagsasaayos, lahat ng paraan na nabanggit ko ay may kakayahang pagsamahin ang mga column sa Google Sheets.

Halimbawa 1. Google Sheets CONCAT

Upang pagsamahin ang buong column sa Google Sheets sa CONCAT, piliin ang buong hanay na dapat maglaman ng resulta (C2:C11 sa aking kaso) at ilagay ang iyong formula wrapping ito sa ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Tandaan. Maaari mong gamitin ang function na CONCATENATE, ngunit isasama nito ang lahat ng mga tala sa loob ng isang cell dahil madali itong pinagsama ang maraming mga cell at hanay ng data.

Halimbawa 2.Concatenation operator

Gumawa ng mga array formula upang pagsamahin ang mga column sa Google Sheets gamit ang ampersand at magdagdag ng mga separator nang sabay-sabay:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Mukhang maganda ito, ngunit kailangan kong ituro ang ilang mga pangunahing kawalan.

Kung mayroon kang masyadong maraming mga column, ang pag-enumerate sa mga ito ay maaaring maging sakit sa leeg, lalo na kung hindi mo sinasadyang malaktawan/na-duplicate/maghalo ng anumang mga character .

Gayundin, kung magpasya kang magdagdag ng higit pang mga column sa formula sa ibang pagkakataon, kakailanganin mong i-edit nang manu-mano ang bawat umiiral na hanay sa formula.

Ang susunod na halimbawa ay malulutas ang mga problemang ito.

Halimbawa 3. Google Sheets QUERY

Ang Google Sheets QUERY function ay angkop din upang pagsamahin ang ilang column sa Google Sheets. Tingnan:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Maaaring isipin mo na ang kakaibang formula na ito ay hindi mo maiintindihan, ngunit hayaan mong ilahad ko ang lahat ng bahagi nito para sa iyo:

1. =TRANSPOSE(A2:D10) ginagawang mga column ang mga row ng data.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) ay nagsasama ng mga tala sa bawat column sa nangungunang mga cell.

   Tip. Kapag inilagay ko ang 9^9 sa formula, sinisigurado kong lahat ng row mula sa lahat ng column ay mapupunta sa unang row na parang mga header. Ito ay 9^9 dahil kasama sa expression na ito ang lahat ng posibleng mga cell sa spreadsheet (tandaan ang limitasyon para sa 10M na mga cell?) at madaling matandaan. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) kinukuha ang header row na iyon mula sa QUERY at ginagawa itong column tulad ngisa ang mayroon ako.

Narito ang mga pakinabang ng pagsasama-sama ng mga column sa Google Sheets gamit ang QUERY:

• hindi mo kailangang piliin ang buong column tulad ng ginagawa mo para sa mga array formula
• hindi mo kailangang banggitin ang bawat column sa formula maliban kung hindi katabi ang mga ito. Sa kasong ito, ganito ang magiging hitsura ng formula:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Pagdugtungin at magdagdag ng teksto ayon sa posisyon

Alam mo na na maaari kang magdagdag ng nawawalang teksto, mga numero , at mga character sa iyong mga string gamit ang CONCATENATE function.

Tip. Makakita ng higit pang mga formula tungkol diyan sa tutorial na ito.

Ngunit kung napakaraming record na sasalihan, anumang dagdag na character ay maaaring pahabain ang iyong formula nang higit pa sa kung ano ang iyong pinlano. Sa mga ganitong sitwasyon, mas mainam na pagsamahin ang mga cell sa Google Sheets kung ano ang mga ito o gumamit ng mga simpleng delimiter tulad ng space at idagdag ang text pagkatapos noon. Makakatulong sa iyo ang isang espesyal na tool namin.

Magdagdag ng text ayon sa posisyon na naglalagay ng anumang mga character at string ayon sa posisyon na iyong tinukoy, walang mga formula ang kailangan. Hayaan mong ipakita ko sa iyo kung paano ito gumagana.

Sa nakaraang halimbawa, isinama ng QUERY ang mga pangalan at numero ng telepono para sa akin. Ngunit gusto kong magdagdag ng mga pagdadaglat ng bansa: (USA/CA) bago ang mga numero ng telepono na nagsisimula sa +1 at UK bago ang +44 :

Hatiin ang mga cell sa Google Sheets

Kung pagsasama-samahin mo ang mga cell sa Google Sheets, malamang na kakailanganin mong hatiin ang mga ito pabalik sa isang punto . May tatlong paraan para gawin iyon:

1. Bumuo ng formulagamit ang Google Sheets SPLIT function.
2. Gamitin ang karaniwang spreadsheet instrument – ​​Hatiin ang text sa mga column.
3. O subukan ang pinahusay na bersyon ng built-in na tool – Hatiin ang text sa mga column para sa Google Sheets:

Hinahayaan ka nitong hatiin ang mga cell sa pamamagitan ng anumang delimiter o kahit na mga hanay ng mga separator, ituturing ang mga ito bilang isa at kasama ang mga conjunction kung kinakailangan. Nag-aalok din ito ng opsyon na hatiin ang mga cell sa Google Sheets ayon sa posisyon.

Tip. May opsyong mag-extract ng data mula sa mga cell ng Google Sheets sa halip na hatiin ang mga content.

Paano pagsamahin ang mga cell sa Google Sheets nang walang mga formula

Kung hindi bahagi ng iyong plano ang pag-master ng iba't ibang formula, gagawin mo makinabang mula sa aming add-on ng Merge Values. Mabilis na isinasama ng add-on ang mga tala sa mga row, column, o sa buong hanay ng mga cell. Ang mga pagpipilian nito ay napakalinaw, at ang kailangan mo lang gawin ay piliin ang hanay at magpasya kung ano ang magiging hitsura ng resulta.

1. Maaari mong piliing pagsamahin ang mga column sa Google Sheets — kahit na hindi katabi, paghiwalayin ang mga ito gamit ang mga kuwit at espasyo, at ilagay ang resulta sa kanan ng orihinal na mga tala:

Kung interesado ka sa tool, maaari mong tingnansa lahat ng ginagawa nito sa espesyal na page na ito o sa maikling video na tutorial na ito:

Alamin kung paano gamitin ang Combine Duplicate Rows sa video na ito :

Sana sa ngayon ay nakapagpasya ka na kung alin sa mga paraan ang pinakaangkop sa iyong kaso. Kung mayroon kang anumang iba pang mga pamamaraan na iniisip, mangyaring ibahagi sa amin sa seksyon ng mga komento sa ibaba :)