Isi kandungan
Adakah anda tahu cara menjumlahkan nombor dalam lajur tertentu apabila nilai dalam lajur lain memenuhi mana-mana syarat yang ditentukan? Dalam artikel ini, anda akan mempelajari 3 cara berbeza untuk melakukan SUMIF menggunakan berbilang kriteria dan logik ATAU.
Microsoft Excel mempunyai fungsi khas untuk menjumlahkan sel dengan berbilang syarat - fungsi SUMIFS. Fungsi ini direka bentuk untuk berfungsi dengan logik DAN - sel ditambah hanya apabila semua kriteria yang ditentukan adalah BENAR untuk sel tersebut. Walau bagaimanapun, dalam beberapa situasi, anda mungkin perlu menjumlahkan dengan berbilang kriteria ATAU, iaitu untuk menambah sel apabila mana-mana syarat adalah BENAR. Dan inilah apabila fungsi SUMIF berguna.
SUMIF + SUMIF untuk menjumlahkan sel sama dengan ini atau itu
Apabila anda ingin menjumlahkan nombor dalam satu lajur apabila lajur lain sama dengan sama ada A atau B, penyelesaian yang paling jelas ialah mengendalikan setiap syarat secara individu, dan kemudian menambah hasilnya bersama-sama:
SUMIF(julat, kriteria1, jumlah_julat) + SUMIF(julat , kriteria2, sum_range)Dalam jadual di bawah, katakan anda ingin menambah jualan untuk dua produk berbeza, katakan Epal dan Lemon . Untuk ini, anda boleh membekalkan item yang diminati secara langsung dalam argumen kriteria bagi 2 fungsi SUMIF yang berbeza:
=SUMIF(A2:A10, "apples", B2:B10) + SUMIF(A2:A10, "lemons", B2:B10)
Atau anda boleh memasukkan kriteria dalam sel berasingan, dan rujuk sel tersebut:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
Di mana A2:A10 ialah senarai item ( julat ), B2:B10ialah nombor untuk dijumlahkan ( sum_rage ), E1 dan E2 ialah item sasaran ( kriteria ):
Cara formula ini berfungsi:
Fungsi SUMIF pertama menambah jualan Epal , SUMIF kedua menjumlahkan jualan Lemon . Operasi penambahan menambahkan sub-jumlah bersama-sama dan mengeluarkan jumlahnya.
SUMIF dengan pemalar tatasusunan - formula padat dengan berbilang kriteria
Pendekatan SUMIF + SUMIF berfungsi dengan baik untuk 2 keadaan. Jika anda perlu menjumlahkan dengan 3 atau lebih kriteria, formula akan menjadi terlalu besar dan sukar dibaca. Untuk mencapai hasil yang sama dengan formula yang lebih padat, berikan kriteria anda dalam pemalar tatasusunan:
SUM(SUMIF(julat, { crireria1, crireria2, crireria3, …}, sum_range))Sila ingat bahawa formula ini berfungsi berdasarkan logik ATAU - sel dijumlahkan apabila mana-mana syarat tunggal dipenuhi.
Dalam kes kami, untuk menjumlahkan jualan untuk 3 berbeza item, formulanya ialah:
=SUM(SUMIF(A2:A10, {"Apples","Lemons","Oranges"}, B2:B10))
Dalam tangkapan skrin di atas, syarat dikodkan keras dalam tatasusunan, bermakna anda perlu mengemas kini formula dengan setiap perubahan dalam kriteria. Untuk mengelakkan perkara ini, anda boleh memasukkan kriteria dalam sel yang dipratentukan dan membekalkan kepada formula sebagai rujukan julat (E1:E3 dalam contoh ini).
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
Dalam Excel 365 yang menyokong tatasusunan dinamik , ia berfungsi sebagai formula biasa yang dilengkapkan dengan kekunci Enter. Dalam versi pra-dinamik Excel 2019, Excel 2016, Excel2013 dan lebih awal, ia harus dimasukkan sebagai formula tatasusunan dengan pintasan Ctrl + Shift + Enter:
Cara formula ini berfungsi:
Pemalar tatasusunan yang dipalamkan ke dalam kriteria SUMIF memaksanya untuk mengembalikan berbilang hasil dalam bentuk tatasusunan. Dalam kes kami, ia adalah 3 jumlah yang berbeza: untuk Epal , Lemon dan Oren :
{425;425;565}
Untuk mendapatkan secara keseluruhan, kami menggunakan fungsi SUM dan membungkusnya dengan formula SUMIF.
SUMPRODUCT dan SUMIF untuk menjumlahkan sel dengan berbilang ATAU keadaan
Tidak suka tatasusunan dan sedang mencari formula biasa yang akan membolehkan anda menjumlahkan dengan berbilang kriteria dalam sel yang berbeza? Tiada masalah. Daripada SUM, gunakan fungsi SUMPRODUCT yang mengendalikan tatasusunan secara asli:
SUMPRODUCT(SUMIF(julat, crireria_range , sum_range))
Dengan mengandaikan keadaan berada dalam sel E1, E2 dan E3, formula mengambil bentuk ini:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
Cara formula ini berfungsi:
Suka dalam contoh sebelumnya, fungsi SUMIF mengembalikan tatasusunan nombor, mewakili jumlah untuk setiap syarat individu. SUMPRODUCT menambah nombor ini bersama-sama dan menghasilkan jumlah akhir. Tidak seperti fungsi SUM, SUMPRODUCT direka bentuk untuk memproses tatasusunan, jadi ia berfungsi sebagai formula biasa tanpa anda perlu menekan Ctrl + Shift + Enter .
SUMIF menggunakan berbilang kriteria dengan kad bebas
Sejak Fungsi SUMIF Excel menyokong kad bebas, anda bolehmasukkannya dalam berbilang kriteria jika perlu.
Sebagai contoh, untuk menjumlahkan jualan untuk semua jenis Epal dan Pisang , formulanya ialah:
=SUM(SUMIF(A2:A10, {"*Apples","*Bananas"}, B2:B10))
Jika syarat anda sepatutnya dimasukkan dalam sel individu, anda boleh menaip kad bebas terus dalam sel tersebut dan menyediakan rujukan julat sebagai kriteria untuk formula SUMPRODUCT SUMIF:
Dalam contoh ini, kami meletakkan aksara kad bebas (*) sebelum nama item untuk memadankan mana-mana jujukan aksara sebelumnya seperti Epal hijau dan Pisang Jari Emas . Untuk mendapatkan jumlah item yang mengandungi teks tertentu di mana-mana dalam sel, letakkan asterisk pada kedua-dua belah, mis. "*apple*".
Begitulah cara menggunakan SUMIF dalam Excel dengan berbilang syarat. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!
Berlatih buku kerja untuk muat turun
SUMIF berbilang kriteria (fail.xlsx)
