Ipinapakita ng tutorial kung paano gamitin ang IFERROR sa Excel upang mahuli ang mga error at palitan ang mga ito ng blangkong cell, isa pang value o custom na mensahe. Matututuhan mo kung paano gamitin ang function ng IFERROR sa Vlookup at Index Match, at kung paano ito maihahambing sa IF ISERROR at IFNA.

"Bigyan mo ako ng lugar para tumayo, at lilipat ko ang lupa," Minsang sinabi ni Archimedes. "Bigyan mo ako ng formula, at ibabalik ko ito ng isang error," sasabihin ng isang user ng Excel. Sa tutorial na ito, hindi namin titingnan kung paano ibabalik ang mga error sa Excel, mas gusto naming matutunan kung paano pigilan ang mga ito upang mapanatiling malinis ang iyong mga worksheet at transparent ang iyong mga formula.

Excel IFERROR function - syntax at mga pangunahing gamit

Ang IFERROR function sa Excel ay idinisenyo upang ma-trap at pamahalaan ang mga error sa mga formula at kalkulasyon. Higit na partikular, sinusuri ng IFERROR ang isang formula, at kung magsusuri ito sa isang error, magbabalik ng isa pang halaga na iyong tinukoy; kung hindi, ibinabalik ang resulta ng formula.

Ang syntax ng Excel IFERROR function ay ang sumusunod:

Where:

• Halaga (kinakailangan) - kung ano ang susuriin para sa mga error. Maaari itong maging isang formula, expression, value, o cell reference.
• Value_if_error (kinakailangan) - kung ano ang ibabalik kung may nakitang error. Maaari itong maging isang walang laman na string (blangko na cell), text message, numeric na halaga, isa pang formula o kalkulasyon.

Halimbawa, kapag hinahati ang dalawang column ng mga numero, ikawmaaaring makakuha ng iba't ibang error kung ang isa sa mga column ay naglalaman ng mga walang laman na cell, zero o text.

Upang maiwasang mangyari iyon, gamitin ang IFERROR function upang mahuli at mahawakan ang mga error sa paraang gusto mo.

Kung error, blangko ang

Magbigay ng walang laman na string (") sa argument na value_if_error upang magbalik ng blangkong cell kung may nakitang error:

=IFERROR(A2/B2, "")

Kung error, magpakita ng mensahe

Maaari mo ring ipakita ang iyong sariling mensahe sa halip na ang karaniwang notasyon ng error ng Excel:

=IFERROR(A2/B2, "Error in calculation")

5 bagay na dapat mong malaman tungkol sa Excel IFERROR function

1. Ang IFERROR function sa Excel ay humahawak sa lahat ng uri ng error kabilang ang # DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF!, at #VALUE!.
2. Depende sa mga nilalaman ng value_if_error argument, maaaring palitan ng IFERROR ang mga error ng iyong custom na text message, numero, petsa o lohikal na halaga, ang resulta ng isa pang formula, o isang walang laman na string (blank cell).
3. Kung ang value argument ay isang blangkong cell, ito ay itinuturing bilang isang walang laman na string (''') ngunit hindi isang error.
4. Ipinakilala ang IFERROR sa Excel 2007 at available sa lahat ng kasunod na bersyon ng Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021, at Excel 365.
5. Upang ma-trap ang mga error sa Excel 2003 at mga naunang bersyon, gamitin ang ISERROR function kasama ng IF, tulad ng ipinapakita sa halimbawang ito.

Mga halimbawa ng formula ng IFERROR

Ang mga sumusunod na halimbawaipakita kung paano gamitin ang IFERROR sa Excel kasama ng iba pang mga function upang makamit ang mas kumplikadong mga gawain.

Excel IFERROR na may Vlookup

Isa sa mga pinakakaraniwang gamit ng function na IFERROR ay nagsasabi sa mga user na ang value na hinahanap nila ay wala sa data set. Para dito, ibalot mo ang isang VLOOKUP formula sa IFERROR tulad nito:

Kung ang lookup value ay wala sa table na iyong hinahanap. , isang regular na formula ng Vlookup ang magbabalik ng #N/A error:

Para sa isip ng iyong mga user, balutin ang VLOOKUP sa IFERROR at magpakita ng mas nagbibigay-kaalaman at madaling gamitin mensahe:

=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")

Ipinapakita ng screenshot sa ibaba ang Iferror formula na ito sa Excel:

Kung #N lang ang gusto mong ma-trap /A error pero hindi lahat ng error, gamitin ang IFNA function sa halip na IFERROR.

Para sa higit pang Excel IFERROR VLOOKUP na mga halimbawa ng formula, pakitingnan ang mga tutorial na ito:

• Iferror with Vlookup to trap at pangasiwaan ang mga error
• Paano makuha ang Nth paglitaw ng lookup value
• Paano makuha ang lahat ng paglitaw ng lookup value

Nested IFERROR function para gumawa ng mga sunud-sunod na Vlookup sa Excel

Sa mga sitwasyon kung kailan kailangan mong magsagawa ng maraming Vlookup batay sa kung nagtagumpay o nabigo ang nakaraang Vlookup, maaari kang maglagay ng dalawa o higit pang IFERROR gumagana sa isa't isa.

Ipagpalagay na mayroon kang ilang mga ulat sa pagbebenta mula sa mga sangay ng rehiyon ng iyongkumpanya, at gusto mong makakuha ng halaga para sa isang partikular na order ID. Sa A2 bilang lookup value sa kasalukuyang sheet, at A2:B5 bilang lookup range sa 3 lookup sheet (Ulat 1, Ulat 2 at Ulat 3), ang formula ay sumusunod:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found")))

Magiging katulad nito ang resulta:

Para sa detalyadong paliwanag ng lohika ng formula, pakitingnan ang Paano gumawa ng mga sunud-sunod na Vlookup sa Excel.

IFERROR sa mga array formula

Tulad ng malamang na alam mo, ang mga array formula sa Excel ay nilalayong magsagawa ng maraming kalkulasyon sa loob ng iisang formula. Kung magbibigay ka ng array formula o expression na nagreresulta sa array sa value argument ng IFERROR function, magbabalik ito ng array ng mga value para sa bawat cell sa tinukoy na range. Ipinapakita ng halimbawa sa ibaba ang mga detalye.

Sabihin natin, mayroon kang Kabuuan sa column B at Presyo sa column C, at gusto mong kalkulahin ang Kabuuang Dami . Magagawa ito sa pamamagitan ng paggamit ng sumusunod na array formula, na naghahati sa bawat cell sa hanay na B2:B4 ng katumbas na cell ng hanay na C2:C4, at pagkatapos ay idinaragdag ang mga resulta:

=SUM($B$2:$B$4/$C$2:$C$4)

Ang formula ay gumagana nang maayos hangga't ang hanay ng divisor ay walang mga zero o walang laman na mga cell. Kung mayroong kahit isang 0 value o blankong cell, ang #DIV/0! ibinalik ang error:

Upang ayusin ang error na iyon, gawin lang ang paghahati sa loob ng function na IFERROR:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Ano ang ginagawa ng formulaay upang hatiin ang isang halaga sa hanay B sa isang halaga sa hanay C sa bawat hilera (100/2, 200/5 at 0/0) at ibalik ang hanay ng mga resulta {50; 40; #DIV/0!}. Ang IFERROR function ay nakakakuha ng lahat ng #DIV/0! mga error at pinapalitan ang mga ito ng mga zero. At pagkatapos, ang SUM function ay nagdaragdag ng mga halaga sa nagreresultang array {50; 40; 0} at ilalabas ang huling resulta (50+40=90).

Tandaan. Mangyaring tandaan na ang mga array formula ay dapat kumpletuhin sa pamamagitan ng pagpindot sa Ctrl + Shift + Enter shortcut.

IFERROR kumpara sa IF ISERROR

Ngayong alam mo na kung gaano kadali gamitin ang function na IFERROR sa Excel, maaaring magtaka ka kung bakit may mga taong nahilig pa rin sa paggamit ng kumbinasyong IF ISERROR. Mayroon ba itong anumang mga pakinabang kumpara sa IFERROR? wala. Sa masamang lumang araw ng Excel 2003 at mas mababa kapag ang IFERROR ay hindi umiiral, KUNG ISERROR ay ang tanging posibleng paraan upang ma-trap ang mga error. Sa Excel 2007 at mas bago, ito ay medyo mas kumplikadong paraan upang makamit ang parehong resulta.

Halimbawa, upang mahuli ang mga error sa Vlookup, maaari mong gamitin ang alinman sa mga formula sa ibaba.

Sa Excel 2007 - Excel 2016:

Sa lahat ng Excel versions:

Pansinin na sa IF ISERROR VLOOKUP formula, kailangan mong mag-Vlookup nang dalawang beses. Sa simpleng English, mababasa ang formula tulad ng sumusunod: Kung ang Vlookup ay nagreresulta sa error, ibalik ang "Not found", kung hindi ay i-output ang Vlookup result.

At narito ang isang real-buhay na halimbawa ng Excel If Iserror Vlookup formula:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Not found", VLOOKUP(D2, A2:B5,2,FALSE ))

Para sa higit pang impormasyon, pakitingnan ang Paggamit ng ISERROR function sa Excel.

IFERROR vs. IFNA

Ipinakilala sa Excel 2013, ang IFNA ay isa pang function upang suriin ang isang formula para sa mga error. Ang syntax nito ay katulad ng sa IFERROR:

Sa anong paraan naiiba ang IFNA sa IFERROR? Ang IFNA function ay nakakakuha ng #N/A error lamang habang ang IFERROR ang humahawak sa lahat ng uri ng error.

Sa aling mga sitwasyon mo maaaring gusto mong gamitin ang IFNA? Kapag hindi matalinong itago ang lahat ng pagkakamali. Halimbawa, kapag nagtatrabaho sa mahalaga o sensitibong data, maaaring gusto mong maalerto tungkol sa mga posibleng pagkakamali sa iyong set ng data, at ang mga karaniwang mensahe ng error sa Excel na may simbolong "#" ay maaaring matingkad na visual indicator.

Tingnan natin kung paano ka makakagawa ng formula na nagpapakita ng mensaheng "Hindi nahanap" sa halip na ang N/A error, na lumalabas kapag ang halaga ng paghahanap ay wala sa set ng data, ngunit nagdadala ng iba pang mga error sa Excel sa iyong pansin.

Ipagpalagay na gusto mong hilahin ang Qty. mula sa lookup table hanggang sa summary table gaya ng ipinapakita sa screenshot sa ibaba. Ang paggamit ng Excel Iferror Vlookup formula ay magbubunga ng isang aesthetically pleasing na resulta, na teknikal na hindi tama dahil ang Lemons ay umiiral sa lookup table:

Upang mahuli ang # N/A ngunit ipakita ang #DIV/0 error, gamitin ang IFNA function sa Excel 2013 at Excel2016:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Not found")

O kaya, ang kumbinasyon ng IF ISNA sa Excel 2010 at mga naunang bersyon:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Not found", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

Ang syntax ng IFNA VLOOKUP at IF ISNA Ang mga formula ng VLOOKUP ay katulad ng sa IFERROR VLOOKUP at IF ISERROR VLOOKUP na tinalakay kanina.

Tulad ng ipinapakita sa screenshot sa ibaba, ang formula ng Ifna Vlookup ay nagbabalik ng "Not found" para lang sa item na wala sa lookup table ( Mga milokoton ). Para sa Lemons , ipinapakita nito ang #DIV/0! na nagpapahiwatig na ang aming lookup table ay naglalaman ng divide by zero error:

Para sa higit pang mga detalye, pakitingnan ang Paggamit ng IFNA function sa Excel.

Pinakamahuhusay na kagawian para sa paggamit ng IFERROR sa Excel

Sa ngayon ay alam mo na na ang IFERROR function ay ang pinakamadaling paraan upang mahuli ang mga error sa Excel at itago ang mga ito ng mga blangkong cell, zero value, o custom na mensahe ng iyong sarili. Gayunpaman, hindi ito nangangahulugan na dapat mong balutin ang bawat formula na may error sa paghawak. Ang mga sumusunod na simpleng rekomendasyon ay maaaring makatulong sa iyo na mapanatili ang balanse.

1. Huwag i-trap ang mga error nang walang dahilan.
2. I-wrap ang pinakamaliit na posibleng bahagi ng isang formula sa IFERROR.
3. Upang pangasiwaan ang mga partikular na error lang, gumamit ng function sa paghawak ng error na may mas maliit na saklaw:
   • IFNA o IF ISNA para mahuli lang ang mga #N/A error.
   • ISERR para mahuli ang lahat ng error maliban sa #N/A.

Ganito mo ginagamit ang function ng IFERROR sa Excel para ma-trap at mahawakan ang mga error. Upang mas masusing tingnan ang mga formula na tinalakay ditotutorial, malugod kang i-download ang aming sample na IFERROR Excel workbook. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo.