Hoewel woord- en karaktertelling in Google Sheets zelden worden gebruikt, is het toch de functionaliteit die sommigen van ons direct in het menu verwachten. Maar in tegenstelling tot Google Docs is het bij Google Sheets de LEN-functie die dat doet.

Hoewel er veel verschillende manieren zijn om tekens in spreadsheets te tellen, zal de blogpost van vandaag de LEN-functie behandelen, omdat het belangrijkste doel ervan in tabellen is om - nou ja, te tellen :) Hij wordt echter bijna nooit alleen gebruikt. Hieronder leert u hoe u Google Sheets LEN correct gebruikt en vindt u de meest gezochte formules om tekens in spreadsheets te berekenen.

Google Sheets LEN-functie - gebruik en syntaxis

Het belangrijkste en enige doel van de LEN-functie in Google Sheets is het verkrijgen van de lengte van de string. Het is zo eenvoudig dat het zelfs maar 1 argument vereist:

• het kan de tekst zelf tussen dubbele aanhalingstekens nemen:

  =LEN("Yggdrasil")

• of een verwijzing naar een cel met de gewenste tekst:

  =LEN(A2)

  Zie ook: Hoe kolomletter omzetten naar cijfer in Excel

Laten we eens kijken of er bijzonderheden zijn bij het gebruik van de functie in spreadsheets.

Karaktertelling in Google Sheets

Ik begin met de eenvoudigste operatie: een karaktertelling uitvoeren in Google Sheets op de meest gebruikelijke manier - door te verwijzen naar een cel met de tekst met behulp van de LEN-functie.

Ik voer de formule in op B2 en kopieer die over de hele kolom om de tekens in elke rij te tellen:

=LEN(A2)

Opmerking. De LEN-functie berekent alle tekens: letters, cijfers, spaties, leestekens, enz.

Je zou kunnen denken dat je op een soortgelijke manier een telling van de tekens voor het hele cellenbereik zou kunnen doen, zoals dit: LEN(A2:A6) Maar, hoe bizar het ook is, zo werkt het niet zomaar.

Om tekens in meerdere cellen bij elkaar op te tellen, moet u uw LEN omwikkelen met SUMPRODUCT - de functie die de getallen van ingevoerde bereiken bij elkaar optelt. In mijn geval wordt het bereik geretourneerd door de LEN-functie:

=SUMPRODUCT(LEN(A2:A6))

Natuurlijk zou je in plaats daarvan de SUM-functie kunnen gebruiken. Maar SUM in Google Sheets verwerkt geen arrays van andere functies. Om het te laten werken, moet je een andere functie toevoegen - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Hoe tekens zonder spaties tellen in Google Sheets

Zoals ik hierboven heb opgemerkt, telt de LEN-functie van Google Sheets elk teken dat het ziet, inclusief spaties.

Maar wat als er per ongeluk extra spaties zijn toegevoegd en u die niet in aanmerking wilt nemen voor het resultaat?

Voor dit soort gevallen is er de TRIM-functie in Google Sheets. Die controleert de tekst op spaties voor, achter en tussen. Wanneer TRIM wordt gecombineerd met LEN, telt deze laatste niet al die oneven spaties.

Hier is een voorbeeld. Ik heb spaties toegevoegd op verschillende posities in kolom A. Zoals u kunt zien, telt Google Sheets LEN ze allemaal als ze alleen zijn:

=LEN(A2)

Maar zodra u TRIM integreert, worden alle extra spaties genegeerd:

=LEN(TRIM(A2))

U kunt verder gaan en uw formule zelfs die enkele spaties tussen woorden laten negeren. De functie SUBSTITUTE helpt daarbij. Hoewel het hoofddoel ervan is het ene teken door het andere te vervangen, is er een truc om spaties volledig te elimineren:

• tekst_naar_zoeken is het bereik waarmee u werkt: kolom A, of A2 om precies te zijn.
• zoeken moet een spatie zijn tussen dubbele aanhalingstekens: " "
• vervangen door moet lege dubbele aanhalingstekens bevatten. Als je spaties gaat negeren, moet je ze vervangen door letterlijk niets (lege string): ""
• voorkomen_nummer wordt normaal gebruikt om de instantie te specificeren die moet worden vervangen. Maar aangezien ik beschrijf hoe tekens zonder alle spaties moeten worden geteld, stel ik voor dat u dit argument weglaat, aangezien het optioneel is.

Probeer deze nu allemaal samen te voegen in Google Sheets LEN en je zult zien dat er geen rekening wordt gehouden met spaties:

=LEN(SUBSTITUTE(A2, " ", ""))

Google Sheets: specifieke tekens tellen

Dezelfde tandem van Google Sheets LEN en SUBSTITUTE wordt gebruikt wanneer u specifieke tekens, letters of cijfers moet tellen.

In mijn voorbeelden ga ik het aantal keren dat de letter 's' voorkomt achterhalen. En deze keer begin ik met een kant-en-klare formule:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Laten we het in stukjes breken om te begrijpen hoe het werkt:

1. SUBSTITUTE(A2, "s", "") zoekt naar de letter 's' in A2 en vervangt alle voorkomens door "niets", of een lege tekenreeks ("").
2. LEN(SUBSTITUTE(A2, "s", "") berekent het aantal tekens behalve 's' in A2.
3. LEN(A2) telt alle tekens in A2.
4. Tenslotte trek je het ene van het andere af.

Het resultaatverschil laat zien hoeveel 's' er in de cel staan:

Opmerking. Je vraagt je misschien af waarom B1 zegt dat er maar 1 's' in A2 staat, terwijl je er 3 ziet?

Het punt is dat de SUBSTITUTE-functie hoofdlettergevoelig is. Ik vroeg het om alle gevallen van 's' in kleine letters te nemen en dat deed het.

Om het tekstgeval te laten negeren en letters in zowel kleine als hoofdletters te verwerken, moet u nog een hulpfunctie van Google Sheets aanroepen: LOWER.

Tip. Bekijk andere manieren om in Google Sheets de hoofdletter van de tekst te wijzigen.

Het is net zo eenvoudig als Google Sheets LEN en TRIM, want het enige wat nodig is, is de tekst:

=LOWER(text)

Deze truc is precies wat je nodig hebt om Google Sheets specifieke tekens te laten tellen, ongeacht hun teksthoofdletter:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Tip. En zoals eerder, om het totaal van specifieke tekens in het bereik te tellen, wikkel je LEN in SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Woorden tellen in Google Sheets

Als er meerdere woorden in cellen staan, is de kans groot dat u hun nummer nodig hebt in plaats van de lengte van de Google Sheets-tekenreeks.

En hoewel er meerdere manieren zijn om dat te doen, zal ik vandaag vermelden hoe Google Sheets LEN de klus klaart.

Herinner je je de formule die ik in Google Sheets gebruikte om specifieke tekens te tellen? In feite zal die hier ook van pas komen. Want ik ga niet letterlijk woorden tellen. In plaats daarvan zal ik het aantal spaties tussen de woorden tellen en er dan gewoon 1 bij optellen. Kijk maar eens:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) telt het aantal karakters in de cel.
2. LEN(SUBSTITUTE((A2)," ","")) verwijdert alle spaties uit de tekststring en telt de resterende karakters.
3. Dan trek je het ene van het andere af, en het verschil dat je krijgt is het aantal spaties in de cel.
4. Omdat er in een zin altijd meer woorden dan spaties zijn, voeg je 1 toe aan het eind.

Google Sheets: specifieke woorden tellen

Tot slot wil ik een Google Sheets-formule delen die je kunt gebruiken om specifieke woorden te tellen.

Hier heb ik The Mock Turtle's Song uit Alice's Adventures in Wonderland:

Ik wil weten hoe vaak het woord 'zal' voorkomt in elke rij. Ik denk dat u niet verbaasd zult zijn als ik u vertel dat de formule die ik nodig heb bestaat uit dezelfde functies als voorheen: Google Sheets LEN, SUBSTITUTE en LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

De formule ziet er misschien eng uit, maar ik kan je verzekeren dat ze gemakkelijk te begrijpen is, dus heb geduld met me :)

1. Aangezien het tekstgeval mij niet uitmaakt, gebruik ik LOWER(A2) om alles in kleine letters te veranderen.
2. Dan gaat SUBSTITUTE(LOWER(A2), "will","")) - het verwijdert alle voorkomens van 'will' door ze te vervangen door lege strings ("").
3. Daarna trek ik het aantal tekens zonder het woord 'will' af van de totale lengte van de string. Het getal dat ik krijg telt alle tekens in alle voorkomens van 'will' in elke rij.

   Dus, als 'will' één keer voorkomt, is het getal 4 omdat er 4 letters in het woord zitten. Als het twee keer voorkomt, is het getal 8, enzovoort.

4. Tenslotte deel ik dit getal door de lengte van het enkele woord "zal".

Tip. En nogmaals, als u liever het totale aantal keren dat het woord "zal" voorkomt wilt weten, sluit dan de hele formule in met SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Zoals u ziet, worden al deze gevallen van karaktertelling opgelost door dezelfde patronen van dezelfde functies voor Google Sheets: LEN, SUBSTITUTE, LOWER en SUMPRODUCT.

Als sommige formules u nog steeds verwarren, of als u niet zeker weet hoe u alles moet toepassen op uw specifieke taak, wees dan niet verlegen en vraag het hieronder in het commentaarveld!